*hide_reuse
*temp attack_graves 0
*temp shot_lewis 0
*temp graves_offense 9
*temp friendly_approach false
*temp brody_sneak false
*temp graves_prepared false
*temp flank_south 1
*temp flank_team 1
*temp outside_camp 1
*temp ambush_graves 1
*temp flank_graves false
*temp graves_attacked_front false
*temp asked_to_scavenge false
*temp asked_about_stereo false
*temp madison_rides false
*temp saw_reilly_targeted false
*temp spotted_trap false
*temp shooter_fled false
*temp shooter_alive true
*temp shooter_surrendered false
*temp tried_door false
*temp upstairs_door false
*temp shooter_alan false
*temp offered_graves_exam false
*temp tag_arc_power_restored "Unpowered"
*temp searched_side_offices false
*temp described_shooter false
*temp talked_to_shooter false
*temp shooter_m16 false
*temp shooters_firestarter false
*temp arc_keycard false
*temp trap_armed true
*temp arc_noise false
*temp madison_bathroom false
*temp driving 1
*temp pointed_out_trap false
*temp search_shooters_nest false
*temp ghp_count 0
*temp shooter_count 0
*temp reg_manager_checked false
*temp ass_manager_checked false
*temp liason_checked false
*temp inspect_offices false
*temp alan_choice false
*temp person_on_right false
*temp examined_vent false
*temp tried_vent false
*temp inspected_camera false
*temp broke_camera false
*temp talked_laurel false
*temp laurel_escape false
*temp laurel_murphy false
*temp hacked_speakers false
*temp searched_closet false
*temp false_area false
*temp tried_to_destroy_camera false
*temp lured_murphy false
*temp protected_from_gas false
*temp murphy_unconscoius false
*temp murphy_restrained_bed false
*temp murphy_fixed_camera false
*temp delusion_chamber false
*temp ptsd_chamber false
*temp with_murphy false
*temp chat_count 0
*temp scared_murphy false
*temp examined_elevator false
*temp climbed_vent false
*temp murphy_restrained_floor false
*temp murphy_told_to_leave false
*temp listened_to_murphy false
*temp helping_ro false
*temp lied_to_rachel 0
*temp group_bonus 0
*temp target 1
*temp zombie_pile false
*temp participate true
*temp danced_with_bailey false
*temp danced_with_brody false
*temp danced_with_gina false
*temp danced_with_jaime false
*temp danced_with_jillian false
*temp danced_with_kelly false
*temp danced_with_lopez false
*temp danced_with_madison false
*temp danced_with_rachel false
*temp danced_with_reilly false
*temp danced_with_rosie false
*temp danced_with_tommy false
*temp danced_with_woody false
*set chapter_point 9
*gosub_scene Part2Events CheckAlive
*gosub_scene Part3Events CountSurvivors
*set ze_date "Tuesday, May 22, 2012"
*set ze_day 13
*if deep_sleeper
  *set timecount 0900
*if not(deep_sleeper)
  *set timecount 0700
*if not(leader)
  *set task_reinforce_gate 2
CHAPTER NINE—Allies and Enemies.

Three days later…

*if (living_quarters = "shipping_container_1_1") or (living_quarters = "shipping_container_2_1")
  Loud bangs of metal on the outside of your living quarters shock you awake. What can you expect from living in a shipping container?
*if (living_quarters = "rv_1_1") or (living_quarters = "trailer_1_1")
  Laughter and voices awaken you. As your eyes pop open, you see the blurry images of people outside the window of your living quarters. They move on quickly from the side of your ${living_quarters_desc}, but now you're awake.
*if (living_quarters = "garage_apartment_1_1") or (living_quarters = "campervan_1_1")
  The roar and sputter of an engine awakens you. As your eyes pop open, you look outside the window of the ${living_quarters_desc} which you've made into your living quarters and spot Eli working on an old Chevy engine. So much for sleeping in.
*if (living_quarters = "house_1_1") or ((living_quarters = "house_2_1") or ((living_quarters = "house_closet") or (living_quarters = "house_attic")))
  The thunder of drums and electric guitars awakens you. The walls of your living quarters shake as rock music plays through the main house of the Junkyard.
*if living_quarters = "camp_outside"
  Light blazes down through the top of your tent and awakens you. Somehow the sun didn't know you were sleeping in today. As soon as you set up, you hear the roar and sputter of an engine, loud voices, and the banging of metal on metal. Sounds like the rest of camp is awake too.

*if end_ch8_with = "Bailey"
  Somehow Bailey slept through it all. She lies next to you half naked and breathing fast in her sleep. You move a lock of hair out of her face and smiled down on her.
  *goto WakeKnit
*elseif end_ch8_with = "Brody"
  Brody stirs next you, sits up, and rubs his eyes. "Who's making all that noise?"
  
  You lean in and give him a kiss. "Don't worry about it. Just go back to sleep."
  
  He frowns. "I'm awake now. I'm going to go check on Maddie. I got yelled at twelve hours and kind of miss it."
  *goto WakeKnit
*elseif end_ch8_with = "Gina"
  Gina sits up next to you. "I've been up for a while but didn't want to wake you. " She holds a sheet against the top of her chest. When you turn to look at her, a devilish smile grows on her face. "I can almost read your thoughts, and we don't have time for what you're thinking."
  *goto WakeKnit
*elseif end_ch8_with = "Jaime"
  Jaime stirs next to you and rolls over. His muscular arm wraps around your legs, and as you go to stand, he holds you. "No, just stay here with me. Please don't get up."
  
  "Believe me, I don't want to get up, but we all have things to do."
  
  He grumbles and slides his arm back.
  *goto WakeKnit
*elseif end_ch8_with = "Jillian"
  Jillian sits up and holds her hands to the sides of her face, covering her ears and exposing her bare body. "What in God's name is making all that racket. Can't we just sleep?"
  
  "I don't know what's going on, but there's no way I'm sleeping through this."
  
  When you start to rise, her hands wrapped around your waist. "We don't have to sleep, but we can still stay here." Her hand creeps lower to your thigh. You turn to look at her, and she has a devilish grin. She raises her eyebrows suggestively.
  *fake_choice
    #I roll on top of her and enjoy some alone time with her.
      *set jillian_faction %+(round(empathy/6))
      *set stress %-(round(wil/5))
      *set timecount +50
      You turn and roll your body on top of hers. She pulls the sheet over your back and then her lips are on yours.
      
      "Well, good morning to you too," she says with a laugh.
      
      You press into her and feel the warmth of her body. Her legs wrap around you, and you run your hand along the contours of her body. She's fun and feisty and free willed, and for a short while, you appreciate every part of her. She's also a giving lover and seems to take more pleasure in your pleasure. Time moves too quickly, and when your morning fun ends, you both move apart, sweaty and breathless.
    #I lie back and cuddle with her for a while.
      *set jillian_faction %+(round(empathy/6))
      *set timecount +50
      You lie back and pull her close. She drapes one leg over you, and you rest one hand on her ample thigh, caressing her smooth skin.
      
      "Not exactly what I had in mind, but it's not half bad." Her voice quickly fades, and her breathing slows.
      
      When you look down, she's fast asleep. You stay there with her for a while, holding her in your arms as she rests through the loud noises.
    #"I'd love to stay but I have a lot to do this morning."
      "Aww, you're no fun. Okay, I will let you go," she says.
  *goto WakeKnit
*elseif end_ch8_with = "Kelly"
  Kelly yawns and sits up beside you. "I miss the peace and quiet of our old neighborhood."
  
  "It's really noisy here."
  
  She stretches and wraps her arms around you. "Good morning. At least I get to sleep next to you."
  
  "It's one definite perk—waking up next you. Unfortunately, now I have to get up and get to work." You @{aromantic slip away from her with a smile.|give her a kiss.}
  
  "Okay, I better get going too."
  *goto WakeKnit
*elseif end_ch8_with = lopez
  ${lopez} lies next to you, still asleep. How can he sleep through this? You shake your head and pull covers over his naked body.
  *goto WakeKnit
*elseif end_ch8_with = "Madison"
  You look around for Madison, but she's gone. On her pillow is a folded piece of tinfoil. Unwrapping it, you see a small square of chocolate. You smile, knowing she left it there for you.
  *goto WakeKnit
*elseif end_ch8_with = "Rachel"
  You look around for Rachel, but she's gone. It was the first night you slept together. You never thought of what happened, but she was a much more capable lover than you ever imagined. You wish she was still here but know that's not Rachel. She's the first to rise and last to sleep.
  *goto WakeKnit
*elseif end_ch8_with = "Reilly"
  Reilly stirs, sits up, and tosses a pillow at the @{(living_quarters = "camp_outside") exit flap|window}. "Shut up out there."
  
  You turn to him and pat his chest. "I guess it's time to get up. This Junkyard is better than an alarm clock."
  *goto WakeKnit
*elseif end_ch8_with = "Rosie"
  You turn to see Rosie, sitting up in bed, with a sheet wrapped around her body. "How long have you been up?"
  
  She shrugs. "Maybe an hour. Maybe two. I just wanted to watch you sleep for a while."
  
  "That's kind of creepy."
  
  She breaks out a wide smile. "Yeah, it is. I can't help it, but it's a hobby I can't often practice."
  *goto WakeKnit
*elseif end_ch8_with = "Tommy"
  Tommy shoots up in bed next to you and looks around frantically, breathing fast. "What's wrong?"
  
  "Everything's okay. We live in a very noisy Junkyard."
  
  He rubs his eyes and stands. You stare at his naked body from behind as he dresses, and when he turns, he looks at you and smiles. "What?"
  
  You shrug and smiled back at him. "Just looking at you."
  
  "I really like it when you look at me," he says and slips his shirt over his head.
  *goto WakeKnit
*elseif end_ch8_with = "Woody"
  You look around for Woody, but he's gone. A cup of lukewarm tea, a biscuit, and a melting pat of butter sit next to you on a plate. A small handwritten note lies beside it.
  
  [i]You were still asleep when I got up, and you looked too peaceful to wake. Jaime needed me to help him with something, so I had to leave. Enjoy the tea and breakfast. It was warm when I left it here. See you soon. Woodrow.[/i]
  *goto WakeKnit
*else
  *goto WakeKnit

*label WakeKnit

You rise and get dressed, ignoring the racket in the area, and when you leave your ${living_quarters_desc}, you find an envelope taped to the outside. Opening it reveals a report from Rachel on the status of the group and the Junkyard. A note on it reads, @{leader "Here's my review of our group and how we're getting along. Hope it helps.|"I thought you may like to read this. If not, feel free to toss it.} —R"
*fake_choice
  #I read it.
    *set read_report true
    First is a list of the assignments you made for each member of the group:
    
    *gosub_scene Part3GroupManage AssignedSoFar
    
    *gosub_scene Part3GroupManage ShowAssgn
  #I throw it away.
*if player_task_status = 1
  *gosub_scene Part2Events ChangeGroupFaction 2 30
*if player_task_status = 2
  *gosub_scene Part2Events ChangeGroupFaction 2 20
*gosub_scene Part2Events CountSurvivors
*gosub_scene Part3Events GroupReport
*gosub_scene Part2Events GroupOD
*gosub_scene Part2Events AdjustSkills
*page_break
*set with_gina false
*set group_offense 12
The morning in the Junkyard passes without notice, which in terms of the apocalypse is the best kind of boring anyone can imagine. Until the sun starts its pass across the middle of the sky, you don't even realize it's the afternoon. Birds fly in and out of the yard, and an animal howls in the distance. Eli made a pitcher of sweet tea, and you sit on a beach chair outside the garage with a glass, enjoying the breeze from the west. All of this creates a sense of peace, and it's interrupted by the twins.

"She said no, so what are we supposed to do?" Brody asks.

*if leader
  "She's not even leader. Let's ask ${him}," 
*if group_leader = "Rachel"
  "It doesn't matter if she's leader. She is treating is differently because we are not adults yet,"
*if group_leader = "Jaime"
  "She's not even leader. Jaime would say it's fine if he was around,"
Madison says. She and her brother walk towards the garage.

Brody @{((main_ro = "Brody") or (second_ro = "Brody")) stands next to you, leans in, and gives you a hug.|stops ahead of you and crouches.} "We have a problem, or I should say, Madison has a problem. Go figure."

Madison rolls her eyes at him. She @{((main_ro = "Madison") or (second_ro = "Madison")) squeezes in next to you on the beach chair.|stands sideways to face both you and her brother, with her hands on her hips.} "I don't have a problem. I have a solution. Brody and I were talking about the prom this year. The outbreak ruined all chances of it happening at Chipper Ridge, but we were thinking we could throw one here. I know it sounds like a silly idea in spite of everything that's happening, but it would be a real morale booster."

"I thought it was an okay idea," Brody says to his sister. He then continues. "Only half the people in our group may be into it.
*if bailey_join
  Bailey was into it, but she didn't care one way or another.
*if jillian_join
  Jillian wants to be a part of it. I was surprised by that. I wasn't even asking her, because I figured she'd just make fun of it. She said she's never been to one, and wants to see what it's all about."
  
  "I can't imagine what she's going to wear. Do they make prom dresses just below the ass?" Madison says, giggling.
  
  Brody smirks. "I don't know about that, but I don't mind if she goes.
*if tommy_join
  Tommy @{((main_ro = "Tommy") or (second_ro = "Tommy")) said he'd ask if you are going, but it sounded like he was interested.|didn't really give me an answer. If we do have it, I hope he goes. He needs to get out of his head for a few hours.}
*if rosie_join and driver_join
  I was surprised Rosie and Driver were so interested in the prom. They actually want to DJ. Now I don't even care about dancing and just want to see how they act playing music.
*if not(rosie_join) and driver_join
  Driver was interested in the prom. He actually wants to DJ. Now I don't even care about dancing and just want to see how he acts playing music.
*if rosie_join and not(driver_join)
  Rosie was interested in the prom. She actually wants to DJ. Now I don't even care about dancing and just want to see how she acts playing music.
*if parker_join
  Parker
  *if kelly_join
    thought it was a fun idea and said he can't wait to dance."
    
    "Oh my gosh, he gave us all of these ideas which basically turns it into some overblown rave. If I see one glow stick, I swear,"
  *if not(kelly_join)
    wasn't very interested. That was a surprise, until he got all upset."
  
    "He's mad that we're wasting time and not going after Kelly. Every day without her is a better day of survival in my opinion,"
  Madison says.
  
  Brody shakes his head at his sister. "Trying to be nice for five seconds." He then turns to you and says, "Anyway, let me see who else.
Kevin said he wasn't interested.
*if main_ro != "Madison"
  He kept asking if Madison is going to be there, and I thought it was high school over again.
He's definitely into it.
*if church_join
  Church said he would chaperone. Madison told him we've fought dozens of infected and don't need someone keeping us from having a good time. He just laughed and said something about dirty dancing. I don't know what he's talking about half the time.
Reilly
*if nora_join
  and Nora
didn't want to go. @{nora_join Nora|He} thought it was a good idea though and gave @{nora_join her|his} blessing, not that we asked for it."

"It will be lots of fun even if three people show up. This leads us to the problem we came to talk about. We found an old stereo system in the back of the garage that plays those big vinyl disc record things, but it doesn't work," Madison says. She @{((main_ro = "Madison") or (second_ro = "Madison")) wraps her arm around you.|puts on a huge smile.} "We want to go out and find one. Eli told us about this old train yard where he used to go to collect junk, and he said we should go there to look for one. Rachel told us we shouldn't go. She said we can't waste resources for nonessential items. If it were up to her, our only downtime would be reading survival manuals and whittling weapons."

"If it's okay with you, we can all go out there and scavenge for things we need. If we happen to see a stereo, we can take it. Even if we don't find one, I'm sure we can find lots of other good things," Brody says.

"A lot of our group are doing chores, so maybe just the three of us should go," Madison says while fixing the band on her ponytail. "Kevin said he's never gone out scavenging with us. If we need anyone else, he can go."

You reply…
*fake_choice
  #"This is your trip. You decide who goes with us. I'm just going along to check out this train yard."
    *set impulse %-15
    *set madison_faction %+(round(empathy/6))
    *set brody_faction %+(round(empathy/6))
    Madison @{((main_ro = "Madison") or (second_ro = "Madison")) leans into you with a tackling hug, almost knocking you over with the beach chair. Brody rolls his eyes and smiles.|smiles at you and punches her brother's arm in excitement. He just shakes his head and smiles at you.}
  #"All three of you can go, but just keep in mind I'm in charge out there."
    *set impulse %+15
    *set allegiance %+(round(m_leadership/6))
    "Totally. We are just going there to get the stereo, but you're running the show," Madison says.
  #"I don't trust Kevin, but if he goes with us, we can test his loyalty."
    *set ideal %-15
    Madison frowns and says, "He's okay once you get to know him."
    
    "He's rough around the edges as my mom used to say about people. It sounds like Kevin has been at this Junkyard living with his father for so long, he's just kind of sheltered. He seems like a good dude, but a bit emo," Brody says.
    
    "Not everyone can be as popular as you," Madison said, her voice growing loud. She catches herself and adds, "Don't worry about Kevin. He'll listen to us."
  #"Kevin can go. This will give us an opportunity to learn more about him."
    *set ideal %-15
    Madison claps her hands together and says, "You'll see he's going to be a good addition to our group."
    
    "I hope so. He's been stuck at this Junkyard for so long, I hope he knows what it's like to go outside of it," Brody says, shrugging his shoulders.
    
    "Have an open mind once in a while, Brody," Madison says. "He has a lot to offer. Besides, scavenging this place will be no big deal."
    
"This will be an easy trip out there and back. Kevin said that place has been deserted for years, so there's no one even there," Brody says.
*if gina_join
  
  "Nothing in this new world is as easy as it seems," Gina says, walking up to you and the twins. "Which is why I'd like to go on your excursion."
  
  "Whoa, awesome shirt," Brody says.
  
  Gina pulls out her shirt from her jeans and stretches it to show the front. It's for the band, Gold Rust, and captures an image of them from a 2011 tour.
  
  *if (main_ro = "Madison") or (second_ro = "Madison")
    Madison leans close to you and whispers in your ear, "Please tell her she can't go. She's going to boss us around and tell us what we can do or can't do."
    
    Gina studies the two of you with a thin smile. "I'm sure Miss Milford is not excited by the prospect of me going with your group.
  *if (main_ro != "Madison") and (second_ro != "Madison")
    Madison backs away from Gina and folds her arms. "No, sorry. This is our trip, and we don't need you there bossing us around."
    
    Gina studies her for a moment with a thin smile. "I understand your concern about me, but I won't get in your way.
  I just want to keep everyone safe and focused. You can search for your party equipment while I find gear we'll need to survive."
  
  Brody laughs so hard he snorts. "Ha, ha. Burn."
  
  "Don't you have things to build around here?" Madison asks. "After all, we have to use everyone according to their skills. Should you really be going out scavenging when you can be fixing up something around here?"
  
  *if leader
    Gina and the twins look to you for a decision.
    *fake_choice
      #"I don't think you're needed on this one, Gina." Madison doesn't want her to go, and this is her mission.
        *set madison_faction %+(round(empathy/6))
        *set gina_faction %-(round(20-(empathy/6)))
        *goto GinaStaysJY
      #I take a diplomatic approach. "I agree with Madison. Your skills are better suited to working here, Gina."
        *set madison_faction %+(round(empathy/6))
        *set gina_faction %-(round(20-(empathy/6)))
        *label GinaStaysJY
        Gina frowns and throws her hands up. "If you think so. Good luck to all of you," she says and walks away without another word.
        
        As Gina walks away, you see a satisfied look on Madison's face.
        *goto StartTrainTrip
      #"I'm always worried when we leave the Junkyard. Gina would improve our odds of making it back."
       *goto GinaJoinsTY
      #"It's Gina's call. If she doesn't have any pressing work to do here and wants to go with us, she can make that decision."
        *label GinaJoinsTY
        *set gina_faction %+(round(empathy/6))
        *set madison_faction %-(round(20-(empathy/6)))
        *set with_gina true
        Madison scoffs in a long, drawnout breath. "Fine, whatever. It's just a trip I planned with my brother, but I guess I'm not in charge around here."
        
        "Great," Gina says, ignoring Madison. "I'll
        *goto StartTrainTrip
  *else
    *set with_gina true
    Gina chuckles. "Don't worry, I asked @{(group_leader = "Jaime") Jaime and he|Rachel and she} thought it was a great idea for me to tag along. So I'll
    *goto StartTrainTrip
*else
  *goto StartTrainTrip
  
*label StartTrainTrip
*if with_gina
  go grab my gear and meet you all at the main gate in fifteen."
  
"Come on, Maddie, let's go get ready," Brody says.

As the two Milfords walk away, you head after them to the main building where the group has set up all inventory. As you prepare to leave the junkyard, you consider your gear.

*gosub_scene Part2Events CheckGear

*gosub_scene Part2Events ChangeUniform
*gosub_scene Part2Events AdjustSkills
*gosub_scene CheckWeapons

Your small group assembles at the main gate. Madison has her typical AR-15 rifle with a pistol tucked into her jeans and a loose fitting button-down shirt over a tank top. She wears a baseball cap and a comment from Brody about her being mini Rachel gets him a punch in the chest. Her brother has on gym shorts with his own tank top, and he carries his favorite weapon, a lacrosse stick fortified with metal and jagged nails that make it look like one half of an alligator's mouth. Kevin has a lever action rifle in hand, and he wears jeans and an Eli's Junkyard and Salvage t-shirt. A long metal pipe hangs across his back by a leather strap.
*if with_gina
  Gina carries her shotgun and wears a holstered Glock automatic pistol on her belt.
  
"So how do we do this?" Kevin asks. "Like, do we have standing orders for how to react to infected or other survivors?"

"We try not to waste ammo on the infected. Plus it makes a lot of noise and draws others in. Avoiding them is best, but if you have to fight, aim for the head." Brody taps his own head.

"As for other survivors that we come across, we
*if sop = 1
  observe them and try to figure out if they are friendly or not. We want to build allies not enemies, so we take a diplomatic approach. Again, we try to avoid fights."
  
  Madison scoffs. "We've done okay except for those idiot militia members from a few days ago.
*if sop = 2
  make friends with everyone we meet and look to help others. We are not in this alone. It's infected versus noninfected, not human versus human."
  
  Madison scoffs. "Someone should tell that to the Silverthornes.
*if sop = 3
  treat everyone as hostile until they prove otherwise. We avoid conflicts but if we have to engage anyone, we do so in a coordinated fashion."
  
  Madison chuckles to herself. "We already had to fight a bunch of idiot militia people
*if sop = 4
  avoid everyone and stick to scavenging to acquire resources. If we meet hostile survivors, we have no problem fighting back. And if resources are low, we're not above taking them from others. It's the reality of the situation. We can't have our people starving."
  
  Madison slides the bolt on her rifle. "Like those Silverthornes. I can't wait to find their base. I'm going to treat that place like I walked into Bloomingdale's and take what I want. I hate those guys.
*if sop = 5
  realize were in a survival situation. Other groups have the resources we need to survive. We're not about to starve out here, and scavenging puts us in a lot of danger. If we come across other groups, we'll give them a chance to hand over their stuff, but if they refuse, we do what we have to do."
  
  Madison slides the bolt on her rifle. "I'm looking forward to meeting those Silverthornes again. I can't wait for some payback.
Those are the ones I was telling you about, Kev."

He smiles to her and nods. Brody rolls his eyes at the two of them.
*if (main_ro = "Madison") or (second_ro = "Madison")
  Seeing how Madison and Kevin are talking to one another, you…
  *fake_choice
    #Wrap my arm around Madison and give her a kiss. She's my girl.
      *set madison_faction %+(round(empathy/6))
      When you pull away from the kiss, Madison blushes and bites her lip. "What was that for?"
      
      "I just wanted to kiss my girlfriend."
      
      She smiles and lays her head on your shoulder. When you glance at Kevin, he looks away, his face stern.
    #Say, "Keep your eyes to yourself, Kevin." I don't like how he's looking at Madison.
      *set madison_faction %-(round(20-(empathy/6)))
      Kevin glares at you and looks at the ground. Madison turns to you and says, "Don't act like that. He's just my friend."
      
      "That's fine, as long as he remembers you're my girlfriend."
    #Say nothing. They're just friends, and I'm not going to play the jealous type.
      *set ideal %+15
      Kevin and Madison can talk and hang out together. She's my girlfriend, and everyone knows it. There's no need to get jealous about their relationship.
  *goto TYIntro
*else
  *goto TYIntro
  
*label TYIntro

Your group walks along a path cut through the densest part of the forest from the east of the Junkyard. After twenty minutes or so of hiking up a gradual hill, you notice the flapping of bird wings and the snorting of a large animal from the other side of high grass. It's at this point you realize you've traveled in silence until this moment.

"We should be coming up to the train yard soon. Look ahead," Brody says, pointing to train tracks through a narrow clearing of trees.

Your group steps onto the tracks made brown by rust and follows for a short stretch until the clearing opens to a full break in the forest. Hundreds of tree stumps mark a border where the forest has been cleared to make way for dozens of trains now sitting in rows, unmoving. Most are cargo cars solo and unhinged. Thick wires and cables stretch out from towers and poles like an intricate web, and the tracks spread out in all directions from a central hub. A lonely brown structure with a sagging tin roof sits at the start of the railyard. A sign with the name of the yard is now covered in thick black graffiti and only a few legible words show through—NO HOPE.

*if search >= 50
  On top of one central train, a figure crouches with a rifle. He's lying prone and wearing a skullcap. He has no shirt on, and you can see he's heavily tattooed. You raise your hands to your group, and they all pause. "There's a guy up top with a rifle. 
*if search < 50
  @{with_gina Gina|Kevin} stops suddenly and points in the distance. "Look on top of that car over there. There's a guy with a rifle."
  
  You scan the top of the train car and see the long barrel of a rifle at first. Lying prone behind it is a thin man with a skullcap. He has no shirt on, and you can see he's heavily tattooed. "Dammit.
Let's get into cover."

The @{with_gina five|four} of you scramble back to the tree line and take cover behind the mighty trunks of oak still standing. Looking back towards the sniper, you see no indication you've been spotted.

"What are we doing now? I thought no one lived at this train yard," Kevin says, clearly upset.

"Things change minute by minute, dude," Brody says. "Feel free to go back to the Junkyard."

Kevin goes tightlipped and looks at the ground. Madison scoffs at her brother and says to Kevin, "Don't mind my brother. I never do."

*if with_gina
  Gina peaks out from behind the tree at the figure on the train. "Maybe we should scout the perimeter to find out what we're dealing with. It could be a lone gunman, or it could be a group of armed survivors. Maybe we can also assess whether they're friendly or hostile."
  
  "Yeah, I agree with Gina.
*if not(with_gina)
  Brody leans out from behind the tree and scans the train yard. "I wonder if it's just one guy on that car over there, or if there's a whole team of survivors inside.
I can go scout it," Brody says.

"It's not a good idea to separate," Madison says. "If there's a group inside and they're hostile, we need to fight together or run together."

Brody shakes his head, not even looking at his sister. "All of us moving through the woods will make a lot of noise and draw more attention than one person sneaking around."

"What do you think, ${firstname}?" Kevin asks.
*gosub_scene CheckWeapons
*choice
  #"We're overreacting. Let's just call out and talk to the guy on top of the train car."
    *set ideal %+15
    *set diplomacy %+15
    *set friendly_approach true
    *if sop <= 2
      *set allegiance %+(round(m_leadership/6))
    *if sop > 2
      *set allegiance %-(round(20-(m_leadership/6)))
    Brody and Kevin nod in agreement, while Madison throws her arms up in disappointment.
    
    "Sure, let's wave to the guy with the rifle and give him easy targets," Madison says. "Since this is your idea, I vote that you do the talking."
    *if with_gina
    
      "For once I agree with Madison," Gina says.
      
    You step out from cover with your hands raised in a show of peace. "Hey there! Can we talk for a minute? I just came across this train yard and saw you up there."
    *goto GravesOutside
  #"Let's all draw our weapons and order him to toss down that rifle to us. We can then find out all about the train yard."
    *if sop <= 2
      *set allegiance %-(round(20-(m_leadership/6)))
      "That seems pretty aggressive," Kevin says. When you turn to look at him, he raises his hands defensively and says, "But you know what you're doing."
      
      "It seems reasonable to me. He won't get hurt if he listens to us, and I trust us more than I trust him," Madison says.
    *if (sop = 3) or (sop = 4)
      *set allegiance %+(round(m_leadership/6))
      "Makes a lot of sense," Kevin says.
      
      "If we're going to talk to him, it's the best way to protect ourselves," Madison says.
    She lifts her AR–15 and tucks the stock and inch in from her shoulder. @{with_gina Gina does the same with her shotgun, while Brody|Brody hangs his lacrosse stick over his shoulder and} whispers to his sister, "Let me get your pistol."
    
    "You didn't bring a rifle or shotgun? What the heck is wrong with you?" she says in a stifled, angry voice.
    *fake_choice
      #Offer Brody a weapon.
        *set weapon_option 2
        *set temp_weapon "brody_weapon"
        *set temp_mod "brody_mod"
        *set temp_class "brody_class"
        *set temp_weaponmode "brody_weaponmode"
        *set temp_range "brody_range"
        *set temp_type "brody_type"
        *set temp_ammo "brody_ammo"
        *set temp_arrow "brody_arrow"
        "I can give you a weapon," you say and offer him…
        *gosub_scene GiveWeapon
        *set brody_faction %+(round(m_leadership/6))
        He takes the weapon, turns it over in his hands, and smiles. "Thanks. I'll be better prepared next time."
      #"Does anyone have a weapon for Brody?"
        *set brody_faction %+(round(m_leadership/6))
        *set brody_weapon "Glock"
        *set brody_mod 7
        *set brody_type "ranged"
        *if with_gina
          Gina takes out her sidearm and hands it to him. "You can have my backup pistol."
          
          "Thanks, Gina. I'll be better prepared next time." 
        *if not(with_gina)
          Kevin takes out a handgun and offers it to him. "Here you go."
          
          "Thanks, Kevin. I owe you."
        Brody takes the gun, clicks off the safety, and racks the slide with a click.
      #"Brody, you need to prepare yourself for these missions. Next time, I'm leaving you back at camp."
        *set brody_faction %-(round(20-(empathy/6)))
        *set allegiance %+(round(m_leadership/6))
        Brody's cheeks turn red, and he looks away. "I'll be prepared next time."
      #"Brody, please remember a ranged weapon next time." 
        *set brody_faction %+(round(m_leadership/6))
        *set allegiance %-(round(20-(m_leadership/6)))
        Brody's cheeks turn red, and he smiles sheepishly. "I'll be prepared next time."
    
    "Everyone ready?" Madison says and nods to Brody with a huff. He rolls his eyes and aims his pistol at the armed man atop the train car. Kevin loops the strap of his lever action rifle around his arm and looks down the barrel.
    *if with_gina
      Gina braces herself against the trunk of a nearby tree and holds up her shotgun.
      
    @{carry_ranged With your own weapon raised,|Without a ranged weapon, you wait for your companions to prepare to attack. When you see that they're ready,} you lean out from cover and shout, "Hey, you on the train, toss your weapon down and raise your hands. We have you covered and just want to talk."
    *goto GravesOutside
  #"Brody should go scout while the rest of us wait here."
    *set impulse %-15
    *set brody_sneak true
    *gosub_scene Part2Events CheckTrained "Brody" "Stealth"
    Brody smiles proudly and stands in front of you. "No problem. I got this."
    
    Madison whips her head around to you, almost losing her baseball cap. "You want him to go to scout? One time, he tried sneaking out of a second-story bedroom. He could go down a trellis and onto a shed. A rhino wearing bowling balls for shoes could get out that window and down the side of the house quieter than he did."
    
    @{passed_training_check "Don't worry about Brody. I spent some time teaching him how to move around quietly. I think he's got this," you say.|"I think he'll do fine. I doubt we have anything to worry about, and he's just going to check things out to make sure."}
    
    Brody knocks his sister's hat off, and she scowls at him. He stretches his back and legs and lays his lacrosse stick on the ground beside you. @{((main_ro = "Brody") or (second_ro = "Brody")) As he stands back up, he plants a kiss on your mouth. You weren't expecting it, and his mouth lands high almost clipping your nose. He laughs at it and turns away.|"I'll be back in no time."}
    
    He sticks in cover of the tree line, disappearing into the foliage. Madison pops onto her tiptoes and cranes her neck to look for him, a worried expression on her face. @{((main_ro = "Madison") or (second_ro = "Madison")) You take her hand and can feel her trembling. She's breathing fast and begins pacing around you.|Kevin reaches out and offers a hug, but she walks away and paces in a circle.}
    
    When you can't see him anymore, you look back to the top of the train where the figure still lies with the rifle pointed out to the forest. You see the sun move, and a few clouds make their way across the sky.
    
    @{with_gina "How long before we go after him?" Gina asks.|"Should he be back by now? Should we go after him?" Kevin asks.}
    
    *if passed_training_check
      A tree branch rustles behind you and to the right. You and your companions all turn, weapons raised. Brody steps from behind a tree, chewing the end of a read sticking out of his mouth.
      
      Madison rushes over to him, arms raised like she's going to hug him. At the last moment she stops and backs off, looking sheepishly at the rest of you. "Took you long enough."
      
      Brody knocks her hat off again and walks past her. He crouches in between you and Kevin and draws with his finger in the dirt. His crude sketch shows several long rectangles, which must indicate train cars. In the middle he draws a circle with tiny Xs. "I saw four train cars and in the center is a camp. There were two guys, two women, and two little kids. The kids were probably two or three years old. Damn, they were cute: running around, skipping, and dancing. I never thought I'd see kids like that again."
      
      @{with_gina "What about weapons?" Gina asks.|"Were they armed?" you ask.}
      
      "All but the kids had rifles. One had a pretty sweet looking automatic rifle," Brody says.
      
      "Good job, Brody. Let's follow the path you took and come from the east side of their camp," you say and Mark the place on his dirt drawn diagram.
      *goto ApproachTrainyard
    *else
      A gun shot rings out. The man with the rifle on the top of the train car spins three sixty degrees, pointing his weapon everywhere.
      
      Madison rushes past you towards the clearing, but you grab her and hold her back.
      
      "Let me go," she shouts.
      
      "You can't go after him. We need to stay in cover," you say.
      *goto GravesSpot
  #"Let's all go scout the perimeter of the train yard. We need to be careful and stick together."
    *set ideal %-15
    Your companions listen as you plot out a course around the perimeter: sticking close to the tree line, crossing to a far train car, and following the tracks to spy from the eastern side. Madison remains tightlipped while Brody stares at you with interest.
    *if with_gina
      Gina paces in a line, while
    Kevin hangs his head and holds the back of his neck with both hands.
    
    "Okay, let's do this," Brody says. He steps to the side and stretches his back and legs like he's preparing for a run.
    
    "Everyone follow me. Stay tight together. Keep your eyes scanning for any movement in the forest. Once we're out in the open, stay sharp. Alright, let's go."
    *goto ApproachTrainyard
  #"We can take out that sniper before he sees us. If we do it fast, we can move on the train yard and overwhelm anyone who's in there."
    *set impulse %+15
    *set ruthless %+15
    *if sop <= 2
      *set allegiance %+(round(m_leadership/6))
      Brody rubs his chin. "That seems pretty aggressive. Why don't we just try to talk to him? He may be up there to shoot the infected, not other survivors."
      
      "We can't take that risk. Right now, we have the upper hand. If we talk to him or move into the clearing, we lose our surprise."
    *if sop > 4
      *set allegiance %-(round(20-(m_leadership/6)))
      "I can hit him from here," Madison says.
      
      "She can make that shot in her sleep. I wish we didn't have to attack, but I know we can't take the risk," Brody says.
    *if with_gina
      
      "My shotgun won't do well at that range, so I vote for Madison, unless Kevin is a whiz with a rifle," Gina says.
    
    "I'm use to shooting groundhogs with a twenty-two, not people with a thirty odd six. But I'll take that shot if you guys want me to do it," Kevin says.
    
    Brody shakes his head. "Don't look at me. If you want me to sneak up to him, that's a different story.
    
    You've seen Madison make shots like this before, but you get the sense that Kevin wants to prove himself and show your group he's part of the team now. You're
    *if ranged >= 65
      not
    confident in your ability to hit the sniper at this range.
    
    Considering these options, you…
    *fake_choice
      *selectable_if (carry_ranged) #Shoot at the sniper top of the train car myself.
        "I'm going to take him out. I know I've got this," you say. Kneeling beside a tree, you ensure a clear line of sight with the target and draw your…
        *if (p_type = "ranged") and (s_type = "ranged")
          *fake_choice
            #$!{p_weapon}.
              *gosub_scene FightCode UsePrimary
              *set using_primary true
            #$!{s_weapon}.
              *gosub_scene FightCode UseSecondary
          You draw your
          *goto GravesSniper
        *elseif p_type = "ranged"
          *gosub_scene FightCode UsePrimary
          *set using_primary true
          *goto GravesSniper
        *elseif s_type = "ranged"
          *gosub_scene FightCode UseSecondary
          *goto GravesSniper
      #Tell Madison to take the shot. I know she can do it.
        *set madison_faction %+(round(empathy/6))
        *set lewis_injured true
        Madison smiles for a moment and then drops the expression as she looks over at the sniper. Bringing up the rifle to her shoulder, she stares down the sights and brings her finger to the trigger. She takes in a slow breath and lets it out, getting into a rhythm of inhalation and exhalation. You can see in her a relaxed focus, like she's done this a thousand times. Does she enjoy killing? Has the outbreak brought out this side of her?
        
        With a squeeze of the trigger, she fires. The shot registers with a loud warble through the railyard. Blood flies from the shoulder of the man atop the train car. He flinches and fires his own rifle, sending a round over your heads. A branch splits from high up, raining leaves on your heads.
        *goto ShotAtLewis
      #Tell Kevin to take the shot. I want him to prove himself and feel part of this group.
        *set kevin_faction %+(round(empathy/6))
        Kevin nods and brings around his rifle. "Okay, I can do this."
        
        Madison rolled her eyes, but when he looks over at her, she smiles. "Just relax, and you'll do it."
        
        Brody slaps him on the back, causing the young man to stagger forwards. He gives Brody a nod as well and then raises the but of the gun to his shoulder. He looks around the group and then gazes down the barrel of the rifle, raising the end towards the rifleman on the train car. Several sparrows fly across your field of vision, and when they're gone, you hear the crack of Kevin's rifle. Across the field, a spark flies atop the train car, and the sniper flinches.
        
        "Dammit, I missed," Kevin yells and yanks down the rifles lever to chamber another round.
        *goto ShotAtLewis
      
*label GravesSniper
*set ranged_matters true
*set target_range 3
*set target_difficulty 120
*gosub_scene FightCode AttackResult

You raise your weapon and aim at the man with the rifle. His prone body provides little target, but you have the gift of time to prepare the best shot. Taking in a deep breath, you let it out and @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) release your bowstring.|squeeze the trigger.}
*if attack_result = 4
  *set lewis_alive false
  *if not(curr_suppressor) and ((curr_weapon != "compound bow") and ((curr_weapon != "recurve bow") and (curr_weapon != "crossbow")))
    *set graves_prepared true
  @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) The arrow sails in a slight arc and lands through his throat. He grips the shaft and|Blood flies from the side of his throat. He} rises to his knees, turns, tumbles sideways, and falls off the side of the train car. He lands on the ground beside the enormous wheels, and a plume of dust rises around him. His body lies flat and remains motionless.
*if attack_result = 3
  *set lewis_injured true
  @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) The arrow sails the distance and lands in|Blood flies from} his shoulder. His rifles fires over your head. Leaves fall from the top of the tree next to you.
*if attack_result < 3
  *set graves_prepared true
  @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) The arrow hits|The bullet strikes} The top of the train car a few feet ahead of him. He flinches from the sudden hit to the roof, and his rifle fires.
*if attack_result <= 3
  *label ShotAtLewis
  *set graves_prepared true
  
  "We are under attack!" he shouts.
  
  Others from your group fire, but he's already receding towards the back of the train. Bullets hit around him, but he disappears. At this angle, you can't see him.
  
"Hold your fire," you say to your group. "We need to circle around and come in from the side. We don't know how many friends he may have, but they'll be ready for us now."
*goto ApproachTrainyard

*label GravesOutside

The man rises to his knees and aims the rifle at you. "Stop right there. Put your hands up." He looks behind himself into the railyard and calls, "We got @{friendly_approach someone|people} here." Looking back at you, he points the barrel as it rattles in his hands.
    
You @{friendly_approach hold your hands up and say, "I'm no threat. I was just passing through and mean no harm."|call out again, "Drop your weapon, now! We will fire."}

"Stay right there," he yells and shakes his rifle at you like it's a spear. He backs away, dragging the rifle along with him. It becomes hard to spot him over the tall train car, and he all but disappears.

"What do we do now? Should we leave?" Kevin asks.

Both Madison and Brody shout "no" at the same time. Madison goes on to say, "We came here for a stereo, and we're not leaving without one."

*if with_gina
  "Risking our lives for a stereo seems pretty stupid if you ask me," Gina says.
  
  "No one asked you," Madison says. "You're free to go back to the Junkyard."
*if not(with_gina)
  "Okay, just asking," Kevin says, sheepishly.

Brody turns to the group. "We haven't even approached them yet. He was yelling down to someone. Maybe they will be reasonable."
*label GravesSpot

Voices call out from deep in the train yard, and though you can't make out what they're saying, you hear urgency as they move closer to your position. A man and a woman emerge from the side of the train car painted red, and they move laterally and take cover behind a pile of crates. As they move, you note firearms in both of their hands.

"This train yard's off-limits, friend," the woman shouts. She has a strong, confident voice and projects it far.
*if brody_sneak
  "Don't worry about your friend. He's not hurt."
*if not(brody_sneak)

  @{friendly_approach "We told your guy on top of the train that we meant no harm. We didn't know anyone is in the train yard, and we just want to talk,"|"We don't want to fight but didn't trust your man on that train pointing a rifle at us. We're willing to talk now,"} you shout back.

@{(search >= 55) As you look around the front of the railyard, you notice another rifle on the far side of the train car aimed at your group from twenty feet to the left of the woman. Yet another rifle pokes out from the side of a stack of lumber on her right.|"I see two more of them aiming rifles at us. That's at least four, maybe five, on their side," Kevin says.}

"You put your weapons down and come out, and we'll do the same. One from your side and one from ours. We meet in the middle. Deal?" the woman asks.
*if ((empathy >= 65) and not(hearing_impaired)) or (empathy >= 75)
  She speaks in a calm and even tone. Nothing in the woman's words seem fake or dishonest.

Madison shakes her head. "I don't trust them."

*if brody_sneak
  "If they have Brody, we don't have a choice. I'll go out and talk to them."
  
  @{((main_ro = "Madison") or (second_ro = "Madison")) "There's a chance I lost my brother, and now you're going out there?"|"I can't believe it. I knew this would happen."} Madison's voice sounds high and shaky. She chews her thumbnail and gazes hard at you.
  
  "It seems risky. You going to be okay?" Kevin asks.
  *goto MeetMiddle
*else
  "Why not? They seem pretty fair when we're the intruders," Brody says.

  You say…
  *choice
    #@{(((empathy >= 65) and not(hearing_impaired)) or (empathy >= 75)) "She's|Let's take a chance she's} telling the truth. I'll go out to talk to her. You all stay here and cover me."
      *set diplomacy %+15
      *set ruthless %-15
      *set truth %+15
      *set ideal %+15
      *if sop <= 2
        *set allegiance %+(round(m_leadership/6))
      *if sop > 2
        *set allegiance %-(round(20-(m_leadership/6)))
      @{((main_ro = "Madison") or (second_ro = "Madison")) "I don't want you to go out there. Why don't we send someone else?"|"Are you sure this is the right call?"} Madison asks, her voice shaky. She chews her thumbnail and gazes hard at you.
      
      @{((main_ro = "Brody") or (second_ro = "Brody")) "What if something happens to you? What if they are lying?" Brody asks.|"I want to trust them, but I don't know about this," Brody says.}
      *label MeetMiddle
      
      "I'll be fine. If any of them make a move, I'll run back to cover. I know you guys have my back."
      *if with_gina
        
        "I'll have my shotgun pointed at her at all times," Gina says.
        
      Kevin adjusts his grip on his rifle and kneels by the base of a tree. "If things go sideways, we need to shoot at each one of them and keep them from firing at ${firstname}."
      
      @{carry_ranged You put away your weapon and|You} step out from cover into the edge of the clearing. The woman on the other side walks around the corner on the pile of crates with her rifle slung over her back and her hands out by her side. The two of you take slow steps, and you scan your surroundings for any signs of movement or attack. With the skies clear and the sun at its peak, you're forced to squint which gives you more of a disadvantage than the woman opposite you.
      *gosub DescEnola
      
      "Hello. My name is Enola Graves. We are peaceful people, but this is our land and our train yard. We can talk but cannot let you scavenge this area. We don't like to be out in the open here, so if you want to talk, you can follow us back to our camp. You can hold onto your weapons but don't keep them out. We have kids with us. I'm putting my arms down now."
      
      She lowers her arms, and you do the same.
      
      "I'm going to whistle to my group to let them know you're coming in with us," she says and turns to her group. She puts two fingers in her mouth and blows a hard whistle that echoes off of the train cars. You see the guns pointed at you lower or disappear.
      
      With this show of good faith, you wave to your own group. Moments pass and then you see Kevin and Brody step from cover. Madison @{with_gina and Gina follow|follows} shortly after. You look at their faces, a mix of surprise and wonder.
      
      "Y'all can follow me," Enola says, and she leads you along the train tracks.
      *page_break
      You travel a short distance and soon the signs of a camp come into view. A small terminal building sits on the western end, and the group has built a camp out just to the east of it. A fire pit sits in the middle with a large iron pot fixed on a spit over a campfire. A clothes line has been stretched out between two huge crates and linens and clothing hang from it. A tarp is stretched between a train car and metal poles making a lean to style tent. Beneath the tarp lies sleeping bags and children's toys.
      
      As you walk towards the camp, Madison catches up to you and whispers, "Should we all go into their camp? We would all be in trouble if things go bad."
      *goto GravesCamp
    #"Let's tell her we're coming out. As soon they make a move out of cover, we attack."
      *set diplomacy %-15
      *set ruthless %+15
      *set truth %-15
      *set attack_graves 1
      *goto AttackGraves
    #"I'll keep talking to her while the rest of you move to better positions to take them out."
      *set diplomacy %-15
      *set ruthless %+15
      *set attack_graves 2
      *goto AttackGraves
    #"I don't trust them either. Let's take them out."
      *set diplomacy %-20
      *set ruthless %+20
      *set attack_graves 3
      *goto AttackGraves
    
*label DescEnola
She's tall, likely in her mid-thirties, and struts with an assuredness uncommon after the outbreak. She walks like she owns the earth and has no worry of impending death from the firepower pointed at her from behind you. Long black hair hangs in a braid with the sides of her head shaved bald. She wears jeans shorts and a T-shirt for the band, Gold Rust.
*return
    
*label AttackGraves
*set graves_attacked_front true
*if sop <= 2
  *set allegiance %-(round(20-(m_leadership/6)))
  "Why are we attacking? They haven't done anything to us," Brody says.
  
  "We can't underestimate them. They are well armed and organized and even have a lookout. If we don't attack first, we put ourselves at serious risk," you say.
*if sop > 4
  *set allegiance %+(round(m_leadership/6))
  "I'm glad you said it, because it's what I was thinking," Madison says.
  
  Brody keeps his gaze on the rifleman atop the train car. "I don't like attacking people for no reason, but I don't want to risk any of us getting hurt if they turn out to be hostile."
*if with_gina

  "We are living in a time when it's foolish to take chances," Gina says, checking her shotgun. She tucks the stock into her shoulder and moves it until she finds the best position.
  
Kevin rubs his hands over his face I've been through his hair. "You know, before I met you guys, I never ran around attacking random strangers."

@{(honor >= 50) "We're not exactly looking for trouble. It's just that we've had some bad experiences and learned it's better to treat everyone as potential enemies. It sucks, but that's reality."|"Just because you were stuck in the Junkyard, doesn't mean you were immune to attack. Eventually someone would find your father and you, or you would have to go out and find food and supplies. At some point you would have to fight."} You turn to address all of your companions.
*if attack_graves = 1
  "I'll tell her to come out. Once she's in the clearing, @{carry_ranged I'll|we'll} take her out. When the firefight starts, 
*if attack_graves = 2
  "I'll keep them talking and distract them. When I give the signal, start shooting.
*if attack_graves = 3
  "Let's get ready to do this.
I want each of you to focus on a different person. Madison can take the sniper on top. Kevin take the left side, and Brody take the right. Gina can pick up whoever's left."
*set ranged_matters true
*set target_range 3
*set target_difficulty 100

Your team tells you they understand, and all prepare as you laid out. When you see they're ready, you turn back to the clearing and
*if attack_graves = 1
  yell to the woman, "Okay, I'm coming out. We don't want any trouble. We just happened to come here to scavenge and had no idea it was already occupied."
  
  The woman
  *if m_persuasion >= 65
    *set target_difficulty -10
    rises from behind cover but does not step into the clearing. "Meet me in the middle."
    
    As she walks, you
  *if m_persuasion < 65
    *set target_difficulty +20
    pokes her head up but stays behind cover. "Start walking, and I will meet you.""
*if attack_graves = 2
  yell to the woman, "
  *if m_persuasion >= 65
    *set target_difficulty -10
  *if m_persuasion < 65
    *set target_difficulty +20
*if attack_graves = 3
  *if m_leadership >= 65
    *set target_difficulty -10
  *if m_leadership < 65
    *set target_difficulty +20
draw your…
*if (p_type = "ranged") and (s_type = "ranged")
  *fake_choice
    #$!{p_weapon}.
      *gosub_scene FightCode UsePrimary
      *set using_primary true
    #$!{s_weapon}.
      *gosub_scene FightCode UseSecondary
  You draw your
  *goto GravesFightClearing
*elseif p_type = "ranged"
  *gosub_scene FightCode UsePrimary
  *set using_primary true
  *goto GravesFightClearing
*elseif s_type = "ranged"
  *gosub_scene FightCode UseSecondary
  *goto GravesFightClearing
*else
  give your group the signal to attack.
  *goto GroupFires

*label GravesFightClearing
*gosub_scene FightCode AttackResult
${curr_weapon} and shoot.
*if attack_result = 4
  *set enola_alive false
  @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) The arrow sails in a slight arc and lands through her throat. She grips the shaft|Blood flies from the side of her throat. She reaches for her neck} and falls back behind cover. There's no way she survived that hit.
*if attack_result = 3
  *set enola_injured true
  @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) The arrow sails the distance and lands in her shoulder. She grips the shaft|Blood flies from her shoulder. Her rifle fires in the air}, and she falls behind the stack of crates.
*if attack_result < 3
  @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) The arrow hits the ground a few feet ahead of the woman.|A piece of the crate explodes from the bullet, spraying out shards of wood.}
*label GroupFires
Gunfire erupts from both sides. A shot splits bark from the tree next to Madison just as her own shot strikes the roof of the train car in front of the sniper. She recoils and drops low behind a tree stump. Brody fires his pistol, landing a tight pattern of bullets into the side of the train car on the right side of the clearing. Sparks fly out and keep the other shooter pinned down.

*if target_difficulty <= 90
  One of the attackers comes out from cover near the woman, and @{with_gina Gina fires. Her shotgun slug clips the side of his leg|Kevin fires. A bullet clips the side of the stranger's leg}, knocking him to the ground. Someone from behind the crates grabs his good leg and drags him back behind cover. Kevin fires at the left side train car, and his target returns fire.
*if target_difficulty > 90
  Bullets hit near your companions: knocking up dirt, splintering trees, and whizzing past your heads. Your team returns fire, but no one hits one of the strangers.
  
"Fall back!" someone yells from the other side. A volley of bullets come speeding at your group, forcing all of you deep in cover. The clamor of rifle fire echoes through the clearing, and as it dies out, you rise and look across the field. The weapon smoke clears, and you see no one at the edge of the train yard.

"Let's circle around and come from the east. I doubt they'll expect us from that direction, but let's keep our eyes up and stay focused," you say.

Brody and Kevin stand and look about, but Madison stays on the ground with her hands over her head. @{(madison_faction >= 60) You kneel beside her and put your hand on her shoulder. "It's okay. We're safe. No one's hurt. If you want to|Kevin kneels beside her and puts his hand on her shoulder. "Are you okay? You don't look hit. Are you just afraid? 'Cause we can} go back to the Junkyard—"

"No," she says and stands. She wipes her eyes with the back of her hand and then reloads her rifle. "Let's go."
*label ApproachTrainyard
*page_break
Your group moves along the edge of the forest towards the east, keeping full cover in the thickest part of the woods. Only ten feet away lies a barren field of dirt leading to the railyard, a graveyard of empty train cars, tracks, and electrical wires. The scent of oak fills the air. Birds whistle all around. It's almost too peaceful.

"I wonder how @{brody_sneak old those kids are|how many people are in the camp,"} Brody asks, pushing away a tree limb with his lacrosse stick.

@{brody_sneak "How should any of us know? You're the one who saw them."|"How would we know? Are we suddenly psychic?"} Madison steps just behind her brother like she's using him as a shield as she walks through the woods.

Kevin shrugs and waves a fly out of his face. "He was probably asking a rhetorical question. Right, Brody?"

"Rhetorical?" Brody asks.

"We're getting close to where we have to cross over. Let's all be quiet and stay on the lookout," you say.

You step out into the clearing where tree stumps cover the ground as far as you can see in each direction. Patches of weeds sprout from the ground in rare sections, but otherwise it's a long stretch of dirt at least fifty yards to the nearest train car. Your group moves with purpose, and you watch for signs of human or zombie. Midway across, Kevin sneezes, causing Madison to shriek. Everyone stops and crouches. You're out in the open with nowhere to hide and nowhere for cover.

*if brody_sneak
  "Their camp is just on the other side," Brody says, pointing to the side of a bright blue freight car with the name G. R. & R. Train Company painted on the side in bold letters.
  *goto EastGraves
*else
  *if ((search >= 50) and not(v_impaired)) or (search >= 65)
    Up ahead you see a thin trail of smoke dissipating in the air just above a bright blue freight car with the name G. R. & R. Train Company painted on the side in bold letters.
    
    "Look there," you say, pointing to the smoke.
    *goto EastGraves
  *else
    *if with_gina
      "Here we go. You see that? Smoke," Gina says,
    *if not(with_gina)
      "Does anyone else smell smoke?" Kevin asks, sniffing the air.
      
      "Look, over there," Brody says,
    pointing to the side of a bright blue freight car with the name G. R. & R. Train Company painted on the side in bold letters.
    *goto EastGraves
    
*label TalkApproach
Your group look around at one another and then to you. All seem satisfied with your approach, so you lean out from cover just enough to project your voice into the camp.
*return

*label EastGraves

Your group doubletimes until you reach the blue freight car. Everyone draws weapons or raises them to prepare for a fight. From here you can smell something roasting—the aroma of food. It's been a few hours since you've eaten, and your mouth waters. Brody's stomach growls, and a quick look around tells you everyone else feels the pangs of hunger as much as you do.

Your group keeps low and moves to the end of the car, taking advantage of the massive wheels to hide you from sight of anyone on the other side. Brody moves ahead and peaks around the corner of the freight car.

*if graves_prepared or graves_attacked_front
  "I don't really see anyone. Wait, I see @{graves_attacked_front the lady we met in front at the train. She's in some kind of building,"|a woman in some kind of building. Damn, she's hot,"} he says.
  
  A gunshot cuts the air, and a spark flies over Brody's head. He ducks and falls back, scrambling away from the edge of the freight car. You rush to the edge and peak around the corner. Twenty feet ahead sits a fire pit with a pot hanging from a spit. Several logs make benches in a circle around the pit, and a tarp stretches from a shorter train car down to metal poles forming an improvised tent. A rocking horse lies on its side and several sleeping bags are unrolled under the tarp. Large crates and thick burlap sacks spread across the upper end of the camp, some with clotheslines stretched between them, articles of clothing hanging from them. The barrels of rifles stick out past crates or around stacks of sacks, all aimed at the freight car. On the other side of the camp stands a small terminal and a maintenance shed. A shirtless man stands at the door frame holding up a rifle.
  
  "We know you're there!
  *if enola_alive and lewis_alive
    Leave now, and leave with your lives. 
  *if not(enola_alive) or not(lewis_alive)
    You killed
    *if not(enola_alive)
      her. My wife.
    *if not(lewis_alive)
      him. My brother.
  We'll kill every one of you sons of bitches," a man shouts.
*if not(graves_prepared) and not(graves_attacked_front)
  @{brody_sneak "They're all still there. Actually, they just took the little kids inside. Come to think of it, I don't see one guy. Maybe I miscounted."|"There's a camp with a few people inside. All of them are carrying weapons, mostly rifles. There are two little kids, and one of the women is bringing them into some kind of small building. Looks like they are cooking a pot of food over a fire pit."}
  
  "Don't let them see you," Madison says, not tugging at her brother's shirt.
  
  Brody pulls back and ducks down. "Too late."
  
  A deep, gravelly voice calls out from the other side. "We know you're there. We're a peaceful group, but we will defend ourselves if you try to come in. Go away, and there won't be any trouble."
  *if empathy >= 55
    His steady, calm tone tells you he has been in combat or tense situations before.
  
Madison and Kevin pull in tight behind you. Both have their weapons raised, though neither has a line of sight to the terminal. Brody gets back to his knees and draws the pistol from his pocket.
*if with_gina
  Gina lies flat on her stomach and looks under the train.
  
"Should we head back?" Brody asks. "I really want that damn stereo, but we can't take on the whole camp."

@{(graves_prepared or graves_attacked_front) "We just got here. Just because he said we have to leave, it doesn't mean we have to listen to him,"|"Even I'm not stupid enough to think we should stick around,"} Madison says.
*if with_gina

  Gina rises to her knees and crawls over to your small group. "I can't see through the train. We're safe here unless they try to move around to attack."
  
Kevin pushes a few fly-aways out of his eyes. "You can call me crazy but what if we try talking to them? We can tell them we just want some gear, and then we'll go."

Madison's eyes narrow, and she clenches her brow before saying, "You know what? The heck with them. Let's tell them to surrender. We don't have to shoot any of them. We just have to make them think we will."

@{with_gina "If we are taking that approach, a few of us could circle to the left and flank from their south. I doubt they'd be able to shoot anyone from that angle," Gina|"A few of us could go left and sneak up on them. I don't think they'd be able to see us from that side," Brody} says.

Considering these options, you say…
*choice
  #"Let's talk to them. We can @{(graves_prepared or graves_attacked_front) negotiate with them to get the supplies we need."|find out more about them and what kind of people they are."}
    *set diplomacy %+15
    *set ruthless %-15
    *gosub TalkApproach
    
    You say…
    *fake_choice
      #"We just want to talk. We didn't know anyone is in this train yard." We mean them no harm and would like to make friends with them if possible.
        *set morality %+15
        *set ideal %+15
        *set diplomacy %+15
      #"We're looking for food and supplies. We thought this train yard was abandoned." I'll get them to invite us in, so we cared assess their defenses.
        *set honor %-15
        *set truth %-15
      #"We just want to look around the train yard for a few items we need, and then we will go."
        *set impulse %+15
    *gosub_scene Part2Events CheckSocial
    *if (graves_prepared or graves_attacked_front) or ({social_skill} < 55)
      *label GravesRejects
      @{(graves_prepared or graves_attacked_front) "You attacked us and now expect us to buy the friendly act? Get out of here, so I don't have to kill any of you,"|"Sorry, but we don't want anyone in our camp and don't want to talk. You may be good people, but we're not taking any chances. Good luck, but we have to ask you to leave."} the bearded man says.
      
      You turn to your group. "We have no choice but to leave or fight—"
      
      Another shot rings off the train car in front of you. Your group retreats a few steps.
      
      "They going to keep shooting," Madison says.
      
      "We shouldn't have attacked them first," Brody shouts at her.
      
      Kevin moves back to the edge of the train. "They're moving closer. We may not have a chance to run."
      
      "Let get ready to return fire. If we force them back, we can make an opportunity to run. Everyone ready?" you ask.
      
      Everyone agrees and raises their firearms.
      *goto GravesAssault
    *else
      "If you are willing to put your weapons down, you can come inside the camp and talk. Just be aware, we have had groups cross us before, and it didn't go well for them. My wife keeps telling me to have an open mind with strangers, so I'm going to take a chance on y'all."
      
      You look around your group, and they all lower their weapons. Madison is the only one to keeper hers raised.
      
      "Are we sure about this? Wouldn't it be smart if a few of us stay outside of camp? What's the point of all of us dying if things go bad?" she asks.
      *goto GravesCamp
  #"Let's tell them to surrender. We have the upper hand and just need to convince them of this."
    *set diplomacy %-15
    *set honor %+15
    *gosub TalkApproach
    
    "We have this train yard surrounded. Lower your weapons and surrender, or we will take this camp by force."
    
    A man with a dark, thick black beard, who you presume to be the leader, shouts, "We're not going anywhere. You can try to attack us, but you'll soon see it's a mistake. We have the means and skills to defend ourselves. I don't want to kill anyone. You have ten seconds to leave."
    *goto GravesAssault
  #"We should attack them head on and overwhelm them."
    *set impulse %+15
    *set diplomacy %-15
    *set ruthless %-20
    Your companions look at you with a shared uneasiness. Madison smirks, "We can do this. They're probably more scared than we are."
    
    "You're scared?" Brody asks, nudging her on the shoulder.
    
    She knocks his hand away. "Knock it off. You know what I mean."
    *if (m_leadership >= 55)
    
      You stand and take a deep breath before saying, "Let's get prepared for this. Remember to pick your shots and don't waste ammo. Fire once, pause, readjust, and fire again. Don't get too exposed."
    *if with_gina
    
      "Both groups have cover so this may go on a while. Some of us need to hold back shots, so we could take turns reloading but keep the pressure constant," Gina says.
      
    Kevin looks between each member of the group as they speak, his brow furrowed and jaw tight.
    *goto GravesAssault
  #"Let's send a few of us to flank them from the south, while the rest of us keep them busy in the front."
    *set impulse %-15
    *set flank_graves true
    *set diplomacy %-15
    *set ruthless %-20
    Your companions look at you with a sense of resolve. Madison smirks and says, "That sounds like a good plan. I'd rather not be crawling around in the dirt. I mean, I'm a pretty good shot, so I should just stay here."
    
    "I'm fine with sneaking around," Brody says.
    *if brody_faction >= 60
      "${firstname},
    *if brody_faction < 60
      @{with_gina "Gina,|"Kev,}
    do you want to go with me?"
    *if brody_faction < 60
    
      @{with_gina "Sure, it makes sense for us to to flank them," Gina says.|"Yeah, I-I guess," Kevin says, swallowing hard.}
      
    Considering how to split your groups, you decide to…
    *choice
      #Take Brody with me to flank from the south. The rest of the group can attack from the east.
        *set brody_faction %+(round(empathy/6))
        Brody nods and steps next to you. Kevin creeps closer to Madison, and the two raise their rifles to prepare the assault from the east of camp.
        *goto FlankSouth
      #Take Kevin with me to flank from the south. The rest of the group can attack from the east.
        *set flank_team 2
        *set kevin_faction %+(round(empathy/6))
        Kevin's eyes go wide. "If you're sure, okay."
        
        Madison moves closer to her brother who peaks back around the front of the freight train.
        *goto FlankSouth
      #Flank from the south by myself. I can move better when I'm on my own.
        *set flank_team 3
        "Sounds risky to me. We'll do our best to keep them focused on us," Brody says.
        *goto FlankSouth
      #Send Brody and Kevin to flank from the South, while the rest of us stay by the freight train.
        *set diplomacy %-15
        *set ruthless %-20
        Brody steps next to Kevin and pats him on the back. "Good plan. Try to keep up with me, Kev."
        *goto GravesAssault
      *if with_gina
        #Send Brody and Gina to flank from the South, while the rest of us stay by the freight train.
          *set flank_south 2
          *set diplomacy %-15
          *set ruthless %-20
          Brody steps next to Gina, who gives him a cordial smile. She says, "Let's stay together. Not too fast. This isn't a race to get there."
          
          He shakes his head at her. "I know."
          *goto GravesAssault
  
*label FlankSouth
*set attacked_graves true

As you turn to leave, Madison 
*if madison_faction >= 50
  rushes over to you. "Be careful. @{((main_ro = "Madison") or (second_ro = "Madison")) You better come back in one peace," she says and follows with a kiss.|Run if they spot you," she says with a look of worry.}

  *if ideal > 65
    "Don't worry. I'm sure I'll be fine. This will all be over in no time."
  *if (ideal <= 65) and (ideal >= 35)
    "I know how dangerous this is. If there is any trouble, I'll back off."
  *if ideal < 35
    "I'm more worried about you guys than me. You stay safe too."
*if madison_faction < 50
  waves to you. "Don't get shot."
*if flank_team = 1

  She turns to Brody and gives him a quick hug. They embrace for a few seconds, and then she turns away from him and moves to the end of the freight car.
*if flank_team = 2
  She turns to Kevin and says, "Just follow ${firstname}. Don't stick your neck out. I'm sure you'll do great."
  
  He smirks and swallows hard. "Thanks."
  
You move along the length of the freight car and crossed the short distance to the next one, remaining in cover around the outside of the camp. When you reach the next car over, you hear talking in the distance. You're not sure what's been said, but then the man from the camp shouts to your group at the blue freight car.

"What're we doing here? We don't have all day."

"Hand over all of your food and gear, and we will leave you alone," Madison shouts.

"Little girl, you are out of your league. We have superior firepower, and I have no qualms about shooting you and your friends. This is your last warning."

You pick up your pace, rushing across the outside of the freight car, when you reach the end you climb the steps up the back of the train, crouching to remain as covert as possible. From this angle, you can see only a sliver of the terminal's front window, where all of the opposing side have gone. From here, it's a straight run to the side of the terminal without cover. You see no wonder watching the southern end of camp, but if you're mistaken, a competent shooter could take you out. 

As you wonder how you're going to cross to the back of the terminal, shots fly through the window and pepper the edge of the camp. Your companions back at the freight train have provided the distraction you need.
*if flank_team = 1
  As you turn to ask if Brody's ready to go, he darts past you for the side of the terminal.
*if flank_team = 2

  "Ready?" you ask Kevin.

  He licks his lips and takes a series of deep breaths. Nodding to you, he says, "Y-yeah. Let's just go."
  
You burst across the southern end of the field at a steady pace, keeping watch on your path for any obstacles. The strangers at the terminal have opened fire on your companions. Bullets whiz through the camp from both sides.
*if m_stealth >= 55
  Staying low, you run in a straight line without sudden movements that may draw attention to you.
  *if flank_team = 1
    Up ahead, Brody stays five paces ahead and reaches the corner of the building like you cross the finish line at a track race. He turns and slips his pistol in his shorts, exchanging it for the lacrosse stick on his back.
  *if flank_team = 2
    From behind you hear Kevin panting. @{hearing_impaired He's mumbling something, but you can't make out the words.|Every once in a while you hear him say, "Oh my God."}
    
  When you reach the edge of the building you press your back against the wall and take a few deep breaths. Gunfire has not stopped from the front of the terminal, and you can barely hear over the breaking glass, angry shouts, and cries from the children.
  
  You inch your way along the terminal, a brick and stone building only a story high. Railroad spikes and broken machinery lie on the ground along the wall, and ten feet away appears the carcass of a small rodent. As you look over, a crow flies down and pecks at what's left of its meat. When you reach the back, you slide along to a wooden door held together by duct tape and nailed to the frame.
  *if flank_team = 1
  
    "How do we want to do this? I'd rather not kill anyone, but I don't want to get shot either." Brody says.
    
    @{(honor >= 50) "We can give them a chance to surrender. Just be ready to fight if things go south."|"I doubt they will surrender, so let's be ready to make an example out of one."}
  *if flank_team = 2
    
    "What should I do now? I guess we're going to go in there, so do I follow your lead or stay out here?"
    
    @{(impulse >= 50) "We're breaking through that door and taking shots. Follow my lead."|"You can follow my lead. I don't know what going to happen on the other side of that door. Let's see how it goes. Stay other and be ready."}
  
  You twist the doorknob. Unlocked. It gives no resistance as you swing it outward. The sounds of gunfire cover the squeaking hinges and your footsteps moving into a back room. Inside, you see a long counter with broken plexiglass where ticket agents would work. Past that stand the survivors from the camp. A man with a thick black beard and crewcut aims an M-16 through a front window.
  *if enola_alive
    Farther down, stands a woman with long black hair hanging in braids with the sides shaved. She wears jeans shorts and a T-shirt for the band, Gold Rust.
  
  "John, you are aiming too high. Bring it down a few inches," the man with the thick beard says.
  
  As you look around, you hear the crying of children. Two toddlers cower in the corner, whimpering. One holds a blanket and the other rocks in place.
  
  "I know, Eric. You don't have to tell me how the fire a rifle. Danica, get the kids in the bathroom. They shouldn't have to see this," another man yells. He's tall and lean with a purple shirt and blue khaki shorts and has black, curly hair and a thin mustache.
  
  A pregnant woman leans her rifle against the wall and waddles to the kids. "Come on, Abel and Grace. Auntie Danica has got you both." She lifts the two children, balances them on her large stomach, and carries them through the opening of a public bathroom on the side of the terminal.
  *if enola_alive
    One of the children reaches her small arms out and whines, "Mama!"
    
    The woman with the long braided hair offers the child a strained smile. "I'll be there any minute, Buttercup."
    
    "Don't worry, and Nola, I got them," Danica says and moves into the bathroom.
  *if lewis_alive
    
    "It doesn't look like there are too many," another man says. He has dark black hair to his shoulders with the wings tied back into a knot. He has a tight beard which runs down his neck and looks like he hasn't shaved in months. He's shirtless, and colorful tattoos cover each arm. Across his back, a tattoo reads Southern Ute. It's the sniper from the first train car.
    
    "Move over one window, Lewis. See if you can get a shot under the freight train," Eric says.
    
    The shirtless man nods, lifts his gun, and moves one window to the right."
  
  These survivors all face the front of the terminal, rifles raised, and firing at your friends across the camp. You have the upper hand, and so you…
  *fake_choice
    #Order them to surrender. Once they give up, we can talk to them about the gear we need.
      *set honor %+15
      *set diplomacy %+25
      *set ambush_graves 1
    #Take out one of them to set the tone that they need to surrender.
      *set morality %-15
      *set humanity %-15
      *set ruthless %+15
      *set diplomacy %-15
      *set ambush_graves 2
    #Kill them all. I'm not taking any chances and don't care about their survival.
      *set morality %-25
      *set humanity %-25
      *set ruthless %+25
      *set diplomacy %-25
      *set ambush_graves 3
  *set ranged_matters false
  *set target_range 0
  *set target_difficulty 90
  
  With your plans set, you draw your…
  *fake_choice
    #$!{p_weapon}.
      *gosub_scene FightCode UsePrimary
      *set using_primary true
    #$!{s_weapon}.
      *gosub_scene FightCode UseSecondary
  You draw out your ${curr_weapon} and 
  *if ambush_graves = 1
    *if curr_type != "ranged"
      Creep from behind the counter. The one named John stands closest to you, and you grab a handful of his hair, yank him backwards, and
      *if (curr_class = "spray") or (curr_class = "taser")
        place the weapon against the side of his head.
      *if (curr_class = "hack") or ((curr_class = "sword") or (curr_class = "knife"))
        hold the blade against his neck.
      *if curr_class = "club"
        press the weapon across his throat.
      *if curr_weapon = "hands"
        wrap your arm around his neck in a choke. With him secured, you
    shout, "Everyone, weapons on the ground. Hands in the air, now!"
    
    
    The survivors all freeze in place. Only their heads turn toward the back of the room. Eric speaks first. "Listen friend, we don't want anyone hurt. We're not lowering our guns. Let's just talk, and everyone keep a cool head."
    
    *if (m_intimidation >= 65) or ((m_intimidation >= 55) and ((flank_team = 1) or (flank_team = 2)))
      *if flank_team = 1
        "You heard ${him}. Weapons on the floor," Brody shouts and takes an aggressive step forward with the spiked lacrosse stick raised.
      
        "I said weapons down. Don't make me hurt @{(curr_type = "ranged") anyone|him}," you shout.
      *if flank_team = 2
        
        "Put your damn weapons on the ground," Kevin says aiming his rifle at Eric.
      
      The survivors all look to their apparent leader, who gives a slow nod and places his rifle on the ground. The others do so in turn, resting their weapons in front of them on the floor.
      
      You shout at them, "Hands on your heads. I want you all single file near that door. Anyone moves, and they lose a kneecap. Move again, and it's your life."
      
      Eric steps in front of the door with his hands up.
      *if enola_alive
        Enola fills in behind him.
      *if lewis_alive
        Lewis raises his hands with a constant glare at you. He takes a few steps towards the line, pauses and looks at you, and then takes his place in line.
      *if curr_type = "ranged"
        John takes up the last spot.
      *if curr_type != "ranged"
        You
        *if (flank_team = 1) or (flank_team = 2)
          release John
        *if (flank_team != 1) and (flank_team != 2)
          @{(curr_weapon = "hands") pick up John's rifle, release him,|release John, hold up your weapon,}
        and shove him towards the back of the line.
      
      Stepping up to one of the broken windows, you yell out to your companions across the camp, "They all surrendered. Don't shoot. We are coming out."
      
      The gunfire from outside ends, and you order the survivors to walk outside.
      *goto GravesMarchedOut
    *else
      Though he says these words, he spins around and shoots at you. The other survivors take his lead and open fire.
      *if curr_type = "ranged"
        You duck behind the counter, pop up, and
        *goto AmbushFightTwo
      *else
        *set john_alive false
        *if ((curr_class = "spray") or (curr_class = "taser")) or (curr_weapon = "hands")
          You hold John in front of you as you back behind the counter. Bullets strike his chest, and you feel his body jerk left and right. You release him and rush to the back of the terminal, just as more bullets fly over your head.
        *if (curr_class = "hack") or ((curr_class = "sword") or (curr_class = "knife"))
          John struggles against your arm, and you pull him towards the counter. He bucks and swings to wrestle off your arm. You draw the blade across his neck and shove him forwards. A gurgling rises in his throat, and he holds his hands over the wound. As you make it behind the counter, John drops to his knees and then falls flat on his face.
        *if curr_class = "club"
          John struggles against your arm, and you pull him towards the counter. He bucks and swings to wrestle off your arm. You release him and swing the club, smashing the back of his skull with one smooth strike. He sucks in a wheeze of air, drops to his knees and then falls flat on his face.
        *label MeleeAmbush
        
        *if (flank_team = 1) or (flank_team = 2)
          @{(flank_team = 1) Brody|Kevin} fires, and as 
        *if flank_team = 3
          As
        you crouch behind the counter, you hear a storm of bullets cut through the front of the terminal. You can't even lift your
        *if (flank_team = 1) or (flank_team = 2)
          head, and you spot @{(flank_team = 1) Brody|Kevin} beside you. He pops up, fires, and crouches behind cover again.
        *if flank_team = 3
          head.
        *label GravesFirefight
        You keep low and cover your ears as the sounds of the gunfire fill the small building. A cloud of gray smoke rises to the ceiling, and you stay ready in case one of the survivors comes around that counter.
        
        "We surrender!"
        
        And then it all stops. The rifle fire goes silent, replaced by groans and gurgles. The smoke dissipates. You peak over the counter.
        *if enola_alive
          *set enola_alive false
          Enola lies on her back with a bullet through her cheek.
        *if lewis_alive
          Lewis sits slumped against the side wall and holds @{lewis_injured his already injured shoulder.|His shoulder, which pumps blood from between his fingers.}
          *set lewis_injured true
        
        Eric tosses his rifle through one of the broken windows and holds his hands up. "We have children here."
        
        "Get up," you say and take one of the rifles lying on the ground. "Get outside. No sudden moves."
        *if flank_team = 1
        
          Brody rushes around the counter with his spiked lacrosse stick up like a baseball bat. He stops ahead of Eric and winds back. "I got this one. He won't try anything."
        *if flank_team = 2
        
          Kevin rushes around the counter and slips in a pool of blood. He stumbles and slams his back against the wall. Recovering, he holds out the rifle and aims at Eric.
        
        "We don't want any more trouble. We'll give you what you want," Eric says and stands. He places his hands on his head, turns to the door, and kicks it open.
        *if lewis_alive
          Lewis groans as he rises and follows Eric.
        *label GravesMarchedOut
        The terminal front door, now torn with holes, swings open, and your captives head in a straight line into the camp. From the back of the freight train, your companions take cautious steps with their weapons raised until they're in the clearing.
        
        You march them single file into the middle of the camp and order them to sit in a line, side-by-side, with their hands on their heads.
        *goto GravesSurrendered
  *elseif curr_type = "ranged"
    prepare to attack.
    
    Eric stands at the front of the building in a narrow, built out niche, which provides a bit of cover.
    *if search >= 70
      You can tell he knows how to hold the weapon, and he has command over the others. You'd place and as military or police in his former life. As you stare at him, you notice a thickness under his shirt. A Kevlar vest?
      *if enola_alive
        The woman to his right, Enola, also knows how to hold the weapon. Eric keeps looking over at her, and when she looks back at him, it's with deep concern. It's likely that you are in a relationship.
      John holds his rifle too high on his shoulder, showing you he's a novice with a rifle.
      *if lewis_alive
        Lewis @{lewis_injured holds up the rifle, but his injured shoulder has him waving the barrel all over the place.|may not be as well-trained as Eric but he knows his way around a rifle.}
    *if (search < 70) and (search >= 55)
      He holds his weapon up with perfect form. He definitely knows what he's doing.
      *if enola_alive
        Same with Enola. She keeps the weapon steady and aims down the sights.
      John keeps checking his rifle and looking over at Eric with an expression of worry.
      *if lewis_alive
        Lewis @{lewis_injured can barely hold up his weapon due to his injured shoulder.|presses the stock against his inner shoulder and has a relaxed look on his face.}
    *if search < 55
      You can tell that he leads this group. You are not sure about the rest of the group or their proficiencies with weapons. Will this be an easy fight or a bloodbath?
    
    Seeing the numerous targets, you
    *label AmbushFightTwo
    fire at…
    *set survivor_kills +1
    *choice
      #Eric—once the leader falls, everyone else will surrender or run.
        *set eric_alive false
        *if curr_class = "shotgun"
          The shot hits his rib cage from the side and throws his body into the wall, the top half bending over the broken window.
        *if (curr_weapon = "compound bow") or (curr_weapon = "recurve bow")
          Drawing back the bowstring, you aim and let an arrow loose. It strikes the back of his neck and comes out through the side. He half turns towards you and then slumps to the wall, sliding down until his body goes still.
        *if ((curr_weapon != "compound bow") and (curr_weapon != "recurve bow")) and (curr_class != "shotgun")
          You fire once into his rib cage and again into the side of his neck. Blood splatters on the wall, and he stumbles backwards a few feet and falls in front of the counter.
          
        Bullet fire erupts into the terminal from outside, and you rush behind the counter. The remaining survivors inside fire back at your companions across the camp while some shoot at you.
        *gosub GunShotsTerminal
        *goto GravesKillAll
      *if enola_alive
        #Enola—she is likely an easier target than Eric but poses a considerable threat.
          *set enola_alive false
          *if curr_class = "shotgun"
            The shot hits her chest and pushes her into the window. The force throws her body through the opening, and her legs fly up.
          *if (curr_weapon = "compound bow") or (curr_weapon = "recurve bow")
            Drawing back the bowstring, you aim and let an arrow loose. It buries into the back of her skull, and she stumbles back a few paces. She half turns towards you and then drops to the floor, her rifle falling from her hands.
          *if ((curr_weapon != "compound bow") and (curr_weapon != "recurve bow")) and (curr_class != "shotgun")
            You fire once into the back of her skull. Blood splatters both sides of the wall around the window and the butterfly pattern. She drops to the ground, her bleeding head in the corner where the wall meets the floor.
          *goto GravesOneShot
      #John—he's an easy target.
        *set john_alive false
        *goto GravesBro
      *if lewis_alive
        *if lewis_injured
          #Lewis—he's an easy enough target, and his death will make a point.
            *goto KillLewis
        *if not(lewis_injured)
          #Lewis—@{(search >= 55) he may be just as dangerous as Eric but an easier shot.|He's close and seems to know his way around a rifle.}
            *label KillLewis
            *set lewis_alive false
            *label GravesBro
            *if curr_class = "shotgun"
              The shot hits high on his shoulder close to his neck. He staggers sideways as a spurt of blood shoots out of the window. With a final step he falls backwards and lands at the corner where the wall meets the floor, his head forced forward.
            *if (curr_weapon = "compound bow") or (curr_weapon = "recurve bow")
              Drawing back the bowstring, you aim and let an arrow loose. It impales his throat, and one hand shoots up to grip the shaft. He turns, blood spilling from his mouth and making a gagging sound. Dropping to his knees, his eyes roll back and he falls face forwards.
            *if ((curr_weapon != "compound bow") and (curr_weapon != "recurve bow")) and (curr_class != "shotgun")
              You fire once through the back of his throat. One hand shoots up to cover the front of the wound as blood shoots out from both sides. He turns, his throat making a gagging sound. Dropping to his knees, his eyes roll back and he falls face forwards.
            *label GravesOneShot
            
            Gunfire rips through the front of the terminal, and the remaining survivors open fire, pivoting between the outside and aiming at you behind the counter. You duck as bullets fly over your head.
            
            *if (flank_team = 1) or (flank_team = 2)
              @{(flank_team = 1) Brody|Kevin} fires, and as 
            *if flank_team = 3
              As
            you crouch behind the counter, you hear a storm of bullets from all around.
            *gosub GunShotsTerminal
            *if ambush_graves = 3
              *goto GravesKillAll
            *else
              *goto GravesFirefight
  *else
    *set lewis_alive false
    sneak around the corner. The one named Lewis is closest to you. Since the survivors keep their focus outside the terminal, you creep behind him and
    *if (curr_class = "spray") or (curr_class = "taser")
      *if curr_class = "spray"
        shoot the pepper spray into his face.
      *if curr_class = "taser"
        fire the Taser. It hits him in the back, and his body stiffens from the shock. Somehow he remains standing.
      He spins around, and you duck as his rifle swings over your head. He gasps and stumbles forward as gunfire breaks out. You scramble behind the counter just as bullets rip through the front of the terminal and strike his body. He collapses to the floor, and a pool of blood spreads out.
    *if curr_weapon = "hands"
      grab him around the neck. You yank him backwards and
      *if mma_style <= 2
        slam a fist into the side of his neck. He struggles against your arm and tries to swing the rifle at you like a club. You punch him again, and his body goes limp in your arms. Laying him to the side, you pick up his rifle and bash his head with the stock.
      *if mma_style = 3
        flip him onto his back. His head slams against the floor, and his body goes limp like you've flipped a switch. You scramble to your feet
      *if mma_style = 4
        loop your other arm to apply a rear choke. He struggles in your grasp and swings the rifle at you like a club. You drop to the floor and cross your legs around him to keep him immobile. He fights against your hold but his strength fades in seconds. When his arms goes limp, you roll him to the side
      *if mma_style >= 3
        and pick up his rifle. Turning the weapon around you bash his skull with the stock until you're sure he's dead.
    *if curr_class = "hack"
      slam the blade of your weapon into the side of his neck. 
    *if curr_class = "sword"
      drive the blade through his back and out of his chest. He takes a short gasp of breath and drops his rifle. Yanking the weapon out, a spray of blood follows,
    *if curr_class = "knife"
      drive the blade through the back of his throat. 
    *if (curr_class = "hack") or (curr_class = "knife")
      His body straightens and a gurgling rises in his throat. His rifle falls from his hands as they reach up to grab the wound. Yanking the weapon out, blood sprays and splatters,
    *if (curr_class = "hack") or ((curr_class = "sword") or (curr_class = "knife"))
      and Lewis drops to the ground, struggling to stop the bleeding.
    *if curr_class = "club"
      slam the ${curr_weapon} across the back of his skull. He falls backwards, and when he hits the floor, you swing the weapon down at the top of his head. Blood splatters across your pants, and a gurgling rises in his throat. More blood spurts from his mouth in a cough, and you slam the weapon down one more time.
    *goto MeleeAmbush
*else
  You run forwards into the clearing, keeping watch on the terminal. Keeping low, you move at a steady pace, knowing success in flanking these survivors may end the fight.
  
  Bullets strike the ground next to you in a straight line, forcing you to cut back.
  *if flank_team = 1
    
    "Run!" Brody says as he turns and sprints back to the train.
  *if flank_team = 2
    You bump into Kevin, and the two of you sprint back to the train.
  Bullets ring off the metal railing just over your head, and you circle the massive train car and take cover. There's no way you're sneaking up on the survivors, so you make your way back around to your companions to join the gunfight.
  *goto GravesRound2
  
*label GunShotsTerminal
The constant pops causes your ears to ring, and the smell of smoke permeates the area. Glass breaks, and spent shells plink against the floor. Bullets hit the counter like nails are being hammered into it. When you hear a break in the gunfire nearby, you pop up, shoot, and drop back down. So many bullets hit the terminal, ripping through the walls, you can hear nothing else.
*return
  
*label GravesKillAll
*if flank_team != 3
  @{(flank_team = 1) Brody|Kevin} Positions near the back exit and fires through broken areas of the cage atop the counter.

You peek around the corner of the counter and @{(curr_type = "ranged") take another shot at the first body you see.|Prepare to attack the first person who wanders close to you.} Something strikes the counter by your rib cage, and you retreat again. The firefight seems to go on forever. Bullets fly in and out of the terminal. You hear a scream from the left side, and a voice calls for help. Another moment later, you hear the pounding of footsteps towards the front door and then a volley of bullets.

"My leg, my leg…oh God, oh G—"

Another shot interrupts the yelling, and you hear gurgling through the labored breaths. All of the gunfire in the terminal ends and only a few shots from outside continue on. When they die out, you creep from behind the counter. All of the survivors lie on the floor. Blood pools beneath their bodies.
*if eric_alive
  Eric lies against the left side wall with his shirt open, which exposes a Kevlar vest with the marks of a half dozen bullets. He's missing the lower half of his left year and his right thigh bleeds from an open wound. He's panting and wincing, and he holds a revolver in hand.
  
  "One…bullet left. Should I…use it…on myself?" he asks.
  
  You hold up your weapon, and he laughs coughing up blood and spitting it to the side.
  
  "I'm not using my last bullet on you," he says and smiles. Blood fills the spaces between his teeth. "Just kill me and get it over with. Or let me get my kids and go far away."
  
  @{(impulse >= 50) "Drop the pistol and push it over here."|"We can talk about that. First, I'd really feel better if you toss the pistol over here."}
  
  He places the revolver on the tile floor and gives it a halfhearted shove.
  *if flank_team != 3
    
    @{(flank_team = 1) Brody Steps around you and walks out of the terminal. From outside, you hear him yell, "Everything's okay. We won."|Kevin steps next to you, aiming his rifle at Eric, but looking between him and you with nervous caution.}
  *choice
    #I kill him. I can't afford to leave any survivors that may come back and threaten my group.
      *set honor %-15
      *goto KillEric
    #I kill him. Only my team deserves to survive this outbreak.
      *set ideal %-15
      *set morality %-15
      *label KillEric
      *set humanity %-15
      *set eric_alive false
      *set survivor_kills +1
      *set ruthless %+20
      *set graves_all_dead true
      *if curr_type = "ranged"
        You raise your ${curr_weapon}, @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) draw back your bowstring, and shoot an arrow. It flies the short distance and lands through his left eye. His head slams back, held in place by the arrow now stuck into the wall.|aim, and fire. The shot hits his eyes socket. His head hits the wall and bounces, and a spray of blood decorates the wall and trickles down.}
      *if (curr_class = "spray") or (curr_class = "taser")
        You pick up his pistol, drawback the hammer, and fire once into his face. It tears through the side of his mouth and exits the back of his skull, leaving a sizable hole in the back wall.
      *if curr_type = "melee"
        You raise your ${curr_weapon} and swing.
        *if curr_class = "hack"
          The blade hits at an angle above his ear and travels halfway into his head. His eyes cross, and his tongue sticks out. You step on his chest and yank the weapon away, flinging a wad of blood and flesh against the other wall.
        *if curr_class = "club"
          It hits the top of his head, cracking the front of the skull. His eyes cross, and his tongue sticks out. Raising the weapon again, you bring it down on the crushed part of his head, pushing the broken bone deeper. He makes a sound halfway between it gargle and a groan. You lift the ${curr_weapon} and swing, caving in the right side of his skull. Blood sprays against the wall, and his body flops to the side.
        *if curr_class = "sword"
          The blade slices through his face at an angle, popping one eye and ripping his bottom lip in two. A slow wheeze escapes his mouth, and you see a look of fear and pain on what's left of his face. Drawing back the blade, you thrust it through his forehead. He sucks in a quick breath, his eyes roll back, and his body goes limp.
        *if curr_class = "knife"
          The blade impales his eye, and the impact slams his head against the wall. His other eye flies around in the socket, and his tongues sticks out an absurd distance. When you pull the blade out, his body leans sideways, dripping blood onto the floor.
      *if curr_weapon = "hands"
        *if mma_style <= 1
          You rush forwards and slam a fist into his face. His head bounces against the wall behind him. You slam your other fist into his cheek. Over and over again, you rain down punches
        *if mma_style = 2
          You take a step forwards and throw a kick into his face. His head bounces against the wall behind him. Lifting your leg again, you kick and land a heel on his cheek. Over and over again, you rain down kicks
        *if mma_style <= 2
          until his face is a bloody, pulpy mess. His eyes are crossed, and he chokes on blood spilling into his mouth. Winded from your assault, you stand back and watch as he takes a final breath.
        *if mma_style >= 3
          You rush forwards and wrap your hands around his throat. Driving all of your weight through your extended arms, you choke him against the wall. His hands grip your forearms as he struggles to push you off. His feet kick, and he fights to draw in breath. His eyes rolled back, and his hands tear into your skin in his feeble, weakened attempt to pry you off. You keep up the pressure, and in time, his arms goes limp. Dripping with sweat, you pull back, and he slumps over.
      *goto ScavengeCamp
    #"Go get your kids and leave. You have two minutes to be gone, or you die."
      *set honor %+10
      *goto ReleaseEric
    #"Take a few minutes, get some supplies for the road, and leave with your kids. Never come back here again."
      *set morality %+15
      *set ruthless %-10
      *label ReleaseEric
      *set graves_left_camp true
      He struggles to stand and grunts and groans as he finds his legs and stumbles into the bathroom. You follow after him to ensure he doesn't change his mind or try to attack. As you enter the large public bathroom, you spot a pregnant woman crouched at the back wall, holding a gun out. Two toddlers sit on the floor next to her.
    
      "That's Danica, my sister-in-law, and my two kids, Abel and Grace." He chokes up at the end. "Dani, put down the gun. We're leaving."
      
      When they draw closer, Danica hands off the children to Eric. She wears a flowing dress and has her hair woven into one long braid. Her arms have tribal tattoos in rows around her forearms, and you noticed the same ones on Lewis.
      
      "Hand over the pistol and then hurry up out of here. If we see you again, we'll have no choice but to attack. I really don't want that."
      
      Eric stands and hikes up @{enola_alive his daughter onto his hip.|the kids onto his hips.} "You won't ever see us again." He speaks in a low voice to the children and to Danica. "Abel, Grace, I want you to close your eyes. We're playing hide and seek. Don't open them until I say it's okay. Dani, you're going to need to hold it together. We need to go."
      
      Danica hands over the pistol, and you follow them out into the terminal. When she sees the dead on the floor, her eyes go wide and her bottom lip trembles. She grips Eric's arm and pushes her face into his back so she can't see. The toddlers hold their hands over their eyes, and the four remaining survivors of the camp exit through the back door and leave the train yard going west. After their unfair distance away, you circle back to the camp where your friends are already started scavenging.
      *goto ScavengeCamp
*else
  *set graves_all_dead true
  *goto ScavengeCamp
  
*label GravesAssault
*set attacked_graves true

Now that you have a plan, you draw a weapon…
*gosub_scene CheckWeapons
*fake_choice
  #$!{p_weapon}.
    *gosub_scene FightCode UsePrimary
    *set using_primary true
  #$!{s_weapon}.
    *gosub_scene FightCode UseSecondary
As you prepare to attack,
*if flank_graves
  Brody and @{flank_south Kevin|Gina} move along the freight train to the southern side of the camp. When they cross to another train, they're gone from sight. They need time to sneak around the back of the terminal, so you need to stall. You
*if not(flank_graves)
  you
lean past the front of the freight train and can see the survivors in camp behind crates, retreating into the terminal, or advancing to better cover.

@{(graves_prepared or graves_attacked_front) "Leave now. I'm not giving you another warning,"|"What's your move? We don't have all day. If you need something, tell us what it is or beyond your way,"} the man in front shouts. He has a thick black beard and a crew cut and carries a rifle, possibly a military variety. Though he's telling you to run, you spot him waving for his team to advance.

On his right, a slightly taller man crouches behind a large crate and has a hunting rifle of some sort. He is dressed in a purple shirt and blue khaki shorts like he's vacationing on an island.
*if enola_alive
  @{(graves_prepared or graves_attacked_front) The woman with the long black hair|Long black hair hangs in a braid with the sides of her head shaved bald. She wears jeans shorts and a T-shirt and} takes cover behind a stack of heavy burlap sacks. Her rifle pokes around the side of the largest sack.
*if lewis_alive
  Finally, another man leans halfway out of the door of the terminal. He's shirtless with countless tattoos over his body and shoulderlength hair as dark as the man with the crew cut and beard. He @{lewis_injured struggles to hold a rifle in his hands, and you can see bandages wrapped around his shoulder.|holds up a rifle to his shoulder and moves the barrel in tiny circles.}
  *if (search >= 55) and not(lewis_injured)
    You can tell by this motion he's looking for the perfect shot.
    
*if flank_graves
  Needing to delay this until your companions are in position to flank the survivors, you shout to the bearded man,
  @{(impulse >= 50) "You can't win here. Leave your camp and stay alive. I'll give you three minutes to gather your people and go."|"We don't want any trouble. We just need a few things, and then we'll be on our way. We don't need to kill each other."}
  
  *if enola_alive and lewis_alive
    @{(impulse >= 50) "You're dead wrong. You stumbled on the wrong camp. I don't want to waste bullets or you'd be dead already. Just leave," he shouts back.|"You don't need anything we have. Just move on. Don't make me waste bullets on you."}
  *if not(enola_alive) or not(lewis_alive)
    Just shut up and go. I don't want to hear anything you have to say.
    You killed
    *if not(enola_alive)
      her—my wife.
    *if not(lewis_alive)
      him—my brother.
    Leave now and leave alive."
    
  You pause, stretching out the time. Peering past the end of the freight car, you see the dark bearded man talking to his companions, though they're to far away to hear the conversations. The man with the long hair lowers his weapon and kicks the door frame. At this the woman shouts at him to stay focused.
  *gosub_scene Part2Events CheckTrained "Brody" "Stealth"
  
  *if (flank_south = 1) or passed_training_check
    Shots fire from inside the terminal.
    *if lewis_alive
      *set lewis_alive false
      Lewis drops to his knees, crawls outside, and collapses in the dirt.
      
      "Lewis!" 
    *if not(lewis_alive)
      *set john_alive false
      Bullets ripped through the tall man in the purple shirt. He stumbles from behind the crate and falls face first onto the dirt.
      
      "John!"
    the man shouts.
  *if (flank_south != 1) and not(passed_training_check)
    "This is getting old," the man shouts. "You got to the count of five."
    
    The man at the door of the terminal spins and fires behind him. "They're flanking us!"
    
  The
*if not(flank_graves)
  "Everyone ready for this?" you ask and stare around at your companions.
  
  All seem @{(morale >= 60) resolved and prepared with weapons raised.|hesitant. Kevin backpedals a few steps, while Brody stares at his pistol and sighs. Only} Madison has a slight smile on her face.
  
  You raise your ${curr_weapon} and @{(curr_type = "ranged") scan for the best target. As you consider your first shot,|hang back from the front of the freight train. Without a ranged weapon, you will need to sneak or run forwards to attack, exposing yourself to gunfire. As you consider your first move,} the
camp survivors open fire. Bullets ring off the freight train, while some whiz over your head. You @{(curr_type = "ranged") return fire, hitting the crate near the bearded man and forcing him to duck.|move into full cover, allowing Madison to take your place at the front and the freight train.}
*label GravesRound2
*if sop <= 2
  *set group_offense +(m_leadership/14)
*if sop = 3
  *set group_offense +(m_leadership/8)
*if sop >= 4
  *set group_offense +(m_leadership/6)
*if brody_weapon != "dummy"
  *set group_offense +round(5+(brody_mod/10))
*if gina_available
  *set group_offense +6
*if curr_type = "ranged"
  *set group_offense +round((ranged + curr_mod)/10)
*if enola_alive and not(enola_injured)
  *set graves_offense +7
*if enola_injured
  *set graves_offense +2
*if lewis_alive and not(lewis_injured)
  *set graves_offense +6
*if lewis_injured
  *set graves_offense +1
*if john_alive
  *set graves_offense +5
  
You @{(curr_type = "ranged") exchange shots between targets, hoping to catch an exposed arm or leg. The survivors stay behind cover and coordinate to reload. They take their time and remain calm. Other than gunfire, you only hear the shouts of their leader giving instructions.|keep low while both sides fire at one another, and the frequent pops of ranged weapons scatters around the camp.}

After the first wave of bullets exchange between the two sides, the camp survivors make a move. The bearded man waves to the guy in the purple shirt, who
*if group_offense > graves_offense
  *set john_alive false
  falls back towards the terminal. A gunshot sounds, and blood flies out the side of his ribs. He topples to the dirt, gripping his stomach, and writhing on the ground.
  
  "John!" the bearded man shouts.
  
  Bullets strike the crate in front of him, forcing him to duck.
  *if enola_alive
    *set enola_injured true
    The woman behind the burlap sacks rushes out of cover towards the body of the fallen man. As she closes in, she's struck in the shoulder. You hear her scream from across the camp, and she half stumbles, half crawls behind a stack of crates.
  
  "We surrender!" the bearded man shouts.
        
  And then it all stops. The rifle fire goes silent. The smoke in the camp dissipates. The leader tosses his rifle several feet away and holds his hands up in the air.
  *if enola_alive
    The woman steps out from cover with one arm raised, the other hanging with her shoulder wound still bleeding.
  *if lewis_alive
    The tattooed man steps from the terminal, @{lewis_injured cradling his injured arm.|holding his rifle over his head.}
  
  Your group moves around the trains on the outer edge of camp, weapons raised, and walks towards the survivors. Kevin runs ahead, grabs the leader's rifle, and steps back to join the rest of you.
  
  As you get closer, the bearded man takes a deep breath and says, "We have children here."
  
  "Sit on the group and keep your hands over your head," you say.
  
  Brody rushes next to him with his spiked lacrosse stick up like a baseball bat. He stops ahead of him and winds back. "I got this one. He won't try anything."
  *if with_gina
  
    Gina moves to the woman and waves at her with her shotgun. "Over there. Sit next to him. No sudden movements."
  
  "We don't want any more trouble. We'll give you what you want," the bearded man says. "I'm Eric and this is my wife, Enola. Behind me is my brother Lewis." As he speaks he looks over at the fallen man in the purple shirt, now darkened by blood.
  *if lewis_alive
  
    The tattooed man, who you now know as Lewis, walks over and sits next to the others.
  *goto GravesSurrendered
*else
  Pops out of cover and fires rapid shots at the edge of the freight train. Madison and Gina retreat behind the train's front end as bullets strike the metal.
  *if flank_south = 1
    
    "Kevin's hit," Brody shouts from across the camp. "It's just his leg. Why the hell are we fighting?"
  *if flank_south != 1
    You hear a shout from your side and spot Kevin drop to the ground.
    
    "I'm hit. Oh God, I'm hit," he yells and grips his leg.
    
    His pants show a tear and a trace of blood goes across the outside of his thigh.
    
  "We didn't want to fight," the leader says. "Put your weapons down and leave. Or die."
  
  "We just wanted a damn stereo!" Madison shouts.
  
  The man in the purple shirt yells out, "We don't have one, but I saw one in the next train yard over outside the terminal in a pile of junk."
  
  You turn to Madison who has the look of someone who just saw a ghost. Her pale skin turns blank white as all the color fades from her face.
  *page_break
  *set kevin_hurt true
  You call for your group's surrender and to rendezvous back at the tree line. Brody carries Kevin in his arms and places him down in front of you. After calming Kevin down, you explain he only took a flesh wound. You rip a strip of his shirt and tie it around the upper end of his thigh. He stands and limps around, and you can almost hear his heartbeat returning to normal.
  
  Going on the words of the camp survivors, your group walks towards the next train yard.
  *gosub OtherTrainYard
  Though the excursion is not a total loss, no one calls it a win. Madison sulks the entire way home. Just before you reach the Junkyard, she steps ahead of the group and turns.
  
  "Let me just say this, and no one say anything back. I'm sorry. I'm sorry to all of you for risking your lives for something as stupid as it stereo. I know I take things too far sometimes. I've been spoiled most of my life, but I realize that. I don't know what else to say but I'm sorry."
  
  She turns and continues along the path, and the rest of you follow.
  *goto OnTheWay
  
*label OtherTrainYard
*set stereo_system true
*set mech_parts +4
*set metal_parts +4
*set wood_parts +6
It's a fifteen minute walk and another ten minutes to search a pile of debris for the stereo and three speakers. You find scrap metal, pieces of wood, and some mechanical parts as well.
*return
    
*label GravesSurrendered
*set graves_surrendered true

"Nice work," Madison says, giddy with excitement.

"There's a young woman and two toddlers inside. Why don't you go get them and bring them outside. I don't think they have any weapons but be careful."

She nods and jogs towards the terminal.

"My name is Eric Graves.
*if enola_alive
  Next to me is my wife, Enola.
*if john_alive
  Him over there in the purple shirt is my brother, John.
*if lewis_alive
  The man without the shirt and all the tattoos is my brother, Lewis.
We're just a family trying to survive. What do you want from us?"
*fake_choice
  #"We came to scavenge and nothing more. We only attacked you, so we're in control while we take supplies."
    *set honor %+15
    "It didn't have to be this way," Eric says. He hangs his head and closes his eyes for a moment, before lifting it again." Everything's gone crazy. This virus has made us all attack one another for scraps. It doesn't have to be this way."
    
    *if with_gina
      "No one cannot argue with that. We do whatever we can to survive. None of us have the luxury of asking for things nicely anymore," Gina says.
    *if not(with_gina)
      @{(ideal >= 50) "We're just doing what we can to help our people survive while doing the least damage to others.|"I agree about the virus, but unfortunately it has to be this way. We're all running out of supplies, and it's only going to get worse."}
  #"Once my teammate brings out the kids, you have three minutes to get out of here. Never come back. That's the only kindness I can offer."
    *set morality %+15
    *set ruthless %-15
    *set graves_left_camp true
    His face shows sudden relief. "Thank you." He tries to find more words, but he just hangs his head.
    
    A few minutes pass, and a pregnant woman holding two toddlers walks out of the terminal. Madison follows with her rifle raised.
    
    "That's Danica, my sister-in-law, and my two kids, Abel and Grace." He chokes up at the end.
    
    When they draw closer, Danica hands off the @{enola_alive children, one to Eric and one to Enola.|children to Eric} The pregnant woman wears a flowing dress and has her hair woven into one long braid. Her arms have tribal tattoos in rows around her forearms, and you notice the same ones on Lewis.
    
    "All right, your weapons stay here, but all of you can go. If we see you again, we'll have no choice but to attack. I really don't want that."
    
    Eric stands and hikes up @{enola_alive his daughter onto his hip.|the kids onto his hips.} "You won't ever see us again."
  #"Shut up, and this will all be over soon," I say and tell my companions to scavenge this place.
    *set honor %-15
    "Just take it easy," Eric says. "You won, so just get this over with."
  #"Where are all of your supplies?"
    *set impulse %-15
    Eric rolls his tongue in his cheek and then says, "Most of what we got is in the terminal. There's some food in there sacks and personal items around our camp. We ain't got much."
  #"We don't want anything more from you," I say and kill them all.
    *set morality %-15
    *set ruthless %+15
    *set graves_all_dead true
    *set humanity %-15
    *set eric_alive false
    *set survivor_kills +1
    *if curr_type = "ranged"
      You raise your ${curr_weapon}, @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) draw back your bowstring, and shoot an arrow. It flies the short distance and lands through his left eye. His head snaps back,|aim, and fire. The shot hits his eyes socket. His head snaps back,} and his body takes a slow descent to the dirt.
    *if (curr_class = "spray") or (curr_class = "taser")
      You pick up his pistol, draw back the hammer, and fire once into his face. It tears through the side of his mouth and exits the back of his skull, leaving a sizable hole.
    *if curr_type = "melee"
      You raise your ${curr_weapon} and swing.
      *if curr_class = "hack"
        The blade hits at an angle above his ear and travels halfway into his head. His eyes cross, and his tongue sticks out. You step on his chest and yank the weapon away, flinging a wad of blood and flesh onto the dirt.
      *if curr_class = "club"
        It hits the top of his head, cracking the front of the skull. His eyes cross, and his tongue sticks out. Raising the weapon again, you bring it down on the crushed part of his head, pushing the broken bone deeper. He makes a sound halfway between a gargle and a groan. You lift the ${curr_weapon} and swing once more, caving in the right side of his skull. Blood sprays against the floor, and his body flops to the side.
      *if curr_class = "sword"
        The blade slices through his face at an angle, popping one eye and ripping his bottom lip in two. A slow wheeze escapes his mouth, and you see a look of fear and pain on what's left of his face. Drawing back the blade, you thrust it through his forehead. He sucks in a quick breath, his eyes roll back, and his body goes limp.
      *if curr_class = "knife"
        The blade impales his eye, and you twist the weapon in place. His other eye flies around in the socket, and his tongues sticks out an absurd distance. When you pull the blade out, his body leans sideways, dripping blood onto the dirt.
    *if curr_weapon = "hands"
      *if mma_style <= 1
        You rush forwards and slam a fist into his face. His head snaps backwards, but he shakes off the blow. You slam your other fist into his cheek. Over and over again, you rain down punches
      *if mma_style = 2
        You take a step forwards and throw a kick into his face. His head snaps backwards, but he shakes off the blow. Lifting your leg again, you kick and land a heel on his cheek. Over and over again, you rain down kicks
      *if mma_style <= 2
        until his face is a bloody, pulpy mess. His eyes are crossed, and he chokes on blood spilling into his mouth. Winded from your assault, you stand back and watch as he takes a final breath.
      *if mma_style >= 3
        You rush forwards and wrap your hands around his throat. Driving all of your weight through your extended arms, you choke him against the floor. His hands grip your forearms as he struggles to push you off. His feet kick, and he fights to draw in breath. His eyes roll back, and his hands tear into your skin in his feeble, weakened attempt to pry you off. You keep up the pressure, and in time, his arms goes limp.
        
        Dripping with sweat, you pull back, and he slumps over.
    *if enola_alive
      *set enola_alive false
    *if john_alive
      *set john_alive false
    *if lewis_alive
      *set lewis_alive false
    
    You hear the cries of the other survivors as they see the body of their fallen brother and husband. Taking your lead, your companions make short work of the strangers, ending their lives in clean shots.
*goto ScavengeCamp

*label GravesCamp
*fake_choice
  #"I agree. Madison, why don't you stay outside. You can be our sniper if we get into a fight."
    *set honor %-15
    *set madison_faction %+(round(m_leadership/6))
    She nods at you and hangs back as you walk towards the camp.
  #"Why don't I go in alone. It's the least risky way, at least for everyone but me."
    *set honor %+15
    *set outside_camp 2
    She looks at you with an intense stare, eyes drawing inward.
    *if madison_faction >= 50
      "I didn't mean for you to put yourself in all of the danger. They could kill you before we even know it's happening."
      
      "This is better for the group. We can't risk everyone. I'll be very careful, and you guys will be watching the whole time. Can you tell everyone?"
    *if madison_faction < 50
      "If you think that's best, I'll tell the others."
    
    You hurry up ahead so no one can argue with your decision. As you draw closer to the camp you glance over your shoulder and see everyone hanging back.
  #"Let's all go in together and show them we're not intimidated."
    *set impulse %+15
    *set outside_camp 3
    *set madison_faction %-(round(20-(empathy/6)))
    Madison sighs and checks the ammunition in her rifle. "They don't sound like the type of people who are intimidated, but okay."
    
    You ignore the comment and proceed ahead.
  #"We should all go in together. If we look suspicious or even cautious, it may make them aggressive towards us."
    *set ideal %-15
    *set outside_camp 3
    *set madison_faction %-(round(20-(empathy/6)))
    Madison sighs and checks the ammunition in her rifle. "We are a group of
    *if with_gina or not(teenager)
      mostly
    teenagers carrying rifles into a train yard. We look suspicious."
    
    You ignore the comment and proceed ahead.
  #"Let's all go together. They have kids in there and look like good people."
    *set ideal %+15
    *set outside_camp 3
    *set madison_faction %-(round(25-(empathy/6)))
    Madison sighs and checks the ammunition in her rifle. "We're all going to die."
    
    You ignore the comment and proceed ahead.
Reaching the stranger's camp, you see it's shaded from sunlight by the train cars and tarp, and every once in a while a cool breeze blows through the clearing. Extension cords stretch from the terminal to the sleeping area, and a series of fans sit idly on the floor of an open train car pointed out.

The man in the black beard steps forward, his rifle on his shoulder and behind his back. "Welcome to our camp. Before we get to talking, let's get through introductions. We may not look it, but we aim to be civilized. I'm Eric and my knockout wife is Enola."

The woman with braided long dark hair kisses his cheek and pinches his arm playfully. She nods to the side of the camp where a man in a purple shirt and blue khaki shorts stands. He has black curly hair and a thin mustache.
*if like_males
  When you look over to him, he smiles and gives you a wink.
"That's Eric's brother, John."
  
"His knockout brother," John says.

By the door frame of the terminal, another man leans out. He's shirtless with countless tattoos over his body and shoulderlength hair as dark as the other two men. "That's my brother, Lewis. His wife, Danica, is inside with my two kids."
*if search >= 55
  As Lewis turns to look inside the terminal, you can see a large tattoo that says Southern Ute. Wasn't that the tribe Woody lived with?

"I'm ${firstname}.
*if (outside_camp = 1) or (outside_camp = 3)
  That's Brody. Kevin is standing over there behind him.
  *if with_gina
    On my left is Gina.
  *if outside_camp = 3
    Standing back over there is Madison.
We just came across your camp looking for supplies. We had no way of knowing anyone was here."

*if outside_camp = 1
  *set graves_faction %-(round(20-(m_leadership/6)))
  
  "What's up with that girl outside camp?" Enola asks.
  
  @{(ideal >= 50) "She's a bit cautious. I felt like it was safe to come in here, but I didn't want to argue with her."|"She didn't feel safe coming in here with the rest of us. Not every group we meet is friendly."}
  
  "You mean strangers aren't dishing out bowls of ice cream and throwing dance parties in the zombie apocalypse? That's news to me,"
*if outside_camp = 2
  *set graves_faction %-(round(25-(m_leadership/6)))
  
  "Why are you the only one coming into camp?" Enola asks.
  
  @{(ideal >= 50) "We've learned to be cautious during the outbreak. I felt it was safe for me to come in here, but we didn't need the whole group to talk."|"We're being cautious. Not every group we meet is friendly."}
  
  "Want me to go out there and give them all hugs? Or I can bake up a quick pie,"
*if outside_camp <= 2
  John says, lifting a plastic basket of clothing and bringing it over to the clothes line.
  
  "You're such a smartass," Enola says.
*if (outside_camp = 1) or (outside_camp = 3)
  *set graves_faction %+(round(m_leadership/6))
  
  Brody stares hard at Enola. When she asks if he's okay, he says, "Oh my goodness, are you the lead singer of Gold Rust? Enola Graves!"
  
  She laughs and gives a short bow. "That's me in the flesh."
  
  "I can't believe it. This is crazy. I'm freaking out," he says.
  *if with_gina
  
    Gina steps up and fans out the bottom of her shirt. "I'm wearing one of your concert shirts."
  
  "It's great to meet fans," she says.
  
  "How are the other members of the band?" Brody asks.
  
  Enola's expression turns sour. "I lost catch with them two days ago. CJ went to visit his family in Ontario. Dustin went to Kansas to be with his girlfriend's family. Since the phone lines gone down, I have no way to reach them. I'll just say it lifts my spirits that you recognized me. I didn't think my music matter to anyone, at least not since all this happened."
  
"Anyway, what brings you here today?" Eric asks.
*set count 0
*label GravesChat
*set count +1
*if count = 3

  Enola raises her hand. "Mind if I ask a question?
  *if college_student or teenager
    *if outside_camp = 2
      Are you and your friends living by yourselves without any adults? You seem young to be surviving on your own."
      *fake_choice
        #"Yes, it's just us. Our parents didn't survive, so we had no choice but to band together."
          *set truth %-15
          *set graves_faction %+(round(m_leadership/6))
          Enola puts her hand to her chest. "I'm so sorry to hear that. Stay strong. I'm sure you're doing the best you can do."
          
          "You're taking a big risk by going around unknown places and scavenging. If you're out of food and water, we can give you some. Don't have much to spare, but right now we could share."
        #"We are in a large group which includes adults."
          *set truth %+15
          *set graves_faction %+(round(m_leadership/6))
          Enola puts her hand to the side of her face in shock. "Adults sent you without supervision?"
          *fake_choice
            *if with_gina
              #"We have an adult with us. She's right outside camp."}
                *set truth %+15
                Eric nods. "I would just expect more than one adult to be with y'all. Just be careful out here.
            #"Me don't need supervision. Young adults today are very capable people."
              *set ideal %+15
              Enola nods. "Of course comment you seem very capable.
            #"We didn't ask for permission and don't need it."
              *set ideal %-15
              Eric scoffs. "Settle down with the attitude. We're just concerned.
            #"We have other groups scavenging nearby, and there are adults in those groups."
              *set truth %-15
              Enola nods. "That's good to hear. It's dangerous to scavenge alone.
          There are a lot of bad people out here these days, looking for opportunities to take advantage of people, especially young people. Please be careful."
        #"I don't feel comfortable with that question."
          *set ideal %-15
          *set graves_faction %-(round(20-(empathy/6)))
          Enola puts her hand to the side of her face in shock. "You don't have to be nervous around us. I'm only asking questions out of concern. We're answering your questions. Conversations are give-and-take."
          
      Next you say…
      *goto GravesHub
    *else
      Did you all go to the same high school or college or something? You look awfully young as a group to be surviving out here alone."
      
      *if teenager
        "Me and Brody
        *if outside_camp = 3
          and Madison
        went to the same high school. We met Kevin not long ago."
      *if with_gina
        "I've been out of high school for many years. Please don't ask my age," Gina says with a laugh.
        
      Eric scratches the under his chin. "There are a lot of bad people out here these days, looking for opportunities to take advantage of people, especially young people. Please be careful."
      
      Next you say…
      *goto GravesHub
  *elseif (uniform = "combat") or (uniform = "service")
    Are you in the military? We've seen people taking uniforms off of dead soldiers."
    *fake_choice
      #"Yes, I was active duty up until the outbreak started."
        *set graves_faction %+(round(m_leadership/6))
        "You don't say? Thanks for your service," Eric says. "I don't know what all those stripes and badges mean. They look cool."
        
        "I'm a
        *if prof_military
          *set truth %+15
          ${military_rank}."
        *if not(prof_military)
          *set truth %-15
          Sergeant."
          
        "Well pleased to meet you, soldier."
      #"No, I just needed some clean clothes."
        *set morale %-15
        *if prof_military
          *set truth %-15
        *if not(prof_military)
          *set truth %+15
        Eric nods. "I don't blame you. Just be careful, because I've heard people are attacking soldiers. They think they have supplies."
      #"No, I killed a soldier and took their gear."
        *set graves_faction %-(round(20-(m_leadership/6)))
        *set morality %-15
        *if prof_military
          *set truth %-15
        *if not(prof_military)
          *set truth %+15
        Eric's eyes widen. "Jesus, did you have a reason to do that? On second thought, I don't want to know."
        
    Next you say…
    *goto GravesHub
  *elseif ((uniform = "scrubs") or (uniform = "white coat")) and not(told_graves_medical)
    Are you a doctor or scientist?"
    *fake_choice
      #"I'm an ER physician."
        *set graves_faction %+(round(m_leadership/6))
        *set told_graves_medical true
        *if doctor
          *set truth %+15
        *if not(doctor)
          *set truth %-15
        Eric nods. "It's good to know that some people with medical experience are surviving. You are going to be a lot more important nowadays. A simple injury could kill anyone."
      #"I'm an ER Nurse."
        *set graves_faction %+(round(m_leadership/6))
        *set told_graves_medical true
        *if nurse
          *set truth %+15
        *if not(nurse)
          *set truth %-15
        Eric nods. "It's good to know that some people with medical experience are surviving. You are going to be a lot more important nowadays. A simple injury could kill anyone."
      #"I'm a research scientist who studies viruses."
        *set graves_faction %+(round(m_leadership/6))
        *if scientist
          *set truth %+15
        *if not(scientist)
          *set truth %-15
        Eric nods. "I realize you need to survive, find food, shelter, and other necessities, but I hope you can get back to researching a cure or treatment or whatever. The human race needs all the help it can get."
      #"No, I just found these scrubs and put them on."
        *set graves_faction %+(round(m_leadership/6))
        *if not(prof_health) and not(scientist)
          *set truth %+15
        *if prof_health and scientist
          *set truth %-15
        Eric nods. "I don't blame you. Just be careful. I've heard people are kidnapping doctors and forcing them to work with threat of violence."
    
    Next you say…
    *goto GravesHub
  *elseif uniform = "cop"
    Are you a police officer?"
    *fake_choice
      #"Yes, I was a beat cop up until the start of the outbreak."
        *set graves_faction %+(round(m_leadership/5))
        *if cop
          *set truth %+15
        *if not(cop)
          *set truth %-15
        Eric nods. "I'm a SWAT team member out of Colorado Springs. Good to meet another officer.
      #"No, I took the uniform off a dead police officer just for a change of clothes."
        *if cop
          *set truth %-15
        *if not(cop)
          *set truth %+15
          Eric nods. "Normally I'd say that's smart.
      #"No, I just felt this uniform commands respect and may keep me safe from attack."
        *set honor %-15
        *if cop
          *set truth %-15
        *if not(cop)
          *set truth %+15
          Eric nods. "Normally I'd say that's smart.
      #"No, I killed a police officer and took his uniform."
        *set morality %-15
        *if cop
          *set truth %-15
        *if not(cop)
          *set truth %+15
        Eric's eyes widen. "I don't even want to ask why you did that.
    Just be careful people. Some survivors are shooting at police out of spite or thinking they have supplies."
    
    Next you say…
    *goto GravesHub
  *elseif movie_star
    Are you the actor, ${name}?"
    *fake_choice
      #"Yes, that's me."
        *set graves_faction %+(round(m_leadership/6))
        *if movie_star
          *set truth %+15
        *if not(movie_star)
          *set truth %-15
        Enola lights up, shaking her hands like a nervous fan outside one of your premieres. "Oh my God, I'm fangirling right now. I've seen all of your movies."
        
        Eric scoffs. "I like the old TV shows better than these Hollywood movies."
        
        "Well, it's good to meet a fan."
      #"No, but I get that question all the time."
        *if movie_star
          *set truth %-15
        *if not(movie_star)
          *set truth %+15
        Enola frowns, bottom lip pouting. "You look just like the actor. It's amazing. But now that I think about it, what would ${name} be doing in Colorado. Anyway, the resemblance is crazy."
      #"No, I didn't even know someone was using my name as an actor."
        *if movie_star
          *set truth %-15
        *if not(movie_star)
          *set truth %+15
        Enola frowns, bottom lip pouting. "You look just like the actor. It's amazing. But now that I think about it, what would ${name} be doing in Colorado. Anyway, the resemblance is crazy."
    
    Next you say…
    *goto GravesHub
  *elseif wrestler
    Are you the wrestler, ${name}?"
    *fake_choice
      #"Yes, that's me."
        *set graves_faction %+(round(m_leadership/6))
        *if wrestler
          *set truth %+15
        *if not(wrestler)
          *set truth %-15
        Eric's eyes widen, and shows you in large smile. "Well what do you know? I've been to your last few matches. We watch on YouTube and try to get out to events when possible. It's crazy to think you're just standing here."
        
        "Well, it's good to meet a fan."
      #"No, but I get that question all the time."
        *if wrestler
          *set truth %-15
        *if not(wrestler)
          *set truth %+15
        Eric frowns. "I could have sworn it was you. My family are big fans. Now that I look at you closer, I can see the differences."
      #"No, I didn't even know someone was using my name as a wrestler."
        *if wrestler
          *set truth %-15
        *if not(wrestler)
          *set truth %+15
        Eric frowns. "I could have sworn it was you. My family are big fans. Now that I look at you closer, I can see the differences."
    
    Next you say…
    *goto GravesHub
  *else
    Are you originally from this area?"
    *fake_choice
      #"Yes, I grew up in Nightfall."
        *set truth %+15
        *set graves_faction %+(round(m_leadership/6))
        Enola smiles. "I have family in Stodgy Farms."
        
        "That's amazing. We're basically neighbors."
      #"No, I'm from Northern Colorado."
        *set truth %-15
        Enola frowns. "I could've sworn I've seen you around Nightfall before the outbreak started. My mistake."
      #"No, I was visiting from out of state when the outbreak started."
        *set truth %-15
        Enola frowns. "I could've sworn I've seen you around Nightfall before the outbreak started. My mistake."
  
    Next you say…
    *goto GravesHub
*label GravesHub
*choice
  #"Are you the only ones here at this train yard?"
    Eric gives you an annoyed smile. "That's a helluva question. Are you trying to find out how many people you'll have to fight?"
    
    Enola nudges him in the ribs. "Don't be so damn cynical. It was just a question." She turns to you and says, "It's just our family here. We've had some strangers come by, but none stick around. There are some train cars farther up the tracks where people were staying, but they all got bit or chased off by infected. We've been here since day zero and don't plan on going anywhere."
    *goto GravesChat
  #"Why this train yard? It doesn't seem like the best place for a family with children."
    Eric chuckles. "What's so bad about it? These train cars can stand up to attack by infected or in a gunfight. That terminal behind us is solid concrete and brick. It still has juice running through it to power the fans. Even the toilets work. I'm not sure how long that will all last, but I see no reason to leave. Just don't think we're taking any new people in. You seem great, but we're still skeptical of strangers."
    *if (outside_camp = 1) or (outside_camp = 3)
    
      "We have a good place to live," Brody says. As he starts to speak again, Kevin kicks his leg.
    *goto GravesChat
  *if (prof_health or (medicine >= 60)) and not(offered_graves_exam)
    #@{told_graves_medical "I told you I work in medicine. Do you want me to give a checkup to Danica and the kids?"|"I'm skilled in medicine and would be happy to give a checkup to Danica and the kids if you'd like."}
      *set offered_graves_exam true
      *set graves_faction %+(round(m_leadership/5))
      Enola's eyes light up.
      *if told_graves_medical
        "I didn't want to impose, but
      *if not(told_graves_medical)
        *set told_graves_medical true
        "Oh my God,
      that would be amazing. The twins were due for an appointment next month, and Danica can use a prenatal exam."
      
      Eric stares at you with intensity and says, "I really appreciate this."
      *goto GravesChat
  #"What did you all do before the outbreak?"
    "I was a SWAT team member for the Colorado Springs Police Department," Eric says.
    
    "I'm a homemaker now since having the twins," Enola says.
    *if (outside_camp = 1) or (outside_camp = 3)
    
      Brody adds on, "But you were in the best band of all time."
    
    John walks by on his way to the makeshift tent. "Male exotic dancer."
    
    Enola boss out laughing, while Eric frowns. He rolls his eyes and says, "He's a fireman out of Colorado Springs."
    
    "He just means I wear a fireman's outfit on stage. My fans call me Big Johnny Flames," John says.
    
    Eric takes a big sigh. "My brother can never be serious. Anyway, Lewis is a mortician and funeral director."
    
    @{((outside_camp = 1) or (outside_camp = 3)) "If life ever gets back to normal, and there is no more virus, he's going to have a lot of business," Brody says.|"That's a really tough job," you say.}
    
    Eric smirks. "He's really good at it. If anyone was born to work with dead people, it's my brother."
    *goto GravesChat
  #"Have you happened to see a stereo and speakers anywhere around here?"
    *set asked_about_stereo true
    Eric's brow furrows in confusion. "What do you need with that? Are there parts specific to a stereo you need for something else?"
    
    John steps next to his brother and breaks into dancing. "They're obviously starting a club."
    
    *if outside_camp = 1
      "We want to hold a prom, since we didn't get the chance to have one," Brody says. As he speaks, Kevin moves away from him and shakes his head.
    *if outside_camp = 2
     "Something like that. We've had a rough time during this outbreak, and some of our group want a morale boost," you say.
    *if outside_camp = 3
      "This stupid outbreak took away our prom, so were throwing our own prom. I don't care if you want to make fun of us," Madison says.
      
    John dances closer to Eric, who shoves him away. John stops dancing and says to your group, "I saw one in the next train yard outside the terminal in a pile of junk. Listen, if I hear music, I'm crashing your prom. You have any eligible singles in your camp?"
    
    "Go finish the laundry," Enola says, laughing.
    *goto GravesChat
  #"Do you mind if we have a look around for items to scavenge?"
    *set asked_to_scavenge true
    Eric frowns, and his eyes form a V. "So you want to rob us?"
    
    *if m_persuasion >= 55
      *set graves_faction %+(round(m_leadership/6))
      Enola smacks his arm. "Be nice. There are lots of things around here we're not using and will never use. Other people may need them."
      
      "If there are things you would like left alone, we won't touch them," you say.
      
      "Fine. Don't touch anything in the terminal. I guess everything else is within limits," Eric says.
    *if m_persuasion < 55
      *set graves_faction %-(round(20-(m_leadership/6)))
      "There are lots of things around here you can't possibly be using," you say.
      
      "It's fine. Please don't take anything in the terminal, but you can have anything else," Enola says.
    *goto GravesChat
  *if not(like_males)
    #I say to John, "Are you the only one not married around here?"
      John stops and strides over like he's on a catwalk. "I'm currently unattached. Why would I restrict myself to one person and deny the rest of the world from my loving embrace? I'm not a selfish person."
      
      "You're a jackass," Eric says, shoving his brother.
      *goto GravesChat
  *if like_males
    #"I'm guessing you're not married?" I ask John. I'm interested in him.
      *set graves_faction %+(round(m_leadership/6))
      John stops and strides over like he's on a catwalk. "I entered this outbreak with no attachments. If you're looking for love, just one condition—please don't break my heart."
      
      "You're a jackass," Eric says, shoving his brother.
      
      John turns back to you as he walks away, holds his hand up to his ear, and mouths the words, "Call me."
      *goto GravesChat
  #"We have quite a few supplies at our camp. Is there anything you need?"
    *set graves_faction %+(round(m_leadership/6))
    Enola smiles and says, "That's a really nice thing of you to offer. We don't need anything right now, but I'm sure we will at some point."
    *if told_graves_medical and not(offered_graves_exam)
    
      Eric speaks up. "You mentioned you work in the ER. Would you mind giving Danica and the twins a checkup before you go."
      *fake_choice
        #"Sure, I'd be happy to do it right before we leave.""
          *set offered_graves_exam true
          *set graves_faction %+(round(m_leadership/5))
          Eric stares at you with intensity and says, "I really appreciate this."
        #"Normally, I'd say yes, but we have to get back to our camp soon."
          *set graves_faction %-(round(25-(m_leadership/6)))
          Eric scoffs. "Didn't you take an oath to help people?"
          
          Enola grips his arm and leans in front of him. "We don't want to impose. Maybe some other time, you can come back and visit us and do the exams."
          
          Eric grunts and shakes his head.
        #"I don't want to look at any patient that aren't mine. I don't know any of their history and don't want to make any mistakes on them."
          *set graves_faction %-(round(25-(m_leadership/6)))
          Eric scoffs. "It's a pregnant woman and two toddlers. What would you do if they walked into the ER?"
          
          Enola grips his arm and leans in front of him. "We don't want to impose. Maybe some other time, you can come back and visit us and do the exams."
          
          Eric grunts and shakes his head.
    *goto GravesChat
  #"Have you ever come across the Silverthorne Militia?"
    Eric scratches the side of his head. "I think so. A bunch of rejects from the circus stopped in the train yard and gave us a strange ultimatum to join them or 'become an enemy.' I told them to get lost." He uses air quotes.
    
    "Was it some guy named Keith?" @{((outside_camp = 1) or (outside_camp = 3)) asks Brody.|you ask.}
    
    Enola nods and frowns at the same time. "He was arrogant and overbearing. They brought us a crate of vegetables and thought that would buy us."
    
    "Like a bunch of vegan whores," John says.
    
    "Mind your tongue," Enola says to John. Turning back to you, she says, "They haven't come back since. I'm hoping we never see them again."
    
    "They had fifteen people with them, all armed. But they were unorganized, and that guy Keith didn't seem to have a firm hold over them like leaders should," Eric says. "If they come back, I'll enjoy wiping that stupid smirk off his face."
    *goto GravesChat
  *if search >= 55
    #"I noticed your brother's tattoo. Is he a member of the Southern Ute?"
      *set graves_faction %+(round(m_leadership/6))
      Eric lifts his shirt and turns, showing the same tattoo—large letters spelling out the name of the tribe. "Us three brothers are Southern Ute. We don't take part in the tribe's activities, except for Lewis over there. He reconnected with them a few years ago both socially and spiritually. Right around the time the outbreak started, he came back to us to be with family. He is the most honorable man I'd ever met."
      
      "One of the members of my group lived with the Southern Ute for a while. I'll have to mention this to him," you say.
      
      Eric nods. "Please do. It's good to know my people are out there surviving this thing."
      *goto GravesChat
  #"That's all the questions I have."
    *if asked_to_scavenge
      *goto ScavengeCamp
    *else
      *goto LeaveGravesCamp

*label ScavengeCamp
*if not(graves_left_camp) and attacked_graves
  
  "There's a woman and two kids in the terminal. Madison, why don't you go get them and bring them out. Be careful, she may be armed," you say. Madison nods to you and jogs towards the entrance to the terminal.

Your group spreads out and checks the train cars,
*if not(asked_to_scavenge)
  the terminal,
the crates, the sacks, and everything else they can find. They make a list of all of the available items so you can decide what to take.
*if not(graves_left_camp) and attacked_graves

  As your search draws to an end, Madison runs out of the terminal and finds you. "I couldn't find a woman and kids in the bathroom. I went out the back door and checked everywhere. I just can't find anyone."
  
  "They must have gone. I don't want to waste time looking for them, so let's just scavenge and get out of here," you say.
  
*set inv_count 0
*gosub_scene Part1Events CalcSlots
*label GravesScav
*if (inv_count >= max_count)
  *goto LeaveGravesCamp
*else
  *gosub_scene CarryList
  *set item_count ((max_count+10) - inv_count)
  You have the following items: ${inventory}
        
  You can take ${item_count} more items.
  *set inv_count +1
  *choice
    *if not(asked_to_scavenge)
      #AR-15 rifle.
        *set ar15 +1
        You add the AR-15 to your inventory.
        *goto GravesScav
    *if scavenging >= 45
      *allow_reuse #Batteries. 
        *set batteries +1
        You add the batteries to your inventory.
        *goto GravesScav
    *if scavenging >= 45
      *allow_reuse #Binoculars. 
        *set w_binoculars +1
        You add the binoculars to your inventory.
        *goto GravesScav
    #Birth control pills.
      *set item_birth_control +1
      You add the pills to your inventory.
      *goto GravesScav
    #Cosmetics.
      *set item_cosmetics 1
      You add the case of cosmetics to your inventory.
      *goto GravesScav
    *allow_reuse #Compound bow.
      *set bow +1
      You add the compound bow to your inventory.
      *goto GravesScav
    *allow_reuse #Duct tape (1 roll).
      *set duct_tape +1
      You add the duct tape to your inventory.
      *goto GravesScav
    *if asked_to_scavenge
      *allow_reuse #Flares (2).
        *set flares +2
        You add the flares to your inventory.
        *goto GravesScav
    *if asked_to_scavenge
      *allow_reuse #Food (5).
        *set group_food +5
        You add the food to your inventory.
        *goto GravesScav
    *if asked_to_scavenge
      *allow_reuse #Football helmet.
        *set football_helmets +1
        You add the football helmet to your inventory.
        *goto GravesScav
    *allow_reuse #Electrical parts (2).
      *set electric_parts +2
      You add the electrical parts to your inventory.
      *goto GravesScav
    *if scavenging >= 45
      *allow_reuse #Laptop. 
        *set laptop +1
        You add the laptop to your inventory.
        *goto GravesScav
    *if not(asked_to_scavenge)
      #M-16 automatic rifle.
        *set m16 +1
        You add the M-16 to your inventory.
        *goto GravesScav
    *allow_reuse #Mechanical parts (2).
      *set mech_parts +2
      You add the mechanical parts to your inventory.
      *goto GravesScav
    *allow_reuse #Metal parts (2).
      *set metal_parts +2
      You add the metal parts to your inventory.
      *goto GravesScav
    #Sledgehammer.
      *set sledgehammer +1
      You add the sledgehammer to your inventory.
      *goto GravesScav
    *if not(asked_to_scavenge)
      #Shotgun.
        *set w_shotgun +1
        You add the shotgun to your inventory.
        *goto GravesScav
    *if not(asked_to_scavenge)
      #Tactical vest.
        *set tactical_vests +1
        You add the tactical vest to your inventory.
        *goto GravesScav
    *if not(asked_to_scavenge)
      #Tarp.
        *set tarp +1
        You add the tarp to your inventory.
        *goto GravesScav
    *if scavenging >= 45
      #Weapon suppressor. 
        *set suppressors +1
        You add the suppressor to your inventory.
        *goto GravesScav
    *allow_reuse #Wood parts (2). 
      *set wood_parts +2
      You add the wood parts to your inventory.
      *goto GravesScav
    #That's all I take.
      *goto LeaveGravesCamp

*label LeaveGravesCamp
*if offered_graves_exam
  *set medical_equipment true
  
  As you finish gathering your items from scavenging, Eric reminds you about examining Danica and the twins. All three come out of the terminal, and he has them wait for you under the tarp. Lewis steps behind his wife and stares at you with tentativeness. Seeing them, you walk over.
  
  "Hello, I'm @{doctor Dr. ${lastname}.|${firstname}.}" You crouch next to the children. "And you're Abel and Grace. Is it okay if I look at you to give you a quick checkup?"
  
  Able smiles and claps his hands, while Grace lifts her shirt over her head.
  
  "Grace is always shy," Enola says.
  
  "Let me take a look at Abel first. Grace can see how easy it is to have a checkup, and she could see what a good boy her brother is."
  
  You check his eyes, ears, nose, and throat with visual inspections and see nothing remarkable. You place your ear against his chest and listen to his breath sounds. You do a quick neurological exam by getting him to follow your finger as you move it around him. He giggles and dances through the exam, but it goes smoothly.
  
  "You have a healthy two-year-old boy here," you say to Enola. "Has your kids had their vaccines? Between one to two years, there are quite a few important ones."
  
  "They both had a lot of shots the last few times they went to the doctors." She rubs her son's head, and he clings to her leg.
  
  "I'm just going to have to assume they are up-to-date. Kids two to three years old should get a flu shot. I'm not sure I'd worry about that in light of everything else going on. Should I look at Grace now? Does she want to show me what a big girl she is?"
  
  She keeps her head low and walks over to you. "What a pretty dress you have on! Do you mind if I have a look at you?" You perform the same examination as you did on Abel. "Her ears are a bit red, but otherwise she's in perfect health. I would keep water out of them when you clean her. If they get any worse or stay read for a while, you will want to get her some antibiotics."
  
  "Thank you so much for examining them. It's a relief knowing you looked at them," Enola says.
  
  "No problem. Danica, are you ready for your exam?" you ask.
  
  "What's involved in this?" Lewis asks, his face a sheet of stone. He steps in front of his wife like he's shielding her from you.
  
  "I'm going to ask questions about Danica's health, and then I'm going to do a typical physical exam. I don't have access to an ultrasound machine or other tools, so I may have to improvise. @{(morality >= 50) Ultimately, it's Danica's decision on her healthcare. I will only do what she is comfortable with.|If you are worried or don't want me to do the exam, that's fine with me.}"
  
  Danica places her hand on his shoulder. "It's okay. I want to make sure the baby is healthy."
  
  Lewis nods at her and says to Enola, "Will you stay for the exam? I need to go for a minute."
  
  Enola agrees, and you start the exam with the typical review of her medical history and simple inspection of her eyes, ears, nose, and throat. As you consider how to proceed with the prenatal portion of the exam, Lewis returns pushing a cart. As he draws closer, you see a stethoscope, blood pressure cuff, and other medical tools. On the bottom level of the cart sits a portable ultrasound machine.
  
  Lewis unplugs a fan from the extension cord and plugs in the ultrasound machine. "I found this the other day in one of the train cars. I wasn't sure exactly what all these are, but I knew they were medical equipment. But I'll take what I can get."
  
  "This is actually perfect. I can listen to her heart, take her blood pressure, and look at the babies shape and position. If I could do blood and urine tests, it would be even better."
  
  Using the medical equipment, you perform a more thorough exam of Danica. She says very little during the examination but listens to you for instructions and allows you to perform everything without objection. When you offer to tell them the sex of the baby, they refuse, saying they would rather be surprised when the baby's born.
  
  At the end, you take off the stethoscope and place it back on the cart. "I'm not an obstetrician, but I can say you and the baby are in very good health. You may be slightly underweight for where you need to be, but I doubt you have access to the vitamins I would want to prescribe. If you have any chance to eat more vegetables, especially fresh vegetables, I would highly recommend it. Otherwise, you are doing great."
  
  Lewis hugs Danica and then turns to you and offers a hand. You shake it, and wish them both well. As you're walking out from the tarped area, Eric thanks you for examining his family.
  
  "We don't have much use for that medical equipment. I'm happy to loan it to you, if you are willing to come back here once in a while to check us out. Of course we would love it if you can deliver the baby when it comes."
  
  You agree and bring it over to your group for help carrying it back to the Junkyard.
  
With your scavenging done, your group
*if graves_left_camp or graves_all_dead
  assembles just outside the train yard carrying the items you will take back with you. Everyone appears content with the equipment and supplies you've chosen, and you all head out of camp.
  *goto EndGraves
*elseif graves_surrendered
  In the middle of the yard. The Graves family watch on with interest, none of them moving from their spots.
  
  As you approach Eric, he looks up at you and says, "Is that it? You're going now?"
  
  "Yes, we're leaving. @{(ruthless >= 50) If you try to follow us or make any moves as we leave this train yard, there will be dire consequences. Forget about us, and you go on surviving."|We gave you our word that we would leave after we scavenge, and that's what were going to do. You don't have to worry about us coming back here, and you should avoid us if we happen to cross paths."}
  
  He nods and looks away. Having nothing more to say to him or his group, you and your group head out of camp.
  *goto EndGraves
*else
  assembles at the edge of @{asked_to_scavenge camp carrying the items you chose to take with you.|camp.} As you prepare to leave, Eric and Enola walk up to you.
  
  @{(graves_faction >= 60) "I'm surprised to admit it, but I really enjoyed meeting you all. We haven't come across any other friendly survivors, so this may have restored my faith just a bit,"|"We'll be seeing you around,"} Eric says.
  
  Enola wraps her arm under her husbands and says to you, "Be careful out there. It looks like things are getting worse. We haven't seen the military or the police, and we doubt they're coming to help ever again. We heard about that organization named OMNUS, but we haven't seen them around. We heard they may start supply drops, but I'm not sure when that will be."
  
  "We haven't seen any yet either. Anyway, thanks for your hospitality. Take care of yourselves," you say.
  
  When you turn to leave,
  *if asked_about_stereo
    John walks up to the group. "Y'all are leaving without hugs goodbye?"
    
    Brody waves his hand. "We're not the hugging type."
    
    John shrugs. "That's fine. You just don't know what you're missing. But seriously, be safe."
  *if not(asked_about_stereo)
    *set asked_about_stereo true
    Madison stays behind and says, "Have any of you seen a stereo and speakers? That's the reason we came here in the first place."
    
    Eric looks at her with surprise. "Is that to lure out infected, or are you using parts from the stereo to make something else?"
    
    Hearing the conversation, John walks over to the group. "If you continue along the tracks, there is another train yard. It's almost identical to this one, but it's mostly been cleared out which is why we chose to stay here instead. In the little bit of junk left behind, there's a stereo system. Look, if you guys are having a dance party, you got to invite me."
    
    Madison gives him a fake smile. "It's like Eric said, we're using parts from the stereo. Thanks for the information. Goodbye."
  *goto EndGraves

*label EndGraves

*if asked_about_stereo
  The camp survivors give you directions to the next train yard over.
  *gosub OtherTrainYard
  With nothing else to do at the camp, your
*if not(asked_about_stereo)
  Your
group follows the train tracks out and makes its way to the place you call home with the sun still high in the sky.
*label OnTheWay
*if conv_store_mission
  *page_break
  On your way back to the Junkyard, you recognize one of the roads leading towards the gas station where you met Sharif and his sister, Ayana. Even from a quarter-mile away, you see the scorch marks and blackened wood siding, the peeling paint, and the piles of ash. When you finally reach the convenience store, you push aside the door leading into Ayana's room in the back. The bed's still there, but it's now a blackened pile of foam and twisted metal. You see no signs of her, nor her oxygen tank or other medical equipment. You call out for Sharif, but no one answers. Your entire group searches the store and finds everything burnt and all supplies taken.
  
  As you walk away from the store, you pass the sign that once read Buzz's & Son Petroleum Station. Silvery barbed wire is wrapped around the post.
*page_break
*set ze_date "Thursday, May 24, 2012"
Two days later…

Since you came back from the train yard, the twins and a small crew from your group have been preparing for prom. Streamers and balloons have been placed around the main yard, planks of wood have been set up as a makeshift dance floor, and a DJ's booth has been erected at the front of the garage with a diesel generator used to fuel the stereo. To go with the prom theme, Madison asked @{(group_cook = firstname) you|${group_cook}} to cook finger foods and make bowls of punch. In addition,
*if group_cook = firstname
  you made…
  *fake_choice
    #A desert based on my heritage.
      While not everyone is accustomed to eating food from your heritage, you make a desert grandmother taught you to make. In this way you honor her and the rest of your family.
    #Apple pie to celebrate America.
      Who doesn't love apple pie in the summer? Several apple trees sit outside the Junkyard, so they're plentiful in supply.
    #Barbecue food for those not interested in the prom.
      Not everyone appreciates the prom and some think it's downright stupid to hold a dance in the middle of the outbreak. Won't the music attract zombies Reilly asked. He's not wrong and for those in the group not participating, you make them some barbecue food to keep up their morale.
  *set morale %+15
*if group_cook = "Jaime"
  Jaime added in a buffet of savory items. Madison felt most of the dishes were elegant enough to be placed on the serving tables.
*if group_cook = "Reilly"
  Reilly cooked Chicken Parmigiana and mini pizzas. Madison argued they were not within the theme of enchanted forest, but he ignored her wishes.
*if group_cook = "Rosie"
  Rosie made a huge pot of spaghetti and meatballs, her favorite from the institution. Madison was livid at having such a basic meal at the prom, but everyone else seemed to like it.
*if group_cook = "Woody"
  Woody prepared roast meat sandwiches. When asked if he meant roast beef, he stated there was no beef in his sandwiches.
*if rosie_join and driver_join
  *set prom_dj 2
*if rosie_join and (driver_join = false)
  *set prom_dj 3
*if (rosie_join = false) and driver_join
  *set prom_dj 4
  
@{prom_dj Jaime|Rosie and Driver|Rosie|Driver} set up the DJ station and started off the night with @{prom_dj Flo Rida's [i]Good Feeling.[/i]|LMFAO's [i]Sexy and I Know It.[/i]|"Weird Al" Yankovic's "White & Nerdy|System Of A Down's [i]B.Y.O.B.[/i]} After that, the music calmed to a playlist based on the hits of the last decade. Though Madison dressed up in the best attire she could scavenge, everyone else dressed in casual clothes with minor enhancements. Eli wore a T-shirt that looked like the front of the tuxedo, while Kevin put on his best dress shirt.
*if nora_join
  Nora wove flowers into her hair.
*if parker_join
  Parker dressed in the preppiest clothes he could find.
Rachel dressed in early nineties punk rock attire but immediately went on watch duty. Unfortunately she showed up before anyone else.

You walk on the outskirts of the makeshift dance floor and move your head to the music. All of the members of your group are in attendance, some dancing, some eating, while others are watching the gate for infected drawn by the music. You decide to…
*set count 0
*choice
  #Participate in the prom. I could use rest and relaxation.
    *set ideal %+15
    *goto ParticipateProm
  #Participate but only to show I'm a team player and to support the twins.
    *set ideal %-15
    *label ParticipateProm
    You make your way onto the dance floor, while sticking to the sidelines to let the dancers have their space. Each one that passes you nods or smiles.
    *gosub DanceMoves
    *if (main_ro = "") or (second_ro = "")
      
      As you look around the dance floor you can't help feel attracted to some of them. Maybe it's the movement of their bodies or the free-spirited nature of the party, but you find yourself loosening up to the idea of another relationship.
      *if main_ro = ""
        *gosub_scene Part2Events CheckRO
      *if second_ro = ""
        *gosub_scene Part2Events NextRO
      
    Looking around, you consider dancing with several people. With the way things are going, you probably have time and energy for four sets of dances. First you ask…
    *goto AskDance
  #Stand on the sidelines and observe. I'm fine with just watching but may dance if someone asks.
    *set impulse %-15
    You stand on the sidelines and watch the dancers in the middle of the floor. Many are paired off while others stick to small groups and move to the music. Smiles fill the yard, and the music carries well above the Junkyard.
    *goto NotParticpating
  #I'm not into proms or dancing. I'll watch the gates and kill off any infected.
    *set participate false
    *set honor %-15
    He walked to the main gate and search outside for any signs of infected or other dangers. The music blares from behind, and you're sure it will attract someone or something to the Junkyard. All many of your group enjoys dancing and eating and partying, you plan to keep the place safe.
    *goto NotParticpating
    
*label SurvivorsDancing
*set morale %+20
*if lopez_join and ((main_ro != lopez) and (second_ro != lopez))
  *if tommy_join and ((main_ro != "Tommy") and (second_ro != "Tommy"))
    *set lopez_romance "Tommy"
  *if not(tommy_join) and ((main_ro != "Jaime") and (second_ro != "Jaime"))
    *set lopez_romance "Jaime"
*if bailey_join and (((main_ro != "Bailey") and (second_ro != "Bailey")) and ((main_ro != "Brody") and (second_ro != "Brody")))
  *set brody_bailey_rel true
*if (lopez_romance = "Tommy") or (lopez_romance = "Jaime")
  
  Looking across the dance floor, you notice ${lopez} and ${lopez_romance} dancing together. Their bodies move together in rhythm, and they exchange light touches and suggestive smiles throughout the dance. When you see them kiss you know this means more than two friends on the dance floor
*if brody_bailey_rel

  Your attention draws to one of the large speakers near the DJ table. Bailey and Brody look to be arguing, though they're both smiling and laughing. He pulls her out on the dance floor, and though she's reluctant, she starts dancing slowly. Within a few minutes they're moving together, and he even leans in for a kiss.
*if gina_join and dependent

  Your nephew runs onto the dance floor, drops to his knees, and slides, nearly bowling over several dancers. Gina helps him up, takes his hands, and spins him around. His mouth hangs open, and you can hear him laughing even from across the dance floor.

A new song plays, and everyone on the dance floor leaps up and down to the beat, hands raised in the air. All you see our bodies hopping in unison with fists in the air, and the music rises and drops and rises again in sudden waves. You're even moving your body on the sidelines, compelled by the beat and the shared movement of your group. @{(ideal >= 50) This party means everything right now. Something so simple and maybe even frivolous matters more than the walls and the fence and the food and supplies. Everyone feels alive again, if even for the length of a few songs.|Maybe it seems crazy to hold a party at the start of the outbreak. Maybe your time would be better spent on other things, but you never know what tomorrow might bring. Everyone knows they may never have this chance again—to feel alive for just a little while.}

From behind a gunshot cracks the air. The music screeches to a halt. Everyone in the yard reacts to it, pausing their dance moves. Looks of surprise and confusion appear on all of their faces. You listen for any other gunfire or shouts from afar or warnings from those on watch duty. None of them come. A murmur spreads on the dance floor. The music continues, and the dancers start up again as if nothing ever happened.
*if (main_ro != "Madison") and (second_ro != "Madison")
  The song goes on, and you notice Madison and Kevin dancing together. As you watch them, you notice how he touches her arm and brushes a stray strand of her golden hair back from her eyes. You don't see the young man smiling often, but on that dance floor with Madison, his smile never fades.
*if nora_join

  You take a walk around the outside of the makeshift dance floor and stare at a group of survivors formed in a circle, clapping and cheering. When you to a different area where you can look past them, you see Eli and Nora dancing in the center. It's mystifying to watch them: hips twisting, legs kicking, and arms shaking. They look like teenagers transplanted from the 50s.
*if ((main_ro = "Jillian") or (second_ro = "Jillian")) and ((main_ro = "Gina") or (second_ro = "Gina"))

  Jillian and Gina step out from the crowd and move to the edge of the dance floor. When they stop, Jillian turns and presses her back against Gina, who slides her hands down the younger woman's hips. Jillian grinds into her partner, then takes Gina's hands and slides them to her thighs. Both turn and stare at you, smiling suggestively. Jillian tilts her head back and tries to kiss Gina who pulls away, biting her lip and shaking her head. After this exchange, they turn back to look at you until the music stops, and they go their separate ways.
*return

*label AskDance
*set count +1
*if count = 5
  *goto EndProm
*if count = 3
  *gosub SurvivorsDancing
  
  You look around the dance floor and consider the next person to dance with…
*if (count = 2) or (count = 4)
  *gosub DanceMoves
  
  For your next dance you ask…
*choice
  *if bailey_join
    #Bailey.
      Bailey sits on the fender of an old Chevy Impala alone and sipping punch from a paper cup. She's wearing a simple summer dress with a print of tiny daffodils and sits crosslegged with bare feet. Her hair's down and loose, strands blowing in a slight breeze. As you walk over, she smiles and takes another drink.
      
      "I think @{nora_join Nora spiked the punch. I thought she was a chaperone, but she's a bad influence on us kids|Reilly spiked the punch. He was grumbling something about no problem should lack alcohol}," she says with a laugh.
      
      "So, are we going to dance?"
      
      She tilts her head forward, letting her hair cover her face, and she uses her free hand to cover her eyes. "No, please don't make me."
      
      *if impulse >= 50
        "Come on, it will be fun," you say and take her hand.
        
        "Fine. But just one dance."
      *if impulse < 50
        "If you don't want to dance, I won't make you. We can just sit here together and @{(ideal >= 50) enjoy the music."|make fun of everyone on the dance floor."}
        
        She stares at you for a moment, and her lips slowly form into a smile. "No, we should go dance."
      She finishes her cup in one swallow and tosses it onto the back of the car. @{(ideal >= 50) You pull her along it|You take her hand and she leads you} to the end of the dance floor.
      
      *gosub BaileyDance
      *goto AskDance
  #Brody.
    Brody stands near the snack table with a full cup of punch. He takes a sip and makes an uncomfortable face, squinting his eyes and squeezing his lips together. As you walk up, he places the cup on the table.
    
    "I know the punch got spiked but wow," he says. He wears gray Bermuda shorts, a linen dress shirt unbuttoned all the way down, and a solid white baseball cap.
    
    "Would you like to dance?"
    *gosub BrodyDance
    *goto AskDance
  *if church_join
    #Church.
      *set church_faction %+(round(empathy/6))
      Church paces a few feet off the edge of the dance floor closest to the main gate and watches all of the dancers. He agreed to chaperone for the night, but there is little to watch as the survivors focus more on dancing and enjoying the food then any form of shenanigans. Even in the fading heat of the day, he wears a full suit of white linen and a widebrimmed hat.
      
      "Care to dance, Reverend?" you ask.
      
      "Only if you're ready for what I'm about to bring to the dance floor," he says.

      The reverend boogies out onto the dance floor, shaking his hips and wagging his finger in the air. When he reaches the dance floor, he takes your hand and spins you around. It's tough to keep up with his pace, but somehow you manage. Soon enough, you're breathing hard with sweat dripping into your eyes. Many of those on the floor crowd around the two of you as Church leads everyone in a dance of his making.
      *goto AskDance
  *if dante_join
    #Dante.
     *set dante_faction %+(round(empathy/6))
     Dante stands on the steps of the RV overlooking the dance floor. He wears a pair of jeans and a basketball T-shirt with his gold chain around his neck, the word DANTE hanging over his breastbone.
      
     As you step close to him, he nods his head in your direction and says, "'sup?"
      
     "I came to see if you want to dance."
      
     He leans back, stretches his arms while holding the railing, springs forwards, and vaults himself over the high beam. He lands on his feet and waves you on.

     Dante starts off with only slight footwork and his hands raised over his head. Within a minute, he's picked up the pace and adding in fancy footwork. By the middle of the song, he's spinning and doing splits. At times the other dancers on the floor stop and circle the two of you, watching the back-and-forth and all of your moves. Even when a slow song comes on, he keeps dancing and singing along with the words.
     *goto AskDance
  *if driver_join
    #${driver}.
      *set driver_faction %+(round(empathy/6))
      You walk up to the DJ station, and ${driver} waves you behind the table. He has on a thin black sweater with the sleeves cut off and a pair of camouflage shorts.
      
      "Want to dance? I'm sure you've earned a break by now," you say.
      
      "Go on, I got this," @{with_rosie Rosie says.|Jaime says, walking up to the two of you.}

      When he agrees to dance, driver puts on a dubstep song, upbeat electronica that instantly gets the crowd going. "I Can't Stop" by Flux Pavilion Plays over the loudspeakers, and your partner shakes his head and moves in a wild, erratic pattern like he's in a mosh pit. Eyes closed and limbs flailing, he bounces around the garage to the thrashing beat. It's hard to keep up with him, but there's no denying he's completely lost in the music. When it fades, he's dripping with sweat with the biggest smile on his face.
      *goto AskDance
  #Eli.
    *set eli_faction %+(round(empathy/6))
    Eli stands by the porch of the main house, nodding his head out of beat to the music. As you walk over, he takes a few steps forwards to greet you with a handshake.
    
    "What a night! Whose birthday is it?" he asks.
    
    "It's not a birthday but a prom. Madison suggested it because @{teenager we're|she's} missing it this year."
    
    Eli nods, smiling and clapping his hands. "I'll have to wish her a happy birthday then."
    
    "Would you like to dance?" you ask.
    
    "You want to dance with me? Sure, I'd love to."
    
    When Eli comes to the dance floor, he's shaking his hips and taking small steps from side to side. He wears a huge smile and shows it to everyone. Before long he's clapping and imitating any move he sees, though he can't quite do them. Everyone cheers him on, and at times he takes your hands and swings you around. When a slow song comes on, @{female he puts his arm around you lightly and grips your hand to lead you in the waltz|he dances by your side in a solo waltz}, though it doesn't really fit the music. His smile never fades, even when the music does.
    *goto AskDance
  *if gina_join
    #Gina.
      You find Gina working on a wooden table inside the smaller gated area. She runs sandpaper up and down the top surface. Dressed in overalls with a toolbelt, she works with focus, not distracted by the loud music. When you walk over to her and called her name, she doesn't react. That's when you notice earplugs. You circle the table not to startle her, and she takes out the plugs.
      
      "I didn't expect you to be working while a party is going on. Care to take a break and dance with me?" you ask.
      
      "I'm not sure. I'm not really good dancer, and I'm not into the music either."
      
      "Just try it. It's fun to move around, and you need to take a break," you say.
      *gosub GinaDance
      *goto AskDance
  #Jaime.
    You @{(prom_dj = 1) head to the DJ table where Jaime stands at the stereo planning out the next few songs.|find Jaime hovering around the DJ table, offering his advice on song choices.} He's wearing a pair of overalls with one of the straps hanging down which shows off his bare chest.
    
    "Having a good time so far?" you ask.
    
    "Amazing. Everyone's enjoying themselves, and it's great to have a break from all of the hard work."
    
    "So, are you ready to dance with me?"
    
    "Hell yeah. @{(prom_dj = 1) I have a few songs queued up, so it's good to go."|Let's do it."}
    
    *gosub JaimeDance
    *goto AskDance
  *if jillian_join
    #Jillian.
      Jillian sits on top of a car near the parking lot, leaning back on her hands like she's sunbathing. She wears a flowing skirt and a halter top with a chain of beads around her neck like a flower girl from Woodstock.
      
      "Having a good time?" she asks as you walk over.
      
      "I was just coming to ask you the same. I think we should dance."
      
      She raises an eyebrow. "Oh, you do? I don't know. Proms are not really my scene."
      
      "I thought you were excited about it. At least that's what Madison told me."
      
      "I told little Miss Milford that I was interested in seeing a prom but said nothing about dancing."
      
      We reach out and take her hand. "Let's go. You have to dance at least once."
      
      *gosub JillianDance
      *goto AskDance
  *if kelly_join
    #Kelly.
      You find Kelly near the parking lot looking in the side view mirror of a parked car as she applies eyeshadow. As you walk up, she stops and turns to you. "Hey, sounds like everyone is having the time of their life. I'm just touching up my makeup. It looks like only a few people dressed up, so I thought I would as well. Maybe it will make Madison happy to see someone else getting into the spirit of this." When she stands, you see her dressed in a pantsuit with wide legs that give the appearance of being a dress. The sleeveless top shows off her tattoos, and she wears a black bow in her hair.
      
      "Once you're ready, I want to dance."
      
      She offers you her hand and smiles. "I'm ready now."
      *gosub KellyDance
      *goto AskDance
  #Kevin.
    Kevin means under the hood of an old Buick with a wrench in his hand. He looks annoyed and shoots angry glances at the DJ booth invading the garage, his sacred space. Strangely enough, he's dressed in a navy blue suit with dress shoes. He even has a tie and matching pocket square.
    
    "Hey Kev, what are you doing in here?"
    
    "Trying to fix this engine."
    
    "You know there's a party going on right now? You're even dressed for it. This car isn't running, so I doubt it's much of an emergency."
    
    He stands and tosses the wrench into a box of tools.
    *if (main_ro = "Madison") or (second_ro = "Madison")
      "I just don't know what to do in there. Am I supposed to ask someone to dance, or is someone going to ask me? Do I stand on the sidelines and watch like a pathetic loser or stuff my face on crap food? I've never been to a dance before and have no idea what the rules are."
      
      @{(ideal >= 50) "This isn't high school. There are no rules, and you don't have to impress anyone or feel like anyone is going to make fun of you for doing something wrong. The whole point of this is to have fun. It looks like everyone else is doing that. Let me be the first to ask you to dance."|"Social events can be unnerving, and believe me I've had the same feelings before that you are experiencing now. Everyone seems to be worrying about themselves and not worrying about anyone else. So you can do whatever you want and not be worried what others may think. How about we go out there and dance together, and then you could see if you like it?"}
    *if (main_ro != "Madison") and (second_ro = "Madison")
      "I don't understand Madison. She tells me she's all excited about this prom, and she tells me to get all dressed up. When I show up, she doesn't say a word to me. She's dancing with everyone else. It's like I don't exist. I don't know what to do, and I just wish the whole thing would end."
      
      @{(morality >= 50) "I'm sorry she's not showing you any attention. I think she's very excited and may not be thinking of your feelings. I bet if you go out there and dance, she will join you."|"Madison can be self-absorbed at times. Well, most of the time. The best thing you can do is go and have a good time. Let her see it, and I bet she will go running to you."}
      
      "You think so?" he asks, his voice having a hint of hopefulness.
      
      "Come on, let's go dance together."
    *set kevin_faction %+(round(empathy/6))

    It takes a good deal of coaxing to get Kevin on the dance floor. After a few seconds of the music playing, you see one of his legs moving and his head bobbing. By the middle of the song, he's dancing with you in his own restrained way. @{((main_ro = "Madison") or (second_ro = "Madison")) When Madison maneuvers her way closer to you and Kevin, he takes a more subdued approach. When she smiles and calls him by name, his face turns red, and he dances his way around you to hide from her view.|He mouths the words to the song, and his arms pumped the air a few times. You even catch a quick smile.} 

    When a slow song comes on, he rushes off the floor before you can stop him. You follow fast, and he turns and thanks you for making him part of the crowd.
    *goto AskDance
  *if lopez_join
    #${lopez}.
      You find ${lopez} by the trailer sitting on a crate, bobbing his head to the music. When you walk up, he smiles and bobs his head faster. "I'm loving this music. I haven't been to a club in a minute. Used to go with my boys all the time. Brings me back." He's wearing dress pants with a white button down shirt, though it's unbuttoned and shows off his bare chest and belly. He picks up a cup of punch from the ground next to him and sips.
    
      When you ask ${lopez} to dance, he's the one leading you onto the dance floor. 
      *gosub LopezDance
      *goto AskDance
  #Madison.
    Madison's taking a break on the sidelines when you walk up to her and ask for a dance. She wipes her face with a hand towel, tosses it to the side, grabs your hand, and leads you onto the dance floor like it was her idea. 
    *gosub MadisonDance
    *goto AskDance
  *if nora_join
    #Nora.
      *set nora_faction %+(round(empathy/6))
      *set reilly_faction %+(round(empathy/6))
      Nora sits on a beach chair just past the dance floor with a large umbrella over her, and an end table positioned on her right holding a plate of snacks and two cups of punch.
      
      "Having a good time?" you ask her.
      
      She laughs with excitement and pops a potato chip in her mouth. "This is nothing like my prom back in the day, but I like seeing everyone having a blast. If I could get them to play some Elvis, I'd go out there and rip up the dance floor."
      
      "I was just coming to ask you to dance with me. You're not going to turn me down, are you?"
      
      She raises and lowers her eyebrows. "I wouldn't dream of turning you down," she says and gives you her hand to help her up.

      You take Nora by the arm and lead her onto the dance floor. When you reach your spot in the middle of the other dancers, Nora tosses hurricane to the sidelines. She raises her hands and shakes her hips, making simple motions with tons of attitude. At one point she smacks her hips and attempts a spin. She stumbles and falls backwards into your arms. She smiles and laughs, still wiggling her arms.

      When you stand her back up, she claps her hands to the beat and shouts, "Somebody hit me with a bucket of water, 'cause I'm on fire!"

      As the music fades, the DJ plays a slower song, and you feel Reilly from behind.

      "Can I cut in? I'd like to dance with my ma," he says and takes her hand. Moran nods that you, and you leave mother and son in the middle of the dance floor.
      *goto AskDance
  *if parker_join
    #Parker.
      *if kelly_join
        *set parker_faction %+(round(empathy/6))
        Parker's taking a break near the refreshment table when you walk over to him. He takes a sip of punch, coughs and sticks his tongue out, and tosses the cup into the trash can.
        
        "You're taking a break? I was just coming to ask if you wanted to dance with me."
        
        He rolls his eyes and spins towards you. "My break is over the minute someone wants to dance."

        Parker struts onto the dance floor with you, his face stone cold focused as the music comes on. He moves his arms in a robotic fashion, and when the tempo of the song changes, he relaxes his body and sings along at the top of his lungs to the shock of others in the crowd. From then on, he is all smiles, and he's moves like he owns their Junkyard, dancing for a few steps with other survivors as he tours the space. Kelly makes her way over, and the three of you dance for the first half of the song, Parker splitting it will time between his two partners. Kelly can barely keep up, but you can see her fascinated by watching him.

        "I haven't had this much fun in forever," he says and shakes his butt. He twirls to one side and spots Madison. "Looking hot, girl."

        She smiles and screams back, "Looking hot yourself, Parker."

        After his turn around the floor, he returns to you to finish off the dance. When it ends, the two of you head to the sidelines to grab some punch.
      *if not(kelly_join)
        When you look for Parker, you can't find him anywhere in the yard. Asking Brody, you find out Parker took watch duty on the south side of the fence. You head over there and find him sitting just outside the gate with a pair of binoculars and a rifle. Instead of walking out of the front gate and all the way around, you talk to him through the chain-link.
        
        "Not joining the party?" you ask.
        
        He turns to you enough to talk while keeping his watch on the south side of the landscape. "Not really in the partying mood. I'm not going to lie, I've been thinking about Kelly.
        *if kelly_alive
          She's at the Silverthornes camp, and no one else seems to care. I know we just got to the Junkyard, but we're not making any plans to go get her."
          
          @{(kelly_faction >= 50) "Many of us do care about Kelly, but we're not sure how to save her yet. Everything is happening so fast that we haven't had time to settle down and come up with a plan. It's on our minds. Maybe not Madison's but Jaime and Rachel have not forgotten about Kelly."|"We just got to the Junkyard and haven't had time to think much about Kelly. It's up to the whole group what we do now, and we have to balance the needs of everyone. I don't think the Silverthornes will hurt Kelly. Once we get set up here, I'm sure we will all sit down and figure out how to get her back."}
          
          "I hope it becomes a priority.
        *if not(kelly_alive)
          Maybe it took her death for everything to sink in. We're in the middle of an outbreak, a global pandemic, and things will never go back to the way they were. I know our group feels much safer being here at the Junkyard. Not going to lie—I never feel safe anymore."
          
          @{(ideal >= 50) "It's not perfect here, but we've made a big upgrade moving from the hill camp. Maybe we can regain some normalcy and not have to worry all the time. I'm not saying the outbreak's over, but we can work together and build this place up to have a good life for as long as possible."|"That's understandable. I don't know when we will feel safe, but the Junkyard has walls and a gate which are improvements from the hill camp. No one knows when this outbreak will be over or if things will ever get back to normal. We've had our fair share of challenges and tragedies. Maybe those will stop for a little while and let us catch our breath."}
          
          "I can't help feeling we're all just waiting for the next zombie attack.
        I don't mean to spoil your fun or anyone else's, but it just seems strange to have a party after all that's happened. What exactly are we celebrating?"
        
        You don't know how to answer him, so you say nothing. After a few moments you wish and good night and walk away to rejoin the prom.
      *goto AskDance
  #Rachel.
    *set rachel_faction %+(round(empathy/6))
    *set danced_with_rachel true

    *if (main_ro = "Rachel") or (second_ro = "Rachel")
      It takes a while to convince Rachel to leave watch duty. She never agreed with the concept of a prom, though she reluctantly approved as a boost to the group's morale. After a considerable amount of coaxing and Jaime's offer to stand in for her watch while she takes a break, Rachel agrees to join you.

      "Prepare to be amazed," Rachel says and gives you one of her telltale sarcastic smiles.

      You walk onto the dance floor with her, and she kicks off her sandals to the sidelines. She dances around you with the grace of a ballerina and the funk of a disco dancer. At the middle of the song, she kicks her leg up, nearly clipping Brody's head and then drops to a split. She rolls on the ground into a handstand and leaps to her feet.

      "Having fun?" you ask and dance next to her.

      "Having a blast!"

      Towards the end of the song, Rachel looks as happy as she's ever been. She even seems disappointed as the music fades into the next song.
    *if (main_ro != "Rachel") and (second_ro != "Rachel")
      You find Rachel outside the main gate as she circles the compound to watch for infected or other signs of dangers. She offers a weak smile as you approach and breaks out a canteen for a drink.
      
      "Enjoying the festivities?" she asks and takes a sip of water.
      
      "Yes, and I came to ask you to dance."
      
      She shakes her head and stands next to you to look out to the forest. "Sorry but I'm not one for dancing and frolicking. I'm happy you all feel safe enough to enjoy yourselves. I'm equally happy keeping watch so the party can go on."
      
      "Wouldn't you like to take a break? You've been at this longer and harder than any of us. You must need to unwind. Didn't you ever get a break from work for some rest and relaxation?"
      
      "Not really. It was always go go go. Look, surviving a global pandemic takes its toll on even the best of us. If our group needs to have a party or a feast or play board games or whatever, I'm all for it. If it raises morale, maybe we fight better or someone's more alert when scavenging. On the other hand such distractions reduce my effectiveness. I just need to stay in it. If you take it me out of survival mode, it may be too hard to go back into it."
      
      She takes another sip of her canteen, screws on the cap, and nods to you as she continues her tour around the Junkyard.
    *goto AskDance
  *if ray_join
    #Ray.
      You find Ray on the side of the garage, leaning against the outer wall, nodding his head to the music. As you walk over, he
      *if morality >= 50
        rolls his eyes and says, "I hope you're not here to ask me to dance."

        "You know me too well. Come on, it will be fun."
        
        You reach out for his hand, but he shrugs away and walks around you. 
      *if morality < 50
        greets you with a wide smile and says, "I've been wanting to dance with you. Are you ready?"
        
        "I guess so. That's not why they came over, but I guess I can't say no to you."
        
        He reaches for your hand and leads you out.
      *gosub RayDance
      *goto AskDance
  #Reilly.
    You find Reilly at the buffet line picking through some of the finger sandwiches. He takes one, looks at it, and puts it back. As he sees you walking over, he fills up his punch cup and adds liquid from a flask to the cup.

    "Hey, what's going on?" he asks, taking several large gulps of his drink. When he lowers the cup, he pounds his chest with his fist. "That'll put some hair on your ass."

    @{(impulse >= 50) "Come on out there and dance with me," you say.|"Would you like to dance?" you ask.}

    He finishes his drink, crumbles the cup, and tosses it towards a waste bin. "Fine, but only if I like the song."
    *gosub ReillyDance
    *goto AskDance
  *if rosie_join
    #Rosie.
      *set rosie_faction %+(round(empathy/6))
      *set danced_with_rosie true

      You walk to the DJ booth, where Rosie stands with headphones pressed against one ear while loading a record with the other. When she spots you, she lowers the headphones and gives you a smile, waving you behind the table.

      "Having a good time?" she asks.

      "Yeah, but it would be better if I got to dance with you."

      *if (main_ro = "Rosie") or (second_ro = "Rosie")
        Hearing this, @{with_driver ${driver} waves her away.|Jaime walks over to the DJ set up.} "Go ahead. I got this."
        
        Rosie walks around the table, grabs your shirt, and pulls you onto the dance. She starts with wild movements and a mix of different dancing styles, none of which match the music or the beat. You try to keep up with her, but she moves so fast it's a blur of hands and feet. Then she starts jumping and weaving in and out of other dancers until she runs and dives in your arms. The two of you collide, and you almost stumbled to the ground. She pops off of you and runs in place, nodding her head at a fevered place, her red hair flailing up and down. Others move a distance away from her and try not to focus on her strange dancing.
        
        When the music fades and @{with_driver ${driver}|Jaime} plays a slow song, Rosie stops and stares at you. "Now what?" she asks, exasperated?
        
        You put one arm around her waist and hold her hand with yours. You lead her in a short circle in your area of the dance floor, and she keeps up with each step. She smiles and watches her feet as the two of you moved to the melody.
        
        "This is weird. I feel like a minute Disney movie," she says and wraps her arms around your neck. You feel her head on your shoulder, and she moves in so closely she stifles the movement of your feet. Instead, you slide from side to side and simply enjoy the music together until the music fades.
      *if (main_ro != "Rosie") and (second_ro != "Rosie")
        "No can do. I'm too busy laying down records. I can't possibly stop and let all of these people down. But if you want, you can help me pick out records."
        
        She lifts up in milk crate filled with vinyl records. As you flip through the colorful covers, you see a number of intriguing titles, mostly from the golden age of music, though some from more modern days. She also has a rack of CDs and even a few cassette tapes.
        
        "It's all about reading the crowd and mixing things up. You can't play a slow jam followed by hard wrap or even Eminem. You also can't play classic rock and then country music. This is serious business." Rosie slips out [/i]London's Calling[/i] by The Clash and queues it up.
        
        You stay with her for several songs in a row, helping her pick out the music, and watching over the dance floor as the survivors in your group enjoy themselves. It's a different view of the festivities from up there, and when you head away, you turned to see Rosie bobbing her head and smiling as she prepares the next song.
      *goto AskDance
  *if tommy_join
    #Tommy.
      *set tommy_faction %+(round(empathy/6))
      *set danced_with_tommy true

      You walk up to Tommy who sits on a bench on the far side of the yard near the main gate. An uneaten plate of food rests on a crate by his side, and he holds a half-full bottle in his hand. A trickle of water spills onto the dirt, and Tommy stares off into the distance.

      *if impulse >= 50
        @{(morality >= 50) "Hey, it doesn't look like you're having a great time out here by yourself. Come on, let's go dance."|"I don't know why you were sitting by yourself, but get your ass up and go dance with me."}
      *if impulse < 50
        @{(morality >= 50) "Hey there. Mind if I sit with you for a moment? You look lonely out here, and I want to keep you company."|"No offense but you look sad out here sitting by yourself while a party's going on."}
        
      Tommy looks up at you with a weak smile, tilts his bottle so it's not spilling, and sets it on the crate next to his plate. "I'm not feeling in a party mood, but you're welcome to sit next to me here." He slides on the bench to provide room for you.

      *if (main_ro = "Tommy") or (second_ro = "Tommy")
        @{(impulse >= 50) "Let's go dance. I promise you'll feel better,"|"Why don't you want to dance? I don't want to force you, but I think you'll feel better if you have a little fun,"} you say.
        
        His smile broadens and he holds up his hand to you. "Okay, maybe just one."
        
        Tommy follows you to the dance floor, and several of your fellow survivors separate to give the two of you room. Once the music starts for the next song, Tommy steps side to side, head down with stiff movements. You grab his hands and shake them, and he laughs and bows his head. His cheeks turn red in embarrassment.
        
        "Sorry, it's just hard for me to get in the
        *if impulse >= 50
          mood."
          
          "Maybe this will help," you say and kiss him on the lips. His eyes widen, and his smile makes it difficult for a proper kiss.
        *if impulse < 50
          mood. Maybe this will help," he says and kisses you on the lips. His hands touch the sides of your face, and you feel his tongue inside your mouth. When he pulls away, he smiles and says, "Yes, that definitely helped."
        
        You take his hands and leave him closer towards the DJ table. The music fills your body, the loud thumps and wispy melody seeping through your skin. Tommy raises his hands over your head and pushes in close, so you feel the heat of his skin. You take him around the waist and bring one leg between his. It's hard to keep your hands off of him, and he can't resist from kissing you.
        
        When the music turns slower, he lowers his head to your shoulder, and the two of you sway from side to side. You can barely hear the music as you focus only on his breath on your neck and the touch of his body against you. Even when the music stops you continue the dance until those around you clap and awaking you and Tommy from your shared dream.
        
        "I'm going to go sit down," he says. "Thanks for the dance. I feel a bit better now." He kisses you one last time and then walks away towards the front of the Junkyard.
        *set tommy_humanity %+15
        *set tommy_breaking_point +10
      *if (main_ro != "Tommy") and (second_ro != "Tommy")
        You sit next to him and lift the plate. "Aren't you going to eat?"
        
        "Not hungry."
        
        "So you're not hungry and don't want to dance. Want to talk about whatever's bothering you?"
        
        Tommy shrugs and takes the plate from you. He picks up a piece of sandwich, bites one end, and lets it drop back to the plate. "I just can't stop thinking about my mother. I don't want to bother anybody else about it, so I just sit here by myself."
        *fake_choice
          #"I'm sure there are people who will talk to you and let you share what's on your mind. You need to talk to people. You can't keep your feelings all bottled up."
            *set morality %+15
            *set humanity %+10
            *set tommy_breaking_point +10
            *set tommy_humanity %+10
            Tommy nods at you. "Thank you. Sometimes I feel like no one wants to hear my problems all the time. Everyone has suffered, so why am I so special?"
            
            "We're all special. Every single one of us. We're survivors. So you should put that thought out of your head, because you deserve to be heard. We're all in this together, and we have to rely on one another. So if you want to talk, I'm here for you. If not me, then talk to Brody or Jaime. Maybe not Madison."
            
            The two of you share a laugh, and Tommy pats you on the shoulder. "Thanks for making me feel better," he says and takes another bite of his sandwich.
            
            You stay with him for a few more minutes as he finishes his food, and the two of you listen to the music.
          #"I understand what you're saying. It was terrible what happened to her. This outbreak has taken away so many people, and I see no end in sight."
            *set ideal %-15
            Tommy nods at you. "It's hard to think about her constantly. I try to push out those thoughts. So many of us have lost people. How do you keep from going crazy?"
            
            "It's a daily struggle. I'm just too worried to lose my focus while I'm out there among the infected. One wrong move, and I'm dead or someone in my group is dead. I can't have that, so I push aside all of those thoughts at least for now. Maybe one day this outbreak will be over, and things will be back to normal. There will be lines coming out of every therapist's office."
            
            Tommy laughs. "That's a good point. I hope they have one of those credit cards where you build rewards like frequent flyer miles."
            
            "You never know," you say and stand. "I'll leave you alone now, but if you change your mind, I'll be on the dance floor."
            
            Tommy waves to you and returns to staring outside the main gate.
          #"I don't blame you for thinking about her. If someone killed my mother, I wouldn't stop thinking about finding the people who murdered her."
            *set morality %-15
            *set humanity %-10
            *set tommy_breaking_point -10
            *set tommy_humanity %-10
            Tommy hangs his head and spits on the ground. When you look down, you see ants drowning in a pool of his saliva.
            
            "It's all I think about, day and night," Tommy says. "I'm not the only person who's ever lost someone, but it's the way she died. They broke into my house and attacked her. She was afraid and alone. They hurt her and left her there to turn into one of those things. It's worse than senseless violence. They tortured her, my mother." He throws his water bottle across the yard. It hits the side gate and explodes.
            
            "I'm going to help you find the people who did this. You will have your revenge. I promise."
            
            With that, you stand and walk away from him to return to the dance.
      *goto AskDance
  *if woody_join
    #Woody.
      When you look for Woody, he's not hard to find—he's in the middle of the dance floor working his way through each of the survivors.
      *gosub WoodyDance
      *goto AskDance
  *if dependent
    #${dep_name}.
      *set dep_faction %+(round(empathy/6))
      You catch your nephew
      *if dep_humanity >= 65
        behind the snack table, scooping out food and making plates for the other survivors. He wears a hairnet and gloves and works with determination.
      *if dep_humanity < 65
        on the sidelines, @{(dep_humanity >= 45) dancing in place|leaning against the wall of a storage container} and watching the other survivors. As you step over to talk to him, he @{(dep_humanity >= 50) greets you with a smile but|barely acknowledges you and} keeps his watch on the dance floor.

      "Not dancing today?" you ask.

      *if dep_humanity > 65
        "Madison said I'm too young to be at a prom, but if I wanted to work, she thought that would be okay. I used to help Mrs. Sandy at school. She was the lunch lady, so this is kinda fun."
      *if (dep_humanity <= 65) and (dep_humanity >= 45)
        He shrugs and says, "Not really. Madison told me kids my age don't go to proms. I'm fine with just listening and watching everyone. It reminds me of dances at school."
      *if dep_humanity < 45
        He shakes his head and says, "No, I don't feel like it. Besides, Madison was being a turd. She told me kids aren't allowed to be at a prom. I don't want to go to it anyway. It's stupid. We should be worrying about the zombies, not dancing."
        
      "So if I asked you to dance, you would say no?"

      *if dep_humanity >= 45
        His eyes grow wide, and a smile creeps over his face. "I would say yes."
        
        You lead him onto the dance floor just as the song changes. The beat picks up, and the two of you dance in the middle of the crowd. His feet shuffled from side to side, and he mimics your movements with amazing accuracy for a boy his age. When Madison twirls by, your nephew shows a moment of nervousness.
        
        "${dep_name}!" she shouts, and she leans over and gives him a kiss on the cheek.
        
        As she dances past him, your nephew wipes his cheek with the back of his hand. "Girls are crazy."
        
        He follows your lead, and the two of you dance for an entire song and one more after. He asks for a break, and you watch as he returns to the @{(dep_humanity >= 45) food table to continue his duty.|sideline.} 
      *if dep_humanity < 45
        He shrugs. "I appreciate it, but I don't want to. Rachel is doing watch duty outside the gate. I want to go watch her. This way I can learn how she does things."
        
        "Okay, have fun."
        
        He walks off, and you watch him leave until he disappears close to the main gate.
      *goto AskDance
  *if pet_owner
    #${pet_name}.
      *set pet_faction %+(round(empathy/6))
      You find ${pet_name} lying behind the large shipping container, buried under a blanket. When you move close to him, he perks up, @{(cat_owner) eyes wide|tail wagging.}
      
      *if small_pet
        You lift them up in your arms and dance around, lifting him in the air and lowering him again to the rhythm of the music. He @{(cat_owner) twists in your arms, and when you lower him to the ground, he darts through the second gate into the park and and disappears beneath a car.|wiggles in your arms, and when you let him down, he hops in place, standing on his back legs, and then spins in a circle. When a barrage of drums hammers in the song, ${pet_name} whimpers and runs through the second gate as far as he can make it away from the speakers.}
      *if not(small_pet)
        ${pet_name} stands and spins in place. As the music plays, you pat your chest, and he lifts his paws. Taking them, you dance with your dog, moving his front legs back and forth. He lets out excited @{wolfhound howls|barks} and taps his back paws to keep balance. When a barrage of drums hammers in the song, he yanks from your grasp, ears perked up. He lies on the ground, head down, and tale tucked. You kneel and pet him until the song ends. As the last note plays, ${pet_name} rolls on his back so you can rub his belly.
      *goto AskDance
  #No one. I'm done dancing.
    *goto EndProm
    
*label DanceMoves
*if hobby_dancing

  *if count = 1
    *set morale %+5
    Finally your favorite hobby comes into play. You love to dance and can show off some of the moves you've learned over the years. As the music starts, you break out The Dougie, moving your hands up and down to the beat while swaying from side to side. Then you do the Stankey Leg, lifting your foot off the ground and shaking it. You finish the song Gangnam Style, Spreading your arms to the side and strutting. While some of your companions laugh at the various dances, most are cheering by the end of your display.
  *if count = 2
    *set morale %+5
    As you head out onto the dance floor, the DJ plays the Cha-Cha Slide. You gather everyone together and stand in the front of the pack leading them through the dance moves: to the left, take it back, one hop, and stomping. Everyone gets involved, and you're all singing along and performing the moves in rhythm.
  *if count = 3
    *set morale %+5
    When you make your way onto the dance floor, you hear Lisa McHugh's song, [i]Bring on the Good Times[/i]. You happen to know the steps to the line dance, so again you lead everyone on the dance floor. You show them the four main steps along with the claps, struts, and slides. It's not long before everyone's hooting and hollering.
  *if count = 4
    *set morale %+5
    Towards the end of the prom, the DJ puts on a song from the big band era of American music. Everyone's confused for a moment, and as the DJ screeches the record to a halt, everyone says to turn it back on. As the melodic music fills the yard, you grab your partner and show off your Foxtrot. You lead with your left leg and take walking steps forward. You moved to the side and snap your legs together. You switch partners to get more people involved, and then finish with your partner as the song comes to an end.
*return
    
*label BaileyDance
*set bailey_faction %+(round(empathy/6))
*set danced_with_bailey true
The first song pounds an electric beat, and the two of you dance a few feet apart. She stumbles along and watches her feet, admitting that she never dances. By the middle of the song, she's moving to the music and follows some moves she sees others doing.

When a slow song comes on, @{((main_ro = "Bailey") or (second_ro = "Bailey")) her expression takes a shy turn, and she almost leaves the dance floor. A moment later she moves into your arms and the two of you sway to the soft beat. She feels good in your arms, and her head rests in the nape of your neck.|The two of you grab hands and sway to the slower beat. Neither of you take this song as slowly as it deserves, but you're sad when it's over.}

She stays for one more song, but you feel her pulling back.

"I kind of enjoyed this," she says pushing her hair out of her face. "Thanks for asking. I'm just going to go back over there and sit for a while. You stay and have fun, and we'll catch up later."
*if (main_ro = "Bailey") or (second_ro = "Bailey")
  She kisses your cheek and leaves with a smile, and you watch her walk across the dance floor until she's out of sight.
*return

*label BrodyDance
*set brody_faction %+(round(empathy/6))
*set danced_with_brody true

Brody leads and dances before he even reaches the floor. He's energetic, pumping his fist to the beat and jumping or moving his feet to match the tempo. You're soon amazed at his rhythm and movement, and the two of you dance in sync for the entire song. When a slow song comes on next, @{((main_ro = "Brody") or (second_ro = "Brody")) he grips you around the waist and pulls you against his body. He wraps his arms around you and moves his hips into you. Before long he's kissing your neck and grinding against you, though he stops when anyone looks over.|the two of you dance side-by-side and take the hands of others dancing nearby. It turns into a group dance, but you're glad Brody started it.}
*return

*label GinaDance
*set gina_faction %+(round(empathy/6))
*set danced_with_gina true

You have to drag Gina onto the dance floor. As you dance, she moves from side to side, looking out the ground, and watching her own feet. There you stand apart, she steps on you twice, apologizing both times with a shy smile. You've never seen her so out of her element. By the middle of the song, she's moving to the beat and clapping her hands.

"I hate to admit it, but I'm having a good time. Not as good as scavenging or building reinforcements, but it's not bad." As a slow song comes on, she moves off the dance floor and resists all of your efforts to get her to dance again. @{(main_ro = "Gina") or (second_ro = "Gina") "Sorry, but I just won't enjoy a slow dance," she says and then leans in close so only you can hear. "I wouldn't mind moving against you tonight when we're alone, but I won't need any music for that.""|"I appreciate you asking me to dance, but I just won't enjoy a slow dance. It would take a lot of drinks, more than we have in the Junkyard."}
*return

*label JaimeDance
*set jaime_faction %+(round(empathy/6))
*set danced_with_jaime true

Before Jaime even makes it onto the floor, he's dancing his way there. For such an immense physique, he's incredibly nimble: spinning, leaping from side to side, and gyrating his body. You expect him to knock you over, but he maneuvers around you like a well-trained professional. When a slow song comes on, @{((main_ro = "Jaime") or (second_ro = "Jaime")) he takes you around the waist and pulls you in close. His hands caress you with a ginger touch, and he takes every chance to steal a kiss. You place your head against his chest as the two of you sway to the melody. The safest place is in his arms, and you wish the song would never end.|the two of you gather into a group with other dancers and take turns exchanging partners. The mood is high all around with smiling faces and warm embraces. Jaime's smile never fades, and laughter fills the dance floor until the end of the song.}
*return

*label JillianDance
*set jillian_faction %+(round(empathy/6))
*set danced_with_jillian true

Jillian walks onto the dance floor reluctantly, but once she's out there, she moves to the beat and gains a focus you've never seen. Her eyes close, and her body flows like it's swimming in the melody. As the song reaches a new tempo, she keeps up with it, and even though she seems locked in her own world, she moves around you and thanks you with a smile. When a slow song comes on, she @{((main_ro = "Jillian") or (second_ro = "Jillian")) takes your hand and leads you off the dance floor to a darker area of the yard. She pushes her body in close, grabs your wrists, and places your hands low on her back. Her head rests in the nape of your neck, and the two of you sway from side to side for the entire length of the song.|Stands next to you and sways to the music. She doesn't need a partner as she moves, and even when she opens her eyes, she stares up at the sky like she's dancing for the universe to recognize her. You watch her for the entire song, and when it ends, she smiles at you.}
*return

*label KellyDance
*set kelly_faction %+(round(empathy/6))
*set danced_with_kelly true

Kelly dances with you onto the floor just as the song ends. She turns to the DJ booth and shouts, "Rock and roll!" Soon you hear the drum and electric guitar riffs of Seven Nation Army by The White Stripes. Kelly dances in place, arms raised overhead, and hops up and down to the beat of the music. You follow her lead so do most of the other dancers in the area. As the song hits its crescendo, the whole Junkyard is synchronized in a crowd of unbridled energy, everyone leaping and dancing, bodies slamming together. When the song fades, it's replaced by howls and applause.

A slow song starts next, and Kelly @{((main_ro = "Kelly") or (second_ro = "Kelly")) moves close to you and wraps her arms around your neck. Her face glistens with sweat, and when she moves in for a kiss you can taste the salt on her lips. The music matters little—it's just the two of you on the dance floor: kissing, swaying, grinding. By the time the song ends, you're panting and burning with desire for her.|Leads you off the dance floor, she turns, fanning herself with both hands. The two of you listen to the music and smile at all of those dancing, from the sidelines in the pauses of the music, you hear the howls of the infected outside the main gates. Somehow you block them out and just enjoy this moment of normalcy.}
*return

*label LopezDance
*set lopez_faction %+(round(empathy/6))
*set danced_with_lopez true

He keeps his arms raised while his feet move in complex steps. He spins and slides from one end of the dance floor to the other, and even does a jumping split at the apex of the song. When he breaks out a new move, the crowd cheers him on. You keep up with him until the song ends, and the whole floor breaks into applause.

The DJ switches to a slow song, and ${lopez}
*if (main_ro = lopez) or (second_ro = lopez)
  glides next to your body and takes you in his arms. You feel the strength in his forearms in the grip of his hands. Sweat trickles down his chest, and he's breathing hard. You feel the movement of his body and the sway of his hips, swinging left and right, in and out, all to the tempo. It's like he's making love to you out on that floor, and each movement he makes tells that story. When the song ends he gives you a soft kiss and thanks you for the dance.
*if (main_ro != lopez) and (second_ro != lopez)
  walks with you to the sidelines. He grabs a towel from a folding chair and wipes down his neck and arms. The two of you watch the dance floor, remarking at the pairs of survivors.
  
  "I never went to my prom, never understood why it was such a big deal until now.," he says.
  
  "Oh really?"
  
  "At least for tonight, everyone out there's free from the outbreak. The world's gone back to normal while that music plays."
*return

*label MadisonDance
*set madison_faction %+(round(empathy/6))
*set danced_with_madison true
The song changes to one that's upbeat and frenzied, and the two of you bounce around on stage like bees buzzing in a jar. She's dancing and singing and moving her body with abandon. She's smiling and laughing and giving high fives. It's not Madison but an alternate version of the girl who's turned on a charm you never knew she possessed. 

When a slow song starts,
*if (main_ro = "Madison") or (second_ro = "Madison")
  she moves her arms over your neck and gives you a quick kiss. Her body presses against yours, and shes hold you close, gripping you tightly.
  
  "Never let me go," she says.
  
  She lays her head on the top of your chest, and you smell the hint of her flowery perfume. Every time her hair brushes your cheek, you feel alive again. The two of you dance in the middle of the floor, like it's just the two of you, not just in the Junkyard but in the whole world. Even when the song ends, you keep dancing, and it's not until the loud drums of the next song break you from your trance that Madison kisses your lips and leads you to the sidelines.
*if (main_ro != "Madison") and (second_ro != "Madison")
  she leads you to the buffet line and pours you each a cup of zombie punch as it's been called.
  
  "This batch is alcohol free, but Kevin added a bottle of hot sauce. It's got a kick."
  
  She's all smiles watching the others dance on the makeshift floor, and she sways to the music and sips her drink with a pure joy you never knew she could possess.
  
  "Looks like everyone's having a good time out there," you say to her.
  
  She puts her cup down, reaches into a handbag at the end of the table, and takes out a camera. "Everyone deserves a good time. Yesterday is yesterday, and tomorrow is tomorrow. But today…" She takes a photo, and a Polaroid slides from the bottom. She shakes it, and when the image takes shape, she stares and smiles like it's already a memory.
*return

*label RachelDance
*set rachel_faction %+(round(empathy/6))
*set danced_with_rachel true
The two of you walk onto the dance floor, and as you begin Rachel's hesitant and stumbling around with no sense of rhythm. She spends more time looking at the other dancers, who don't look back at her. As the song plays, you see a look of calm come over her. She sways to the beat, and her body loosens up. You keep up with her as she struts around the dance floor.

When the next song starts, it's up-tempo, and Rachel kicks up her dancing a few notches. Her emotions become like a ballerina on high-speed. She glides and leaps and shakes her arms. Her expression shows a freedom it didn't show only a song ago.

When that song ends, and the DJ plays a slow ballad, Rachel smiles at you and moves in close. You take her hand and wrap your arm around her waist. She does the same, and you make your way into the center of the floor. She must know the moves to some elaborate ballroom dance, but she relaxes into the motion. She smiles, her eyes focused and intent, like she's on a mission, and you keep up with each step and pause, allowing her to lead and then taking the lead at times. At times she makes a misstep and chuckles at the mistake.

When the song ends, she's nothing but smiles. "I should head back on watch duty, but this was a lot of fun. Completely unexpected. Maybe we'll do it again."

She holds her hands out to the sides and pretends to curtsy. With that she walks off but looks back and winks.
*return

*label RayDance
*set ray_faction %+(round(empathy/6))
Following ${ray_him} to the center of the dance floor, ${ray_he} stands close and moves in some erratic set of motions like performance art: limbs flailing like rubber, hips swinging in wide circles, and face expressing strange emotions. You stay close to ${ray_him} and try to match ${ray_his} movements but most of the time you're avoiding ${ray_his} wild maneuvers. This draws stairs from all around the dance floor, though many glance at you instead of Ray.
  
"Having a good time?" Brody asks.

You wait for Ray to answer, but ${ray_he}'s locked in ${ray_his} dance, he ignores the question. @{(morality >= 50) "I'm having a great time,"|"It's okay. I'm just trying to keep up,"} you say.

Brody stares at you with an odd expression, shrugs, and moves off to the other side of the floor.
  
You dance with Ray until the end of the song, and a slower melody comes over the loudspeakers. Ray pushes ${ray_his} body against yours. It's such a quick move, you gasp. Suddenly, you're gliding around the dance floor weaving in and out of the crowd. Spinning so fast, you become dizzy and stumble to the sidelines, only to have Ray lift and swing you across the dance floor. $!{ray_his} moves are so elaborate and fanciful, the rest of the dancers stare at the two of you. They separate and form a circle, watching as Ray leads you through an intricate set of dance steps. When the song fades, you stand in the center, out of breath, sweaty, and exhilarated. When you look around at the other partygoers, you see them staring in shock. You're not sure why they look at you that way, but you try not to care. When you turn back to Ray, ${ray_he}'s gone, and a new song starts.
*return

*label ReillyDance
*set reilly_faction %+(round(empathy/6))
*set danced_with_reilly true

You lead him into the middle of the floor just as the song changes to something loud and upbeat. Reilly raises his hands and moves his feet in a deliberate range of steps taking up a short area right next to you.

"I haven't danced in years. Used to go clubbing all the time, but that was just to find someone to sleep with for the night. Those were the days," he says. He takes out the flask and downs another swallow, spilling some on his shirt. As he puts the flask away, he stumbles sideways and bumps into Madison.

"Watch it!" she shouts, and maneuvers away.

Reilly sticks his tongue out of his mouth and makes a fart noise. "Just having fun, Princess."

@{((main_ro = "Reilly") or (second_ro = "Reilly")) He wraps his arms around your shoulder, and you lead him away from the other dancers|You continue dancing with him, keeping close and moving him away from others} to avoid any more accidents. He smiles and laughs and even tries to sing the song. Mostly he makes up his own words. As the song fades, he @{((main_ro = "Reilly") or (second_ro = "Reilly")) gives you a hug, thanks you for the dance,|thanks you for the dance} and walks back to the buffet line by himself.
*return

*label RosieDance
*set rosie_faction %+(round(empathy/6))
*set danced_with_Rosie true
When you get to the dance floor, Rosie brings her arms straight out and moves her body like a snake, undulating her chest, hips, and legs in never ending waves. When the beat changes, she leaps in place. She keeps her eyes closed, snapping her fingers. When you get close to her she puts her arms by your sides so she's dancing with you but not touching you.

From the sidelines, Reilly @{nora_join and Nora watch Rosie with looks of pure shock, and they raise their arms and clap|watches Rosie with a look of pure shock, and he raises his arms and claps} for her. She continues unfazed, moving her body to the song.

As the song changes to a slow melody, Rosie @{((main_ro = "Rosie") or (second_ro = "Rosie")) takes your arms and pulls them around her. She snuggles against you, burying her head against your chest. You sway with her from side to side, taking small steps in a circle. From the outside the two of you must look like young students at their first dance. It's simple and sweet, and you enjoy the music with Rosie against you.|Wraps her arms around her body like she's dancing with herself. She stands in front of you, swaying to the music and taking small steps in a circle. From the outside she looks like a young student at her first dance with an invisible partner. The smile on her face proves how much she's enjoying it.}


After another few songs shift from slow to up-tempo, you keep up with her every step and every movement. As the song changes, the record skips, and Rosie breaks away from you.

"I better go check," she says looking across to the DJ table. "This was fun. Maybe we can do it again, but I'm afraid to leave the DJ station for too long." She raises her hand and gives you a high five before walking off.
*return

*label TommyDance
*set tommy_faction %+(round(empathy/6))
*set danced_with_tommy true
You step onto the dance floor as one song ends. Tommy stands around with an expression of confusion and fear, something you're not used to you seeing. As the next song starts with a flurry of quick beats, his body moves and he draws in close to you. His legs move side to side, shuffling his feet in a series of steps that show he's comfortable on the dance floor, but you keep up and follow his lead.
*if (main_ro = "Tommy") or (second_ro = "Tommy")
  At times his body bumps into yours, not in mistake, but in planned moments of connection. He wants you to feel him moving. The tempo increases, and he leans in with a kiss. You struggle to keep your hands off of him, and whenever you reach out, he slips away. He's teasing you with his dance. Your heart beats faster, and any time you meet his gaze it beats even quicker.
  
  When a slow song comes on, he he presses his body against yours, and though the movements are the same as the last song, he moves slow and with a power behind each step. He pauses at times and runs his hands along your chest. Further into the song he moves behind you and kisses the side of your neck. When he moves to the front he turns his back to you and pulls your arms around him. You feel the muscles of his arms and smell the sweat on his body. Anytime you try to pull him into an embrace, he slips away.
*if (main_ro != "Tommy") and (second_ro != "Tommy")
  
  "I used to go to a club at Nightfall with friends every Sunday night. It was guys night, and everyone went. You'd see old boyfriends there and check out guys you've been flirting with. It was like an alternate reality, because on Monday mornings we all went home and back to our lives. We all seem to just wait for Sunday nights." He looks off in the distance, eyes unfocused like he's picturing all of this.
  
  When a slow song comes on, he slows his movements and dances next next to you. Others come over, and you dance as a group with Tommy leading you all through a series of steps.

As the music shifts again to a faster song, Tommy fans himself with his hands and moves to the side of the dance floor. "I'm going to take a break, but we should dance again later if there's time."

@{((main_ro = "Tommy") or (second_ro = "Tommy")) As he walks off, he looks over his shoulder at you and his gaze lingers until he steps around the corner of the garage and out of sight.|"Sounds good. Thanks for the dance," you say and watch him walk off.}
*return

*label WoodyDance
*set woody_faction %+(round(empathy/6))
*set danced_with_woody true

He has few dance moves and simply shuffles from side to side bouncing his legs and moving his arms like he's running. The smile on his face tells a different story of the best dancer on the planet.

As you walk over to his side, he jerks his head back, takes a step to the side, and twirls in a circle. At the end, he stumbles and bumps into Madison who laughs and shoves him back. You catch him and stand him straight.

"Sorry 'bout that. I'm not too good at this, but damn it's fun," he says.

As a new song comes on, the beat grows stronger and more intense—a pounding of drums with a twang of electric guitar. Woody picks up the pace, moving his arms and legs in uncoordinated, grand motions. You dance next to him, and the two of you take a tour around the dance floor. As you move, you see the looks of delight on the faces of your fellow survivors.

When the music changes to a country tune, Woody moves to the front of the crowd and starts a series of hand and foot steps: kicking his heels, raising his knees, and clapping his hands. Everyone separates, faces forwards, and follows his lead. The clapping rises louder than the music. Woody chants along with the lyrics, and spirits rise for the length of the song.
*if (main_ro = "Woody") or (second_ro = "Woody")
  He even brings you up beside him, so you dance together with the other dancers behind the two of you.
  
When the song ends, everyone gives a round of applause, and Woody gives you a  @{((main_ro = "Woody") or (second_ro = "Woody")) quick kiss|high five} before dancing off.
*return

*label NotParticpating

As you stand there, @{(main_ro != "") ${main_ro}|Jaime} steps next to you. "Not
*if participate
  dancing? I thought you'd be out there already."
  
  "No one has asked me yet, so I'm just watching everyone else."
*if not(participate)
  taking part in the party?"
  
  "No, I want to make sure this place stays safe. @{(ideal >= 50) I'm enjoying the music, but I'm not too into dancing."|I don't really see the point of having the prom in the middle of an outbreak."}
*set count +1

*if main_ro = "Bailey"
  *goto BaileyDanceQuestion
*elseif main_ro = "Brody"
  *goto BrodyDanceQuestion
*elseif main_ro = "Gina"
  *goto GinaDanceQuestion
*elseif main_ro = "Jillian"
  *goto JillianDanceQuestion
*elseif main_ro = "Kelly"
  *goto KellyDanceQuestion
*elseif main_ro = lopez
  *goto LopezDanceQuestion
*elseif main_ro = "Madison"
  *goto MadisonDanceQuestion
*elseif main_ro = "Rachel"
  *goto RachelDanceQuestion
*elseif main_ro = "Reilly"
  *goto ReillyDanceQuestion
*elseif main_ro = "Rosie"
  *goto RosieDanceQuestion
*elseif main_ro = "Tommy"
  *goto TommyDanceQuestion
*elseif main_ro = "Woody"
  *goto WoodyDanceQuestion
*elseif not(asexual)
  *if ((second_ro != "Bailey") and (bailey_join and ((like_females and (bailey_faction >= 50))))) and (bailey_other != 2)
    *set flirting_with "Bailey"
    *goto BaileyDanceQuestion
  *elseif ((second_ro != "Brody") and ((like_males and teenager) and (brody_faction >= 50))) and (brody_other != 2)
    *set flirting_with "Brody"
    *goto BrodyDanceQuestion
  *elseif ((second_ro != "Gina") and ((gina_join and (teenager = false)) and (gina_faction >= 50))) and (gina_other != 2)
    *set flirting_with "Gina"
    *goto GinaDanceQuestion
  *elseif ((second_ro != "Jaime") and (like_males and (jaime_faction >= 50))) and (jaime_other != 2)
    *set flirting_with "Jaime"
    *goto JaimeDanceQuestion
  *elseif ((second_ro != "Jillian") and (jillian_join and (like_females and (jillian_faction >= 50)))) and (jillian_other != 2)
    *set flirting_with "Jillian"
    *goto JillianDanceQuestion
  *elseif ((second_ro != lopez) and ((lopez_other != 2) and (lopez_join and (teenager = false)))) and (like_males and (((male or nb) and (lopez_faction >= 50)) or (female and (lopez_faction >= 75))))
    *set flirting_with lopez
    *goto LopezDanceQuestion
  *elseif ((second_ro != "Kelly") and (like_females and ((teenager = false) and (kelly_faction >= 50)))) and (kelly_other != 2)
    *set flirting_with "Kelly"
    *goto KellyDanceQuestion
  *elseif ((second_ro != "Madison") and ((like_females and teenager) and (madison_faction >= 50))) and (madison_other != 2)
    *set flirting_with "Madison"
    *goto MadisonDanceQuestion
  *elseif ((second_ro != "Rachel") and (like_females and (rachel_faction >= 50))) and (rachel_other != 2)
    *set flirting_with "Rachel"
    *goto RachelDanceQuestion
  *elseif ((second_ro != "Reilly") and ((like_males and (teenager = false)) and (reilly_faction >= 50))) and (reilly_other != 2)
    *set flirting_with "Reilly"
    *goto ReillyDanceQuestion
  *elseif (second_ro != "Rosie") and (like_females and (female and ((rosie_faction >= 50) and (rosie_other != 2))))
    *set flirting_with "Rosie"
    *goto RosieDanceQuestion
  *elseif ((second_ro != "Tommy") and (tommy_join and ((male or nb) and (like_males and (tommy_faction >= 50))))) and (tommy_other != 2)
    *set flirting_with "Tommy"
    *goto TommyDanceQuestion
  *elseif ((second_ro != "Woody") and (woody_join and (woody_other != 2))) and (((like_males and (woody_like = 0)) and (teenager = false)) and ((((male or nb) and ((woody_faction >= 75) and (m_persuasion >= 60)))) or (female and ((woody_faction >= 50) and (m_persuasion >= 50)))))
    *set flirting_with "Woody"
    *goto WoodyDanceQuestion
  *else
    *goto JaimeDanceQuestion
*else
  *goto JaimeDanceQuestion
  
*label CheckParticipation
*set count +1
*gosub SurvivorsDancing

*if count > 1
  *goto EndProm
*if second_ro = "Bailey"
  *goto BaileyDanceQuestion
*elseif second_ro = "Brody"
  *goto BrodyDanceQuestion
*elseif second_ro = "Gina"
  *goto GinaDanceQuestion
*elseif second_ro = "Jillian"
  *goto JillianDanceQuestion
*elseif second_ro = "Kelly"
  *goto KellyDanceQuestion
*elseif second_ro = lopez
  *goto LopezDanceQuestion
*elseif second_ro = "Jaime"
  *goto JaimeDanceQuestion
*elseif second_ro = "Rachel"
  *goto RachelDanceQuestion
*elseif second_ro = "Reilly"
  *goto ReillyDanceQuestion
*elseif second_ro = "Rosie"
  *goto RosieDanceQuestion
*elseif second_ro = "Tommy"
  *goto TommyDanceQuestion
*elseif second_ro = "Woody"
  *goto WoodyDanceQuestion
*elseif not(asexual) and (flirting_with = "")
  *if ((main_ro != "Bailey") and (bailey_join and ((like_females and (bailey_faction >= 50))))) and (bailey_other != 2)
    *set flirting_with "Bailey"
    *goto BaileyDanceQuestion
  *elseif ((main_ro != "Brody") and ((like_males and teenager) and (brody_faction >= 50))) and (brody_other != 2)
    *set flirting_with "Brody"
    *goto BrodyDanceQuestion
  *elseif ((main_ro != "Gina") and ((gina_join and (teenager = false)) and (gina_faction >= 50))) and (gina_other != 2)
    *set flirting_with "Gina"
    *goto GinaDanceQuestion
  *elseif ((main_ro != "Jaime") and (like_males and (jaime_faction >= 50))) and (jaime_other != 2)
    *set flirting_with "Jaime"
    *goto JaimeDanceQuestion
  *elseif ((main_ro != "Jillian") and (jillian_join and (like_females and (jillian_faction >= 50)))) and (jillian_other != 2)
    *set flirting_with "Jillian"
    *goto JillianDanceQuestion
  *elseif ((main_ro != lopez) and ((lopez_other != 2) and (lopez_join and (teenager = false)))) and (like_males and (((male or nb) and (lopez_faction >= 50)) or (female and (lopez_faction >= 75))))
    *set flirting_with lopez
    *goto LopezDanceQuestion
  *elseif ((main_ro != "Kelly") and (like_females and ((teenager = false) and (kelly_faction >= 50)))) and (kelly_other != 2)
    *set flirting_with "Kelly"
    *goto KellyDanceQuestion
  *elseif ((main_ro != "Madison") and ((like_females and teenager) and (madison_faction >= 50))) and (madison_other != 2)
    *set flirting_with "Madison"
    *goto MadisonDanceQuestion
  *elseif ((main_ro != "Rachel") and (like_females and (rachel_faction >= 50))) and (rachel_other != 2)
    *set flirting_with "Rachel"
    *goto RachelDanceQuestion
  *elseif ((main_ro != "Reilly") and ((like_males and (teenager = false)) and (reilly_faction >= 50))) and (reilly_other != 2)
    *set flirting_with "Reilly"
    *goto ReillyDanceQuestion
  *elseif (main_ro != "Rosie") and (like_females and (female and ((rosie_faction >= 50) and (rosie_other != 2))))
    *set flirting_with "Rosie"
    *goto RosieDanceQuestion
  *elseif ((main_ro != "Tommy") and (tommy_join and ((male or nb) and (like_males and (tommy_faction >= 50))))) and (tommy_other != 2)
    *set flirting_with "Tommy"
    *goto TommyDanceQuestion
  *elseif ((main_ro != "Woody") and (woody_join and (woody_other != 2))) and (((like_males and (woody_like = 0)) and (teenager = false)) and ((((male or nb) and ((woody_faction >= 75) and (m_persuasion >= 60)))) or (female and ((woody_faction >= 50) and (m_persuasion >= 50)))))
    *set flirting_with "Woody"
    *goto WoodyDanceQuestion
  *else
    *goto MadisonDanceQuestion
*else
  *goto MadisonDanceQuestion
  
*label BaileyDanceQuestion
"I'm not much of a dancer, but I figured it would be fun if we got out there together," she says. @{participate "Can you take a break for a few minutes or even just one song?"|"Let's go, if even for just one song."}
*if flirting_with = "Bailey"
  The way she's looking at you makes you realize she may be interested in more than a dance.
  *choice
    #I like ${flirting_with} and would like to explore a relationship with her.
      *set bailey_like 1
      *if main_ro = ""
        *set main_ro "Bailey"
        *set main_ro_he "she"
        *set main_ro_his "her"
        *set main_ro_him "her"
      *if (second_ro = "") and (main_ro != "Bailey")
        *set second_ro "Bailey"
        *set second_ro_he "she"
        *set second_ro_his "her"
        *set second_ro_him "her"
        "So would you like to dance?" she asks.
      *goto CheckBailey
    #I like her as a friend but nothing more.
      You see Bailey as a friend, maybe even as his sister, but not as a partner.
      
      "So would you like to dance?" she asks.
      *goto CheckBailey
    #I don't like her too much and don't want to lead her on.
      *set bailey_faction %-(round(20-(empathy/6)))
      Bailey is a member of your group but that's about as close as you want to get to her.
      
      "No thanks. I just want to be alone for a while," you say.
      *goto BaileyDissappointed
*label CheckBailey
*choice
  #"Sure, I'll dance with you."
    Bailey smiles and leads you onto the dance floor.
    *gosub BaileyDance
    *goto CheckParticipation
  #"I don't want to dance, but I'd like to hang out."
    *set bailey_faction %+(round(empathy/6))
    Bailey seems content with staying with you for a little while as the two of you listen to the music and even hold hands. After a few songs play, she excuses herself to go get some food and leaves you with a kiss.
    *goto CheckParticipation
  *if not(participate)
    #"Sorry, but I'm going to stay on watch duty."
      *goto BaileyDissappointed
  #"No thanks. I just want to be alone for a while."
    *label BaileyDissappointed
    Baily nods and looks at the ground. "Okay. If you change your mind, I'll be around. We should dance at least once, but it's cool if you don't want to."
    
    She smiles at you and hurries off.
    *goto CheckParticipation

*label BrodyDanceQuestion
"You have to dance with me at least once, so let's go," he says.
*if flirting_with = "Brody"
  The way he's looking at you makes you realize he may be interested in more than a dance.
  *choice
    #I like ${flirting_with} and would like to explore a relationship with him.
      *set bailey_like 1
      *if main_ro = ""
        *set main_ro "Brody"
        *set main_ro_he "he"
        *set main_ro_his "his"
        *set main_ro_him "him"
      *if (second_ro = "") and (main_ro != "Brody")
        *set second_ro "Brody"
        *set second_ro_he "he"
        *set second_ro_his "his"
        *set second_ro_him "him"
        "So would you like to dance?" he asks.
      *goto BrodyCheck
    #I like him as a friend but nothing more.
      You see Brody as a friend, maybe even as his brother, but not as a partner.
      
      "So would you like to dance?" he asks.
      *goto BrodyCheck
    #I don't like him too much and don't want to lead him on.
      *set bailey_faction %-(round(20-(empathy/6)))
      Brody is a member of your group but that's about as close as you want to get to him.
      
      "No thanks. I just want to be alone for a while," you say.
      *goto BrodyDissappointed
*label BrodyCheck
*choice
  #"Sure, I'll dance with you."
    *gosub BrodyDance
    *goto CheckParticipation
  #"I don't want to dance, but I'd like to hang out."
    *set brody_faction %+(round(empathy/6))
    Brody dances by your side for the length of the song, and the two of you watch the @{participate forest and road to the east of the Junkyard.|survivors on the dance floor.} He talks about his sister and how much fun she's having, and before you know it one song turns into three.
    
    "I'm going to check out the buffet. Want anything?" he asks.
    
    "I'm okay for now. Thanks for hanging out."
    
    As he walks away you turn your attention back to @{participate the dance floor.|watch duty.}
    *goto CheckParticipation
  *if not(participate)
    #"Sorry, but I'm going to stay on watch duty."
      *goto BrodyDissappointed
  #"No thanks. I just want to be alone for a while."
    *label BrodyDissappointed
    Brody frowns but it quickly fades as he looks back to the people dancing. "Suit yourself. If you change your mind, you know where to find me."
    *goto CheckParticipation
    
*label GinaDanceQuestion
"Do you have any interest in dancing with me?" she asks.
*if flirting_with = "Gina"
  The way she's looking at you makes you realize she may be interested in more than a dance.
  *choice
    #I like ${flirting_with} and would like to explore a relationship with her.
      *set gina_like 1
      *if main_ro = ""
        *set main_ro "Gina"
        *set main_ro_he "she"
        *set main_ro_his "her"
        *set main_ro_him "her"
      *if (second_ro = "") and (main_ro != "Gina")
        *set second_ro "Gina"
        *set second_ro_he "she"
        *set second_ro_his "her"
        *set second_ro_him "her"
        "So would you like to dance?" she asks.
      *goto GinaCheck
    #I like her as a friend but nothing more.
      You see Gina as a friend, maybe even as his sister, but not as a partner.
      
      "So would you like to dance?" she asks.
      *goto GinaCheck
    #I don't like her too much and don't want to lead her on.
      *set gina_faction %-(round(20-(empathy/6)))
      Gina is a member of your group but that's about as close as you want to get to her.
      
      "No thanks. I just want to be alone for a while," you say.
      *goto GinaDissappointed
*label GinaCheck
*choice
  #"Sure, I'll dance with you."
    *gosub GinaDance
    *goto CheckParticipation
  #"I don't want to dance, but I'd like to hang out."
    *set gina_faction %+(round(empathy/6))
    "Sounds great to me," she says. The two of you talk about the Junkyard, plans you have for making it better and more secure, and predictions on when the outbreak will end. She tells you how much she enjoys the people in the group and Kevin and his father. Though she misses her husband, part of her feels it's better off he's not around anymore.
    
    "I know that sounds weird. Of course I wish he was alive. But he wouldn't like the way things are going: people getting infected, scavenging for supplies, the constant worry. I'm glad he doesn't have to deal with all of that. He was a sensitive man who didn't like to see suffering. He's not suited for this world anymore. I hate that I even think that way."
    
    You sit with her in silence as a few songs play. You feel at peace standing next to her and looking out at @{participate your companions enjoying themselves all while the two of you remain quiet.|the main road and the Eastern woods.}
    
    "I'm going to check out the buffet. Want anything?" he asks.
    
    "I'm okay for now. Thanks for hanging out."
    
    As she walks away you turn your attention back to @{participate the dance floor.|watch duty.}
    *goto CheckParticipation
  *if not(participate)
    #"Sorry, but I'm going to stay on watch duty."
      *goto GinaDissappointed
  #"No thanks. I just want to be alone for a while."
    *label GinaDissappointed
    Gina nods slowly. "No problem. I just thought I'd ask. If you change your mind and want some company, please come find me." With a smile she walks away.
    *goto CheckParticipation

*label JaimeDanceQuestion
@{(main_ro = "Jaime") "Come dance with me.|"I'm not going to have my buddy miss out on some dancing. Come on.} It will be fun."
*if flirting_with = "Jaime"
  The way he's looking at you makes you realize he may be interested in more than a dance.
  *choice
    #I like ${flirting_with} and would like to explore a relationship with him.
      *set jaime_like 1
      *if main_ro = ""
        *set main_ro "Jaime"
        *set main_ro_he "he"
        *set main_ro_his "his"
        *set main_ro_him "him"
      *if (second_ro = "") and (main_ro != "")
        *set second_ro "Jaime"
        *set second_ro_he "he"
        *set second_ro_his "his"
        *set second_ro_him "him"
        "So would you like to dance?" he asks.
      *goto JaimeCheck
    #I like him as a friend but nothing more.
      You see Jaime as a friend, maybe even as his brother, but not as a partner.
      
      "So would you like to dance?" he asks.
      *goto JaimeCheck
    #I don't like him too much and don't want to lead him on.
      *set jaime_faction %-(round(20-(empathy/6)))
      Jaime is a member of your group but that's about as close as you want to get to him.
      
      "No thanks. I just want to be alone for a while," you say.
      *goto JaimeDissappointed
*label JaimeCheck
*choice
  #"Sure, I'll dance with you."
    *gosub JaimeDance
    *goto CheckParticipation
  #"I don't want to dance, but I'd like to hang out."
    *set jaime_faction %+(round(empathy/6))
    "Cool, I'll hang out for a bit," Jaime says and @{(main_ro = "Jaime") puts his arm around you.|walks closer to the main gate. He puts his fingers to the chain-link and looks out at the road.}
    
    The two of you talk about the @{participate dancers and the food, and then your conversation moves to discuss the Junkyard. Jaime can't believe how far you've come since your group formed in Nightfall.|last few days and your time so far at the Junkyard. Jaime thinks he spots something moving through the forest, but a large rodent runs across the path.} Song after song plays, but eventually Jaime grows restless.
    
    "Are you sure you don't want to dance?" he asks.
    
    You can tell he wants to head back onto the dance floor, so you say, "No, but you go ahead."
    
    He @{(main_ro = "Jaime") smiles and leans in with a kiss before heading off.|pats you on the back and says, "Okay, I'll be back around in a bit to check on you."}
    *goto CheckParticipation
  *if not(participate)
    #"Sorry, but I'm going to stay on watch duty."
      *goto JaimeDissappointed
  #"No thanks. I just want to be alone for a while."
    *label JaimeDissappointed
    Jaime frowns. "I get it. Let me know if you change your mind. I'm sure everyone would love to see you out there on the dance floor." He @{(main_ro = "Jaime") smiles and leans in with a kiss before heading off.|pats you on the back and walks away.}
    *goto CheckParticipation

*label JillianDanceQuestion
"So, are you ready to dance with me? I promise we'll have a good time," Jillian says.
*if flirting_with = "Jillian"
  The way she's looking at you makes you realize she may be interested in more than a dance.
  *choice
    #I like ${flirting_with} and would like to explore a relationship with her.
      *set jillian_like 1
      *if main_ro = ""
        *set main_ro "Jillian"
        *set main_ro_he "she"
        *set main_ro_his "her"
        *set main_ro_him "her"
      *if (second_ro = "") and (main_ro != "Jillian")
        *set second_ro "Jillian"
        *set second_ro_he "she"
        *set second_ro_his "her"
        *set second_ro_him "her"
        "So would you like to dance?" she asks.
      *goto JillianCheck
    #I like her as a friend but nothing more.
      You see Jillian as a friend, maybe even as his sister, but not as a partner.
      
      "So would you like to dance?" she asks.
      *goto JillianCheck
    #I don't like her too much and don't want to lead her on.
      *set jillian_faction %-(round(20-(empathy/6)))
      Jillian is a member of your group but that's about as close as you want to get to her.
      
      "No thanks. I just want to be alone for a while," you say.
      *goto JillianDissappointed
*label JillianCheck
*choice
  #"Sure, I'll dance with you."
    *gosub JillianDance
    *goto CheckParticipation
  #"I don't want to dance, but I'd like to hang out."
    *set jillian_faction %+(round(empathy/6))
    Jillian lets out a sigh of relief. "Thank God. I really don't want to dance, but I think it's what everyone expects."
    
    The two of you stand and watch the @{participate dance floor, and she can't help but comment on each of the dancers, sometimes with very colorful language. By the second song, the two of you are laughing so hard, some of the other survivors stop and look over at you.|main road and the eastern woods. You talk about the last few days, but she brings up her past life with Lyle and and how they wound up at your house.} A while passes, and she grows restless.
    
    "I'm going to take a walk. I'll be back later to see what you're up to." She kisses you and then strides towards the side of the Junkyard.
    *goto CheckParticipation
  *if not(participate)
    #"Sorry, but I'm going to stay on watch duty."
      *goto JillianDissappointed
  #"No thanks. I just want to be alone for a while."
    *label JillianDissappointed
    *set jillian_faction %-(round(20-(empathy/6)))
    Jillian frowns and stares at you for a moment. "Okay, I get it. Well, see you later."
    
    You can tell by her tone she's disappointed, but she walks away, leaving you alone again.
    *goto CheckParticipation

*label KellyDanceQuestion
"Do you feel like dancing with me?" she asks.
*if flirting_with = "Kelly"
  The way she's looking at you makes you realize she may be interested in more than a dance.
  *choice
    #I like ${flirting_with} and would like to explore a relationship with her.
      *set kelly_like 1
      *if main_ro = ""
        *set main_ro "Kelly"
        *set main_ro_he "she"
        *set main_ro_his "her"
        *set main_ro_him "her"
      *if (second_ro = "") and (main_ro != "Kelly")
        *set second_ro "Kelly"
        *set second_ro_he "she"
        *set second_ro_his "her"
        *set second_ro_him "her"
        "So would you like to dance?" she asks.
      *goto KellyCheck
    #I like her as a friend but nothing more.
      You see Kelly as a friend, maybe even as his sister, but not as a partner.
      
      "So would you like to dance?" she asks.
      *goto KellyCheck
    #I don't like her too much and don't want to lead her on.
      *set kelly_faction %-(round(20-(empathy/6)))
      Kelly is a member of your group but that's about as close as you want to get to her.
      
      "No thanks. I just want to be alone for a while," you say.
      *goto KellyDissappointed
*label KellyCheck
*choice
  #"Sure, I'll dance with you."
    *gosub KellyDance
    *goto CheckParticipation
  #"I don't want to dance, but I'd like to hang out."
    *set kelly_faction %+(round(empathy/6))
    "Works for me," she says, and the two of you stand next to each other and @{participate watch the members of your group dancing and singing to the music. She points out a few moves Brody makes, and she calls out a few song requests. You take her hand and before long the two of you are swaying back and forth to the sounds of the music.|Keep watch together. The music drifts over to where you're standing, and she talks about her time covering music in Nightfall and how she misses all of the musical events and concerts.}
    
    After several songs, she gives you a kiss and says, "I'm going to see if anyone needs help with the food or DJ booth. I'll check back with you in a little while."
    
    You nod and watch her walk away.
    *goto CheckParticipation
  *if not(participate)
    #"Sorry, but I'm going to stay on watch duty."
      *goto KellyDissappointed
  #"No thanks. I just want to be alone for a while."
    *label KellyDissappointed
    "Bummer, but okay. I'm going to see if they need help with the buffet table or the DJ booth. If you change your mind about that dance, give me a holler."
    
    You nod and watch her walk away.
    *goto CheckParticipation

*label LopezDanceQuestion
"You ready to @{participate go out there with me on the dance floor?"|take a break and dance with me?} ${lopez} asks.
*if flirting_with = "Lopez"
  The way he's looking at you makes you realize he may be interested in more than a dance.
  *choice
    #I like ${flirting_with} and would like to explore a relationship with him.
      *set lopez_like 1
      *if main_ro = ""
        *set main_ro lopez
        *set main_ro_he "he"
        *set main_ro_his "his"
        *set main_ro_him "him"
      *if (second_ro = "") and (main_ro != lopez)
        *set second_ro lopez
        *set second_ro_he "he"
        *set second_ro_his "his"
        *set second_ro_him "him"
        "So would you like to dance?" he asks.
      *goto LopezCheck
    #I like him as a friend but nothing more.
      You see ${lopez} as a friend, maybe even as his brother, but not as a partner.
      
      "So would you like to dance?" he asks.
      *goto LopezCheck
    #I don't like him too much and don't want to lead him on.
      *set lopez_faction %-(round(20-(empathy/6)))
      ${lopez} is a member of your group but that's about as close as you want to get to him.
      
      "No thanks. I just want to be alone for a while," you say.
      *goto LopezDissappointed
*label LopezCheck
*choice
  #"Sure, I'll dance with you."
    *gosub LopezDance
    *goto CheckParticipation
  #"I don't want to dance, but I'd like to hang out."
    *set lopez_faction %+(round(empathy/6))
    "Okay, that's fine," he says. He stands behind you, wraps his arms around your waist, and places his chin on your shoulder. You listen to the music and watch the @{participate other dancers,|the road and eastern woods} and he sways you left and right to the beat. You stay with him for a few songs, enjoying the feel of his embrace.
    
    His stomach growls, and he pulls away. "I'm going to check out that food table. You want anything?"
    
    "No, on good for now."
    
    He pats your butt and walks off with a smile.
    *goto CheckParticipation
  *if not(participate)
    #"Sorry, but I'm going to stay on watch duty."
      *goto LopezDissappointed
  #"No thanks. I just want to be alone for a while."
    *label LopezDissappointed
    He shakes his head. "You are seriously going to say no to me? Okay, I get it. When you change your mind, and you will change her mind, come find me."
    *goto CheckParticipation

*label MadisonDanceQuestion
Madison dances her way over to you and takes you by the hands. "You have to dance with me. I won't take no for an answer."
*if flirting_with = "Madison"
  The way she's looking at you makes you realize she may be interested in more than a dance.
  *choice
    #I like ${flirting_with} and would like to explore a relationship with her.
      *set madison_like 1
      *if main_ro = ""
        *set main_ro "Madison"
        *set main_ro_he "she"
        *set main_ro_his "her"
        *set main_ro_him "her"
      *if (second_ro = "") and (main_ro != "Madison")
        *set second_ro "Madison"
        *set second_ro_he "she"
        *set second_ro_his "her"
        *set second_ro_him "her"
        "So would you like to dance?" she asks.
      *goto MadisonCheck
    #I like her as a friend but nothing more.
      You see Madison as a friend, maybe even as his sister, but not as a partner.
      
      "So would you like to dance?" she asks.
      *goto MadisonCheck
    #I don't like her too much and don't want to lead her on.
      *set madison_faction %-(round(20-(empathy/6)))
      Madison is a member of your group but that's about as close as you want to get to her.
      
      "No thanks. I just want to be alone for a while," you say.
      *goto MadisonDissappointed
*label MadisonCheck
*choice
  #"Sure, I'll dance with you."
    *gosub MadisonDance
    *goto CheckParticipation
  #"I don't want to dance, but I'd like to hang out."
    Madison gives you a sideways glance like she's surprised and confused by your answer. "Do you seriously not want to dance with me? I'm not going to stop dancing all night, so if you're not up for it, that's cool. I'm still going to go out there. Okay?"
    
    "Sure, go do your thing."
    
    *goto MadKissCheek
  *if not(participate)
    #"Sorry, but I'm going to stay on watch duty."
      *goto MadisonDissappointed
  #"No thanks. I just want to be alone for a while."
    *label MadisonDissappointed
    Madison gives you a sideways glance like she's surprised and confused by your answer. "You're not going to dance with me? @{(main_ro = "Madison") Fine, but I want to hang out later. I'm going to dance until I drop, so you can come lay down with me when I pass out."|}
    *label MadKissCheek
    She @{(main_ro = "Madison") gives you a kiss on the cheek|smiles at you} and dances her way to the dance floor.
    *goto CheckParticipation

*label RachelDanceQuestion
"Well, it seems social protocol requires me to ask you to dance," she says with a bow, offering her hand.
*if flirting_with = "Rachel"
  The way she's looking at you makes you realize she may be interested in more than a dance.
  *choice
    #I like ${flirting_with} and would like to explore a relationship with her.
      *set rachel_like 1
      *if main_ro = ""
        *set main_ro "Rachel"
        *set main_ro_he "she"
        *set main_ro_his "her"
        *set main_ro_him "her"
      *if (second_ro = "") and (main_ro != "Rachel")
        *set second_ro "Rachel"
        *set second_ro_he "she"
        *set second_ro_his "her"
        *set second_ro_him "her"
        "So would you like to dance?" she asks.
      *goto RachelCheck
    #I like her as a friend but nothing more.
      You see Rachel as a friend, maybe even as his sister, but not as a partner.
      
      "So would you like to dance?" she asks.
      *goto RachelCheck
    #I don't like her too much and don't want to lead her on.
      *set rachel_faction %-(round(20-(empathy/6)))
      Rachel is a member of your group but that's about as close as you want to get to her.
      
      "No thanks. I just want to be alone for a while," you say.
      *goto RachelDissappointed
*label RachelCheck
*choice
  #"Sure, I'll dance with you."
    *gosub RachelDance
    *goto CheckParticipation
  #"I don't want to dance, but I'd like to hang out."
    *set rachel_faction %+(round(empathy/6))
    She stands and smiles. "Brilliant. I was hoping you'd say that."
    
    The two of you talk for a while and watch the @{participate dancers move about the floor.|eastern road and woods beside it.} She talks about the Junkyard and the work that's being done to make it more habitable for your group. After three songs, she tells you she's going to take a walk around the yard to check the security of the gate. When you turn to say goodbye, she's already gone.
    *goto CheckParticipation
  *if not(participate)
    #"Sorry, but I'm going to stay on watch duty."
      "I completely understand. Thank you for doing that. I feel better knowing some of us are keeping watch while the others party. 
      *goto RachelDissappointed
  #"No thanks. I just want to be alone for a while."
    "I completely understand. There've been many times I wanted to be alone.
    *label RachelDissappointed
    I'm going to take a walk around the outside perimeter. I'll check in with you later."
    *goto CheckParticipation

*label ReillyDanceQuestion
"So are you going to @{participate take a break and dance with me?"|dance with me or what?"}
*if flirting_with = "Reilly"
  The way he's looking at you makes you realize he may be interested in more than a dance.
  *choice
    #I like ${flirting_with} and would like to explore a relationship with him.
      *set reilly_like 1
      *if main_ro = ""
        *set main_ro "Reilly"
        *set main_ro_he "he"
        *set main_ro_his "his"
        *set main_ro_him "him"
      *if (second_ro = "") and (main_ro != "Reilly")
        *set second_ro "Reilly"
        *set second_ro_he "he"
        *set second_ro_his "his"
        *set second_ro_him "him"
        "So would you like to dance?" he asks.
      *goto ReillyCheck
    #I like him as a friend but nothing more.
      You see Reilly as a friend, maybe even as his brother, but not as a partner.
      
      "So would you like to dance?" he asks.
      *goto ReillyCheck
    #I don't like him too much and don't want to lead him on.
      *set reilly_faction %-(round(20-(empathy/6)))
      Reilly is a member of your group but that's about as close as you want to get to him.
      
      "No thanks. I just want to be alone for a while," you say.
      *goto ReillyDissappointed
*label ReillyCheck
*choice
  #"Sure, I'll dance with you."
    *gosub ReillyDance
    *goto CheckParticipation
  #"I don't want to dance, but I'd like to hang out."
    *set reilly_faction %+(round(empathy/6))
    Reilly smiles and holds up a bottle of beer. "Cheers. Even better."
    
    The two of you sit and chat about recent events, moving into the Junkyard, and your predictions on when the outbreak will end. Reilly finishes a beer and pops open another one at the start of the next song. His cheeks turn red and eyes look bloodshot. As the music plays on, he dances in place, and his voice grows louder.
    
    "I'm going to take a piss and get more beers. I'll check back with you later," he says and gives you a hug. He stumbles away and tosses a beer bottle at the far gate.
    *goto CheckParticipation
  *if not(participate)
    #"Sorry, but I'm going to stay on watch duty."
      *goto ReillyDissappointed
  #"No thanks. I just want to be alone for a while."
    *label ReillyDissappointed
    Reilly frowns and takes a step back. His eyes are bloodshot and cheeks are red. He starts to speak but takes a sip from his bottle. After a long swallow he says, "I gotta piss anyway. I'll be back later. I'm going to get you to dance before the night is through."
    
    He stumbles away and tosses a beer bottle at the far gate.
    *goto CheckParticipation

*label RosieDanceQuestion
"Well I took a break from DJ duty to come over here and ask you this question. You better give me the right answer. Wanna dance?"
*if flirting_with = "Rosie"
  The way she's looking at you makes you realize she may be interested in more than a dance.
  *choice
    #I like ${flirting_with} and would like to explore a relationship with her.
      *set rosie_like 1
      *if main_ro = ""
        *set main_ro "Rosie"
        *set main_ro_he "she"
        *set main_ro_his "her"
        *set main_ro_him "her"
      *if (second_ro = "") and (main_ro != "Rosie")
        *set second_ro "Rosie"
        *set second_ro_he "she"
        *set second_ro_his "her"
        *set second_ro_him "her"
        "So would you like to dance?" she asks.
      *goto RosieCheck
    #I like her as a friend but nothing more.
      You see Rosie as a friend, maybe even as his sister, but not as a partner.
      
      "So would you like to dance?" she asks.
      *goto RosieCheck
    #I don't like her too much and don't want to lead her on.
      *set rosie_faction %-(round(20-(empathy/6)))
      Rosie is a member of your group but that's about as close as you want to get to her.
      
      "No thanks. I just want to be alone for a while," you say.
      *goto RosieDissappointed
*label RosieCheck
*choice
  #"Sure, I'll dance with you."
    *gosub RosieDance
    *goto CheckParticipation
  #"I don't want to dance, but I'd like to hang out."
    *set rosie_faction %+(round(empathy/6))
    Rosie blows out a long sigh. "Right answer."
    
    The two of you watch @{participate your companions on the dance floor,|the area outside the main gate,} and as the music plays you talk about the Junkyard, life outside Nightfall, and your plans for surviving the outbreak. As she looks back at the DJ booth, she looks more agitated. When you ask about it, she says she feels the crowd is depending on her to keep the music going.
    
    "Go ahead back. It was nice to get a few songs with you," you say.
    
    She gives you a hug, squeezing you around the head, and then runs off to the DJ table.
    *goto CheckParticipation
  *if not(participate)
    #"Sorry, but I'm going to stay on watch duty."
      *goto RosieDissappointed
  #"No thanks. I just want to be alone for a while."
    *label RosieDissappointed
    Rosie purses her lips like she tasted something sour and wrinkles her nose. "Wrong answer. But I get it. If you get bored, find me at the DJ booth. I'll let you spin some tunes. The stereo is pretty awesome with all these sliders and buttons that you are kinds of things. Maybe you can slide things and play with about." She giggles and slaps her thigh. "That sounded dirty. Well bye."
    
    She turns and runs away.
    *goto CheckParticipation

*label TommyDanceQuestion
"Normally I love dance parties, but I haven't been in the mood. But I like to dance with you at least for a few songs. Do you feel up to it?"
*if flirting_with = "Tommy"
  The way he's looking at you makes you realize he may be interested in more than a dance.
  *choice
    #I like ${flirting_with} and would like to explore a relationship with him.
      *set tommy_like 1
      *if main_ro = ""
        *set main_ro "Tommy"
        *set main_ro_he "he"
        *set main_ro_his "his"
        *set main_ro_him "him"
      *if (second_ro = "") and (main_ro != "Tommy")
        *set second_ro "Tommy"
        *set second_ro_he "he"
        *set second_ro_his "his"
        *set second_ro_him "him"
        "So would you like to dance?" he asks.
      *goto TommyCheck
    #I like him as a friend but nothing more.
      You see Tommy as a friend, maybe even as his brother, but not as a partner.
      
      "So would you like to dance?" he asks.
      *goto TommyCheck
    #I don't like him too much and don't want to lead him on.
      *set tommy_faction %-(round(20-(empathy/6)))
      Tommy is a member of your group but that's about as close as you want to get to him.
      
      "No thanks. I just want to be alone for a while," you say.
      *goto TommyDissappointed
*label TommyCheck
*choice
  #"Sure, I'll dance with you."
    *gosub TommyDance
    *goto CheckParticipation
  #"I don't want to dance, but I'd like to hang out."
    *set tommy_faction %+(round(empathy/6))
    Tommy smiles and steps right next to you, so close you feel the warmth of his body. He takes her hand and points up with the sky. "My mother read this book on astronomy, but it wasn't written by a scientist. She learned the names of all the constellations but not the real ones, made-up ones based on religious symbols. You see the Big Dipper? The book called it the Cup of God. Way over there is Alpha Centauri. It forms a triangle with another star. My mother called it the Trinity. And you can faintly see that one over there called the Southern Cross. That's the actual astronomical name, so the book got it right."
    
    You and Tommy stand there for a while looking up at the stars and listening to the music. After several songs have played, he gives you a hug and walks to the DJ booth. You and Tommy stand there for a while looking up at the stars and listening to the music. After several songs have played, he gives you a hug and walks to the DJ booth.You and Tommy stand there for a while looking up at the stars and listening to the music. After several songs have played, he gives you a hug and walks to the DJ booth. The next song comes on, [i]A Sky Full of Stars[/i] by Coldplay.
    
    You glance over at Tommy who's smiling back at you.
    *goto CheckParticipation
  *if not(participate)
    #"Sorry, but I'm going to stay on watch duty."
      *goto TommyDissappointed
  #"No thanks. I just want to be alone for a while."
    *label TommyDissappointed
    Tommy nods at you and though you looks disappointed, he smiles and says, "I understand. If you change your mind or want to hang out or something, let me know. I won't be far away."
    *goto CheckParticipation

*label WoodyDanceQuestion
"So what if I asked you to dance? Feel like cuttin' the rug with me?"

"Cuttin' the rug?"

"Colloquial term for dancin'." He gives you a slight bow and extends his hand.
*if flirting_with = "Woody"
  The way he's looking at you makes you realize he may be interested in more than a dance.
  *choice
    #I like ${flirting_with} and would like to explore a relationship with him.
      *set woody_like 1
      *if main_ro = ""
        *set main_ro "Woody"
        *set main_ro_he "he"
        *set main_ro_his "his"
        *set main_ro_him "him"
      *if (second_ro = "") and (main_ro != "Woody")
        *set second_ro "Woody"
        *set second_ro_he "he"
        *set second_ro_his "his"
        *set second_ro_him "him"
        "So would you like to dance?" he asks.
      *goto WoodyCheck
    #I like him as a friend but nothing more.
      You see Woody as a friend, maybe even as his brother, but not as a partner.
      
      "So would you like to dance?" he asks.
      *goto WoodyCheck
    #I don't like him too much and don't want to lead him on.
      *set woody_faction %-(round(20-(empathy/6)))
      Woody is a member of your group but that's about as close as you want to get to him.
      
      "No thanks. I just want to be alone for a while," you say.
      *goto WoodyDissappointed
*label WoodyCheck
*choice
    #"Sure, I'll dance with you."
      *gosub WoodyDance
      *goto CheckParticipation
    #"I don't want to dance, but I'd like to hang out."
      *set woody_faction %+(round(empathy/6))
      "Fair enough," Woody says. The two of you talk about the outbreak so far and the new living situation in the Junkyard. He tells you his concerns for security but admits being excited at all the work to be done.
      
      "Ever watch one of those fixer-upper shows on HGTV? You know the ones where they take a crew of contractors nobody could afford to hire, and they find some rundown house so they can fix it and overprice it for sale? Besides the sellin' part, I feel like I'm livin' in one of them shows."
      
      You and when you talk for a while about plans to improve the Junkyard. He seems so excited about the work, time escapes the two of you. Eventually he suggests getting some food at the buffet table. When you pass, he says, "My stomach's grumblin', so I better fill it. I'll talk to you later." He leans in and kisses your cheek, carrying off before you can turn to say goodbye.
      *goto CheckParticipation
    *if not(participate)
      #"Sorry, but I'm going to stay on watch duty."
        *goto WoodyDissappointed
    #"No thanks. I just want to be alone for a while."
      *label WoodyDissappointed
      Woody nods. "Alrght then. I'm gonna hit the food table. Some good fixin's over there. I'll talk to ya later." He leans in and kisses your cheek, carrying off before you can turn to say goodbye.
      *goto CheckParticipation

*label EndProm
*page_break
*set stress %-(round(wil/5))
As the prom winds down, you move over to the food table and look over the snacks and special dishes laid out for all. As you try one of the hors d'oeuvres, Jaime walks over. He's shirtless, and it hangs over one shoulder, and a thin layer of sweat covers him.

"Damn, dancing in the heat, I think I've lost five pounds tonight," he says. He lifts his shirt and uses it as a towel over his face and then his body. "Hey, I've been meaning to talk to you about something.
*if leader
  *if allegiance >= 40
    Everyone thinks you're doing a really good job, and we're all really happy that you're in charge. I'm not sure anybody has given you that feedback. Kind of human nature that we complain when things are bad but never compliment people for a good job."
    *fake_choice
      #"Thanks for saying that. I appreciate the feedback."
        *set ideal %+15
        "You're very welcome, my friend,"
      #"There's no need to compliment me. I see leading this group as my job."
        *set honor %+15
        "That's definitely something a leader would say,"
      #"Does everyone feel that way or just you?"
        *set impulse %-15
        *set ideal %-15
        "Everyone feels just like I do, but they aren't going to say it,"
      *if (main_ro = "Jaime") or (second_ro = "Jaime")
        #"Maybe you can give me a special thank you later," I say and wink at him.
          *set impulse %+15
          "I think that type of reward can be arranged," Jaime says and gives you a soft kiss on the lips.
      #"I don't need anyone to compliment me. I just need everyone to listen to me, so I can keep you alive."
        *set honor %-15
        "That's definitely something a leader would say,"
  *if allegiance <= 40
    I've heard some concern over the way you're leading the group. This may not be the best time to talk to you about it, but it's been on my mind to talk to you about it."
    *fake_choice
      #"I didn't realize people felt like that. I'm going to try harder to be a better leader."
        *set ideal %+15
        "Thanks for saying that. I was really worried to tell you,"
      #"It's been difficult since the start of the outbreak, but that's no excuse for my performance. I'll do better."
        *set honor %+15
        "It has definitely not been easy on any of us. I appreciate how hard you're working, and I'm sure that's how everyone feels,"
      #"So people in this group are too scared to badmouth me to my face? Or is this just the way you feel?"
        *set ideal %-15
        *set impulse %-15
        "It's not just how I feel. I've heard rumblings from everyone, well, for most of the group. I know you're doing your best, and I'll help anyway I can,"
      #"I don't care what people think about my leadership. I run this group, and if they don't like it, they can leave."
        *set honor %-15
        "Don't be like that. People still want you as leader, but they're worried about surviving. I'm just giving you a head's up,"
*if not(leader)
  *if humanity  >= 50
    I'm really impressed by the way you're handling the stress and challenges of the outbreak. It seems like you're really keeping it together. Some of the people in our group are letting it all get to them but not you."
    *fake_choice
      #"Thanks for saying that. I'm trying to stay strong, so I can be a help to everyone."
        *set morality %+15
        "That's awesome. Trust me, everyone appreciates all the things you do for us,"
      #"I appreciate that. I'm trying to stay positive, and everyone in this group has been very supportive."
        *set ideal %+15
        "I agree. This group has really kept us alive both physically and mentally. We have great people,"
      #"It's not always easy to stay positive. There are many days when I want to break down, but I just keep fighting."
        *set ideal %-15
        "I hear you. Just keep doing what you're doing, and I'll keep fighting by your side,"
      #"I think I've just become numb to all of the hardships of the outbreak. The only way I can keep going is if I ignore it all."
        *set honor %-15
        "That's going to be a hard approach the farther along we go in this outbreak. If you ever need someone to talk to, don't hesitate to find me,"
  *if humanity <= 50
    I feel like you're doing well with the stress and challenges of the outbreak, but I sometimes worry it's getting to you. Some of the people in the group are noticing it too. Let me know if there's anything I can do for you."
    *fake_choice
      #"Thanks, Jaime. Just hearing you say that reminds me why we're friends."
        *set morality %+15
        "I'm glad we're still together. Even when the world looks dark, knowing I have a friend nearby helps me keep going,"
      #"I'm stronger than you think. Sometimes the pressure gets to me, but I'm doing just fine."
        *set ideal %+15
        "No, I know you're strong. But I'm your friend and you don't need to do this alone. If you ever need me, just find me. We can talk and spend time together. I'm here for whatever you need,"
      #"I don't think I'm better or worse than anyone else. If you're not affected by this outbreak, you must already be dead."
        *set ideal %-15
        "I can't argue with that. But still, we've been through a lot, and we're all in this together. If you need something, just ask. As the outbreak goes on longer, we are going to need to rely on each other,"
      #"I don't need anyone worrying about me and don't want people spreading rumors either. Everyone should just worry about themselves and leave me alone."
        *set honor %-15
        "Don't be like that. We are all concerned about you, especially me. We're friends, and I'm not going to stop trying to be your friend. I'll leave you alone though. If you need me, please just find me, so we could talk,"
Jaime says.

The prom comes to an end with one final song, something you've never heard before by a local band. You listen to the lyrics and by the end, you're singing along…

[i]The end is always near, that's how the saying goes[/i]
*line_break
[i]Time keeps moving on from year to year.[/i]
*line_break
[i]I know I'll always miss you, and my love for you still grows[/i]
*line_break
[i]I'm so sad the end is always near.[/i]
*if teenager
  *page_break
  As you're @{(morality >= 50) helping to clean up,|walking back to your living quarters,} Eli rushes up to you with a huge smile on his face. He holds a scrap of paper in his hand and points at it. "${firstname}, you're not going to believe what I just found. I was talking to Jaime tonight, and he happened to mention your last name. It rang a bell. Your father had a classic car, right?"
  
  "Yeah, it was a Chrysler New Yorker, I think. He was always working on it, but he sold it a few months ago. I think he was going to buy a different car to work on. Why do you ask?"
  
  "That's right, it was a black 1956 Chrysler New Yorker, two speed automatic with a red interior. I bought a bunch of scrap from this car dealer who went out of business, and he had an original AM/FM radio from that make and model. Your father saw the ad and called my Junkyard. To make a long story short, he couldn't come to pick up the part, so he sent his friend. I have his contact information and phone number."
  
  He hands you the piece of paper where you see handwritten notes. You stare at the circled name and phone number, John Dorsey, 719-255-5790.
  
  "I know this guy. He used to come over my house and talk about classic cars with my father."
  
  Eli claps his hands together. "Let's go give him a call."
  
  "A call? How are we going to do that?"
  
  "Come on, I'll show you," Eli says and waves you to follow. He leads you to his office where he has an old rotary phone on the desk. He points to it and says, "I have a hardwired landline. Go ahead and give it a try. Maybe he knows where your parents are, and they can come pick you up."
  
  As you lift the phone, you think of your parents. Your father's name is…
  *label DadsName
  *fake_choice
    *if male
      #${firstname}. I'm named after my father.
        *set fathersname firstname
    #Carlos.
      *set fathersname "Carlos"
    #Charles.
      *set fathersname "Charles"
    #Jonathan.
      *set fathersname "Jonathan"
    #Michael.
      *set fathersname "Michael"
    #Ronald.
      *set fathersname "Ronald"
    #Walter.
      *set fathersname "Walter"
    #Something unique.
      Your father's name is…
      *input_text fathersname
  *if ((fathersname = "Tommy") or ((fathersname = "tommy") or ((fathersname = "Ben") or ((fathersname = "ben") or ((fathersname = "Dante") or ((fathersname = "dante") or ((fathersname = "Jaime") or ((fathersname = "jaime") or ((fathersname = "Nathan") or ((fathersname = "nathan") or ((fathersname = "Parker") or ((fathersname = "parker") or ((fathersname = "Reilly") or ((fathersname = "reilly") or ((fathersname = "Woody") or ((fathersname = "woody") or ((fathersname = "Brody") or (fathersname = "brody"))))))))))))))))))
    That's not your father's named. His name is…
    *goto DadsName
  Your mother's name is…
  *label MomsName
  *fake_choice
    *if female
      #${firstname}. I'm named after my mother.
        *set mothersname firstname
    #Amy.
      *set mothersname "Amy"
    #Crystal.
      *set mothersname "Crystal"
    #Monica.
      *set mothersname "Monica"
    #Nicole.
      *set mothersname "Nicole"
    #Rhonda.
      *set mothersname "Rhonda"
    #Sherry.
      *set mothersname "Sherry"
    #Something unique.
      Your father's name is…
      *input_text mothersname
  *if ((mothersname = "Bailey") or ((mothersname = "bailey") or ((mothersname = "Jillian") or ((mothersname = "jillian") or ((mothersname = "Madison") or ((mothersname = "madison") or ((mothersname = "Rachel") or ((mothersname = "rachel") or ((mothersname = "Rosie") or ((mothersname = "rosie") or ((mothersname = "Sifer") or ((mothersname = "sifer") or ((mothersname = "Gina") or ((mothersname = "gina") or ((mothersname = "Thelma") or (mothersname = "thelma"))))))))))))))))
    That's not your mother's name. Her name is…
    *goto MomsName
  You reach for the phone and pause. Could your parents really be alive? Could your father's friend somehow have information on how to reach them if they are alive? Staring at the phone, you see a large rectangular piece of plastic with a wheel and painted numbers, odd shaped buttons with numbers next to them, a coiled wire and a handset the size of a banana.
  
  "How do I use this thing?" you ask.
  
  Eli chuckles, hands you the handset, and looks at the paper with the phone number on it. "Put that to your ear and talk through the bottom part. I'll dial." He puts his finger in a hole in the dial and rotates it. You hear a click through the top of that handset, and he continues this pattern of using his finger to dial the circular wheel. It takes ten times longer than a cell phone, but then you hear a beep and a sound like it's ringing.
  
  "Hello? Hello? Who's this?" A voice asks.
  
  "Mr. Dorsey, is that you?" you ask.
  
  "Yes, this is John Dorsey. Who is this?"
  
  "It's ${firstname} ${lastname}. I'm calling about my parents, ${fathersname} and ${mothersname}. Do you have any idea where they are?"
  
  "Wait, this is Tiberius's son?"
  
  You haven't heard that name and a long time and not very often. You overheard Mr. Dorsey call your father Tiberius "WolfDrake" ${lastname}. You never knew why, and when you asked your father, he just told you to call him dad and forget you ever heard it.
  
  "Yes, that's me. Have you seen my parents?"
  
  "No, well yes…I saw them a few days ago. They were going to Nightfall to find you."
  
  Eli taps you on the shoulder. "What's he saying?"
  
  You hold up a finger to Eli to ask him to wait. You keep talking to Mr. Dorsey and say, "I left Nightfall a few days ago. I must have missed them. Do you have any idea where they are now? Are they still alive?"
  
  "I have no idea. I'm guessing they're still looking for you. Look, I have to go. I can't even believe you reached me this way. Phone lines have been down, but I guess you got lucky. Stay safe, and if you see Tiberius, tell him to watch out for…"
  
  The line goes dead.
  
  "So what happened? Are they alive? I hear you ask if they can come get you," Eli says.
  
  You hang up the phone and ask Eli to redial. He gives you a hard time but finally dials the phone number. This time the call doesn't connect.
  
  "Hey Eli, do you mind if we keep this between us?" you ask, not wanting to share this information with the rest of your group just yet.
  
  "No problem, consider it forgotten," Eli says and scratches his head. "Wait, what were we talking about?"
  
  You ignore his question and step out of the office. Your parents are alive and looking for you. You're not even sure how to find them or how to let them know you're at the Junkyard. There must be a way to reach them, and you think about it all the way back the ${living_quarters_desc}. When you lay your head to rest, images of your parents faces stay in your mind. They're alive and out there. You need to find them.
*page_break
*set ze_date "Saturday, May 26, 2012"
The next morning…

You walk along the edge of the Junkyard, looking at the few infected dead by the main gate.
*if ideal >= 65
  The defenses have held up so far, a testament to your group's efforts.
*if (ideal < 65) and (ideal > 35)
  The defenses have held so far, though the Junkyard's defenses have truly not been tested yet.
*if ideal <= 35
  While the group seems unfazed by the corpses, part of you is uncertain whether all the infected are truly dead or not. However, all is quiet. Neither low pitched moans nor spasmodic twitches of limbs. 
Just as you are about to turn around and walk away, Madison calls your name. When you look toward her, she is sitting cross-legged on the ground, a cheap looking laptop sitting on her legs. 

"What's up?" you ask, kneeling down by her side. 

"I've been messing around with this laptop I found," Madison explains. "I finally got it working and found something rather interesting."

"What is it?"

*if electronics >= 60
  Before Madison can reply, your gaze drops to the right-corner of the computer's screen, and you see a WiFi icon indicating there's a live connection nearby, one which reads DBARC. Those initials resonate—the DBA Research Center.

  "I've heard of that research center," you say. "And it obviously has power."

  Madison smiles, "And has some kind of Internet access."
*if electronics < 60
  You glance at the computer screen, and other than familiar icons for solitaire and word processing programs, nothing really stands out. "What am I looking for?"

  Madison taps the corner with her finger. "This. It found a network that was actually up and running. More importantly is the name—DBA Research Center."

"Let me guess, you think this place is worth investigating?"

Madison nods, stretching her arms back over her head.
*if (main_ro = "Madison") or (second_ro = "Madison")
  Her cleavage lifts through her shift, and you inadvertently smile.
  
  She fixes her shirt to hide the cleavage. "Settle down," she says with a smirk.
"If some group survived, they obviously have power. Maybe it's a place we could join. It sure beats sleeping in a Junkyard. And if they were doing research…maybe…maybe they were working on a cure."
*if kelly_join

  From behind, you hear a slight clearing of a throat, and Kelly joins the gathering. "Did you say DBA Research Center?"

  "Yeah," Madison answers. "Do you know about it?"

  Kelly's face darkens, and she nods. "The DBA stands for Devil's Backbone Agricultural. Supposedly they were doing research for crops and that sort of thing."

  "Supposedly? I gather you have a different impression of them." You glance up at her @{(timecount < 2000) and cover your eyes to block the sunlight|and slide to the side to give her room to join you and Madison}.

  Kelly takes a deep breath. "About six months ago or so, I actually got a tip from a…well, let's just call her a friend. She said the Centers for Disease Control were moving in, doing some kind of black-flag medical research. Her words. I managed to corroborate parts of her story, but when I tried to look further, all I got was stonewalled. At one point, my editor cut half my story and threatened to fire me over it. I'm a damn good journalist, and he never slashed apart one of my pieces like that before."

  *if ideal >= 50
    "The ad space isn't the only thing for sale, huh?" Madison says.
    
    Kelly scrunches her face. "What?"
    
    "She's implying your editor is working for someone who doesn't want the story televised," you say.
  *if ideal < 50
    "Sounds like someone got to him," you say.
    
    Kelly rubs her chin. "Hmm…you think so?"
    
    Madison's eyes go wide. "Yay, someone just as cynical as me."

  "One of the best chances to do something serious, not just another fluff piece, and I was told to back off or I would be fired," Kelly grumbles. "Something was going on, but not enough to jeopardize my career. Anyway, that place had a top-notch medical facility built into it too."
*if not(kelly_join)
  "It may be worth a shot for medical gear. I mean, we'll always need antibiotics, but they may have ultrasound machines, portable X-rays, and stuff like that."
*if research_virus
  
  This research setting may provide you a place to do research or at least access to devices and supplies you can bring back to the Junkyard.

"A medical facility?" Reilly shouts as he walks over, now adding to your group. "So they gotta have lots of meds, right?" 
*fake_choice
  #"Why do you need medicine? Everything alright?" I'm genuinely concerned about him.
    *set truth %+10
    Reilly's lip quirks slightly at your concern. @{nora_join "I'm fine. I'm more worried about Ma. Not that she isn't tough, but…well, she's my ma. You only get one right?"|"Not much out here can kill me, not zombies, people, or wild animals. Watch me get a cut and get an infection. That'll kill me. We need meds."}
  #"I doubt there's any left. Places like that get scavenged first." I want to discourage him from going.
    *set truth %-10
    "Considering we're out in the middle of friggin' nowhere, I'd bet there is something there," Reilly states.
  #"Madison could be wrong about them having a medical facility." I don't want to give him false hope.
    *set ideal %-10
    *set madison_faction %-(round(20-(empathy/6)))
    Madison's scowls. "You think I'm wrong? Sorry to burst your bubble, but my information is legit."
    
He glances in Madison's direction and rests a hand on the back of his neck. "You know where this place is? Up for a road-trip, Princess?"

Madison growls. "No. Even if you stopped calling me Princess, you couldn't pay me enough to ride in the same car as you."

"Have it your way. Besides, your brother would be the better choice when I think of it. I'll just ask…"

"No," Madison says with more vehemence than before. "Brody is likely to get you killed. Fine, let me get a couple of things." Madison trudges off, looking briefly in her brother's direction, shakes her head, and keeps walking.

"You're really going out there?" you ask.

"Yeah. @{nora_join If there is even a chance I can find the meds Ma uses, well, I have to go,"|I may not be the sharpest knife in the drawer, but I know medicine is the new gold,"} Reilly says. "And before you ask, no I wouldn't ask Madison along except she seems to know how to find the place." He looks you up and down. "There is always room for one more."

You nod, deciding to go to keep an eye on the two, although you feel…
*fake_choice
  *if leader
    #Pissed at Reilly for usurping my authority.
      *set reilly_faction %-(round(20-(empathy/6)))
      You feel furious since Reilly essentially decided on a course of action without your say-so. You make a mental note that when you get back, you will warn him not to do that again, or else.
  #Concerned about the safety of the two.
    *set morality %+10
    Madison and Reilly mix about as well as oil and water, and the only way to ensure they get back safely is if you go along. 

    [i]Hopefully their fighting doesn't lead to all our deaths[/i], you think.
  #Eager for some action.
    *set impulse %+10
    You feel anticipation and excitement start to rise. While you are safe at the Junkyard, you are growing weary of the bouts of boredom as well.
  #Irritated by two people acting like bickering kids.
    *set ideal %-10
    For a moment, you feel like slamming Reilly's and Madison's heads together since they are acting like squabbling children. Then you glance at the rest of your group, and you wonder how many of the others will start acting that way.
  #Someone is needed to lighten the mood.
    *set ideal %+10
    "You and Madison actually think a lot alike," you say. "She values our group's safety more than outsiders, she's good in a fight, and she's proven to be useful. She's been a sheltered rich kid for a while, but she's trying to fit in."
    
    Reilly shrugs. "I guess."
    *if empathy >= 55
      Though he tries to play it off, you can tell you've gotten him thinking.

You secure your own belongings, and get ready to head out.

*gosub_scene Part2Events CheckGear

*gosub_scene Part2Events ChangeUniform
*gosub_scene Part2Events AdjustSkills
*gosub_scene CheckWeapons

Next, you select a vehicle.
*gosub_scene SelectVehicle
*set timecount +25

You find yourself taking a quick look around the ${vehicle} you're taking to the research station. There doesn't appear to be any major damage. Just before leaving, you take a few more precious moments to make sure the tires are filled with air. As you finish the task, you hear the footsteps of your companions moving closer. Reilly has his shotgun resting on his shoulder, putting you briefly in mind of every generic shooter with a scruffy-looking thirty-something, gun-toting hero. Madison keeps a calm expression on her face, though there is a brief spring to her step. She wears yoga pants, a tight t-shirt, and sneakers with a small backpack.

"Who's driving?" Reilly asks. 

Madison cocks her head. "Why, are you offering?"

*if vehicle = "motorcycle"
  "I'm taking my motorcycle, so one of you will have to drive the SUV."
  
  *if (madison_like > 0) or (((like_females and teenager) and (madison_faction >= 50)) and (madison_other != 2))
    *set madison_rides true
    "Can't I ride with you?" she asks.
    *goto DriveKnit
  *else
    "Fine, let Reilly do it," she says.
    *goto DriveKnit
*else
  Sensing another petty squabble coming, as well as a possible headache, you decide…
  *label DriveChoice
  *choice
    #Madison will drive.
      *set madison_faction %+(round(empathy/6))
      You toss Madison the keys. "Why don't you get behind the wheel."

      Madison appears surprised, a slight smile building on her face. Then she shakes her head and tosses the keys back. "Um, I never learned how to drive. My parents…"

      Reilly interrupts with a smirk. "Did you also have a butler to chew your food for you?"
      
      She whips around on him. "Jealous much?"
      
      As they bicker, you decide…
      *goto DriveChoice
    #I will drive.
      "I'll drive," you say, opening the ${vehicle} door, momentarily feeling like a parent taking a couple of kids on a long trip.
      
      Given how the two act around each other, you quickly decide to keep them separated. As such, you decide to sit with…
      *fake_choice
        #Reilly.
          "Great," Madison says, muttering as she climbs in back. "Sticking me downwind of the pig."

          Reilly snorts. "Don't act like your farts don't stink, Princess."
          *goto DriveKnit
        #Madison.
          "Good," Reilly says. He climbs in back and stretches out lengthwise.

          Madison enters the front passenger side. "I'll blow your head off if you kick the back of my seat."
          *goto DriveKnit
    #Reilly will drive.
      *set driving 2
      You toss the keys to Reilly. "You drive."
      
      He grabs the keys with a single hand and heads for the driver's door. You move into the passenger seat to keep him and Madison apart.
      *goto DriveKnit
      
*label DriveKnit

*if driving = 1
  You pull out, adjusting the side mirror and catching the hilltop slowly disappearing from view. There is a brief moment of reflection as you realize this might be the last time you see it. You banish this thought and continue.
  *if madison_rides
    
    Madison locks her arms around your waist and rests her head on your back. Once in a while, you feel her give you a light squeeze, maybe just to remind you she's there.
*if driving = 2
  Reilly pulls out, and you spare a backward glance at the hilltop. Despite how isolating it feels, it offers a measure of protection from the infected. Then you settle down for the drive, Madison giving directions every so often by looking at her laptop.

The trip passes with peaceful quiet for a change. You glance @{(vehicle = "motorcycle") at the abundant foliage|out of the window}, glad to see the green of May. Of course, if the weather proves dry as normal, things will start turning brown as soon as June rolls around.

*if vehicle = "motorcycle"
  @{(madison_rides) Having Madison with you keeps her separated from Reilly, giving them a break from bickering.|You look over at the SUV from time to time and notice Reilly and Madison riding in silence. At least they're not bickering.}
  *if madison_rides
    
    *if hearing_impaired
      Madison says something from behind, but your hearing fails to catch her words over the roar of the motorcycle's engine.
      *goto DriveToResCenter
    *else
      "This is actually relaxing," Madison says from behind. Luckily, you're riding the motorcycle slow enough to hear her over the roar of the engine.
      *goto ResearchDriveChat
  *else
    *goto DriveToResCenter
*else
  For a change, it looks like your two companions are actually getting along, though they seem to find the silence a bit deafening.
  *goto ResearchDriveChat

*label ResearchDriveChat
*choice
  *selectable_if (madison_rides = false) #Talk to Reilly.
    *goto ResReillyTalk
  #Talk to Madison.
    *goto ResMadisonChat
  #Continue to the Research Center.
    *goto DriveToResCenter

*label ResReillyTalk
You glance briefly at Reilly and decide this might be a good chance to get to know him a little better. You bite your lip as you decide what to ask him.
*label RCReillyChat
*choice
  *if not(bank_robber)
    #"Since you like to cook, have you ever thought about opening a restaurant?"
      "Rest…" Reilly says quietly, then quickly shakes his head. "Do I look like someone who owns a restaurant? No, I used to work at one, but that was a while back. Before the outbreak, well, let's just say I'm self-employed."
      *if empathy >= 55
        From Reilly's body language, you can tell he is truthful for what he says, but he is still rather evasive about something.
      *goto RCReillyChat
  *if nora_join
    #"How is your mom holding up?"
      "You mentioned medications. If we need to, we can try to find a pharmacy sometime," you say.

      Reilly's mouth quirks upward. "Ma is doing fine at the moment. As I said earlier, if we find something, well, it doesn't hurt to be prepared." His face darkens. "I think we both know pharmacies are going to be the first places scavenged."
      *goto RCReillyChat
  *if not(nora_join)
    #"How are doing since your mom passed?"
      Reilly shakes his head. "What do you want me to say? Not too great. She was a mean ol' buzzard but meant a lot to me. I'm trying to hold it all together, but what do you expect? I'm not perfect and am struggling every day."
      *goto RCReillyChat
  *if (((like_males and (teenager = false)) and (reilly_faction >= 50)) and (reilly_other != 2)) and (reilly_like = 0)
    #I'm attracted to Reilly and want to see if he feels the same.
      *set reilly_like 1
      You offer a sidelong glance at Reilly, and for a moment your pulse quickens as you find something attractive about him. He catches your glance, and for a moment you think his checks redden. "Uh, is something the matter?" he drawls, a little more shy than you expected.
      
      "Nothing," you reply. "Just thinking that I really enjoy your company."
      
      He smiles, and the two of you keep shooting glances, catching each other eye to eye.
      
      "Are you two hot for each other?" Madison asks with a sigh. "It's the apocalypse, people. No time to waste on puffing out your chests or flapping your eyelashes."
      
      Reilly breaks out into laughter. "Goldilocks has a point. When we get back to the Junkyard, let's talk."
      *goto RCReillyChat
  #Tell him to stop picking fights.
    You take a deep breath, preparing yourself for a likely outburst. "Reilly, I'm not trying to start anything, but do you think you can drop the attitude? We can't afford to have everyone at each other's throats."
    
    Reilly 
    *if persuasion >= (110 - reilly_faction)
      grimaces, and at first you think he is going to disagree. "I will, maybe, at least if a few people toughen up." His eyes flick briefly in Madison's direction, but otherwise he says nothing.
    *if persuasion < (110 - reilly_faction)
      *set reilly_faction %-(round(20-(empathy/6)))
      chuckles, though there is a deadly edge to it. "There is one person I listen to above all others, and it certainly isn't you. Keep the advice and judgment to yourself. And if other people can't take some jabs, she can stay home next time."
      
    Madison folds her arms and wears a pout, her lips clenched.
    *goto RCReillyChat
  *if bank_robber
    #Reminisce how this reminds you of previous jobs.
      "Reilly, you know what this little jaunt reminds me of?" you ask.

      "What?"

      "Remember that little town—Berthoud I think it was called?"

      A low rumble of laughter fills the air. "Those hicks didn't know what hit them, did they? We sure scored big that day. Who knew farmers had all that money? That's a lot of corn, wheat, and chicken. If only every county had a farmer's bank, we could have retired young."

      Madison glances at the both of you, an inscrutable look on her face before she looks back out the window.
      *goto RCReillyChat
  #End the conversation.
    You let the conversation with Reilly drift off.
    *goto ResearchDriveChat

*label ResMadisonChat
Madison @{(vehicle = "motorcycle") repositions on the seat behind you and leans forward. Once in a while, you feel her cool breath on the back of your neck.|twirls a strand of long hair around a finger, and other than occasionally looking at her laptop, she stares out of the window, lost in her own thoughts.} You briefly consider what to ask her and start with…
*label RCMadisonChat
*choice
  #Ask Madison why she never learned to drive.
    "I'm a bit curious, but you never really learned how to drive?" you ask Madison. "Most teenagers usually have their license by now."

    Madison @{(vehicle = "motorcycle") sighs.|crosses her arms.} "You can thank my parents for that. As they would say, why should bother driving when we have a chauffeur?"
    *goto RCMadisonChat
  #Ask how Madison how she learned about computers.
    You @{(vehicle = "motorcycle") lean back and turn enough to watch the road and talk to Madison.|cast a glance at Madison, but she sees engrossed in her computer. You clear your throat a little.} "If you don't mind me asking, what made you so interested in computers?"

    Madison @{(vehicle = "motorcycle") slides her hands higher around your waist.|closes her eyes}. "As opposed to…wait, you were asking seriously?" 
    
    @{(vehicle = "motorcycle") "Yes, I'm serious."|You give a nod, which encourages her to continue.}
    
    "I guess I always found tinkering with stuff like this fun. It was something I could do on my own. It's a puzzle. You can learn anything you want online about this, whether it's hardware, software, coding, or whatever. So anytime I'm home alone and bored, I take my dad's laptop apart or code a script to download music, or whatever."
    *goto RCMadisonChat
  #Tell Madison she needs to be more considerate of her fellow survivors.
    You bite your lip, hoping that Madison won't blow up. "Madison, I'm sure you've how tense things have been. If you could stop causing drama, I would appreciate it."

    *if persuasion >= (110 - madison_faction)
      "And if I don't?" Madison asks, then quickly answers. "This isn't a reality show, I can't just go home if the group votes me out, can I? You've made your point. I'll keep my attitude in check, but I can only do so much to contain myself when I see stupidity."
    *if persuasion < (110 - madison_faction)
      *set madison_faction %-(round(20-(empathy/6)))
      She scoffs and shakes her head. "Maybe you should tell everyone else that before you get on my case. Trust me, I don't really have anything to say to most of the others and would like to keep it that way."
    *goto RCMadisonChat
  *if teenager
    #Feel out if Madison had plans for prom.
      "I hope you don't find this too strange. But I was kind of curious what your plans for prom were." You take a deep breath. "I mean, I know it may be a bit macabre considering how we left the school, but…"

      Madison seems sympathetic. "You are thinking of 'might have beens,' aren't you? I do that myself. If you really want to know." She takes a deep breath.
      *if madison_like > 0
        "I was thinking of asking @{(vehicle = "motorcycle") you."|you," she says quickly, cheeks burning.}

        "Really? But I thought you and
        *if male
          Jonathan
        *if female
          Brittaney
        *if nb
          River
        Reynolds were going? You've been a couple for the longest time."

        Madison smiles. "It depends how you measure it. We broke up so many times, that…well, it doesn't matter now, does it?
      *if madison_like = 0
        "I probably was going to go with
        *if male
          Jonathan
        *if female
          Brittaney
        *if nb
          River
        Reynolds," Madison says thoughtfully.

        "Probably?" you ask. "Didn't you two have a good relationship?"

        Madison shrugs. "We broke up a couple times already and made up. By that point, I think it was more habit than anything else.
      Enough about me. What about you? Did you have any plans for Prom?"
      *fake_choice
        #"I would have liked to go with you."
          *set madison_faction %+(round(empathy/6))
          There is quiet in the @{(vehicle = "motorcycle") air|car}, and for a moment you think you might have offended Madison. Instead, she sighs. "You and almost everyone else at school."
          
          You @{(ideal >= 50) laugh a bit, like you're in on the joke. "I don't doubt it|frown and feel your body sag. "I didn't think I had a chance}."
          
          She @{(((main_ro = "Madison") or (second_ro = "Madison")) or (madison_like > 0)) touches your arm. "If you would have asked, I would have said 'yes.'|murmurs something under her breath. "Trust me, I was no prize. You wouldn't have had fun at all. Madison a week ago was kind of a bitch.}"
        #"I was thinking of asking Taylor Regan."
          *set madison_faction %-(round(20-(empathy/6)))
          Madison lets out a high-pitched squeal that would call dogs within a mile. "This outbreak saved you from a terrible night. Taylor planned to get drunk at Prom and meet up with Grayson Tucker, whose parents were gone for the weekend. You would have gotten all dressed up and paid for tickets and a limo, only to be ditched. As my Uncle Nate would say, you dodged that bullet."
        #"I was thinking of asking Brody."
          "I thought of asking Brody if he would go," you say.
          
          There is quiet in the @{(vehicle = "motorcycle") air|car}, and for a moment you think she didn't hear you. "He had a line of people almost as large as mine wanting to go out with him. He would have chosen whoever was 'in' at that moment. Hate to say it, but it wasn't based on popularity or good looks or personality but your family's bank account. All our friends were superficial. Lot of good money does now."
        #"I didn't have anyone particular in mind."
          Madison nudges you, playfully. "Nothing more pathetic than a wallflower at a dance. I'm just teasing. If you went, you would have had a good time. Me, on the other hand, would have been miserable and whiny. So stupid. All that time worrying about what people thought of me and being in with the crowd. Where did it get me?"
      *goto RCMadisonChat
  *if teenager
    #"Do you miss being in high school? We lost out on our senior year."
      Madison shakes her head. "No way. I couldn't stand high school. Everyone was so fake. And let's not even mention the place was full of bullies. If you didn't live by their rules or act the way you were supposed to act, you would have be ostracized. I'm glad I don't have to go back. I actually feel like I get to be me now."
      *fake_choice
        #"I'm sorry that happened to you. I wish I would have stood up for you more."
          *set madison_faction %+(round(empathy/6))
          *set morality %+15
          "That's okay. I got through it all," she says. "It wasn't all bad. I did enjoy some of my friends who were the 'cool kids.' I just wish I got to hang out with other people without the risk of being bullied for it. But that part of my life is over, so there's no use looking back."
          *goto RCMadisonChat
        #"Is that why you hang out with the popular kids? So you could fit in and not be bullied?"
          *set impulse %-15 
          Madison nods. "Exactly. If I even talked to one of my old friends, the unpopular ones, I would get picked on or someone would bully them for talking to me. It just got easier to avoid them altogether. Let's not talk about this anymore. Why bring up bad memories when we have all of these new bad memories being made every day."
          *goto RCMadisonChat
        #"If people were acting that way towards you, you should have stood up to them. I don't see you as backing down to anyone."
          *set honor %-15
          "Madison rolls her eyes at you. "That's easy for you to say. You weren't the one being picked on and called a loser just for the type of friends you have. Maybe I should have stood up to that, but I handled it the best way I could. There's no use second-guessing myself now. That's all in the past."
          *goto RCMadisonChat
        #"No one stopped you from doing anything. You decided to hang with the cool kids, because that's what you wanted to do. I mean, you kind of enjoy being a bully."
          *set ideal %-15
          Madison's cheeks turn red and she says, "You don't know what you're talking about. I was friends with a lot of kids who are seen as nerdy or geeky or whatever, and I was a target because of it. I had to adapt or I would keep getting bullied."
          
          "I think that's just your perception. No offense but the smart girl who turns into miss popular to avoid being bullied, well, it's just a bit contrived. You could have been smart [i]and[/i] popular. @{((cha >= 50) and (int >= 50)) "Nothing stopped me. You let it stop you."|They're not mutually exclusive. You just took the easy road."}
          
          "You can believe what you want."
          *goto RCMadOver
  #End the conversation.
    *label RCMadOver
    Madison turns away, and you can tell she's signaling the end of your chat.
    *goto ResearchDriveChat

*label DriveToResCenter
*set timecount +50
*if driving = 1
  You continue
*if driving = 2
  Reilly continues
to drive in near silence with only the sounds of the whistle of air @{(vehicle = "motorcycle") as it passes around the windshield|from a crack in Madison's window}, and the roar of the ${vehicle}'s engine.

*if driving = 1
  You spot a speed bump in the distance. As you draw closer, you notice it to be an infected, lying face down. Dressed in a lab coat, it takes up half of the road. Pecking at the body are five rather large black birds, crows by the look of them. One bird glances your way, and its eyes appear blood red.
*if (driving = 2) and (vehicle != "motorcycle")
  The vehicle cuts speed, and Madison asks, "Why are we slowing down?"

  "Speed bump," Reilly says, and he points to an obstacle on the road. As you get closer, you see it is a person dressed in a lab coat, while bony claws extend out and upward. Then you make out several black, feathered birds pecking at the corpse. Their eyes appear bloodshot, and they seem unfazed by your vehicle coming. You count five of them.

However, as the @{(vehicle = "motorcycle") SUV|${vehicle}} passes on the side, a small object darts in front of the vehicle.
*if (vehicle = "motorcycle") or (driving = 2)
  *set stress %+(round((100-wil)/5))
  Reilly slams on the brakes, but he isn't fast enough to avoid one of the birds as it smacks headfirst into the windshield, pitting it in the process before sliding down to the wiper blades.
*if (vehicle != "motorcycle") and (driving = 1)
  You get into the other lane and make your way to the side of the body. Then one of the birds gives a loud squawk, and the birds erupt in a flurry of feathers and fury.
  
  *if (driving + v_man) >= 55
    You slam on your brakes, almost hitting one of the birds before it climbs just a little higher, avoiding the car entirely. Then, you hear a couple of raucous cries, and two of the crows flutter up and peck at the window.
  *if (driving + v_man) < 55
    *set vehicle_health %-(20-round(v_ram/2))
    You slam on your brakes, but not before a black body crashes into the middle of your windshield. You hear a loud, final squawk, and then a feathery body slides down, streaking the glass with its blood and a leaving sizable pit in the glass.

    "Just go already," Madison mutters. 

    You proceed once more, putting the body behind you. 
*if vehicle != "motorcycle"
  "Let's get out of here before we meet another suicidal bird."
*label ParkingLot
*page_break
You come to a stop in the middle of a parking lot, turning off the engine in front of a large, light-brown building with a single-story structure that has the appearance of an enormous loaf of bread. Long horizontal windows look like blank eyes, though some appear shattered, while some others are dotted with bullet holes. Letters stretch across the top near the roof:

[b]Devil's Backbone Agricultural Research Center[/b]

"I don't like the looks of this," Madison says quietly, and she points to the right side of the parking lot where a burned-out police car sits in charred despair. 

Reilly puts ammunition in his revolver. "Tell you what Princess, you can stay here and be nice and safe while @{teenager we|the grown-ups} take care of things."

Madison's eyes narrow, her hands tighten on her rifle, and for the shortest of moments, she seems like she wants to raise her firearm in Reilly's direction.

@{(ideal >= 50) "Come on, guys, we're all part of the same group. Let's not do this,|"Don't make me regret bringing the two of you along,}" you say.

Madison snorts. "Or what? You're going to send us to our room without dinner?"
*if madison_rides
  She climbs off the back of your bike.

You @{(vehicle = "motorcycle") step off your motorcycle|exit the ${vehicle}} and take stock of your surroundings. The outer facade is new and well-kept, though graffiti covers some areas low to the ground. Blinds cover all windows, while some are boarded from the inside. What parts of the interior you can see appear much darker than the outside, though you do notice some light in other parts of the building.
*if search >= 55
  Security cameras line the wall every thirty yards or so.

"Looks like they have back-up power," Madison says, pointing to the @{(search >= 55) roof.|roof where you can see security cameras.}

Reilly rests his shotgun on his shoulder. "Watch where you go. I bet there are people inside."

To the left of the building are two clear, semi-cylindrical buildings, and each is labeled "Greenhouse Pinky" and "Greenhouse Brain". Even from here, you can see plants in various stages of growth within the two grow houses. The walls are fairly solid except for the occasional window. However, the roof of each greenhouse has a clear skylight.

Behind the greenhouses are several large, freshly tilled fields. You notice small signs at various rows with writing in a language you can't read, though each sign bears the drawing of a vegetable: potato, carrot, ear of corn, and others.

Finally, you spot a single vehicle in the parking lot, a small truck of the sort used to transport animals with a cage over the flatbed.

"What the hell are those names? 'Pinky' and 'Brain'?" Reilly asks.

"The cartoon lab rats—Pinky and The Brain…from the cartoon?" Madison says, emphatically.

Reilly shrugs. "I don't watch cartoons."

"What a fossil." Madison scoffs and turns to you. "Where do we go first?"
*set count 0
*label RCOutsideMenu
*set count +1
*if count = 2
  *set madison_bathroom true
  
  Madison dances in place. "I really have to go to the lady's room. Can we go to the building now?"
    
  *if madison_faction >= 50
    *if morality >= 40
      "We can go soon. Can you hold it for a few minutes?" you ask.
      
      Madison shrugs. "I hope so."
    *if morality < 40
      "Didn't you go before we left?" you ask.
      
      Madison glares at you. "Kevin was in the bathroom for like thirty minutes."
  *if madison_faction < 50
    *if morality >= 40
      "We can go there soon. Just hold it a bit longer," you say.
      
      Madison purses her lips. "I'll try."
    *if morality < 40
      "We'll go when we finish out here. You should have went before we left," you say.
      
      Madison glares at you. "I tried but, Kevin was in the bathroom for like thirty minutes."
      
  "Just go over there," Reilly says, pointing to a sculpted bush behind the truck.
  
  "I had to pee in the woods for three days while we camped on the hill," Madison says. "I'm going to use restrooms from now on, thank you very much."
  
  Next you…
*choice
  #Examine the truck in the parking lot.
    *goto ParkingLotTruck
  #Search Greenhouse Pinky.
    *goto GreenhousePinky
  #Search Greenhouse Brain.
    *goto GreenhouseBrain
  #Enter the Agricultural Research Center.
    *goto ARC

*label ParkingLotTruck
You move closer to the truck and notice that the back doors are swung wide open. Within the interior of the van is a solid built cage with enough space you could look through the bars, but not large enough to stick an arm through. A blood-stained clipboard with an official form lies on the floor of the flatbed.

Reilly taps a bar. "Whoever was transporting wanted to make sure the animals didn't get out."  

From this angle, you notice a body in the passenger seat, head twisted almost one-hundred-eighty degrees, dead eyes staring right at you. 

Madison shakes her head and stands to the side, scanning the horizon, her hand on her gun.
*label RCTruck
*choice
  #Examine the body in the front seat.
    The figure in the front seat wears a uniform of some kind with black slacks and blue shirt, but there is no other insignia. Being this close, you can't help but notice the body actually suffered greater damage. Part of the face, hidden from your view, bears teeth marks, similar to those of the infected. There is also a small hole on that same side of the body, indicating someone didn't want the corpse to rise again. The corpse doesn't have any identification or weapons.

    Searching the glove compartment reveals only the vehicle's license, as well as the fact that it is registered to the university itself.
    *goto RCTruck
  #Search the cage more closely.
    You open the door of the cage a little and examine the back of the van. The floor and walls bear several deep gouges, and you're immediately put in mind of the clawed hands and feet of the infected.

    Examining the cage door also shows the bars were bent. Experimentally, you try to close the door, but they open slightly once more.

    Reilly scratches the back of his neck, "Something busted out of there. Something nasty."
    *goto RCTruck
  #Read the clipboard.
    The clipboard is soaked with drench and gore, but you can make out a few details. The first is in the upper right hand corner—you make out the words, Centers for Disease Control. Below that is the date to just four days before you fled your burning home. 

    The few other entries you make out list:
    
    Sample 23 – Terrance Mendoza - Terminated
    *line_break
    Sample 24 – Florence Braxton – Terminated
    *line_break
    Sample 25 – Lyla Sanford – Transported
    
    Having read the clipboard you place it back on the floor of the flatbed.
    *goto RCTruck
  #Return to the parking lot.
    *set timecount +25
    "Nothing left to see here," Reilly says.
    
    "Back to the parking lot," you say.
    *goto RCOutsideMenu
    
*label GHPDoor
All three of you grip the door handle. The metal springs creak, providing tension against you. With all of your combined strength, it moves, though slowly.

"My gosh, did the maintenance crew ever hear of WD-40?" Madison says, huffing. At the end of the door's range of motion,
*return

*label GreenhousePinky
*set visited_greenhouse_pinky true
Moving toward Greenhouse A, code named Pinky, you glance at the nearby sign. Below its designation, you make out the words, Botanical Samples. Clear windows flank each side of a tall glass door. Behind the door lies a table flipped to its side and pushed against the door, and several heavy looking bags behind it give support. The table stands as high as the top off your chest. Glancing through the windows, you see a room filled with a variety of plants in varying stages of growth.
*if (survival >= 55) or hobby_gardening
  Even at a distance, you can make out numerous medicinal plants: marigold, passionflower, Echinacea, motherwort, ginseng, and lemon balm. Some of these prefer different environments or food to thrive, making them a rare find.

"Looks like someone was trying to keep something out," Madison says quietly, her eyes darting behind the three of you.

You check the parking lot and see nothing coming.

Reilly touches the door handle and pulls it back a fraction of an inch. "Barricading doesn't seem like a good idea if the door opens outward," he says.

"It would work if the the you fear found doors beyond their reasoning, such as one of the infected," you say, pointing to scratch marks on the class.

Taking a closer look at the windows and door itself, you note several scratches as if made from claws marring the surface but not enough to break the glass. Gouges of different shapes and sizes mark the glass wall in patterns resembling hieroglyphics.

Madison @{madison_bathroom dances in place.|runs her fingertips over the surface.} "Or infected, plural. At least a few."

Reilly taps the door. "The fact someone put that up makes me want to explore further. However, I'm not too keen on home invasions."

"Are home invasions too low-level? Like, do bank robbers look down on breaking and entering?" Madison says, snickering.

Reilly's face breaks into a smile, and he pops a cigarette out of his pocket.
*if madison_bathroom
  "You guys hear running water? Like a tinkling of rain? Or maybe it's rushing like a waterfall."
  
  Madison squeezes her legs shut. "Stop it. That's not funny."
  
  Reilly steps closer to her. "Warm water running down your legs."
  
  Madison covers her ears and bounces. "I'm not listening. La la la la."
  
  @{(madison_faction >= 50) "Leave her alone, man,"|"Can we move on here?"} you say.
  
  Reilly chuckles and lights his cigarette.
  *if (reilly_faction >= 60) and add_nic
  
    You take it from his mouth and take a puff.
    
    "Sure, have it," he says and lights another.
"So how do you want to do this?"

You examine the doorway once more, seeing that tight springs keep tension to hold it shut. It will take someone holding it while one or more of you push aside the table. Holding the door open will take a lot of endurance while pushing the table is a feat of brute strength. For that matter, it may be easier to climb over the table, but you would expose yourself to anything on thee other side without a clear exit.
*label BarricadeMenu
*choice
  #Push the barricade back by myself while the others cover me.
    *set tried_door true
    "Why don't you two hold the door and watch my back while I push the barricade."
    
    Both Madison and Reilly agree. He grips the door handle and swings it outward. The metal springs creak, and Reilly struggles to swing the door wide. His biceps bulge and veins pop in his forearms. When it's open enough for you to move to the table, Madison puts her shoulder against the door and stretches out her legs for support.
    
    You crouch and place your shoulder right against the table. On the mental count of three, you press forward.
    *if str >= (fatigue - 10)
      At first it feels like you are trying to move a boulder. Your muscles bulge, and the metal bottom groans against the cement. However, things slowly but surely start to move, and you open enough space that a person can enter the greenhouse proper.
      *goto InsidePinky
    *else
      *set fatigue %+(round((100-sta)/5))
      *set stress %+(round((100-wil)/5))
      The bottom of the table scrapes the cement floor making a sound like nails on a chalkboard. Despite your best effort, nothing moves. You continue this way for a moment before fatigue sets in, and you back away.
      
      "It won't budge," you say and pull away from the barricade.
      
      "Can't hold it," Madison says, straining.
      
      "Let go. We'll reset." Reilly waits for you and Madison to clear the path of the door before releasing it. The door swings fast and slams shut, rattling.
      
      "Now what?" Reilly asks, bent over, hands on his knees.
      *goto BarricadeMenu
  #Get Reilly to help push the barricade back, while Madison holds the door.
    "Madison, keep the door open. Reilly, help me move this," you say.
    
    *if tried_door
      Reilly grumbles but gets right next to you. All three of you swing open the door. With all of your combined strength, it swings easier.
    *if not(tried_door)
      *gosub GHPDoor
      she braces her back against it, sitting low for leverage.
    "I won't be able to hold it for long," Madison says through grunts. "Move fast."

    You nod and crouch next to the table. Reilly stands next you, hands on the top, arms outstretched.
    
    "On the count of three," you say. "One, two, three."
    *if str >= (fatigue - 20)
      Slowly, the table starts to scoot along the floor, and soon you have an opening big enough for someone to slip on through.
    *if str < (fatigue - 20)
      *set p_health %-(round((100-sta)/5))
      The table scrapes the floor and moves only a few inches. You shove again, hard, and feel a sharp pain in your shoulder blades. Luckily, you slide the table enough to make an opening big enough for someone to slip through.
    *goto InsidePinky
  #Have Reilly and Madison push the barricade back, while I hold the door.
    "Reilly, Madison," you say. "I want the two of you to push the table."
    
    *if tried_door
      "Alright, let's all get the door open first," Madison says.
      
      All three of you grip the door handle. With all of your combined strength, it swings easier.
    *if not(tried_door)
      "And what will you be doing?" Madison asks. 

      "Someone has to keep the door open," you answer. 

      Madison shares a glance with Reilly and shakes her head.
      
      *gosub GHPDoor
      you brace your back against it, sitting low for leverage.
      
    Reilly kneels beside Madison, pressing up against the table. "On the count of three, push."

    The two count down, and then with a massive grunt, they shift the table with a low metallic squeal. At the last moment, though, Reilly slips, and his leg flails out, striking the bottom of the door in the process. The door bounces from the inadvertent kick, and you brace yourself as the door handle presses into the middle of your back.
    *if sta >= fatigue
       You absorb the worst of it, and though your lower back muscles groan, you keep the door open.
    *if sta < fatigue
      *set p_health %-(round((100-sta)/5))
      You shout in pain and twist away. The door slides you several inches before you regain your hold on it. Though you manage to keep it open, you know you're going to be dealing with a lot of pain later.
    *goto InsidePinky
  #Climb over the table, while the others hold the door.
    Rather than push the table out of the way, you decide to climb over it. "How about you two hold the door. I'll climb over the table and try to clear it from the inside."
    
    Your companions agree and get into position.   
    *if tried_door
      All three of you swing open the door. With all of your combined strength, it swings easier.
    *if not(tried_door)
      *gosub GHPDoor
      she braces her back against it, sitting low for leverage.
      
      Reilly pushes against the top, legs outstretched. "Climb fast, or this door's hitting you in the ass."
    
    You step over to the table, grip the top of it, and pull yourself up. It wobbles beneath your weight.
    *if m_athletics >= fatigue
      With reflexes that would do a cat credit, you leap to the side and down, landing on your feet with a light thud.
    *if m_athletics < fatigue
      *set p_health %-(round((100-sta)/5))
      As you ascend the surface and balance at the peak on your outstretched arms, you lift one leg over. Your arms flail as you try to maintain your weight, but instead you tumble down over the top of the table. The world spins, and you do a mid-air flip, the ground stopping your fall. You feel a dull ache where you hit.
      
      "You okay?" Reilly yells from the other side.
      
      "I think so," you say as you stand, one hand on your back.
      
    Now that you are on the other side, you clear the sand bags away from the table. It moves much easier when you free the added weight, allowing the three of you to shove it aside and clear the door.
    *goto InsidePinky
    
*label InsidePinky
*page_break
*set timecount +25
Now that you are inside the greenhouse, the air feels a lot more stuffy, and sweat beads your forehead. The air is filled with a blend of scents, all putting you in mind of fresh vegetables.
*if allergy
  *set stress %+(round((100-wil)/5))
  You go into a fit of sneezing and coughing from an abundance of pollen in the area.

With a closer examination of the tables, you see rows of corn, tomatoes, carrots, onions, and other sorts divided into smaller groups. The far left side is labeled 'Control Group', while other areas bear labels like 'Drought Resistant,' 'Fungus Resistant,' and 'Extra Yield.' Some of the tables also have lab equipment like test tubes, beakers, and such for samples.
*if science >= 55
  As a scientist, these items make you particularly excited.
  *if science_spec = "clinical laboratory science"
    With your focus on lab sciences, you know you can use what's here to recreate a laboratory back at the Junkyard.
    
"What do you know," Reilly says. "Fresh ingredients. Madison, how do you feel about stuffed peppers?
*if group_cook = "Reilly"
  I'll make them with some mushrooms and cook them in a tomato sauce."
*if group_cook = "Jaime"
  That's if Jaime knows how to cook them like I do."
*if group_cook = firstname
  That's if ${firstname} feels up to making them."

"Jalapeno or green?" she asks, then her nose scrunches as she reads a label. "These aren't exactly GMO free, are they?"

"GMO?" he asks.

"Genetically modified organism," @{(science >= 50) you say.|Madison says.}

Reilly shrugs. "Beggars can't be choosers."

From the far back of the greenhouse in an area cordoned off by vegetation, you hear someone clear their throat and the crackle of a walkie-talkie. @{hearing_impaired You can't make out what is being said.|A loud, gravelly voice yells, "Damn, they got in."}

Instinctively, you duck low, and Reilly and Madison quickly follow your gesture. Madison bumps one of the nearby tables, and a glass beaker falls to the ground with the crash of breaking glass, which is quickly forgotten as a bullet whizzes overhead and buries itself into a far wall.

Reilly moves to cover behind a wall, while Madison shimmies next to you, her hand holding her rifle close.

The shooter is tall and slender, stands behind a crate of fertilizer, and holds a rifle in hand.
*if search < 55
  You can make out no other details.
*if search >= 55
  *set saw_reilly_targeted true
  He aims the weapon at Reilly and faces away from you.
*if m_search >= 75
  *set spotted_trap true
  He's not firing but staring at something across the room. Following his gaze, you spot an open box the size of a coffin with a slender pipe sticking out. Could it be a trap?
*label GHPHub
*set shooter_count +1
*if shooter_count = 4
  *set shooter_surrendered true
  
  Reilly scoffs, spitting on the ground. "Tired of waiting. It's one guy. Give me cover."
  
  Before you can reply, he crawls out and crab walks down one aisle of flowers looming taller than him. From your own spot behind cover, you can barely see him.
  *label ReillyMadisonShooter
  
  "Don't come any closer," the shooter yells.
  
  "You started this, jerk." Madison rises, shouts at him, and fires her own rifle.
  
  You hear a groan from behind the shooter's table and then fast movement through the flower aisle. Catching a glimpse of Reilly, he rushes around the back of the shooter's cover. You and Madison run in.
  
  You hear shuffling and footsteps, a few grunts, and a loud smack. Rounding the shooter's table, you see Reilly with his shotgun aimed at the man. 
  
  "There are three of you. Don't any of you hurt me."
  *gosub DescShooter

  Reilly stands and slings his shotgun on his back. "Alright, guy, just relax. We're all friends here. Just calm your nerves."

  "Y-you guys aren't gonna hurt me, right?" he asks and sits with his back against a crate.
  *goto TieUpShooter
*gosub_scene CheckWeapons
*choice
  #Call out to the shooter. (Select a further option.)
    You take a deep breath and shout across the greenhouse…
    *choice
      #"Please stop shooting. We come in peace."
        *set diplomacy %+10
        *set morality %+10
        *set truth %+10
        There is a moment of silence before another shot whistles through the air, this time breaking a window near you.
        
        "You think I'm gonna let you rob this place again?"
        
        "We didn't rob you in the first place," Madison shouts back.
        
        *gosub PauseCheck
        *goto ShooterSocialFail
      #"Drop your weapon! We have you outnumbered."
        *set truth %+10
        *set ideal %-10
        *gosub PauseCheck
        *if (m_leadership >= 75) or (m_intimidation >= 65)
          the shooter steps from cover, holding his rifle out to the side. "Don't hurt me. I-I'm giving up." He tosses the assault rifle to the floor several feet away.
          *goto ShooterGivesUp
        *else
          *goto ShooterSocialFail
      #"Drop your weapon, or you're dead. You have three seconds."
        *set honor %-10
        *set impulse %+10
        *gosub PauseCheck
        *if (m_leadership >= 75) or (m_intimidation >= 65)
          the rifle slides out from cover and slams into a table of flowers six feet away. "Don't kill me. Leave me alone!"
          *goto ShooterGivesUp
        *else
          *goto ShooterSocialFail
      #"Drop your weapon, or I'll set this place on fire."
        *set honor %-10
        *set impulse %+10
        *gosub PauseCheck
        *if (m_leadership >= 60) or (m_intimidation >= 55)
          the shooter steps from cover, holding his rifle out to the side. "What are you nuts? Don't burn this place down. I'll give up." He tosses the assault rifle to the floor several feet away.
          *goto ShooterGivesUp
        *else
          *goto ShooterSocialFail
      *if college_student
        #"Don't shoot. I'm just a college student. I'm no threat to you."
          *set truth %+10
          *gosub PauseCheck
          *if m_persuasion >= 55
            *goto ShooterSurrenders
          *else
            *goto ShooterSocialFail
      *if medic
        #"Don't shoot. I'm an Army medic. I can help you."
          *set truth %+10
          *gosub PauseCheck
          *if m_persuasion >= 70
            *goto ShooterSurrenders
          *else
            *goto ShooterSocialFail
      *if nurse
        #"Don't shoot. I'm a nurse. I can help you."
          *set truth %+10
          *if m_persuasion >= 65
            *goto ShooterSurrenders
          *else
            *goto ShooterSocialFail
      *if doctor
        #"Don't shoot. I'm a medical doctor. I can help you."
          *set truth %+10
          *gosub PauseCheck
          *if m_persuasion >= 65
            *goto ShooterSurrenders
          *else
            *goto ShooterSocialFail
      *if infantry
        #"Don't shoot. I'm a soldier in the Army. I can help you."
          *set truth %+10
          *gosub PauseCheck
          *if m_persuasion >= 80
            *goto ShooterSurrenders
          *else
            *goto ShooterSocialFail
      *if commander
        #"Don't shoot. I'm a captain in the Army. I can help you."
          *set truth %+10
          *gosub PauseCheck
          *if m_persuasion >= 80
            *goto ShooterSurrenders
          *else
            *goto ShooterSocialFail
      *if mma
        #"Don't shoot. I'm no threat to you. Don't you recognize me? I'm a fighter for the UFC."
          *set truth %+10
          *gosub PauseCheck
          *if m_persuasion >= 80
            *goto ShooterSurrenders
          *else
            *goto ShooterSocialFail
      *if movie_star
        #"Don't shoot. I'm ${name}. Don't you recognize me from my movies?"
          *set truth %+10
          *gosub PauseCheck
          *if m_persuasion >= 80
            *goto ShooterSurrenders
          *else
            *goto ShooterSocialFail
      *if cop
        #"Don't shoot. I'm a police officer. I can help you."
          *set truth %+10
          *gosub PauseCheck
          *if m_persuasion >= 80
            *goto ShooterSurrenders
          *else
            *goto ShooterSocialFail
      *if wrestler
        #"Don't shoot. Don't you recognize me? I'm a wrestler for the WWL."
          *set truth %+10
          *gosub PauseCheck
          *if m_persuasion >= 65
            *goto ShooterSurrenders
          *else
            *goto ShooterSocialFail
      *if scientist
        #"Don't shoot. I'm a scientist. I can help you."
          *set truth %+10
          *gosub PauseCheck
          *if m_persuasion >= 65
            *goto ShooterSurrenders
          *else
            *goto ShooterSocialFail
      *if social_worker
        #"Don't shoot. I'm a social worker. I can help you."
          *set truth %+10
          *gosub PauseCheck
          *goto ShooterSurrenders
      *if teenager
        #"Don't shoot. We're just kids. We're no threat to you."
          *set truth %+10
          *gosub PauseCheck
          *if m_persuasion >= 45
            *goto ShooterSurrenders
          *else
            *goto ShooterSocialFail
  *if (spotted_trap and trap_armed) and not(pointed_out_trap)
    #Warn Reilly and Madison about the possible trap.
      *set impulse %-10
      *set pointed_out_trap true
      You point to the box with the pipe in it and wave to Reilly and Madison to gain their attention. They nod, and Reilly gives you a thumb's up. Hopefully, they now know to avoid it.
      
      Next you…
      *goto GHPHub
    *selectable_if ((crafting >= 60) or (survival >= 50)) #Move to disarm the trap. (Requires Crafting 60+ or Survival 50+)
      You creep out from cover and move through the middle of the greenhouse towards the coffin-shaped box. With the shooter in position, you keep your head low, fearing a gunshot.
      *if m_stealth >= 60
        You listen for sounds of movement, the click of a rifle's hammer, or anything that indicates he's firing at you. Switching to new cover along the path, you stay out of his sight and reach the trapped box.
        
        *gosub DisarmBoxTrap
        
        With the trap no longer a threat, you sneak back to cover.
      *if m_stealth < 60
        
        "Stay back," the shooter shouts, and you freeze in place.
        
        A shot rips into a potted plant near your left shoulder, exploding it into shards of clay and bits of leaves. You rush back to your starting point in cover.
      *goto GHPHub
  *if saw_reilly_targeted and not(spotted_trap)
    #Warn Reilly that he's being targeted. 
      *set reilly_faction %+(round(empathy/6))
      *set honor %+10
      You wave to Reilly until he eyes you. Pointing at the shooter and then to Reilly, you gesture with your fingers like they're a gun firing. Reilly points at his chest and mouths, "me?"
      
      You nod and look back at the shooter. 
      *goto GHPHub
  #Sneak closer to the shooter.
    You move forward, keeping as low as you can. Plants occasionally tickle your nose, but you simply push them away as you advance.
    *if stealth >= 60
      *label SneakAtShooter
      Once again, you see a table on its side, but this time you spot a makeshift nest among the plants. A brief shadow rises, and you see the shooter, a man in his early thirties, rising up from behind the table.
      
      You cross his far-left side, flanking him, losing sight of him for a few moments while circling to his back. When he's in view again, you see him pointing the assault rifle at Reilly, ready to take a shot.
      
      With the shooter unaware of your presence, you…
      *choice
        #Order him to surrender.
          *set honor %+15
          You take a deep breath and shout at the shooter. "Drop your weapon right now."
          
          The shooter turns the weapon towards you, his face panicked with wide eyes and a trembling mouth.
          
          "Lay your weapon down now!" you call out, projecting your voice with all the intensity you can muster.
          
          *gosub PauseCheck
          *if (m_intimidation >= 55) or (m_leadership >= 60)
            the shooter steps from cover, holding his rifle out to the side. "Don't hurt me. I-I'm giving up." He tosses the assault rifle to the floor several feet away.
            *goto ShooterGivesUp
          *else
            *goto ShooterSocialFail
        #Gain his attention, so he's not aiming at Reilly.
          *set honor %+10
          *set morality %+10
          You wave your arms and call out to the shooter. "Hey, over here!" As he turns and points the rifle, you drop below cover.
          
          He raises the assault rifle to his shoulder and aims along the barrel. In turn, Reilly and Madison both take cover and aim back.
          *goto ReillyMadisonShooter
        #Sneak even closer to attack him.
          *set honor %-15
          You skirt along the outside of the greenhouse, rounding a row of flowering plants providing you cover. Everyone once in a while, you poke up your head to spot the shooter, whose inching his way backward while keeping his rifle on Reilly.
          
          *if allergy
            *set stress %+(round((100-wil)/5))
            You feel a tickle in your nose, and tears blur your left eye. The air is thick with pollen, and you feel a sneeze coming on. It's builds and builds, and you cover your mouth and nose with you hands to stifle it.
            
            *if wil >= 55
              Holding your breath, you squeeze your eyes shut and try to keep it in. If you sneeze, the shooter will hear you. Tears run down your cheeks. Your ears pop.  It takes everything you have to fight off the reflex. Somehow, you do it, the feeling passes,.
              
              You wipe your eyes and nose and continue on.
              *goto SucceedStealth
            *else
              "ACHOO!"
              
              Your sneeze goes off like a gunshot. You blink hard to clear tears from your eyes, and when you look over at the stranger, he's craning his head and scanning your direction.
              *goto FailedStealth
          *elseif delusions
            "What are you doing here?" Ray says, crouching next to you. $!{ray_he} @{nb grab|grabs} a polka-dot-petaled flower, holds it to ${ray_his} noise, and sniffs so hard, the petals flutter.
            
            "What are you doing here?" you say in a harsh whisper.
            
            Ray breaks into laughter and pops the flower in his mouth. "I just asked you that," $!{ray_he} @{nb say|says} while chewing. "I'll see you outside."
            
            As Ray rushes out, you turn to watch, and your arm strikes a table. It rocks and a plot of ripe tomatoes falls with a crash.
            *goto FailedStealth
          *else
            *label SucceedStealth
            You sprint along the narrow aisle until you're behind the shooter who stretches his neck in a circle and keeps his weapon poised to fire. He keeps forwarded, though every few seconds, he takes a step backwards. As you draw closer to him, you hear him muttering to himself. @{hearing_impaired It's too low to hear what he's saying.|You hear the words [i]trap[/i], [i]zombie[/i], and [i]computer[/i].} His shirt is bloody and dirty, and he's limping on his right foot.
            
            A few more steps separate the two of you, so you…
            *choice
              #Threaten him to force him to surrender.
                *gosub StealthDraw
                You draw your ${curr_weapon} and
                *if curr_type = "ranged"
                  @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) load an arrow. Pulling back the string, you point the loaded bow at the middle of the man's back.|place the barrel on the back of his head.}
                *if (curr_class = "spray") or (curr_class = "taser")
                  hold it out towards the man.
                *if curr_type = "melee"
                  @{(curr_class = "club") wrap it around his neck with the shaft against his windpipe.|press the blade against the side of his neck.}
                *if curr_weapon = "hands"
                  wrap your arm around his neck, your forearm pressed on his windpipe.
                
                "Drop the weapon, or you're dead."
                
                He @{(curr_type = "ranged") gasps and raises his hands to the side, one hand holding out the rifle.|struggles for a moment, reflexively.} "Don't hurt me. I give up." He tosses the weapon to the ground several feet away and lets out soft sobs.
                *label FriendsArrive
                
                Your companions rush through the greenhouse. Once they arrive, the man lets out loud whimpers.
                
                "Just don't hurt me anymore." His nose runs into his mouth and tears stream down his cheeks, but he holds out his arms in surrender, both trembling.
                *goto TieUpShooter
              #Tackle him to the floor.
                *label TackleShooter
                Moving towards him with careful, silent steps, you crouch and lunge.
                *if hth >= 55
                  *set fatigue %+(round((100-sta)/6))
                  Your arms wrap around his legs as your shoulder hits the small of his back. You pull him towards you, driving him face-first to the floor with a hard thump. Caught off guard, the gun flips out of his hands and spins away on the floor. The shooter groans and struggles for a moment, but you drop a knee into the middle of his back and hold him there.
                *if hth < 55
                  *set fatigue %+(round((100-sta)/4))
                  You slam your body into his, and he falls forwards, hitting the floor. The rifle rattles out of his hands and slides away a few feet. As you climb up his back to secure him, he turns and struggles against you. You grip his collar and one arm, rolling him back to his belly. He feels weak in your arms, and he grunts and groans while feebly resisting you.
                *goto FriendsArrive
              #Disable him. I can't take any chances.
                *gosub StealthDraw
                You
                *if curr_type = "ranged"
                  rush forwards, raise your ${curr_weapon}, and @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) slam the point into the base of his head.|slam the butt of it against the side of his neck.} With a grunt, he drops to his knees.
                  *goto FriendsArrive
                *if curr_class = "spray"
                  *label DisableSpray
                  rush forwards, raise your ${curr_weapon}, and spray the side of his face. The gas envelopes him, and he cries out and covers his face with the crook of his arm. He lets out a tremendous cough and heaves and groans, spinning in a circle and shouting in pain.
                *if curr_class = "taser"
                  *label DisableTaser
                  move low and raise your ${curr_weapon}, aiming at his back. You press the trigger. A barb flies out, landing between his shoulder blades. You hear the sudden buzz of electricity, and his body straightens up, rigid and jerking. He screeches out a cry and drops to the ground.
                *if curr_class = "club"
                  rush forwards, raise your ${curr_weapon}, and slam the shaft against the side of his neck. With a grunt, he drops to his knees.
                *if curr_class = "sword"
                  raise the sword, leaving it in its @{(curr_weapon = "katana") sheath|scabbard}, and slam it against the side of his neck.
                *if curr_type = "melee"
                  rush forwards, raise your ${curr_weapon}, and slam the handle into the base of his head. With a grunt, he drops to his knees.
                *if curr_weapon = "hands"
                  move towards the shooter's back, wind back, and
                  *if hth >= 55
                    *set fatigue %+(round((100-sta)/6))
                    slam your fist against the side of his neck. With a grunt, he drops to his knees.
                  *if hth < 55
                    *set fatigue %+(round((100-sta)/4))
                    punch the side of his neck. Your fist hits too high, closer to the jawline, and he leans sideways and groans. As he tries to spin, you send your other fist and connect with the base of his skull. He wobbles and drops to one knee.
                The rifle falls from his hands and spins away across the floor several feet away.
                *goto FriendsArrive
              #Kill him. He's too dangerous to keep alive.
                *gosub StealthDraw
                You draw your ${curr_weapon} and
                *if curr_type = "ranged"
                  @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) load an arrow. Pulling back the string, you point the loaded bow at the middle of the man's head. Releasing the bowstring,|raise the barrel to the back of his head. Pulling the trigger,} you send swift death.
                  
                  The man's body falls forwards, the rifle flipping out of his hands and spinning across the floor. Blood spreads from his head wound in a tiny river and soaks into his filthy shirt, turning it pink then red.
                  *goto KillGHShooter
                *elseif curr_type = "melee"
                  You draw your ${curr_weapon} and creep the last few steps.
                  *if curr_class = "hack"
                    You raise the weapon and swing across your body, burying the blade in the back of his skull. It makes a wet smacking sound, and his body stiffens. When you yank it out, his body bends like a rubber band and drops to the floor.
                  *if curr_class = "club"
                    You wind back and bring the weapon from overhead straight down on the back of his skull. It makes a wet smacking sound, and his body stiffens. He takes two lumbering steps and drops to his knees. You raise the ${curr_weapon} again and slam it on top of his head. The top of the weapon reverberates, and your hands feel the vibration rising through the shaft. The shooter falls flat, gurgling sickling for a moment.
                  *if curr_class = "sword"
                    With a swift thrust, you slide the blade through his lower back and drive it halfway through. The shooter shouts in pain and makes a sickly, wet gurgle. He drops to his knees, and his rifle pops off a single shot into the top of the greenhouse.
                    
                    When you yank out your blade, he lets out a yelp. You raise the ${curr_weapon} again and bring it down in a downward slash. It slices through his neck, shoulder, and upper back. He falls to his face.
                  *if curr_class = "knife"
                    In one swift motion, you grab a handful of his hair, yank back his head, and jam the blade under his chin. His body stiffens, and you draw the blade across his throat, yanking at times when you meet resistance. He only manages to let out a sickly, wet gurgle as he drops to his knees. Blood sprays out from his neck,and you release him. He reaches up to his throat as it pours from the wound, and he falls to his face.
                  His gun drops and spins away from his body.
                  *goto KillGHShooter
                *elseif curr_weapon = "hands"
                  wrap your arm around his neck, your forearm pressed on his windpipe. He struggles against you, bucking his body against yours. He raises his rifle but cannot get an angle to fire at you. His free hand reaches back and claws at your face, but he's too weak to cause harm. Already his sinks to his knees, and you push against his head with your own to apply more pressure.
                  
                  A few moments pass. His arms drop to his sides, and the rifle rattles to the floor. You keep squeezing until you feel his windpipe crack and his body hangs in your arms. It's only then that you release him. He flops to his face and lies still.
                  *goto KillGHShooter
                *elseif curr_class = "spray"
                  *goto DisableSpray
                *else
                  *goto DisableTaser
    *else
      You keep low, moving forward as quickly and quietly as you can. You are almost near the back when a flash of movement catches your attention. You stop, a feeling of dread creeping down your back.
      *label FailedStealth
      
      "Get back!" the shooter yells, and you dive for cover as he turns the rifle around and fires. The shot whizzes over your head. Gunfire from your companions hits his table, forcing him low. You use the opportunity to crawl back to the front of the greenhouse.
      *goto GHPHub
  *selectable_if (carry_ranged) #Fire at the shooter, to disarm, wound, or kill him.
    *if (s_type = "ranged") and (p_type = "ranged")
      *fake_choice
        #Use my ${p_weapon}.
          *gosub_scene FightCode UsePrimary
          *set using_primary true
        #Use my ${s_weapon}.
          *gosub_scene FightCode UseSecondary
      *goto ShootShooter
    *elseif p_type = "ranged"
      *gosub_scene FightCode UsePrimary
      *set using_primary true
      *goto ShootShooter
    *else
      *gosub_scene FightCode UseSecondary
      *goto ShootShooter
        
    *label ShootShooter
    *set ranged_matters true
    *set target_range 1
    *set target_difficulty 110
    Seeing the shooter ahead, you @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) notch an arrow into your bow|raise your weapon} and…
    *fake_choice
      #Aim for his weapon to shoot it out of his hands. I'd rather not harm him.
        *set morality %+15
        *gosub_scene FightCode AttackResult
        *if attack_result = 4
          @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) The arrow flies across the greenhouse and strikes|You fire the weapon and sparks fly from} the pistol grip of the rifle. The shooter cries out and drops the weapon which spins to a stop five feet away from him.
          
          "Step out with your hands raised, now!" you shout and move from cover with your ${curr_weapon} trained on him.
          
          You and your companions move across the greenhouse, repeating commands for him to stand with his hands raised. He complies the whole time and whimpers as you draw closer.
          
          "Don't hurt me," he says through sobs. Snot runs into his mouth, and tears stream down his cheeks.
          *goto TieUpShooter
        *elseif attack_result = 3
          *goto WoundShooter
        *else
          *goto ReillyKillsShooter
      #Aim to wound, so I can question him.
        *gosub_scene FightCode AttackResult
        *if attack_result >= 3
          *label WoundShooter
          *set shooter_alive false
          *set survivor_kills +1
          You wait for him to pop out from cover. @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) The arrow flies across the greenhouse and strikes him.|As soon as you see his rifle, you shoot at it.} He doubles over, shrieks, and falls to the ground.
          
          "Stay on the ground!" you shout and move from cover with your ${curr_weapon} trained on him.
          
          You and your companions move across the greenhouse, repeating commands for him to stay down. He lies on his side and in the fetal position. As you draw closer, you kick his rifle away.@{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) The arrow sticks out of his stomach,|He covers a wound with his forearms,} and blood seeps onto the floor.
          
          You crouch to talk to him, your weapon still readied. "Don't move."
          
          The shooter groans and breathes in short gulps. He tries to talk but only squeals come out. His face strains and shakes.
          *gosub DescShooter
          
          "He's not gonna make it," Reilly says.
          
          Madison turns and walks away, her face pale and waxy.
          
          You stare at the man, and in those few seconds, his breathing goes even more shallow until it stops. His arms drop and eyes fix forwards, as lifeless as a doll.
          
          "I tried disarming him."
          
          Reilly shrugs. "Yeah, you missed. Oh well.
          *goto ExamineGreenhouseA
        *else
          *goto ReillyKillsShooter
      #Aim to kill. He's too unstable.
        *set ideal %-15
        *gosub_scene FightCode AttackResult
        You wait for him to pop out from cover.
        *if attack_result >= 3
          *set survivor_kills +1
          @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) The arrow flies across the greenhouse and strikes him.|As soon as you see his rifle, you shoot at him.}
          
          *if attack_result >= 4
            His head flips back, and his body takes a momentary pause. He sinks to the ground behind the can of fertilizer.
          *if attack_result >= 3
            He doubles over, shrieks, and falls to the ground.
          
          "Stay on the ground!" you shout and move from cover with your ${curr_weapon} trained on him.
          
          You and your companions move across the greenhouse, repeating commands for him to stay down. First to reach his body, you see your @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) arrow sticks out of his head like a unicorn's horn.|bullet hit him straight through the forehead, exposing brain and bone.}
          
          When Madison and Reilly reach you and the body, they both breathe a sigh of relief.
          
          "You totally got him," Madison says. She has a look half of sadness and half of wonder.
          *goto ExamineGreenhouseA
        *else
          @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) The arrow flies across the greenhouse and dings off the side of a clay pot.|As soon as you see his rifle, you fire at him. Your bullet shatters a clay pot next to his head.}
          *label ReillyKillsShooter
          
          You hear Reilly's voice from a distance, "oh, screw this guy." You hear a rash of movement and the shooter starts firing off shots all across the greenhouse. Madison stands behind cover and pops out once in a while to shoot into the can of fertilizer.

          "Don't kill me! Don't kill me!" the shooter screams. In his panic he fires into the ceiling raining down glass everywhere. It's like a shower of confetti shards.

          You hear the heavy blast of a shotgun, and the shooter's body flies out from cover. His back hits a table of plants knocking it over. He sucks in deep bloodied breaths but quickly goes still, staring up at the top of the greenhouse and now the open sky.

          Reilly is the first to make it to his body. "You had to make me run all the way over here," he says, loading another shell in his shotgun. "That guy seriously had something wrong with him. Sucks but he had to go."

          When you and Madison reach the body, you both stare down at his torn torso, a ripple of holes from the shotgun's buckshot.
          *goto ExamineGreenhouseA
  #Charge the shooter to tackle and disarm him.
    *set impulse %+15
    Considering the shooter is still among the living, you know of an easier way to subdue him.
    
    Stepping out from cover, you burst across the greenhouse. Reilly and Madison notice your movement and fire in tandem at the shooter to provide cover for you. The man crouches behind the can of fertilizer, dropping his rifle and covering his ears with his hands. He scrunches his face and rocks back and forth, crying uncontrollably.
    
    *gosub CutShoulder
    
    *if (Pepper_spray > 0) or (taser > 0)
      As you draw near, you…
      *choice
        #Tackle him.
          *goto TackleShooter
        *selectable_if (pepper_spray > 0) #Use pepper spray.
          Although you don't care for this angle, you aim your pepper spray at the shooter, and let a quick mist fill the air. You quickly move aside to avoid the worst of it, while the man falls to the ground, clawing at his face and giving you the chance to subdue him.
          *label ShooterStopped
          
          "Stop hurting me."
          *gosub DescShooter

          With a sudden burst of speed, your companions rush in.
          
          Reilly stands and slings his shotgun on his back. "Alright, guy, just relax. We're all friends here. Just calm your nerves."

          "Y-you guys aren't gonna hurt me, right?" he asks and sits with his back against a crate, still wiping his red and tearing eyes.
          
          @{(Morality >= 50) "Don't resist, and we won't hurt you."|"Sit back and stop asking questions."}
          *goto TieUpShooter
        *selectable_if (taser > 0) #Use a Taser.
          You pull out your taser, and at this range you can't miss. You fire, and the prongs hit the man's shoulder, sending waves of electricity through him. He falls to the ground, twitching.
          *goto ShooterStopped
    *else
      *goto TackleShooter
  #Order one of my companions to distract the shooter.
    *set impulse %-15
    "Madison, Reilly, one of you make a distraction," you order.

    "Why?" Reilly yells as he rises up to take a shot at the back, then sinks back down as another bullet fills the air.

    "Just do it," you say. 

    Madison looks around, and raises her gun toward a back window, and fires. Glass falls down, and the shooter's own shot goes in that direction.
    
    While the shooter's distracted, you run along the side of the greenhouse, keeping low to avoid detection. Reilly sees what you're doing and moves the opposite side of the greenhouse out of your line of sight.
    
    "Hey, asshole, we got you surrounded," Reilly shouts.
    
    The shooter turns in the direction of your companion's voice and fires off a shot. From here you can now see Madison, whose face lights up at the clear shot at the man. She sniffles as she fires and sends a round in a wooden plank above his head. He turns back to her and returns fire, forcing her to duck.

    Reilly's voice rings out from the side of the greenhouse again. "Asshole, you take one more shot at that girl, and I'm going to beat you with that rifle."

    You rush farther along your side of this plant house and move within several feet of the shooter. You notice a bit of blood on your left shoulder.
    *gosub CutShoulder
    *goto SneakAtShooter
  *selectable_if  ((drone > 0) and ((electronics >= 70) and (driving > 40))) #Distract the shooter with the drone while a companion moves in.
    *set impulse %-15
    There is no point risking yourself or the lives of your friends, not when you have a drone available.

    You take out the small electronic device instead of on the ground in front of your companions. Their faces light up. Realizing this is the first time they've ever seen it, you let them know you picked it up at the pharmacy with Jaime.

    "What the hell is it?" Reilly asks. He recoils and stares at the drone like it's an alien bug ready to strike.

    "Don't be such a baby," Madison says, scoffing. "My guess is it's a SkyShark, a hobby drone. My Uncle Doug had one until he got it taken by the FAA. Apparently they don't like it when civilians use it to fly around beaches and film young girls in bikinis. God, what a perv. Do you know he had three open sexual harassment lawsuits right before the outbreak?"
    *if prof_health or social_worker
      *set madison_uncle_doug true
      
      "Trust me, I had my own run in with that guy."
      
      Madison shakes her head. "You have to tell me about it sometime."
      
    You start up the drone. It's four propellers whirl in tiny circles, and once they catch air, you send it speeding to the top of the greenhouse.

    "What is it? Get out!" the shooter shouts.

    You soar it high and keep it at the fastest speed possible while maintaining control. Shots fire at it, but hit glass panes in the ceiling just behind it. Knowing that the shooter is completely distracted by the SkyShark, you turn to your companions.
    
    "While I've got his attention, see if you guys can move in."

    Your companions waste no time rushing across the greenhouse while keeping low to avoid further detection. They don't take long. In seconds they disappear behind the can of fertilizer covering the shooter. You hear the sounds of a scuffle, glass breaking, and something slamming the ground.

    "We got him," Reilly shouts.

    You take the shortest time possible to land the drone. Once you turn it off and place it in your inventory, across the distance to meet your companions.
    
    "Y-you guys aren't gonna hurt me, right?" the shooter asks, sitting with his back against a crate.
          
    "Sit back and shut up," Reilly says.
    *goto TieUpShooter
    
*label CutShoulder
*set p_health %-(round((100-sta)/5))
Fueled by adrenaline, you must have failed to notice cutting yourself on one of the many pieces of wood or glass shards in your path.
*return

*label KillGHShooter
*set shooter_alive false
*set survivor_kills +1
You hear a burst of footsteps and see your companions rushing over.

"Good job, ${firstname}," Reilly says, staring down at the shooter's corpse.
*goto ExamineGreenhouseA
    
*label StealthDraw
Coming up from behind the shooter, you draw your…
*fake_choice
  #$!{p_weapon}.
    *gosub_scene FightCode UsePrimary
  #$!{s_weapon}.
    *gosub_scene FightCode UseSecondary
*return
  
*label DisarmBoxTrap
*set trap_armed false
You peer inside and spot a red beam of light emanating from the box. Surmising the trap springs if the light is displaced, you avoid it for now. Examining the trap, you see a fairly simple mechanism installed. Two flasks of liquid sit atop a pair of balances with a mixing tray below. A tube sits alongside it with a fire-extinguisher-sized cannister of compressed air. It looks as if the trap springs, mixes the liquids in the tray, and the pressurized air expels the fumes through the metal pipe.

With great care, you reach in the box and push aside the nozzle on the cannister. To prevent an accidental triggering, you slide the flasks off the balances. With these precautions, the trap is disarmed.
*return

*label PauseCheck
You hear no response nor movement from the shooter. Madison trades a look with you and shrugs. Just then,
*return

*label ShooterSocialFail
another shot rings out, and a plant behind you explodes in a rain of petals.

You duck as more shots pepper the area.
*if ptsd
  Your heart races and you're struck with a wave of dizziness, causing you to cower and curl up. The sounds of more gunfire warbles in your ears like you're underwater.
  *if wil >= 65
    As the panic sets in, you swallow hard and look up. Through deep breaths, you look up and catch the shooter running out of the back of the greenhouse.
    *goto ShooterRan
  *else
    *set stress %+(round((100-wil)/4))
    *set shooter_fled true
    Panic sets in, and you lie on the floor balled up until Madison and Reilly are by your side.
    
    "He's gone," Reilly says, tapping your back.
    *if (main_ro = "Reilly") or (second_ro = "Reilly")
      *set stress %-(round(wil/6))
      As you rise, he hugs you. Immediately, you sink into his arms, pressing your body to his. You feel safe, and the feelings of panic and stress disappear. Even his scent makes you more comfortable, and you inhale deeply.
      
      "I love this tender moment, but we need to keep going," Madison says. "You two can go all Nicholas Sparks when we're back at the Junkyard."
    
      You break your embrace from Reilly and look around the greenhouse. The area's clear except for you and your companions.
      *goto ExamineGreenhouseA
    *else
      Madison moves closer to you.
      *if madison_faction >= 60
        "Can I give you a hug?"
        *fake_choice
          #"I'd like that," you say and hug her.
            *set morality %+10
            *set humanity %+10
            *set stress %-(round(wil/6))
            You wrap your arms around her and feel safer in her arms. She rests her head on your shoulder and strokes your back. You inhale a sweet scent from her hair, and you feel your stress evaporating.
            
            "Okay, guys, let's Rock and Roll." Reilly glances around the greenhouse.
          #"I'm fine but thanks."
            She nods and stands with a pout.
          #"No, I'm fine."
            *set ideal %-10
            She nods and stands with a pout.
          #"I don't need a hug—I need to kill that guy."
            *set morality %-10
            She stands, letting out a hard exhale which blows away a strand of hair from her face. "If he's not long gone, he's an idiot. One of us will get him."
        *comment end/
        
        You rise and compose yourself for a moment. The area's clear except for you and your companions.
        *goto ExamineGreenhouseA
      *else
        "You're fine. It's just us now."
        *goto ShooterRan
*else
  @{(ranged >= 60) Based on the way he's firing wildly, you figure he's trying to keep you pinned down.|His shots whiz past you, forcing you to keep low.}
  *goto GHPHub

*label ShooterRan
*set shooter_fled true

You rise and see the far back door of the greenhouse swinging shut.
*goto ExamineGreenhouseA

*label ShooterSurrenders
*set shooter_surrendered true
the shooter steps out, holding his rifle to the side like he's surrendering. "There are three of you. Don't any of you hurt me."

*gosub DescShooter

Reilly stands and slings his shotgun on his back. "Alright, guy, just relax. We're all friends here. Just calm your nerves."

"Y-you guys aren't gonna hurt me, right?" he asks and sits on the ground with his back against a crate. He lowers his assault rifle to the ground beside himself, and Reilly picks it up and secures it.
*label TieUpShooter

Madison finds some bundled twine lying on a workbench and uses it to tie his hands. He doesn't resist.
*goto ExamineGreenhouseA
      
*label ShooterGivesUp
*set shooter_surrendered true

You rise and move out of cover along with Reilly, who walks over to the assault rifle and slings it over his shoulder.

"I give up," the shooter says and sits on the ground with his back against a crate.
*gosub DescShooter
*label ExamineGreenhouseA
*set timecount +25

You hear a deep sigh from behind you and turn to spot Madison wiping away sweat from her forehead with the hem of her shirt.
*if (main_ro = "Madison") or (second_ro = "Madison")
  Your pulse quickens slightly at the flash of her skin, but she doesn't notice your glance.
*if not(shooter_fled)
  She stares at the
  *if not(shooter_alive)
    lifeless body of the
  shooter.
"Who would defend vegetables with their life?"

Reilly rubs a leaf hanging from a long stalk. "What I would like to know is why these plants aren't wilted. If you look, they've just been watered."

"Maybe the water is being pumped," Madison says. "If so, then that means this place has power, at least somewhat." She points to the solar panels above the main building. 

With the place secured, you notice a small impromptu living area behind the table the shooter used for protection. The vestiges of freshly picked vegetables lie strewn about, while a pile of clothes look like they were bound up into a pillow. 

From this vantage point, you also notice several bags below some of the standing tables still in the greenhouse.
*label ScavengePinkyMenu
*set ghp_count + 1
*if (ghp_count = 2) and (trap_armed and not(pointed_out_trap))
  
  As Reilly moves through the center of the room, you hear a slow hiss followed by a sudden rush of air. Yellowish-green gas shoots from a pipe sticking out of a supply box. Reilly waves his arms and then covers his head to clear the smoke. Through violent coughs, he rushes away from the coffin-shaped box.
  
  "This way," you shout and @{(gas_mask > 0) give him your gas mask to use. You run with him over to a broken window, so you and Madison can breathe in the clean air.|run to a broken window, through which clean air circulates.}
  
  "It smells like bleach," Madison says, her eyes already watering.
  
  The three of you huddle near the window and keep clear of the poisonous glass. Reilly's eyes and nose are watery and burning, @{(gas_mask > 0) but putting on your gas mask so quickly may have saved him|and after a coughing fit, he seems able to breathe again. His lungs burn, and you're not sure of the long-term effects.}
  *if gas_mask = 0
    *set reilly_hurt true
    *set reilly_poison_gas true
    *set p_health %-(round((100-sta)/5))
    
    "Damn it, that burns," Reilly says, rubbing his teary eyes.
    *if medicine >= 55
    
      "Can I do anything to stop this burning?"
      
      You shake your head. "No. There's no treatment. If we can find you an inhaler with a steroid like albuterol, it can help. Otherwise, you need rest."
      
  *if shooter_alive
    Reilly coughs and clears his throat.
    *if shooter_fled
      "I should find the scientist guy and shoot him.
    *if not(shooter_fled)
    
      *gosub ShooterDescTrap
  *if not(shooter_alive)
    "I wish that shooter was alive, so I could shoot him."
    
  You and your companions wait while the fumes dissipate and it's safe to resume your search.
*choice
  *if spotted_trap and trap_armed
    *selectable_if ((crafting >= 60) or (survival >= 50)) #Disarm the trap. (Requires Crafting 60+ or Survival 50+)
      *set timecount +25
      You move over to the trap you spotted earlier. If you and your companions are going to search this room, one of you may accidentally trigger it.
      *gosub DisarmBoxTrap
        
      With the trap no longer a threat, you return to Madison and Reilly.
        
      Next you…
      *goto ScavengePinkyMenu
    *if not(pointed_out_trap)
      #Warn Reilly and Madison about the possible trap.
        *set impulse %-10
        *set pointed_out_trap true
        You point to the box with the pipe in it and wave to Reilly and Madison to gain their attention. "Be aware of that strange-looking box over there."
        
        "Trap?" Madison asks.
        
        Reilly kicks the foot of the shooter. @{shooter_alive "Trying to kill us?"|"This guy had some screws loose."}
        *if shooter_alive and not(shooter_fled)
        
          *gosub ShooterDescTrap
        
        Next you…
        *goto ScavengePinkyMenu
  #Look closer at the shooter's nest.
    *set search_shooters_nest true
    *set timecount +25
    Near one of the walls, you can make out the remains of a fire pit. Closer examination of the pit shows the fire was started with bits of paper, all of which look official. One sheet has the words, [b]Project Revenant[/b] in bold, while below that is a series of letters and numbers, 20Mb13.

    "Yuck," Madison says, from the other corner. She steps back, rubbing her shoe along the ground,  "I believe I found his bathroom." 

    Near the fire you spot a small piece of brown rock and a bit of metal in the shape of a U.
    *if m_survival >= 45
      *set shooters_firestarter true
      You recognize the rock as a piece of flint, and with the metal, it would be possible to start a fire.

    A small dripping faucet sticks out of a low area of wall, and near lies a coffee cup with the words, World's Greatest Dad, written on it.

    You first sift through the pillows, and then come across a few personal effects. The first is a photograph with the face of the shooter, arms raised up on a theme park ride, with a woman on the right, and a young girl on the left in the same car. You can't make out their features as their faces have been removed with a black marker. The back of the photo reads: Elitch Gardens, 2010.

    Finally, you spy a few magazines of ammunition lying near the improvised pillow.
    *goto ScavengePinkyMenu
  #Scavenge the place.
    *set timecount +25
    You search through the greenhouse to see if there's anything worth taking. Of course, vegetables and edible plants are everywhere. While most are still in the seedling stage, some are old enough to pick if you desire to. The seeds may be even more valuable if you intend to plant them in the Junkyard.

    You also take a closer look at the bags below the tables. You see some of them are twenty-pound bags of seed for many of the plants already growing in the greenhouse. There are also fifty-pound bags of fertilizer and numerous chemicals.
    *if science >= 55
      Looking around the chemicals, you identify a bottle of liquid hydrogen cyanide.
    *if scavenging >= 45
      
      On top of the greenhouse solar panels take up a wide portion of roof, and below them lies a pile of spare panels.
    *if scavenging >= 55
    
      In one corner of the room, you spot a strange assortment of flasks and tubes configured in a specific way. Examining it closer, you deduce that the contraction collects rainwater from the top of the greenhouse and funnels it into the flasks. This makeshift water collector could be useful.
    *set inv_count 0
    *gosub_scene Part1Events CalcSlots
    *label GHPScavMenu
    *if (inv_count >= max_count)
      *goto FinishScavGHPinky
    *else
      *gosub_scene CarryList
      *set item_count (max_count - inv_count)
      You have the following items: ${inventory}
            
      You can take ${item_count} more items.
      *set inv_count +1
      *choice
        *allow_reuse #Biological parts (5).
          *set bio_parts +5
          You add the biological parts to your inventory.
          *goto GHPScavMenu
        #Bleach (1 bottle).
          *set bleach +1
          You add the bleach to your inventory.
          *goto GHPScavMenu
        *allow_reuse #Cigarettes (5).
          *set w_cigarettes +5
          You add the cigarettes to your inventory.
          *goto GHPScavMenu
        #Cookware (1).
          *set cookware +1
          You add the cookware set to your inventory.
          *goto GHPScavMenu
        #Crowbar (1).
          *set w_crowbar +1
          You add the crowbar to your inventory.
          *goto GHPScavMenu
        *if science >= 55
          #Cyanide (1 bottle).
            *set cyanides +1
            You add the bottle of cyanide to your inventory.
            *goto GHPScavMenu
        *allow_reuse #Duct tape (1).
          *set duct_tape +1
          You add the duct tape to your inventory.
          *goto GHPScavMenu
        #Laptop (1).
          *set laptop +1
          You add the laptop to your inventory.
          *goto GHPScavMenu
        #Liquid cleaner (1 bottle).
          *set liquid_cleaners +1
          You add the liquid cleaners to your inventory.
          *goto GHPScavMenu
        *if search_shooters_nest
          #Coffee (3 cups).
            *set coffees +3
            You add the coffee to your inventory.
            *goto GHPScavMenu
          *allow_reuse #5.56 ammunition (1 magazine).
            *set ammo_556 +1
            You add the magazine to your inventory.
            *goto GHPScavMenu
          #Marijuana cigarette (1).
            *set marijuana_cigarettes +1
            You add the marijuana cigarette to your inventory.
            *goto GHPScavMenu
        *if shooters_firestarter
          #Firestarter (1).
            *set firestarter +1
            You add the firestarter to your inventory.
            *goto GHPScavMenu
        *if not(shooter_fled)
          #M16 rifle(1).
            *set m16 +1
            *set shooter_m16 true
            You add the M16 to your inventory.
            *goto GHPScavMenu
        #Rope (1).
          *set w_rope +1
          You add the rope to your inventory.
          *goto GHPScavMenu
        #Shovel (1).
          *set shovel +1
          You add the shovel to your inventory.
          *goto GHPScavMenu
        *selectable_if (item_count > 1) #Sleeping bag (2 slots).
          *set sleeping_bag +1
          *set inv_count +1
          You add the sleeping bag to your inventory.
          *goto GHPScavMenu
        #Tarp (1).
          *set tarp +1
          You add the tarp to your inventory.
          *goto GHPScavMenu
        *if scavenging >= 45
          *allow_reuse #Solar panel (1).
            *set solar_panels +1
            You add the solar panel to your inventory.
            *goto GHPScavMenu
        *allow_reuse #Water (5 bottles).
          *set w_water +5
          You add the water to your inventory.
          *goto GHPScavMenu
        *if scavenging >= 55
          #Water collector (1).
            *set water_collectors +1
            You add the water collector to your inventory.
            *goto GHPScavMenu
        *allow_reuse #Vegetables (5).
          *set w_food +5
          You add the vegetables to your inventory.
          *goto GHPScavMenu
        #That's all I take.
          *goto FinishScavGHPinky
    
    *label FinishScavGHPinky
    
    Having finished looting, you move on…
    *goto ScavengePinkyMenu
  *if shooter_alive
    #Talk to the shooter.
      *goto TalkToShooter
  #Go back to the parking lot.
    *goto RCOutsideMenu
    
*label ShooterDescTrap
@{talked_to_shooter "Sorry. I never wanted to hurt good people. Just those damn Paynes|"You have no idea what I've been through}," he says.
*return
    
*label DescShooter
*if not(described_shooter)
  *set described_shooter true
  Blue-and-purple bruises cover the left side of his face. Both lips are split and held by medical tape. Burn marks dot his neck and right cheek. One eye is nearly swollen shut, and the top lobe of an ear is missing. He wears what used to be a white shirt, now stained with blood and dirt. His black dress pants have held together, and his feet have on mismatched shoes.
*return

*label TalkToShooter
*set talked_to_shooter true
You decide to talk to the shooter, and with him currently weaponless and tied up, you are about as safe as you can be.
*gosub DescShooter

"Hello," you say neutrally. "Can you understand me?" 

"Yes," rasps the man. "Who are you?"
*fake_choice
  #"Your captors."
    *set honor %-10
    You glower and answer. "Just what it looks like. We're your captors. And if you want to get out of this, play nice and answer our questions."
  #"Potential friends."
    *set ideal %+10
    "Then why do you have me tied up?" growls the man.

    "It is for safety purposes—ours and yours."
  #"Just passing through."
    *set truth %+10
    "We're no one you need to worry about," you add.

    The man shakes his head, "Yeah, no worries. After all, you're not the one tied up."

"Now, I have a few questions I'd like to you answer," you say.

"Will you let me go if I do?" the man says.

"It really depends on how forthcoming you are," you state.
*label AskShooterMenu
*choice
  #"Who are you? Do you have any friends or family?"
    *set shooter_alan true
    "I'm Alan," the man replies, "Alan David. My family…my family all died. The infection got them. I used to work here before everything else went to Hell, I thought I could bury myself in work."
    
    Next you say…
    *goto AskShooterMenu
  #"How did you get all those bruises?"
    *set paynes_research_mission true
    The man grimaces. "A gang of thugs came here, beat me. At first, I thought they were friendly. They asked for food and supplies. When I wasn't fast enough to hand it over, they beat me." His voice breaks.
    
    "Who are these thugs?" Reilly asks.
    
    He shakes his head. "All I know is that they kept talking about Cliff and Dee. They said 'Cliff and Dee would be happy to see all the loot.' I don't know anymore."
    *if v_loc = "country"
    
      "Could it have been the Paynes?" you ask.
      
      "Who's that?" Reilly asks.
      
      "Cliff and Delilah Payne from my hometown. This sounds like them."
    
    Next you say…
    *goto AskShooterMenu
  #"Why are you holed up in here?"
    The shooter glances at the far door. "There was a large group of infected here a few days ago. I…I was afraid they would get in. They went into the main building." He shrugs "When you came in, I thought you were one of them. As for why I'm here? It has food, water."
    
    Next you say…
    *goto AskShooterMenu
  #"What relation, if any, do you have with this place?"
    "If you're asking me if I had anything to do with those CDC creeps, the answer is no," the man says. "I was just an agronomist. I was looking at ways of making disease-resistant corn, but a while back the CDC came in and claimed the whole bottom of the research center. They said it was off-limits to those without the proper clearance." He gives a bitter laugh. "At least, that was before the zombies rose [i]en masse[/i] and tore them all to shreds."
    
    Next you say…
    *goto AskShooterMenu
  #"What can you tell me about the main research building?"
    *set warned_about_arc_by_alan true
    He swallows hard hangs his head for a moment before looking back up. "How much time you got? It's a big place with sub-levels. Most of the staff stood there during the early part of the outbreak. Unfortunately most of them also became zombies. With all their knowledge of viruses contamination and protocols, the fools let in our regional manager. He was infected but thought he had treated himself with immunoglobulins and things to boost his immune system. Boy, was he wrong."
    
    He lets out a soft whimper, then composes himself. "I was trying to gain access to the facility right as he turned. Some smart soul must've realized what was happening and put the place on lockdown. That person probably saved my life. But I heard their screams. I can look through the windows and see the blood. I saw them running. I saw Jenny run to the door, slam against it, and beat her hands on the glass. She begged for my help. I can only hope in her last moments of life that she realized I had no hope for her. I couldn't let her out. She was trapped in there, and it wasn't long before she was…" His voice trails off.
    
    @{(morality >= 50) "I'm sorry. I know it's hard."|"So is it worth going there or what?"}
    
    He sniffles and clears his throat. "If you're looking for research equipment, you'll want to head in there. If you make it to the bottom, there are supplies. You have to understand, we had grants to do research in other countries, places where we were roughing it. We had preserved foods, camping supplies, and basically anything else you would need to survive this thing."
    
    Reilly claps his hands together, making the stranger flinch and bury his head for a moment. "Jackpot!"
    
    *if impulse >= 50
      "We gotta get in there," you say.
    *if impulse < 50
      "What are we talking about here? Enough food and resources for a few weeks, a few months, longer?"
      
      "We would take a group of four or five into the Amazon for six weeks, maybe two months. The food's not great. It's standard military grade rations. I think they call them MREs. You add water and get chicken curry or beef stroganoff. But it will keep you fed."
      
      You look to your companions. "It goes without saying—we need those supplies."
      
    The man chuckles for the first time. "Go ahead. It's your funeral."

    Madison kicks his foot. "Don't be a jerk."

    "Look, the place is locked down," he says, squeezing his eyes together intensely. "Even if you get inside with the key card, there are zombies everywhere. In the lowest levels, we have other means of deterring civilian breaking. Some of our research was awarded through military grants, and rumor has it they installed some nonlethal devices in case of a breach. Under normal circumstances, these measures would do no more than knock you out and give you a good nap for an hour while you woke up in detention. But on lockdown, some of the safety measures automatically turn off. What I'm saying is that even if you get past the infected, you'll have to circumvent all of those countermeasures which are now lethal. If you think you can get down there and get past all that, you're welcome to all of the supplies. Don't call me a jerk for thinking that it's a fool's errand."
    *goto AskShooterMenu
  *if not(visited_greenhouse_brain)
    #"What can you tell me about Greenhouse Brain?"
      The man shakes his head. "We were doing animal research in there. It's similar to this place except that here we're devoted to plants. I wouldn't go there now. I kind of put in some deterrents for those thugs who beat the crap out of me. We had these two techs, Brian and Raj, who just started working here on a work program. Two college guys looking for experience before graduation. We told them to stay here but they didn't listen. The outbreak starts, they try to make it home, and next thing you know they're stumbling back here. We only knew a little bit about the virus then. We tried to help them, tried to sanguinate them. We figured if we get their blood out fast, maybe the virus would come with it. They just spread too damn fast."
      
      "So what you're saying is those two guys were infected?" Madison asks.

      The man nods and swallows hard, tears once again forming under his eyes. "It didn't take long. Maybe two hours? Way faster than any of us predicted. Normal incubation rates for humans is so much longer for other diseases. For most viruses or bacteria, three to six days is a fair average. Hepatitis can take a month. AIDS can take a year or more. Something fast like influenza takes a day at the least. But this Zeta, it's incredible." He stares over the three of you in a sort of wondrous haze.

      Reilly bends down and says to him in a hushed voice, "It's not a living thing. It's a bug. You don't have to have respect for it."

      The man looks at Reilly through squinted eyes. "It most certainly is alive. Viruses may be microscopic, but they have life. They grow, they work together, they reproduce—like all life."
      
      Reilly stands and smacks his teeth. "This guy is a real piece of work."
      
      "Once they turned, most of the other staff fled. They realized what was happening or thought about their loved ones. The facility cleared out. I stayed for some reason. It's all in the past now I guess. When those guys broke in here, they beat me up and took what they wanted. After that, I knew I had to defend myself. There was no way I could stand up to them. So I did what I had to do. Brian and Raj, well, I wasn't going to waste their new lives. I put them back to work. They're in the other greenhouse."
      
      "Is there anything we can use in there?" you ask.

      "Are you any better than those thieves if you rob this place? I guess it's all over. Who am I to stop you from taking anything. We kept a mother load of supplies in there: bandages, antibiotics, first-aid gear. We were working on a vaccine for rabies. Normally you only get treated with vaccine several times after exposure. We were close to developing a single dose primary vaccine. Take whatever. I don't care anymore."
      *goto AskShooterMenu
  #"Let's move on…
    *set timecount +25
    *goto NextShooterTalk
    
*label NextShooterTalk
  
You take a deep breath. "What should we do with you?"

"Look, I don't want any trouble," the man says.

Reilly lets out a bark of laughter, "Then you shouldn't have fired at us, should you?"

Shaking his head, he says, "Let me go, and you won't see me again. I promise."
*label AlanHub
*choice
  *if not(alan_choice)
    #Offer to let the man join us.
      *set morality %+10
      *set shooter_fled true
      *set alan_choice true
      "Do you want to join our group?"
      
      The man shakes his head. "No. I…I don't think I can. I'm leaving Colorado. I hate everyone here." He flinches as Reilly raises his hand.
      
      "Just scratching my nose," Reilly says.
      *goto AlanHub
    #Force him to join our group.
      *set shooter_fled true
      *set alan_choice true
      *set morality %-10
      *set ruthless %+15
      "We have a group at a safe place. Get your gear. You're coming with us."
      
      The man shakes his head. "No. I…I don't think I can. I'm leaving Colorado. I hate everyone here."
      
      "I didn't say you had a choice," you say.
      
      He flinches and cowers. "No, no! Don't hurt me. Leave me alone." You smell a strong odor in the area.
      
      "Oh gross," Madison says. She turns away and covers her nose.
      
      Reilly steps close to you. "Jesus, he shit himself. Forget this guy. He's broken."
      *goto AlanHub
  #Let the man go without his weapons and gear.
    *set honor %-10
    "As long as you leave us alone," you say, "we're going to let you go."

    "Really?" the man asks, his tension lifting. 

    "Really, but only after we make sure you can't do us any harm," you reply. "You can go right now but you're leaving everything here."
    
    He nods and swallows hard. "Fine. Fine. Whatever you say."
    
    Reilly cuts the twine from his wrists helps him to stand. As soon as the stranger is free to go,
    *label AlanTurns
    *set shooter_fled true
    he turns and runs towards the back of the greenhouse, leaving through back to were you didn't know existed, without saying another word.
    
    "I hope we never encounter the people that hurt that man," Madison says.
    
    "He was weak. Probably never got punched in the face before the outbreak. I've had the shit kicked out of me before. It didn't break me, just pissed me off more."
    
    @{(impulse >= 50) "Come on, let's get back to checking this place out,"|"It truly makes me wonder if he has the will to survive out there,"} you say.
    *goto ScavengePinkyMenu
  #Let the man go with his weapons.
    *set morality %+10
    *if shooter_m16
      *set m16 -1
    "We're going to let you go," you state. "In fact, we're going to leave your weapons with you."

    "Is that really smart?" Reilly drawls, a look of surprise on his face.

    "He won't survive long without them," you say.
    *if shooter_m16
      "You hand him back his rifle and to his supplies.
    "Take what you think you might need. @{(ideal >= 50) You're a smart guy, so I'm sure you can make it out there."|It's a strange world out there. It's only been a few days but things have broken down. If you think you've had it rough in here, be ready for a real struggle."}
    
    Reilly cuts the twine from his wrists and helps him to stand. As soon as the stranger is free, he dumps out a trash bag and shoves items from the area inside of it.

    "Thank you. You'll never see me again." When his bag is half full,
    *goto AlanTurns
  #Kill the man.
    *set shooter_alive false
    *set survivor_kills +1
    "Sorry," you say. "But we can't take any chances." You take a deep breath and end the man's life. 
    
    Reilly takes a rag from his back pocket and wipes his forehead. "You had to do it. The guy was too unstable. If we let him live, he could have come back and attacked us. And if he did run, he wouldn't be able to survive out there. You were actually very merciful."
    
    Madison looks around the area, but never looks at the body.
    *if empathy >= 55
      *set madison_sorry_alan true
      You sense sympathy behind those eyes. Could she feel sorry for the man?
    
    Next you…
    *goto ScavengePinkyMenu

*label GreenhouseBrain
*set visited_greenhouse_brain true
As you move toward Greenhouse Brain, the writing on the sign becomes much more readable: Animal Samples. There is a clear glass door, and a couple of large windows on each side. 

Madison frowns.
*if madison_bathroom
  She crouches and pushes her knees together, bouncing in place.
"Animal samples? What could be in there?"

Reilly looks as if he is about to answer, but is interrupted by a loud howl coming from inside. 
*if search >= 55
  From the corner of your eye, you notice several large shadows moving swiftly in your direction.

Within moments, the glass shatters and small bits of shards fly outward, and two infected push through the walls, only slowed by the thin metal slats holding the glass. Each zombie wears some kind of uniform. One rushes at you, while the second zombie reaches for Reilly. He keeps it at bay with the barrel of his shotgun. 
*choice
  #Order Madison to help Reilly, while I fight.
    "Madison," you yell, "help Reilly!"
    
    She answers back, but you ignore it as a creature with a face full of fangs suddenly garners your attention.
    
    *gosub AttackGHZ
    *gosub GHZAttackPenalty

    With your zombie down, you turn to assist Reilly who is still engaged in a life-and-death struggle with his infected. Just as you move, a loud crack fills the air, and the zombie's head snap sideways with a single shot.  

    Reilly breathes hard, but raises his finger to his forehead, saluting Madison.
    *goto AfterGHBrainFight
  #Order Madison to help me.
    "Madison," you yell, "help me with this thing."

    "But you're in the way!" she yells, but before you can answer, the zombie is upon you. You manage to avoid its first strike when you could swear you feel a bullet whiz by you and hit the infected in the knee. The zombie drops, but crawls towards you, stretching out with one arm while pulling himself across the concrete with the other. You reach for one of your weapons but Madison raises her AR-15 and fires once more, ending the infected technician's life. 
    
    With your foe defeated, you turn to help Reilly but see he needs no assistance. He gives the zombie a hearty shove, momentarily knocking him off balance. Reilly points his shotgun at the zombie's head, and ends its existence in a spray of gore.
    *goto AfterGHBrainFight
  #Tell Madison to stay back while I fight.
    You barely have time to yell, "Madison, stay back" before an infected is upon you. His rancid breath churns your stomach.
    
    *gosub AttackGHZ
    *gosub GHZAttackPenalty
    
    While you were engaged in your own fight, Reilly and Madison weren't idle. You notice the other infected on the ground, while the butt of Reilly's shotgun appears to have pieces of blood and hair on it.
    *goto AfterGHBrainFight
  #Toss my infected into Reilly's.
    You dance to the side, evading the zombie's claws, and leaving it momentarily unbalanced.
    *if (m_athletics >= 60) or (mma_style >= 3)
      You dance to the side as the zombie lunges forward and leaving it off balance. Before it can right itself, you knock it in Reilly's direction. Both infected become briefly entangled in each other, claws sinking deep into the other's body. Reilly points his gun upward, and ends both zombies with a loud boom.
      *goto AfterGHBrainFight
    *else
      *set fatigue %+(round((100-sta)/5))
      *set stress %+(round((100-wil)/5))
      *set p_health %-(round((100-sta)/5))
      *set reilly_faction %-(round(20-(empathy/6)))
      He recovers quickly and reaches for your throat, latching his hands onto your collar. You struggle to fight him off, but he drives you backwards, farther from your friends. As you turn, you hear the blast of a shotgun and pop of rifle. Blood flies out of the rib cage of the infected technician.
      
      "Go help ${firstname}!" Reilly shouts from the front of the greenhouse.
      
      You keep dropping back, driven by the infected's hands. His mouth snaps just short of your nose. You struggle to keep your footing and feel yourself weakening. Stumbling, you fall to your back with the zombie on top of you.
      
      "Hold him up," Madison yells. "I need a clear shot."
      
      With one last exhaustive shove, you force him back. Another shot rings out. A shower of bloody gore rains over you. You blink fast until you can see—a crater marks the side of the zombie's head. You twist your body to the side to avoid him landing on you.
      
      Sitting on the ground to catch her breath, your companions rush over.
      
      "Not too smart throwing that zombie at me," Reilly says. "You almost got us both killed with your antic."
      
      "I thought…I could knock…one into…the other," you say, stammering through labored breaths.
      
      He hands you a clean rag from his pocket and you use it to wipe the blood off your face and upper clothing. "Thanks." After a few minutes of rest, the three of you set your sights back on the greenhouse.
      *goto AfterGHBrainFight
      
*label AttackGHZ
Without much room, you quickly decide on the right means to defend yourself.
*gosub_scene CheckWeapons
*set ranged_matters false
*set target_difficulty 90
*fake_choice
  #Use my ${p_weapon}.
    *gosub_scene FightCode UsePrimary
  #Use my ${s_weapon}.
    *gosub_scene FightCode UseSecondary
*gosub_scene Part3Events CheckWeaponSize
*if not(close_combat_possible)
  *set target_difficulty +20
*gosub_scene FightCode AttackResult
*set zombie_kills +1
The zombies staggers ever closer, his eyes lit with infectious rage. Tiny marks and cuts coat his body like tattoos, all from walking through the broken glass and metal framing. In fact some metal pokes through his bicep on his right arm and out of his left thigh. As your eyes dart around, you see his name tag reads, Brian.

*if curr_weapon != "hands"
  @{close_combat_possible Choosing a weapon easily managed in this close form of combat, you|Struggling to use such a long weapon in this close form of combat, you just barely react before the zombie's next attack. You throw your body to the side and}
*if curr_type = "ranged"
  let loose ${curr_weaponmode}. It
  *if attack_result >= 3
    strikes him just between the right eye and nose bone, sending his head back at an angle with a snap. He falls in to the wall, breaking more of the glass.
    *return
  *else
    lands in his chin, cracking his jawbone. Shards of teeth fly from his mouth, and he rolls his head as if he feels the pain. A half second later he turns back to you and lunges forward. You manage to shoot again, this time striking just above his ear. He corkscrews once, trips over his own feet, and slams face first into a pile of glass.
    *return
*elseif (curr_class = "spray") or (curr_class = "taser")
  *gosub_scene Part3Events LoseCurrentWeapon
  fire. The @{(curr_class = "spray") spray hits the zombie's eyes but does|barbs hit the zombie's eyes but do} nothing. Having wasted the attack, you scramble to grab another weapon, but he falls into you, forcing you to drop the ${curr_weapon} and hold him back.
  
  You give them a hard shove and send him backwards, but he quickly recovers. Taking a fighting stance, you
  *goto GHZHands
*elseif curr_type = "melee"
  swing your ${curr_weapon}.
  *if attack_result >= 3
    *if attack_result = 3
      *set fatigue %+(round((100-sta)/5))
    @{(curr_class = "club") It catches his chin, knocking him backwards into the glass partition. He falls, impaling himself. You bring your weapon over your head and down again across his face, smashing his cheekbone. One more time you raise the weapon and slam it down. Thick drops of blood fly out in all directions. The side of his skull caves in, and the infected technician goes still.|The blade slices upward, through his upper jaw and deep through his skull. It's an odd angle, but you must hit brain. His body shuts off, and he drops to his knees, pulling your weapon down with him. You step on his chest and yank hard to free it.}
    *return
  *else
    *set fatigue %+(round((100-sta)/4))
    In the short distance, you can't generate much force. @{(curr_class = "club") Your blow only manages to stagger the zombie momentarily. He recovers quickly and reaches for your throat. You swing upwards, clipping his chin and turning his head sideways. His teeth snap air by the side of your face. Moving to his side, you swing down at his leg and smash the kneecap.|You slice across his face, lobbing off his nose and part of his cheek. The hit only knocks them sideways for a moment, and then he's back on you. You shove him back to gain some space and swing again, this time low. You jam the blade into his kneecap and quickly pull out.} The infected technician drops to a crouch.
    
    Finally you can move back and get some distance. With more room to swing, you raise the ${curr_weapon} over your head and bring it down across the back of his skull. It takes three more strenuous swings to end his life.
    *return
*else
  Fighting the zombie unarmed allows you more fluidity of movement in such a tight space. You
  *label GHZHands
  *if attack_result >= 3
    *if attack_result = 3
      *set fatigue %+(round((100-sta)/5))
    *if mma_style <= 1
      drive a fist into the side of his head, knocking him back. Two teeth fly out of his mouth and rattle across the ground. You send your other fist into his nose bone, snapping it beneath your knuckles. With an uppercut to his chin, you send them sprawling into the glass partition. It takes a few more hammering blows to end his life.
    *if mma_style = 2
      front kick his chest, knocking him back. Now with a little distance, you drive a sidekick into his head. He topples backwards and sprawls into the glass partition. You raise your foot high over your head and slam an ax kick down onto his skull, cracking it and ending his life.
    *if mma_style = 3
      give him a hard shove, sending him back towards the partition. Now with some distance, you shoot in on his legs and tackle him to the ground. Holding onto his legs, you roll until he's face first and then you hold him there while you mount his back.
    *if mma_style = 4
      Grip his collar, spin your hips sideways, step over his leg, and pivot. The angle sends him flipping over your body and landing face first onto the ground.
    *if mma_style >= 3
      With complete control over him, he cannot harm you. Gripping the back of his head, you slam it onto the concrete floor with a crack. It takes a few more hammering blows to end his life.
    *return
  *else
    *set fatigue %+(round((100-sta)/6))
    you try to shove him away to gain some distance. He recovers quickly and reaches for your throat. Throw out a punch and barely connect the side of his face. His teeth snapped the air by the side of your head. You keep circling to his right and punching or kicking, which only serves to keep him off balance and tire you out.
    
    With one final burst of energy, you rush forward and shove him backwards. He tumbles and falls, landing with his shoulders and back across the broken glass partition. Not letting up, you lift your foot and slam it down on his head, feeling a crack beneath your heel. It takes a few more exhaustive blows to end his life.
    *return
    
*label GHZAttackPenalty
*if attack_result < 3
  *set p_health %-(round((100-sta)/5))
  
  Somewhere in the scuffle, something sliced your left hip. It's not a terrible wound but something you'll need to address later. For now you have bigger concerns.
*return

*label AfterGHBrainFight
*page_break
*set timecount +25
You breathe rapidly and feel your heart race as the infected lie in an unmoving heap on the ground. 
*if (main_ro = "Reilly") or (second_ro = "Reilly")

    Reilly quirks his lips. "You know, any date after this is going to be a bit of a let down."
*if (main_ro = "Madison") or (second_ro = "Madison")

  Madison runs her hand along your back. "Are you okay? Please say you're okay."

  "I'm fine Madison," you say, and she steps back, relief on her face.  

With the entrance secured, you cross the threshold into the greenhouse. The stench of rotting meat fills your nostrils. Two tables line each side of the building, while down the center of the room carcasses hang from hooks. At first you think they might be human bodies, but they prove to be animal bodies. 

At the back of the greenhouse stands a clear glass cabinet filled with a variety of vials and jars. Some of them bear a skull-and-crossbones symbols, indicative of poison, while others show only labels.
*if madison_bathroom
  *set madison_bathroom false
  
  As you consider which one to examine the first, you look around for Madison but see her nowhere. Before you have a chance to ask Reilly, she walks up to you buttoning her pants.
  
  Reilly snickers. "You guys smell something? It has a strange odor, like someone just took a piss in here."
  
  Madison covers her face, which has quickly turned red. "It's not my fault. I really had to go."
  
  "That was you?" Reilly says, acting surprised. "I can't believe it. The Princess just tinkled out in public? What will us peasants think?"
  *fake_choice
    #"Okay, you had your fun Reilly. Let's get going. We don't have time for this."
      *set impulse %+15
      *set madison_faction %+(round(empathy/6))
      Reilly shrugs and rolls his eyes. "I'm just having a bit of fun. Fine, I'll leave alone."
      
      When he turns away, Madison mouths the words to you, "thank you."
    #"Reilly, knock it off. It's not her fault she had to go."
      *set morality %+15
      *set madison_faction %+(round(empathy/6))
      Reilly sighs and waves his hand dismissively. "You guys are no fun."
      
      When he turns away, Madison mouths the words to you, "thank you."
    #"I wish I had a camera right now to film this. No one is going to believe it back at the Junkyard."
      *set morality %-15
      *set reilly_faction %+(round(empathy/6))
      Madison stamps her foot. "Stop it. Both of you. I'll turn around and go right back to the Junkyard. You two can walk home for all I care."
      
      Reilly waves his hand at her dismissively. "Okay, okay. Don't get bent out of shape. I'll stop teasing you."
    #"Reilly, do you really need to be a jerk? You tease her enough. It's getting really old."
      *set ideal %-15
      *set madison_faction %+(round(empathy/6))
      *set reilly_faction %-(round(20-(empathy/6)))
      Reilly sighs and waves his hand dismissively. "You guys are no fun."
      
      When he turns away, Madison mouths the words to you, "thank you."
  *goto GHBrainMenu
*else
  *goto GHBrainMenu
  
*label GHBrainMenu

Next, you…
*choice
  #Examine the tables.
    *set zeta_knowledge %+5
    You examine the tables and note numerous papers, many bearing what look to be test results of animal experiments. You recognize entries for dogs, cats, raccoons, chimpanzees, cows, and rats. The entry for rats is circled in bright red with exclamation points right by it. 

    Madison looks at another paper and swears under her breath. She slides the paper toward you. "Take a look."

    You skim through it, and see "unfortunately, while we surmised that the rabies virus may bear some similarities to the zombie virus, this assumption proved false. While creatures deep in the throes of hydrophobia will exhibit similar violent behaviors as infected humans, this is superficial at best."

    Then your eyes drop to the bottom as you read. "In fact, the zombie virus has been shown to prolong the lives of animals infected with rabies by ten-fold."

    "Seems like they were testing everything they could think of," Madison says.
    *goto GHBrainMenu
  #Examine the glass cabinet at the back.
    *set timecount +25
    The glass cabinet at the back contains a variety of bottles, some with liquid solutions while others are filled with pills. Some broken bottles lie on the ground, but you easily nudge the pieces aside with your foot. 

    Then you notice vials marked with RabbiVacc, @{(science >= 60) which sounds like brand names for drugs commonly used to treat rabies. You can only imagine that these are vaccines for the disease.|though you have no clue what that means. You search the cabinet until you find a drug list and can match the name to a description. "Fast acting rabies vaccine" sits beside the name remarked on the vials.} You collect them all and shove them in your inventory.

    A quick search reveals a few items for the taking, but they are in limited supply: bandages, ointment, and antibiotics.
    *set bandages +3
    *set ointments +3
    *set antibiotics +1
    *goto GHBrainMenu
  #Examine the zombies.
    *set arc_keycard true
    *set timecount +25
    The clothing both zombies wear look to be identical uniforms, but once more there is no insignia on them to indicate as to their origin. 

    Making sure not to come into contact with its fangs or claws, you quickly search the first infected, but find its pockets are completely empty.

    The second infected is in almost the same condition, except you find a keycard with the picture of the zombie, as well as the name 'Sarah Reynolds'. Small print indicates the holder worked for the Centers for Disease Control. You decide to hold onto the card in case you can use it for the future.
    *if research_virus
    
      Staring down at the fresh corpses, you reach for your specimen collection kit.
      *set specimen_difficulty 20
      *set living_subject false
      *gosub_scene Part1Events AcquireSpecimen
    *goto GHBrainMenu
  #Examine the animal carcasses.
    You take a look at the nearest animal carcass hanging up and determine it's a raccoon. Above it is a simple label, 'Test Subject 1-A: Infected with the zombie virus'. There is something different about the creature. 

    "Thinking of making a raccoon skin cap?" jokes Reilly. 

    Ignoring him, you realize that raccoon's upper and lower canines are extended, actually lying outside the mouth, leaving one with the impression of a saber-toothed cat. Then you take a look at the claws, and these are longer as well. 

    The other animals labeled Test Subject bear similar elongated teeth and claws. A rare few bear other changes, such as thickening of the bones, making it much tougher to pierce internal organs.

    However, not all animals bear these touches. A small number of bodies bear the label 'Control Subject' and look like normal, dead animals. Eventually, you learn nothing more from these bodies.
    *goto GHBrainMenu
  #Go back to the parking lot.
    *goto RCOutsideMenu

*label ARC
You move closer to the large, light-brown building. The sides are covered with a layered, shale façade, broken up with the several large windows. A nearby sign reads "Devil's Backbone Agricultural Research Center."

You step to the entrance and see a large reception area. Chairs are knocked aside, red stains and bloody chunks lie on the floor, and a single large desk sits in the middle of the room. The overhead lights flicker from soft white, turn off, and turn back to the soft white. 

"Looks like a rolling blackout," Madison says. "But at least it means we won't be completely in the dark."

"That's reassuring," you say.
*if madison_bathroom

  She crosses her legs and wiggles. "Guys, I really have to go. I'm sorry."

The left of the room has a large arch, leading into cubicles and small offices. The right side of the room has an elevator. In front of you is a regular door. You give the handle a tentative pull but find it remains locked. To the side of the door you see a card slider, occasionally blinking a green light that goes off at the same time as the lights inside.
*if search >= 55
  Just as you decide to check for a way in, you glance through the window to an open doorway and see a number of shadows shambling in the flickering light beyond the shadow.
*if warned_about_arc_by_alan

  "So, we're doing this?" Reilly asks. He rubs his hands together and takes a few nervous breaths.

  "That freaky scientist made it sound like it's a house of horrors in there." Madison wraps her arms around her body and looks behind her at the road leading out.
  *choice
    #"We're stronger and smarter than that guy gave us credit for. Of course we're going in."
      *set ideal %+15
      *if {social_skill} >= 55
        *label ARCEntranceSucceed
        *set madison_faction %+(round(empathy/6))
        *set reilly_faction %+(round(empathy/6))
        Based on your words, Madison and Reilly show a look of ease. Riley takes down his shotgun and holds it in both hands while Madison does the same with her rifle. Both of your companions appear as seasoned soldiers ready to go into battle with you.
        
        "Are you two ready?" you say.
        
        They both nod.
        *goto ARCEntrance
      *else
        *label ARCEntranceFail
        *set madison_faction %-(round(20-(empathy/6)))
        *set reilly_faction %-(round(20-(empathy/6)))
        Your words don't seem to ease the fears of your two companions. Madison shifts nervously from side to side while Reilly continues to look between the door on the road like he might make a break for the junkyard at any moment.
        
        "Alright, let's do this," you say.
        *goto ARCEntrance
    #"It won't be easy. At the first sign of trouble we can always turn back. But we have to try and reach those supplies."
      *set ideal %-15
      *if {social_skill} >= 65
        *goto ARCEntranceSucceed
      *else
        *goto ARCEntranceFail
    #"You believed that guy? His mind was cracked. For all we know he was hallucinating the whole thing. Let's get in there and get those supplies if they exist."
      *set ideal %-15
      *set impulse %+15
      *if {social_skill} >= 60
        *goto ARCEntranceSucceed
      *else
        *goto ARCEntranceFail
    #"I never thought of you two as cowards. Let's go."
      *set truth %-15
      *if {social_skill} >= 65
        Madison lets out a short huff. "I'm not afraid. Seriously, I'm not afraid." She swings the rifle off her shoulder and stands at the ready,and for a moment her mood suggest she may shoot you.
        
        Reilly smirks. "Seems like you know how to motivate me."
      *if {social_skill} < 65
        *set madison_faction %-(round(20-(empathy/6)))
        *set reilly_faction %-(round(20-(empathy/6)))
        Reilly steps close to you. "Coward, huh? Saying something like that is not really a good way to motivate me. It just makes me get pissed off and maybe ignore the person on my right whose getting attacked by a zombie and screaming for help."
        
      You turn your attention to the entrance and prepare to head in.
      *goto ARCEntrance
    #"It's not just my decision. If you think it's not worth the risk, then let's just go."
      *set diplomacy %+15
      The three of you exchange a series of glances like you're watching a three-way tennis match. 

      Madison stomps away two steps from the entrance. "I see no reason to go in there. If you two want to go in, be my guest. It's not about being afraid—it's about being smart. That psycho scientist told us what's in there, and were not set up to deal with the zombies and the traps and the military devices. Let's just go back and tell everyone what we found. If secret agent Rachel wants to go all Mission Impossible on this place, then good for her."
      
      Reilly takes a half step towards her. "Pains me to say it, but I gotta agree with Princess. @{nora_join If I die out here, who's going to take care of my ma?"|I'm not about the risk my life unless I know for sure we're getting what we need. I say we go back to the Junkyard."}
      *goto MissionEnd
    #"Why don't we just head home. We can tell the others we found. Maybe we'll come back later."
      *set impulse %-15
      Reilly nods and scratches his neck. His eyes shift all around like he's searching for an answer. "Good idea. If you two don't want to go in there, I totally get it."

      Madison rolls her eyes at him. "Sure, only me and ${firstname} are too afraid to go in."
      
      "It's settled. We're heading back. We'll tell our group what we've learned, and if they want to come back, we can figure out a good plan."
      *goto MissionEnd
*else
  *goto ARCEntrance
  
*label ARCEntrance
*set visited_arc true
*choice
  *selectable_if (arc_keycard) #Run the card through the card slider. (Requires keycard)
    You slide the card through the card reader, but nothing happens. Then you take a closer glance as the green light flickers on and off. Once you get the timing down, you slide it again, and this time you hear a welcoming click opening the door beside.
    *goto EnterARC
  #Bypass the card reader.
    *if electronics >= 60
      You remove the cover from the card reader, tracing the various wires, overlooking the non-essential ones. You rearrange a few wires and hear a satisfying click from the nearby door.
      *goto EnterARC
    *else
      *set p_health %-(round((100-sta)/5))
      You manage to remove the cover to the card reader and glance at the wires inside. While you can trace some of them, others seem to be a little beyond your understanding. Taking your best guess, you pull one wire…only to fall down on the ground in extreme pain, as if every nerve was on fire, only to stop when the power flickers off.
      
      You'll have to try something else.
      *goto ARCEntrance
  #Shoot at the lock and card reader.
    *if not(carry_ranged)
      Without a ranged weapon prepared, you turn to Reilly. "Can you shoot the lock?"
      
      He nods and draws his revolver. "Sure, stand back."
      
      You take a few steps backwards, while Madison backs away, turns, and covers her ears with her hands.
      *goto ShotReader
    *else
      You take out
      *if (p_type = "ranged") and (s_type = "ranged")
        your…
        *fake_choice
          #$!{p_weapon}.
            *gosub_scene FightCode UsePrimary
            *set using_primary true
          #$!{s_weapon}.
            *gosub_scene FightCode UseSecondary
        *goto ShootLock
      *elseif p_type = "ranged"
        *gosub_scene FightCode UsePrimary
        your ${curr_weapon}.
        *goto ShootLock
      *else
        *gosub_scene FightCode UseSecondary
        your ${curr_weapon}.
        *goto ShootLock
        
      *label ShootLock
      "Okay, stand back."
      
      Reilly takes a few measured steps backwards. Madison does the same, turns, and covers her ears with her hands.
      
      *if (curr_weapon = "compound bow") or (curr_weapon = "recurve bow")
        You draw back your bowstring, and Reilly steps closer to you.
        
        "What the hell are you doing?" he says. "You can't shoot through the lock with an arrow, dummy. Step aside."
        *goto ReillyLock
      *elseif curr_class = "shotgun"
        You raise the shotgun and fire once an angle. At such close range, the buckshot hammers the lock and card reader, knocking it off the surface.
        
        "A little bit of overkill, but it worked," Reilly says.
        *goto ShotReader
      *if ((curr_weapon != "compound bow") and (curr_weapon != "recurve bow")) and (curr_class != "shotgun")
        You raise the ${curr_weapon} and fire once into the lock.
        *goto ShotReader
    
    *label ShotReader
    With a loud pop, the card reader dies in a crunch of plastic and metal, exposing a bundle of wires, and you hear the click of a lock in a nearby door. This draws the attention of two shadows and two infected, both wearing slacks and white t-shirts.
    *goto EnterARC
  #Muscle our way in.
    *set fatigue %+(round((100-sta)/5))
    You take a deep breath, square your shoulders, and then run at the door with as much speed as you can muster. Pain fires first in your shoulder, 
    *if m_athletics >= 45
      but you are pleased to hear something break in the lock.
    *if m_athletics < 45
      *set p_health %-(round((100-sta)/5))
      then along your arm as you hit the door with a meaty thud. You fall to the side, holding your arm. 
      *label ReillyLock
      Reilly kicks the door repeatedly, and after many hard slams, the lock pops open.
    *goto EnterARC
  
*label EnterARC
*set timecount +25

Any celebration is short lived as you hear a bell from the inside ring, and the infected move to the reception area. The lead one pauses, sniffing the air, then catches sight of you. With a howl, it heads in your direction, the other one hot on its heels. The infected are moving swiftly, and you only have time to enact one course of action.
*choice
  #Attack the zombies. I can kill them all by myself.
    *set impulse %+15
    Two-on-one odds aren't the best, but there isn't much room for your companions to flank you. Considering how fast zombies move, you know you don't have much time to act.
    
    You draw your…
    *set using_primary false
    *set ranged_matters false
    *set target_difficulty 110
    *fake_choice
      #Use my ${p_weapon}.
        *gosub_scene FightCode UsePrimary
        *set using_primary true
      #Use my ${s_weapon}.
        *gosub_scene FightCode UseSecondary
    *gosub_scene FightCode AttackResult
    *if curr_type = "ranged"
      You draw your ${curr_weapon} and aim at the closest infected, who rushes from your left side. With the speed of his approach you barely have time to level your weapon.
      *if attack_result >= 3
        *if curr_class = "shotgun"
          *set zombie_kills +2
          With the shotgun chest high, you pull the trigger and aim upwards, sending a burst of buckshot into his head. The blast creates a hole in his chin the size of a grapefruit. Blood sprays out in a fan shape, and he slams against the wall back first. His body slides down the wall and folds at the bottom.
          
          The second zombie is only a step or two behind, and you barely get off a shot. You raise the barrel to eye level and pull the trigger. The shot bores through his skull, knocking him sideways in a death spin.
          *goto CheckSilent
        *elseif (curr_weapon = "compound bow") or (curr_weapon = "recurve bow")
          With your bow drawn, you notch an arrow and fire into the first infected. Having little time to make it a perfect shot, you launch the arrow upwards, through his chin, and out the back of his neck and a strange angle. With a final how he tumbles to the side and slides down the wall with a smear of blood left behind.
          
          The second zombie is only a step or two behind and you barely have time to draw another arrow and fire. It lands in his eye and knocks him backwards from the force. He lands with arms outstretched and legs folded.
          *goto ARCReception
        *else
          With the barrel chest high, you pull the trigger and aim upwards, sending a shot through his chin. His head snaps back, but forward momentum carries him into you. You sidestep, and he crashes into the wall, bounces off, and drops to the floor at your feet.
          
          The second zombie is only a step or two behind, and you barely get off a shot. You raise the barrel to eye level and pull the trigger. The shot enters his skull at an odd angle, blowing off a chunk of bone and matter. He spins and flops face first into the side wall, sliding down with a smear of blood left behind.
          *label CheckSilent
          
          *if (using_primary and (p_suppressor)) or (not(using_primary) and s_suppressor)
            After the infected are dead, you notice the walls of the research station are made of concrete covered in some type of metallic surface in certain portions. Luckily your weapon is suppressed or the noise of firing in such a confined space may have been a problem.
            *label ARCEKill
            
            "Good job killing the both of them," Reilly says, now standing by your side. "You're making our little trip here easy on me."
            
            Madison steps inside and looks about the room, already studying it.
            *goto ARCReception
          *else
            *set p_health %-(round((100-sta)/5))
            The sound of the shot echoes through the narrow confines of the concrete walls. You wince and bend over, years ringing in pain. You open your mouth wide and try to relieve the pressure in your head. A minute or so passes before the ringing dulls and you are able to stand again.
            
            *if (main_ro = "Reilly") or (second_ro = "Reilly")
              "Are you okay?" Reilly asks, placing his hand gently on your back.
              
              "I'll be all right," you say in a wobbly voice. "Thank you."
            *if (main_ro != "Reilly") and (second_ro != "Reilly")
              "You'll be okay," Reilly says. "Just walk it off."
            
            *if (main_ro = "Madison") or (second_ro = "Madison")
              Madison glares at Reilly, but she turns her attention to you. "Are you okay," she asks in a whisper.
              
              "I will be in a few minutes," you say and work up a smile for her.
            *if (main_ro != "Madison") and (second_ro != "Madison")
              Madison steps inside and looks about the room, already studying it.
            *goto ARCReception
      *else
        As you @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) notch an arrow,|fire the weapon, the shot goes wide,} and
        *label ARCHtHDeath
        the zombie barrels into you. With a growl he opens his mouth wide and juts it forward to bite. You lean your head away just-in-time to avoid his teeth. You raise the weapon into his neck and use it to force him back, giving yourself only a bit of space to avoid his next bite.
        *label ARCZDeath
        
        "Try to spin right, so I can get a shot off," Reilly yells. "Look out!"
        
        As you hear his words, you feel a sharp pain on your right shin. Something pulls at your leg, and the pain intensifies. Staring down, you see the second zombie with his mouth against your leg. You cry out and shove the first zombie with all of your might, sending him back several feet. The force knocks him over, though he scrambles to stand. Another burst of pain rises from your leg, and you throw your head back and scream.
        
        You are shoved from behind, and Reilly pushes his way inside the door. A shot rings out, and the pressure on your leg drops off. When you look down, deep gouges run through your shin and calf.
        
        Reilly levels his revolver and shoots the first infected in the head, sending him back to the floor. He moves forward, allowing Madison to run inside.
        
        You stare down at your leg which hurts so much you're surprised it's not on fire. Your breathing turns rapid, and you lie flat on the floor to try to suck in air.
        
        "What do we do?" Madison shouts, crouching by your side. "What if we cut off ${his} leg? Maybe the infection won't spread."
        
        Reilly runs a hand through his hair. "Hell if I know. It's worth a shot."
        
        Madison digs through her backpack and draws out a cleaver. She sprinkles alcohol all over it, cringing as she does. Reilly snatches it out of her hand and lights a cigarette.
        
        "Should we tie his leg above the wound or something? Like a tournament." He practices with the cleaver, swinging it over his head and down.
        
        "You mean out tourniquet. I have a scarf in my bag," Madison says and takes out a purple scarf. She wraps it high on your thigh, whimpering the whole time.
        
        "Works for me," Reilly says. "Looking real fashionable there, ${reilly_pc}."
        
        You stare up at him, panting and grunting from the pain. It feels like razor blades are crawling through your leg. When he swings, the cleaver hits above your knee and slices a deep gash across the meat. You throw your head back and arch your back. You feel warmth around your leg, and through your screams, you hear the second strike. Metal hits bone, and you pass out.
        *goto DeadEnd
    *elseif (curr_class = "spray") or (curr_class = "taser")
      As the first zombie closes in, you raise your ${curr_weapon} and fire. He ignores her attack and barrels into you. At the last moment, you reach up and grab his throat to hold his jaws back from clamping on your neck.
      *goto ARCZDeath
    *elseif curr_type = "melee"
      *if attack_result >= 3
        You raise your weapon and wait for the last moment to swing. As the zombie leans forward to lunge, you step to his right and
        *if curr_class = "hack"
          slam the blade into the side of his head. Blood spurts out and hits the concrete wall. 
        *if curr_class = "club"
          bash the side of his head. He wobbles on his feet, and you step back and swing again, slamming the weapon onto his skull. The hit makes a wet smacking sound, and the infected drops to the ground.
        *if curr_class = "sword"
          slash the blade across the side of his head. A wedge of his skull splits off and hits the concrete wall.
        *if curr_class = "knife"
          slam the blade into the side of his head, burying it to the handle. Blood spurts out and hits the concrete wall.
      *if attack_result = 4
        *set zombie_kills +2
        *set fatigue %+(round((100-sta)/7))
        While his body falls, you
        *if curr_class = "hack"
          yank out the ${curr_weapon}, jump over his body, and backhand the second zombie. The blade slices across his forehead, scalping off a portion of skin and skull. The force of the hit knocks him sideways. You raise your weapon and swing it down in an overhead chop. The blade cleaves his head in half, exposing his diseased brain.
        *if curr_class = "club"
          wind up and swing wide on the advancing second zombie. The tip of your weapon smashes into his mouth. Teeth, bone, and blood explode out and hit the concrete wall. His body spirals, and he trips over the dead corpse of the first zombie. As he falls you help him along, swinging your weapon from overhead and landing it on the crown of his skull. It splits like a ripe melon, and he splays out across the floor.
        *if curr_class = "sword"
          jump over his body and thrust the blade into the second zombie. The tip of the blade lodges into his chin, and you drive it forward until it pokes out of the back of his head. You yank out the blade and let him fall to the ground, and his blood mixes on the floor with the other dead zombie's.
        *if curr_class = "knife"
          yank out the ${curr_weapon}, jump over his body, and thrust the knife into the second zombie. The blade lodges into his chin, and you twist the handle until he stops growling. You yank out the blade and let him fall to the ground, and his blood mixes on the floor with the other dead zombie's.
        *goto ARCEKill
      *elseif attack_result = 3
        *label ARCOneKill
        *set zombie_kills +1
        *set fatigue %+(round((100-sta)/5))
        As you recover from your first attack, the next infected lunges faster than you anticipated. You twist your body away and slam into the concrete wall. Off-balance, you stumble away and gain some distance.
        
        Since you're no longer blocking the entrance, Reilly enters the room and fires once into the back of the zombie skull. Blood sprays out in an arc and hits your
        *if (uniform = "service") and female
          skirt.
          *goto ReillyShootsLast
        *elseif uniform = "scrubs"
          medical scrubs.
          *goto ReillyShootsLast
        *elseif uniform = "tailored dress"
          dress.
          *goto ReillyShootsLast
        *elseif uniform = "white coat"
          white coat.
          *goto ReillyShootsLast
        *else
          pants.
          *goto ReillyShootsLast
          
        *label ReillyShootsLast
        "Good job killing the first one," Reilly says, now standing by your side. "Sorry about the blood. A little bit of detergent will get that right out."
            
        Madison steps inside and looks about the room, already studying it.
        *goto ARCReception
      *else
        swing. The weapon cuts through the air and misses. Before you can recover,
        *goto ARCHtHDeath
    *else
      As the zombies advance, you
      *if attack_result >= 3
        *set zombie_kills +1
        *set fatigue %+(round((100-sta)/5))
        change your stance and prepare to attack. The one on your left lunges first. You
        *if mma_style <= 1
          dodge to your right and throw a quick hook to his head. Your fist pummels his eye, knocking it into the socket and bursting it like a ripe grape. You twist at your hip and throw an overhead right to his temple, knocking him against the concrete wall. Leaping forward, you ram an elbow
        *if mma_style = 2
          dodge to your right and throw a quick side kick to his head. Your foot connects with his eye, knocking it into the socket and bursting it like a ripe grape. You twist at your hip and throw a snap kick to his temple, knocking him against the concrete wall. Leaping forward, you slam a knee
        *if mma_style <= 2
          into the side of his face which is pinned against the wall. You feel a crack as you connect, and the zombie drops to the floor.
        *if mma_style = 3
          grab his bloodstained shirt, spin, and throw him headfirst into the concrete wall. With a growl he slams into the hard surface, spraying blood from an instant wound. You slip around to his back, wrap your arms around his waist, lift him high in the air, and drop them on his head. You feel a crack as he land, and his body goes limp.
        *if mma_style = 4
          Fall back, grip his bloodstained shirt, twist your hips, and flip him over your body. He lands on the ground flat on his back. Still holding his collar, you squeeze it around his throat and drop your knee onto his chest. With a quick yank, you bend his neck at an extreme angle into you hear crack in his body goes limp.
        *goto ARCOneKill
      *else
        rush forwards to attack. Swinging at the first, your fist connects with the side of his head. He lunges at you, hands gripping your throat to draw you into his bite. You push his shoulders to keep him away, and the two of you stumble into the concrete wall.
        *goto ARCZDeath
  #Brace the door and have the others shoot the infected.
    Though the door is unlocked, it is still whole enough to offer a momentary barrier to the infected if someone is strong to keep it closed. With a run, you quickly put your entire weight against the door. 

    *if m_athletics >= 45
      It rattles as the weight of the infected hit the door dead on, but you prove strong enough to keep them back. "Shoot through the windows," you yell at your two companions. You momentarily wince as two shots crack in the air and break the glass on either side of you. In that moment, the door is completely still once more and you see the fallen forms of the zombies.
      
      "Jesus, what the hell?" Reilly yells, holding the side of his head. He paces along the wall opening and closing his mouth like he's popping his eardrum.
      
      Madison swings her rifle over her shoulder. "Well who told you to get in my way?"
      
      "Sorry, Princess, I can't hear you over the ringing in my ears." Reilly squeezes his nose and blinks rapidly. "You don't need to put your rifle to the side of my head."
      
      "Next time don't get my way." Madison moves past you and enters the reception area.
      *goto ARCReception
    *else
      "Madison, Reilly, cover me," you say as the first infected crashes into the door. You don't prove strong enough and fly off the door as the force from the other side is too much for you to handle. The door swings open, but the zombie falls onto the ground, the second one actually standing on top of it. It snarls, attention focused on you. 
      
      Madison screams and fires her rifle, shooting the zombie through the arm. He lifts his head, notices the girl, and lunges for her. She backpedals, stumbling as she moves. Reilly shoulder blocks the infected, knocking him into the side wall.
      
      The zombie under the door crawls forwards to escape. With a running leap you jump on top of the door to pin him beneath it. He howls in anger, arms swinging wildly, nails scraping the floor.
      
      "Stop running so I can get a clear shot," Reilly says, aiming his pistol at the moving zombie.
      
      Madison runs in a zigzag and shrieks the entire time. The infected never loses a step as he chases close behind her. A shot rings out, lowered and echoing in the small space, and the zombie drops to the ground, his right leg bent and broken from a bullet. Madison runs back towards Reilly, who strides towards his target. The zombie scurries on the floor like a spider, head raised and mouth wide open ready to bite.
      
      "Get out of my way," Reilly shouts, and as Madison darts to the side of the room, he fires into the head of the zombie, killing it.
      
      Back at the entrance, you lay on the door like it's a surfboard as the zombie below it bucks and tussles to free himself.
      
      "A little help over here," you say.
      
      Madison takes a deep breath, aims her rifle, and fires twice. The movement below the doorstops, and you breathe a sigh of relief.
      
      "Nice job, your Majesty. Not too hard to shoot one that ${firstname} @{nb are|is} holding down for you." Reilly shakes his head and reloads his pistol.
      
      Madison says nothing, but presses her lips together and groans. She walks forwards, steps on the door, and climbs past you.
      *goto ARCReception
  #Back away and let the zombies run outside. It will be easier to kill them out here.
    "Get ready. Let the door funnel them out to us," you yelled to your companions.
    
    All three of you spread out and prepare to attack. Reilly draws his revolver, while Madison holds up her rifle. You reach for your…
    *set using_primary false
    *set ranged_matters false
    *set target_difficulty 90
    *fake_choice
      #Use my ${p_weapon}.
        *gosub_scene FightCode UsePrimary
        *set using_primary true
      #Use my ${s_weapon}.
        *gosub_scene FightCode UseSecondary
    *gosub_scene FightCode AttackResult
    The lead zombie rushes through the narrow door, and
    *if curr_type = "ranged"
      the three of you unload. Bullets strike his shoulder and chest, while your
      *if attack_result >= 3
        *set zombie_kills +1
        *if curr_class = "shotgun"
          buckshot peppers his head and sends
        *if (curr_weapon = "compound bow") or (curr_weapon = "recurve bow")
          arrow sticks through the bridge of his nose and into his head, sending
        *if ((curr_weapon != "compound bow") and (curr_weapon != "recurve bow")) and (curr_class != "shotgun")
          shot pierces his eye socket, sending
        him crashing into the side wall.
      *if attack_result < 3
        *if curr_class = "shotgun"
          buckshot peppers his stomach and ribs.
        *if (curr_weapon = "compound bow") or (curr_weapon = "recurve bow")
          arrow embeds in his stomach.
        *if ((curr_weapon != "compound bow") and (curr_weapon != "recurve bow")) and (curr_class != "shotgun")
          shot cuts through his stomach.
        The multiple hits knock him into the side wall, and Madison drops in with a headshot.
      *goto NextDoorShot
    *else
      Madison and Reilly fire, ripping shots through his shoulder and chest. You wait for him to draw closer and then
      *if curr_class = "spray"
        *set reilly_faction %-(round(20-(empathy/6)))
        *set madison_faction %-(round(25-(empathy/6)))
        fire your pepper spray into his face. It has no fact, but in the close area, the mist hits Madison. She turns and coughs into her arm, eyes watering and nose running.
        
        Reilly raises his revolver higher and fires once into the side of the zombie's head, killing it. "Damn it, ${firstname}."
        
        As the next zombie rushes through the door, Reilly dashes forwards, kicks it to the ground, and stomps on its head until it goes limp. Blood sprays on his pant legs, onto the side wall, and all along the entranceway.
        
        Madison leans against the wall and blots her eyes with her sleeve. "Oh my gosh," she says through labored whispers.
        
        Reilly walks over to her and takes a bottle of water from his bag. "Here, let me help you rinse it out."
        
        He helps her to rinse out her eyes, which takes a few minutes and more coughing and whimpering. When they are finished, her eyes are red and bloodshot but she still able to glare at you.
        
        "You can't use pepper spray on a zombie. How could you not know that by now?" she shouts that you.
        
        Reilly moves towards the open door. "We can argue about this all day, but we should get a move on.
        *goto ARCReception
      *elseif curr_class = "taser"
        *set reilly_faction %-(round(20-(empathy/6)))
        *set madison_faction %-(round(20-(empathy/6)))
        shoot the tazer. Though it strikes him in the chest, the electric charge has no effect on him.
        
        "Stop playing games," Reilly yells.
        
        Luckily for your group, Madison places a headshot in the infected, ending his life. She flashes a self-insured smile at you and Reilly.
        *goto ARCReception
      *elseif curr_type = "melee"
        *if attack_result = 4
          *set zombie_kills +1
          leap forward with your attack.
          *if curr_class = "hack"
            With an overhead swing, you slam the blade into his forehead, embedding it halfway into the skull. 
          *if curr_class = "club"
            With an overhead swing, you bash his forehead with the point of your weapon, caving in his skull.
          *if curr_class = "sword"
            With an overhead slash, you cleave through his forehead, and embed your blade halfway through his skull.
          *if curr_class = "knife"
            You drive the knife upwards and into his chin, driving it up to the hilt. With a twist of your blade, his growling stops, and you draw out your weapon.
          His body drops to the floor and pulses of blood shoot out across the tile.
          *goto ARCReception
        *else
          *gosub MadisonHS
          *goto NextDoorShot
      *else
        *if attack_result = 4
          *set zombie_kills +1
          *set fatigue %+(round((100-sta)/5))
          leap forward with your attack. You
          *if mma_style = 1
            slam your fist into the side of his face at the peak of his jawbone and follow with a left hook to the bridge of his nose.
          *if mma_style = 2
            throw a front kick into his chest to stop his forward movement and follow-up with a roundhouse kick to the side of his head.
          *if mma_style = 3
            shoot in for a double leg takedown and slam the infected onto his back.
          *if mma_style = 4
            grab him by the collar, trust your hips, and flip them over your back.
              
          "Back off. Let me shoot it," Madison shouts, stamping her foot.
            
          "Let ${him} do ${his} thing," Reilly says, leaning against the wall and twirling his revolver.
            
          *if mma_style = 1
            The zombie wobbles, and you grab his throat and shove him against the wall. You hammer your fist and forearm against the side of his head until it's a bloodied mess and he crumples to the floor.
          *if mma_style = 2
            The zombie wobbles, and you push kick him into the side wall. You hammer a few fists into the side of his head until he's seated in the corner of the room. Taking a few steps back you drive a few kicks into his skull until it's a bloodied mass and his growls stop.
          *if mma_style = 3
            Moving to the zombie's side, you grip his head, tangling your fingers into his greasy hair, and slam his skull against the floor until his growls stop.
          *if mma_style = 4
            With the zombie in front of you now in a seated position, you wrap your arms around his neck and twist them so you hear a snap. The pop of his vertebrae echoes in the narrow area.
          *goto ARCReception
        *else
          *gosub MadisonHS
          *goto NextDoorShot
    
    *label NextDoorShot
    
    As the next zombie rushes through the door, Reilly dashes forwards.
    
    "I got this one," he yells and slams the butt of his revolver onto the infected's head.
    
    "What the heck?" Madison shouts and lowers her rifle. "We had a plan."
    
    Reilly kicks the creature to the ground and stomps on its head until it goes limp. Blood sprays on his pant legs, onto the side wall, and all along the entranceway. When he's finished, he backs away and performs a good grand flourish, ending with his hands pointing through the doorway. "I was just clearing the way for you, your Majesty."
    
    "Oh my gosh, you are such a Neanderthal." Madison stomps along the floor and then tiptoes past the bodies of the dead and the blood that's spilled. You follow after her.
    *goto ARCReception
      
*label MadisonHS
move forward to attack. Before you can take two steps, Madison places a headshot into the infected, ending his life. She flashes a self-insured smile at you and Reilly.
*return
        
*label ARCReception
*page_break
*set timecount +25
Now that the area is secure, you quietly move into the reception area, and the distant howls of infected come from the doorway to the east. The air is thick with the smell of decayed bodies, and a part of you wonders just when you became used to such odors.
*if madison_bathroom

  As you look around, Madison rushes to a doorway a dozen or so feet away and heads inside. You see this symbol of female bathroom on the door.
  
On a wall near the elevator, you see a floor plan of the building. A small X marks your location, the reception area. To the left is a small group of staff offices and cubicles. At the end of that room is a stairwell which leads downward. Much like the rest of the room, lights flicker on the elevator buttons, then go dark when the power surges off. 

There isn't much in the reception desk. Closer inspection shows a monitor fallen onto the ground, broken from its impact. There are two big, closed drawers on the desk as well as some papers on top of the desk. That's when you see Reilly leaning against the wall, shaking his head.

"What's wrong?" you ask, quickly scanning his body in case he got infected.

"It's these lights," he says. " They're not as bad as strobe lights, but their flickering…it's distracting."

@{madison_bathroom A door at the end of the hall swings open, and Madison steps out. Right, the bathroom. She strides up, wiping her hands with paper towel. "So what's the plan?"|Madison taps the floor plan. "Circuit breaker box is right below us."}
  
*label RecMenu
*choice
  #Examine the desk and drawers.
    *set timecount +25
    The top of the desk is full of gouges and bullet holes. A silent computer terminal lies on its sides, innards exposed by more bullet holes.

    Opening a few drawers, you see a small official-looking piece of paper—the letters almost alive with the flickering light:
    
    [i]Entry into the second basement is prohibited without previous authorization.[/i]
    
    Otherwise, the drawer is barren except for typical office supplies like staplers, pens, and sticky notes.
    *goto RecMenu
  #Open the elevator.
    *set reilly_faction %+(round(empathy/6))
    You walk over to the elevator and push the button. With the cycling power, you have to hit it five more times before the doors open. Reilly almost steps forward until you grab him by the shoulder, making him stop.

    Before you, there is no elevator, just a broken cable swaying slightly in front of you. A rather large, filthy brown rat is at the end. It screeches in surprise and then starts to clamber up the cable.
    
    Reilly pats your back. "Thanks. That would've sucked."
    *goto RecMenu
  #Scope out the left-side offices and cubicles.
    *set inspect_offices true
    You inch slightly forward, looking at the small cluster of offices to the left and cubicles in the middle. The right shows three office doors, each with a label. From closest to farthest, you make out Regional Manager, Assistant to the Regional Manager, and Liaison.

    You make out the stairs at the back, and it appears closed with shadows the farther it descends.

    Of much more concern are the cries of the infected, their bodies having a stop-motion effect in the flickering light. They appear to be in a minor tug of war, each snapping at the fleshy remains of a leg between them. As you look closer, you see the zombies stop for a fraction of a second each time the overhead lights flicker on and off. On the other side of the room stand to infected staring at the wall. They make no motion toward you and seem content to wait idly for something to happen.
    *if night_blindness
    
      With your poor vision in darkness, you have great difficulty seeing in the room.
    *goto RecMenu
  *if inspect_offices
    #Enter the left-side offices and cubicles.
      *goto SideOffices
  *if searched_side_offices
    #Leave the Research Center.
      "I think we've searched this place enough," you say to your companions.
      
      Reilly nods. "Yeah, I don't see much worth taking from here. We got a few things, so let's just head back to the Junkyard before it gets too late."
      
      "You'll get no argument from me. It's just offices and zombies everywhere. No need to risk our lives for staplers and file folders." Madison picks up a small statue of a cartoon squirrel from the reception desk and tosses it on the floor.
      *goto MissionEnd
 
*label SideOffices
*set searched_side_offices true
You move forward, the desire to explore outweighing any hesitancy at facing yet more threats. You mentally prepare since once the infected notice you, they will be upon you.
*label OfficeZombiesHub
*choice
  #Get the zombies to chase me and have the others kill them.
    *set impulse %+15
    You point Madison and Reilly to take up a point on either side of a cubicle. "Be ready to shoot them. I'm going to lead them this way."

    Madison looks like she wants to say something but only shakes her head. Reilly claps you on the shoulder and takes up his position. 

    You inhale a couple of breaths, and dart forward, making as much noise as you can. The infected fixate on you, and their cries become higher as they shamble toward you.

    You enter the room quietly at first and make your way to the first desk. With one last glance behind you to see that Madison and Reilly stand ready, you slam your hands on the metal surface of the desk and shake it violently. The two zombies on the right who are staring at the wall turn and start toward you.
    *gosub DescGrayZees
    
    *if (m_athletics >= 60) or ((m_athletics >= 75) and (night_blindness or v_impaired))
      You wait for them to draw closer and back away. "Come on this way. Let's go," you yell at them.
      
      When they open their mouths to growl, low moans fill the area. You maneuver between two close cubicles and swing around the side of a wooden desk. The two great infected switch their angle to move it you in their labored motion.
    *if (m_athletics < 60) or ((m_athletics < 75) and (night_blindness or v_impaired))
      *label ARCSneakFail
      *set p_health %-(round((100-sta)/5))
      You turn and run but bump into a desk, bending at your waist over the surface. You scramble to stand up as you hear footsteps draw closer. Shifting around the desk, you turn to see the zombies only a few steps behind, so you rush forward and cut down a small aisle made by two cubicles. Losing sight of your pursuers, you glance back for a moment and see them only ten feet away. You trip on something across the floor and stumbled to the ground. Extending your arms to brace your fall, use scuff your forearms and hands. You roll out of the way as one of the infected lunges at you, but in his lethargic state, he misses. You rise, rush around the cubicle, and run back to your companions.
      
    Bullet fire erupts around you. Reilly's first shotgun blast hits one infected in the chest, knocking it down as a second shot spatters its brains on the ground. Meanwhile, Madison drops her infected with a single shot, the bullet exiting its head and embedding itself into the cubicle wall beyond.
    *goto SearchOffices
  #Have my companions distract the zombies while I kill them.
    "Why don't you two distract the zombies while I kill them?"
    
    Madison and Reilly give each other a look before turning to you.
    
    *if (((p_type = "ranged") or (s_type = "ranged")) and ({social_skill} >= 55)) or ((p_type != "ranged") and ((s_type != "ranged") and ({social_skill} >= 70)))
      "If you think that's the best plan, I'll do it," Reilly says.
      
      Madison shakes her head, looks like she's going to say something, but slaps her hands on her legs. "I trust you."
          
      They sneak into the room and head right, close to the two zombies staring at the wall. One of the infected tilts its head, sniffing the air, and lets out a small whine, attracting the attention of the other zombie. The two then shamble toward your companions, who back away, guns drawn.
      
      "Lead them back here," you say in a hushed voice loud enough for them to hear.
      
      The two infected rotate toward your voice and come at you in a straight line.
      *gosub DescGrayZees
      
      Reilly moves to one side of a metal desk and pushes it across the linoleum floor. A long screech echoes in the room, and the two zombies switch their focus to him.
      
      Now that he has their attention, you draw out your…
      *set using_primary false
      *set ranged_matters false
      *set target_difficulty 80
      *fake_choice
        #$!{p_weapon}.
          *gosub_scene FightCode UsePrimary
          *set using_primary true
        #$!{s_weapon}.
          *gosub_scene FightCode UseSecondary
      *gosub_scene FightCode AttackResult
      As your companions lead the two zombies past the doorway,
      *if curr_type = "ranged"
        you fire your ${curr_weapon}.
        *if attack_result >= 3
          *set zombie_kills +1
          @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) The arrow strikes him in the back of the skull, and he collapses to the floor and slides on the linoleum. Taking a few steps inside the office, you notch another arrow and let it fly, hitting the other one high on the shoulder. He continues on unfazed, though your companions stay far ahead of him. Loading another arrow, you take careful aim, exhale, and release the string. The arrow speeds forward and lands perfectly in the center of his head. His body topples sideways into a cubicle|Your first shot hits the back of the closest zombie's skull, boring a hole inside of it. He collapses to the floor and slides on the linoleum. Taking a few steps inside the office, you fire again, hitting the other one high on the shoulder. The force knocks it into a cubicle wall, and you follow-up with another shot, killing it. His body knocks into the} wall, which tumbles over and darkens quickly with his blood.
          *goto KillGrayZees
        *else
          The ${curr_arrow} hits him high in the back, but he continues chasing your companions. You rush into the room and adjust your aim for your next shot. Since your target faces away, you have no risk of being attacked so you take your time and relax. @{((curr_weapon = "compound bow") or (curr_weapon = "recurve bow")) Notching another arrow, you let it fly and bury it into|Exhaling as you squeeze the trigger, you fire and open a sizable hole on} the base of his skull. Liquid rot leaks out, and he falls to the floor.
          
          *gosub MadisonKillsLast
          *label MissGrayZees
          *set reilly_faction %-(round(20-(empathy/6)))
          *set madison_faction %-(round(20-(empathy/6)))
          
          You run forward to the body of the read zombie and kick it to ensure it's dead.
          
          "Took you long enough," Madison says, growling.
          
          "If you use me as bait again, I will kill you myself," Reilly adds.
          *goto SearchOffices
      *elseif (curr_class = "spray") or (curr_class = "taser")
        *set reilly_faction %-(round(25-(empathy/6)))
        *set madison_faction %-(round(25-(empathy/6)))
        you fire your ${curr_weapon}. It hits the lead zombie who continues unfazed.
        
        "Are you trying to get us killed?" Madison shouts. "That weapon doesn't work against the infected."
        
        Reilly raises his shotgun and blasts the other zombie, killing it. Madison takes his lead and fires three rapid shots into the remaining zombie, the last one placed in his head.
        
        "If you plan to stay alive in this outbreak and especially if you plan to join me on scavenging missions, learn how to kill a zombie," Reilly says. "Next time you pull this crap will be the last time."
        *goto SearchOffices
      *elseif curr_type = "melee"
        you step into the room and swing your ${curr_weapon} at the trailing zombie. You
        *if attack_result >= 3
          *set fatigue %+(round((100-sta)/5))
          *if (curr_class = "hack") or (curr_class = "sword")
            cleave a deep gash through the back of his skull. Blood and rot leak out, and he rolls sideways before dropping to the floor.
          *if curr_class = "club"
            bash through the back of his skull in one clean swing. Blood and rot shoot from the sides of the gash, and he tumbles forwards to the floor.
          *if curr_class = "knife"
            Run up behind him and bury your knife into the base of his skull. His body shuts off, and as you yank out your blade, blood and rot leak out. You shove him over, and he falls to the floor.
          *label ReillyKillsFinal
          
          Reilly raises his shotgun and blasts the other zombie, killing it. "Sorry, I was bored running around this place."
          
          You walk into the office and kick the second zombie to ensure it's dead.
          *goto KillGrayZees
        *else
          *set fatigue %+(round((100-sta)/5))
          @{(curr_class = "club") bash his shoulder, dislocating his arm,|slice through the flesh of his shoulder,} but he continues toward your companions. Following after him, you swing from overhead and @{(curr_class = "club") bash open the top of his skull.|slam the blade onto the top of his skull.} A fountain of liquid rot leaks from the hole.
          
          *gosub MadisonKillsLast
          *goto MissGrayZees
      *else
        run up from behind the trailing zombie and
        *if attack_result >= 3
          *set fatigue %+(round((100-sta)/6))
          *if mma_style <= 1
            slam your fist
          *if mma_style = 2
            throw a sidekick
          *if mma_style <= 2
            into the back of its skull. The force pushes it forwards, but it keeps its focus on your companions. You grab its collar, swinging around, and slam its head
          *if mma_style >= 3
            lift him by his waist. Spinning, you slam him headfirst
          onto the corner of the desk. A splash of blood coats your clothing, and the infected collapses to the floor.
          *goto ReillyKillsFinal
        *else
          *set fatigue %+(round((100-sta)/5))
          Throw a punch at the back of its head. You graze him, and he keeps his focus on your companions. Following close, you grip him around the waist and spin him around to slam into a desk. As you go to lift him, you slip on the linoleum. Though you don't fall you lose your grip on the infected, who spends to attack. You throw your arm up into his neck to brace him from getting too close. He snaps his teeth together an inch from your nose.
          
          With a yell, you drive him backwards over the desk. He slams headfirst to the floor, opening a sizable gash on the top of his head. You lift and metal rolling chair and bring it down on his skull, lifting and slamming repeatedly until his body goes limp.
          *goto MissGrayZees
          
      *label KillGrayZees
      *set zombie_kills +1
      
      "Well I guess that worked. Now we just have the to eating their lunch over there," Reilly says, pointing to the two infected eating the leg in the far side of the office.
      *if (main_ro = "Reilly") or (second_ro = "Reilly")
        As he extends his arm, the long muscles flex, and you can't help but stare at his physique. When he sees you staring, he gives you a quick smile.
        
        "I think it's great that you two found each other in the Apocalypse and all, but for those of us still single, can you wait until I'm not around before you to flirt?" Madison says.
        
        Reilly chuckles. "I can't promise anything."
        
      "It's kind of fascinating how focused they've remained while they have a source of food." Madison stands on her tippy toes to see over one of the cubicle walls.
      *if (main_ro = "Madison") or (second_ro = "Madison")
        And she stretches to observe the other two zombies, her leg muscles flex, and you can't help but stare for a moment. When she catches you looking, she wiggles her butt and shoot you a quick smile.
      *goto SearchOffices
    *else
      *if leader
        *set allegiance %-10
      Reilly shakes his head. "Are you nuts? Me and Princess can kill them just as good as you can. Why would we play games and run around like chickens with our heads cut off?"
      
      "It makes no sense. We should just shoot them from here where it's safe," Madison says.
      
      Since your companions refuse to go, next you choose to…
      *goto OfficeZombiesHub
  #Sneak in closer, then attack.
    *set impulse %-15
    "I'm going to sneak in there and kill them," you say.
    
    Madison flashes a look of concern. "Are you sure? That seems risky. We could probably just shoot them from here."
    
    "Yeah, I agree with her." Reilly leans in and scans the room.
    
    "Sure, we could go in there guns blazing, and maybe we kill the two on the right. The two and back here that and start skulking around the perimeter of the room. With the flashing lights, we lose sight of them or get distracted, and one of us gets killed. With my way, only I'm at risk. I sneak my way in and killed the two on the right. Then we can deal with those in back."
    
    Reilly @{((main_ro = "Reilly") or (second_ro = "Reilly")) hangs his head for a moment. "I don't like it. I don't want you risking yourselves for us. If anything happens to you…" His voice trails off.|shrugs. "It's your funeral."}
    
    @{((main_ro = "Madison") or (second_ro = "Madison")) "I really don't want you to do this. I know it's your choice but don't agree with it one bit,"|"I voiced my opinion. It's up to you now,"} Madison says.
    
    "Don't worry, I'll be fine."
    *if (main_ro = "Madison") or (second_ro = "Madison")
    
      Madison wraps her arms around you in a tight hug. "Don't leave me."
      
      "I'll be right back."
      
      She stares at you in the eyes and shakes her head. "No, I mean I just found you. It's only been like a week. Don't leave me for good." She kisses you gently at first and then presses in harder.
      
      You hear Reilly sigh, but he says nothing.
      
      "Like I said, I'll be right back," you say with a smile to her. You pull away, and she holds her hands until they slip away.
    *if (main_ro = "Reilly") or (second_ro = "Reilly")
      Reilly moves up to you, puts one arms around your waist, and plants a kiss on your mouth. You close your eyes and enjoy his embrace. For a moment you forget where you are until a low growl from inside the room jars you back to reality. You pull back and smile at him, and he lets his arm drop by your side only to hold your hand and give the light squeeze.
      
      "I'll be back in no time."
      
      He nods and back away, bringing his shotgun around into both hands. "If anything goes wrong, you run back to us."
    
    You enter the office and make your profile as small as you can, inching toward the zombies standing by the right-side wall. Your heart thuds in your ears, and you become much more aware of every breath you make. With one last glance behind you to see that Madison and Reilly stand ready in case of emergency, you skulk along the outer wall, taking careful steps and avoiding any objects that may rattle or make noise. The two zombies on the right who are staring at the wall remain motionless. 
    *if night_blindness or v_impaired
      *set stress %+(round((100-wil)/5))
      Due to the flickering lights, you can't make out any details of them. As the overhead lights pop on and off repeatedly, you find yourself squinting and staring down at your feet to avoid hitting anything in your path and alerting the zombies.
    *if not(night_blindness) and not(v_impaired)
      In the flickering lights, you can barely make out their details, but their skin looks gray and waxy rather than yellow and decomposing. 
      
    You move along the office and find a narrow aisle made by close cubicles. 
    *if claustrophobic
      *set stress %+(round((100-wil)/5))
      The walls create a maze, and as you move along they seem to close in. You stop and take a few deep, measured breaths, knowing if you lose your cool you'll make noise and alert the two infected.
      
      *if wil >= 60
        Holding onto one of the walls, you close your eyes and meditate of an open field on a warm sunny day with the cloudless sky overhead. You take breaths in through your nose and out your mouth, relaxing with each exhalation. This method works as you feel your heart rate returned to normal. You open your eyes and continue on.
        
        *goto ContSneakOffice
      *else
        *set stress %+(round((100-wil)/5))
        Gripping the walls, you feel your heart rate race and your breathing grow shallow and random. When you feel like you should be breathing in, is you're breathing out. Everything spins, and you can't focus your eyes on anyone thing. It all swirls, and you know you can't stay here.
        
        You find the strength to retrace your steps and back all the way to the door. Madison and Reilly stand there and help you out. They hold you up as your breathing returns over the next minute.
        
        "I can't do it," you say, still panting. "We'll have to find another way."
        
        The two don't argue with you. When you regain your composure, you decide to…
        *goto OfficeZombiesHub
    *else
      *goto ContSneakOffice
      
    *label ContSneakOffice
    *if (m_stealth >= 45) or ((m_stealth >= 60) and (night_blindness or v_impaired))
      At the end of the aisle, you turn sideways and inch your way between a copier and a standing printer. The infected remain by the wall, now only ten feet away. You creep up so close you smell the rancid odor wafting from each of them. As you make your final approach, you draw your…
      *fake_choice
        #$!{p_weapon}.
          *gosub_scene FightCode UsePrimary
          *set using_primary true
        #$!{s_weapon}.
          *gosub_scene FightCode UseSecondary
      *set zombie_kills +2
      *if curr_type = "ranged"
        Raising your ${curr_weapon}, you stand at point blank range and fire.
        *if curr_class = "shotgun"
          Your first shot decimates the head of the first zombie, and as the second one rotates towards you, your shotgun sends him to eternal rest.
        *if (curr_weapon = "compound bow") or (curr_weapon = "recurve bow")
          Your arrow sticks straight through the base of his skull and lodges into the wall, hanging him there. Wasting no time to admire your shot, you draw another arrow and send the remaining zombie to his final rest.
        *if ((curr_weapon != "compound bow") and (curr_weapon != "recurve bow")) and (curr_class != "shotgun")
          Two quick shots to the back of the skull is all it takes to send both to their eternal rest.
        *goto ARCSneakZombies
      *elseif (curr_class = "spray") or (curr_class = "taser")
        Raising your ${curr_weapon}, you stand at point blank range and fire.
        *if curr_class = "spray"
          The spray shoots out in one continuous stream, splashing across the faces of the infected. They turn and lumber at you not affected by the pepper spray.
        *if curr_class = "taser"
          The barb flies out and latches on to the right one's neck. He turns and lumbers at you not affected by the electrical charge. The second one follows after him.
          
        You backpedal to evade their hands and slam your back into a cubicle wall. It falls over with you on top of it. As you try to push off to move from the zombies now falling upon you, the wall breaks in half, and you lose your footing. Another cubicle wall falls on top of you, awkwardly pinning you beneath it.
        
        Pain shoots through your left calf, and you cry out. Shoving the wall aside you see one zombie chewing on your leg, while the other meals and bites into your stomach. You slam your fist on the second one's head, but he continues his feast. His hands did inside of you and yank of flesh and entrails into his mouth.
        
        Nothing has prepared you for the pain you feel. You struggle to kick and push against the two infected, but you're too weak to fight them off. All you can do is watch in horror at the site of them eating you alive. You quickly feel woozy, and your vision fades out. You listen to the chopping and gnawing of flesh but also here footsteps all around and the sound of gunshots. Maybe it's your companions coming to your rescue, but it's far too late as you fall unconscious and fall into the darkness.
        *goto DeadEnd
      *elseif curr_type = "melee"
        Raising your ${curr_weapon}, you
        *if curr_class = "hack"
          slam the blade into the right side zombie. Blood sprays out from the sudden wound. You plant the sole of your foot on his back and yank out your weapon. As the second zombie turns, you swing and slam the ${curr_weapon} into his forehead, ending his life as well.
        *if curr_class = "club"
          slam it onto the head of the right side zombie. Blood shoots out from all directions from the sudden fracture. As the second zombie turns, you raise and slam the ${curr_weapon} onto his forehead, ending his life as well.
        *if curr_class = "sword"
          thrust the blade through the back of his skull driving the tip of the weapon into the wall. Blood sprays out from the sudden wound. You plant the sole of your foot on his back and yank out your weapon. As the second zombie turns, you pierce his forehead with the ${curr_weapon}, ending his life as well.
        *if curr_class = "knife"
          slide the blade into the base of the right ones skull. A single growl escapes his lips, and you yank out your blade and let him fall to the ground. As the second zombie turns, you pierce his forehead with the ${curr_weapon}, ending his life as well.
        *goto ARCSneakZombies
      *else
        *if mma_style <= 1
          Raising your fists, you hammer
        *if mma_style = 2
          Turning to the side, you lash out with a kick to
        *if mma_style <= 2
          the back of his skull and drive his forehead into the wall he faces. He staggers and lets out a low growl. You
        *if mma_style <= 1
          slam your fists
        *if mma_style = 2
          kick him
        *if mma_style <= 2
          over and over in quick succession until his body collapses to the ground.
        *if mma_style >= 3
          Lurching forwards, you grip the right side zombie around his legs, left him off the floor, and drop backwards. His head slams against the corner of the copier machine, breaking open and splattering the cream-colored surface with blood.
          
        As the second one turns around, you reach up, grab his throat, and slam his head against the wall. It bounces off and leaves a smear of blood. You swing him around and slam his face onto the large printer, cracking the top tray. The infected growls and reaches for your throat, but you throw him headlong into the wall. You hear a crack, and his body slips to the ground, leaking a trail of blood.
        *goto ARCSneakZombies
        
      *label ARCSneakZombies
      
      With the two zombies dead, you maneuver back through the office from the way you came and return to your companions at the entrance.
      
      "Those two on the right side are both dead," you say.
      
      "Nice. I knew you'd have no trouble," Reilly says.
      
      Madison @{((main_ro = "Madison") or (second_ro = "Madison")) gives you a quick peck on the cheek. "Awesome, baby."|rolls her eyes at Reilly. "Good job."}
      *goto SearchOffices
    *else
      Turning sideways, you slip through the narrow corridor but find it difficult to move. Each step has your body bouncing off one side or the next. When you reach the middle and spot the two infected, you lose your focus and kick a large copy machine.
    
      The two zombies on the right who are staring at the wall turn and start toward you.
      *gosub DescGrayZees
      
      *goto ARCSneakFail
  #Jury rig something to impede the zombies.
    Once the zombies catch sight of you, they will be relentless, but you can also make this work against them. You quickly scan the nearby section of the office and grab a half dozen chairs. You build an impromptu barricade out of them, Tying them together with printer cables and telephone wires. This isn't going to stop them by any means but can slow them down just enough to take them out.
    
    Reilly peers over your shoulder. "What are you doing, building a fort?"
    
    Madison scoffs. "No dummy, ${he}'s building an obstacle to slow them down, so we can kill them."
    
    "It's just like she said," you say. "This will greatly reduce our risk. If they can't reach us, they are far less dangerous."

    *if (m_crafting >= 45) or ((m_crafting >= 75) and (night_blindness or v_impaired))
      You manage to overlap the chairs enough that it creates a seamless whole without drawing the attention of the zombies. Once you're satisfied, you cup your hands and let out a yell. The two infected staring at the wall on the right turn and rush toward you, paying no heed to what is in front of them. They stumble into your barricade, caught among the chairs and web of cables and wires. As they spill to the ground, your companions shoot the prone infected, ending their nightmarish existences.
      *goto SearchOffices
    *else
      *set p_health %-(round((100-sta)/5))
      In your haste you push on one of the chairs and topple all of them over like a house of cards. They slam and rattle onto the floor. The two zombies facing the wall on the right side race toward you. Madison and Reilly fire past you, but the two zombies zigzag through the office, evading their shots. You try to retreat, but become entangled in the barricade you were making, hitting the ground with a thud.
      
      @{(madison_faction >= reilly_faction) Madison reaches down and drag you away, while Reilly |Reilly grips under your arms and pulls you out from the bottom, while Madison raises her rifle and} waits for the zombies. The two infected round a corner of the desk and lumber along, their movement much slower than zombies you've previously encountered. Once you're at the entrance to the office, your two companions joined in firing at the infected, ending their lives in a storm of bullets and buckshot.
      
      "Well that didn't go as planned," Reilly says. @{((main_ro = "Reilly") or (second_ro = "Reilly")) "It was a good idea though. How bad are you hurt?"|"Stick to building things at the Junkyard."}
      *if (main_ro = "Reilly") or (second_ro = "Reilly")
        *gosub IdealHurt
       
      Madison shakes her head. @{((main_ro = "Madison") or (second_ro = "Madison")) "It was a good idea. That office has crappy equipment and chairs, or else it would've worked. How bad are you hurt?"|"Let's just shoot zombies from now on. Every time we try to get fancy, we almost die."}
      *if (main_ro = "Madison") or (second_ro = "Madison")
        *gosub IdealHurt
      *goto SearchOffices
  #Leave the offices.
    You leave the side offices and return to the reception area at the front of the research center.
    *goto RecMenu
    
*label IdealHurt

@{(ideal >= 50)  "Just a little bump," you say. "I barely feel it."|"I guess I've felt worse," you say. "I didn't expect to hit the ground so hard."}
*return
    
*label DescGrayZees
In the flickering lights, you can barely make out their details, but their skin looks gray and waxy rather than yellow and decomposing. They move in slow, shambling steps, like they are drugged, but as they set their eyes on you, their pace increases still not at the rate of a normal zombie.
*return

*label MadisonKillsLast
When the zombie falls to the ground, you turn your attention to the last one remaining. Ten paces ahead you spot Madison raise her rifle and fire at him. Blood spurts out of three holes from the back of his body, the last one in his head. He falls over into a cubicle wall which tumbles with him.
*return

*label SearchOffices
*page_break
*set timecount +25
You wipe your brow as the fight with the zombies worked up a bit of sweat, but it is better than the alternative. 

Overhead, the lights continue to flicker on and off.
*if night_blindness
  *set stress %+(round((100-wil)/5))
  You have to take a deep breath as you try to ignore the strobe-like effect, especially when it leaves you in temporary darkness.
  
Two more infected remain, but with all of the noise in the room, neither have risen while eating the human leg. You, Madison, and Reilly creep through the middle of the office. From here you can see the two undead lower their mouths to bite with lethargic motions even more so than the other two zombies you dispatched moments ago.

"What's wrong with them?" Reilly asks in a whisper.

"Their skin is all gray. It looks so different than normal zombies, if normal is the right word." Madison wrinkles her face in disgust.

@{(science >= 45) You pause to examine them from afar. "This is quite interesting. It's almost like they've been starving and the mere presence of food is increasing their focus. They are clearly different than other infected, like they are malnourished and turned slow due to lack of energy."|"I don't know what's wrong with them, but I don't care if find out. If they're easier to kill, I hope they all turn out this way from now on."}
*if science < 45

  Madison moves in a few steps closer and stares at them for a few moments. "Maybe they haven't eaten in a few days? There gray because they're hungry. I don't know—it's just a theory. Who cares anyway. Let's just kill them and get out of this creepy place faster."
  
The three of you walk on, weapons drawn. When you're only a few feet away, the three of you dispatch the two gray zombies with ease.
*set zombie_kills +1
*page_break
With the room secure, you can take your time to explore. The center of the room is made up of cubicles divided into separate work areas by gray panels. Several of the panels bear spilled blood and deep gouges. A strong, foul odor comes from behind a bank of desks, and you discover pool of dried vomit in the center of them. In the cubicles themselves, you find little of importance other than various office supplies.
*if add_alc
  
  As you search the room, you feel a strong craving for a hard drink. You
  *if alcohol = 0
    *set stress %+(round((100-wil)/5))
    search your inventory but find no alcohol. Feeling withdrawal symptoms in the middle of a zombie-run research station is a sure way to get distracted and killed.
  *if alcohol > 0
    *set alcohol -1
    You pop open a bottle and down its contents while your companions are off looking around. The drink soothes you and helps calm your nerves.
*if add_nic
  
  *if w_cigarettes = 0
    You check your pockets for a pack of cigarettes and find nothing. Didn't you have some before? You can't believe you ran out already.
    
    "Reilly, can I bum a cigarette?"
    
    *if (main_ro = "Reilly") or (second_ro = "Reilly")
      "Sure, but it's my last one," he says and walks over to you. "Want to share it?"
      
      You nod and take the cigarette from him. He lights it up and for a short while the two of you pass it back and forth. It's a simple act and not to romantic, but while you share it with him, you feel a sense of calmness.
      *goto OfficeMenu
    *else
      *set stress %+(round((100-wil)/5))
      "Sorry, I'm out," he says and lights up one." Seriously, this is my last one and its old and taste kind of stale."
      
      You turn away from him and go back to your search, though your craving for a cigarette gnaws at you.
      *goto OfficeMenu 
  *else
    *set w_cigarettes -1
    @{add_alc After your drink,|As you search the room,} You pop out a cigarette and light it. The smooth flavor taste better than your dry mouth, and you suck in deeply.
    *goto OfficeMenu
    
*label OfficeMenu

Next you…
*choice
  #Check the Regional Manager's office.
    *set reg_manager_checked true
    *set timecount +25
    The Regional Manager's room looks like one person used it for a long time. A scenic print of the Garden of the Gods adorns the right wall, while there is a small photo of a golden retriever on the corner of the desk. You took a trip to the Garden of the Gods long ago and walked along the parks red rock corral pathways. There is a computer here, but you won't get anything off of it as it was riddled with several bullets. 

    "That's a waste of lead, if you ask me," Reilly says with a snort, pointing at the damaged computers.

    Madison shrugs. "Unless someone wanted to hide something." 

    Several documents sit on the desk. @{arc_power_restored With the light in the room restored,|When the light permits,} you see the first one is labeled "Rise in Animal Attacks." Glancing over them, you read about a rise in animal attacks several weeks before the Zeta outbreak. Researchers proposed that it was a strain of rabies, but testing proved to hold no relationship with the rabies virus.

    The second paper bears badly scrawled handwriting. Over and over, you read, "The end of days. The end of days."
    
    You search the room for a few more minutes and find a pack of cigarettes in a drawer along with a bottle of scotch.
    *if scavenging >= 45
      In another drawer you find a box containing three doses of insulin.
    *if scavenging >= 55
      Between two filing cabinets you spot an unopened bag of potato chips wedged far down.
    *if scavenging >= 65
      Opening one of the filing cabinets, you search through manila folders and find an adult magazine inside a folder labeled Old Account.
    *goto OfficeMenu
  #Check the Assistant to the Regional Manager's office.
    *set ass_manager_checked true
    *set timecount +25
    The Assistant to the Regional Manager's room is rather sterile. The walls are mustard yellow, except for the few places where bullet holes show, and several diplomas for Murphy Fleming: Master of Science, Doctor of Medicine, and Doctor of Philosophy.

    The computer in here is destroyed, bullets piercing the case, and breaking the motherboard. Below the desk, you see a small scrap of torn paper. You can make out what was part of a title:  Variation in Human—
    
    Finally, in a closet you find a number of useful items. Opening a small plastic bag a receipt drops out showing purchases at Home Depot made on May 9. Among them include a roll of duct tape, a flashlight, a set of mechanical tools, a sewing kit, and a tarp. Lying loose in the closet are bandages, packs of batteries, candy bars, a large jar of protein powder, a bottle of supplement pills, and a gun magazine, [i]Hotshots[/i].
    *if scavenging >= 55
    
      Checking around even further, you find a fake back wall to the closet. Once you pop it open you find a 3' x 3' area containing a large tin of gunpowder, a bottle of cyanide, and a small wired device.
      *if crafting >= 45
        Examining the device, you identify it as an explosive charge. If you were to bring it back to the Junkyard, you're sure you can figure out how to set it and arm it.
    *goto OfficeMenu
  #Check the Liaison's office.
    *set liason_checked true
    *set timecount +25
    Reilly enters the room first and staggers out. He coughs and doubles over, pinching his nose. "God dammit, that smells." He moves down the hallway and dry heaves.

    "I am not going in there," Madison says, backing away from the entrance. "It's so hard to take showers or even get washed down, and I am not about to get that kind of smell on me."
    
    You wrap a scarf around your nose and mouth as tightly as possible while still breathing and enter the liaison's office. A man lies sprawled across a metal desk, dried blood painting the side surface and leaving a thick stain on the tile floor. Flies buzz around his body, and maggots crawl from different holes. He bears two gunshot wounds—one to the chest and the other to the head. A nameplate on the desk reads Jacob Danvers. From the smell and decay of the body, the man has been dead for several days at least.

    A small cell phone lies near his left hand. Bending down, you see that it still has about fifteen percent battery. A small amount of text is on the screen:
    
    Outbreak confirmed. Initiate evacua—
    
    The word isn't finished, as if the sender was interrupted.

    Searching the rest of the room, you find a variety of computer parts all scattered about: a motherboard, some hard drives, memory sticks, and the like.
    *if survnet_mission
      It would take little effort to piece together a SurvNet server from the parts lying around.
      
    Under the desk you find a thermos of cold coffee and a case of bottled water. Not much else of salvageable value exists in the room.
    *if scavenging >= 45
      Something tells you to keep searching. You open every drawer of every filing cabinet and the desk, the closet, and the plastic bin in the corner of the room. Nothing. As you leave the office, you spot a pile of trash under a couch. Searching through it, you find a Dungeons & Dragons manual in good condition.
    *goto OfficeMenu
  #Examine the bodies of the four zombies.
    *set examined_gray_zombies true
    You crouched beside the corpses of the two gray zombies and spend time examining. These are unlike any zombies you've seen before. Not only is there skin a light gray color unlike the normal yellow shade of infected you've grown far to use to, but the green lesions common on their bodies are all but faded. Their teeth and nails, while long, look old and brittle and ready to fall apart. In fact the whole gray body of each infected looks like it has aged. All four of the zombies moved much slower than their yellow counterparts. Could this be a variation on the Zeta virus? Or has the same virus had a different effect on them? They seemed to focus on the human leg from which they ate. Was their grayish tint and lack of energy from malnourishment?
    *if research_virus
    
      Knowing that these zombies are unique, at least as far as you know, you take out your specimen collection kit.
      *set specimen_difficulty 20
      *set living_subject false
      *gosub_scene Part1Events AcquireSpecimen
      *set timecount +25
      
      After completing your sample extraction from the first you turn to the second. Its skin is much thicker and leathery like that you waste several needles poking it. When you cut into the skin to try for a sample of blood, none runs out. All you can do is biopsy some skin and inner tissue.
      
    You check the first two gray zombies who were staring at the wall but find nothing more remarkable about them than the other two in the room. Having gotten as much as you can out of examining the bodies, you move on to other things.
    *goto OfficeMenu
  *selectable_if (reg_manager_checked and (ass_manager_checked and liason_checked)) #Take items from the offices. (Requires all three offices were checked.)
    Looking among the items you found in all three offices, you decide which ones to take.
    *set inv_count 0
    *gosub_scene Part1Events CalcSlots
    *label OfficeSearch
    *if inv_count >= max_count
      *goto LeaveOfficeItems
    *else
      *gosub_scene CarryList
      *set item_count (max_count - inv_count)
      You have the following items: ${inventory}
            
      You can take ${item_count} more items.
      *set inv_count +1
      *choice
        *allow_reuse #Bandages (3).
          *set bandages +3
          You add the bandages to your inventory.
          *goto OfficeSearch
        *allow_reuse #Batteries (1 pack).
          *set batteries +1
          You add the batteries to your inventory.
          *goto OfficeSearch
        *allow_reuse #Candy bars (2).
          *set candy +2
          You add the candy bar to your inventory.
          *goto OfficeSearch
        *allow_reuse #Cigarettes (5).
          *set w_cigarettes +5
          You add the cigarettes to your inventory.
          *goto OfficeSearch
        *allow_reuse #Coffee (2 cups).
          *set coffees +2
          You add the coffee to your inventory.
          *goto OfficeSearch
        *if scavenging >= 55
          #Cyanide (1 bottle).
            *set cyanides +5
            You add the bottle of cyanide to your inventory.
            *goto OfficeSearch
        #Duct tape (1 roll).
          *set duct_tape +1
          You add the duct tape to your inventory.
          *goto OfficeSearch
        *if scavenging >= 45
          #Dungeons & Dragons manual.
            *set dnd_manual +1
            You add the Dungeons & Dragons manual to your inventory.
            *goto OfficeSearch
        *if (scavenging >= 55) and (crafting >= 55)
          #Explosive charge.
            *set explosive_charges +1
            You add the explosive charge to your inventory.
            *goto OfficeSearch
        #Flashlight (1 roll).
          *set w_flashlight +1
          You add the flashlight to your inventory.
          *goto OfficeSearch
        #Gun magazine.
          *set gun_mag +1
          You add the gun magazine to your inventory.
          *goto OfficeSearch
        *if scavenging >= 55
          #Gunpowder (1 tin).
            *set gunpowder +1
            You add the gunpowder to your inventory.
            *goto OfficeSearch
        *if scavenging >= 45
          #Insulin (3 doses).
            *set insulin +3
            You add the insulin to your inventory.
            *goto OfficeSearch
        *if scavenging >= 45
          #Mechanical tools.
            *set mechanical_tools +3
            You add the mechanical tools to your inventory.
            *goto OfficeSearch
          #Potato chips (1 bag).
            *set potato_chips +1
            You add the potato chips to your inventory.
            *goto OfficeSearch
        #Protein powder.
          *set protein_powders +1
          You take a jar of protein powder and add it to your inventory.
          *goto OfficeSearch
        *if scavenging >= 65
          #Porn magazine.
            *set porn_mag +1
            You add the porn magazine to your inventory.
            *goto OfficeSearch
        *selectable_if (item_count > 1) #Sewing kit (2 slots).
          *set sewing_kit +1
          *set inv_count +1
          You add the sewing kit to your inventory.
          *goto OfficeSearch
        #Scotch (1 bottle).
          *set alcohol +1
          You add the bottle of Scotch to your inventory.
          *goto OfficeSearch
        *if survnet_mission
          #SurvNet server.
            *set survnet_servers +1
            You assemble the SurvNet server from the available computer equipment in the room and add it to your inventory.
            *goto OfficeSearch
        #Tarp.
          *set tarp +1
          You add the tarp to your inventory.
          *goto OfficeSearch
        #Vitamin supplements (5 doses).
          *set supplement_pills +5
          You take a jar of supplement pills and add it to your inventory.
          *goto OfficeSearch
        *allow_reuse #Water (3).
          *set group_water +3
          You add the bottles of water to your inventory.
          *goto OfficeSearch
        #That's all I take.
          *label LeaveOfficeItems
          *set timecount +25
          You leave the other items for Reilly and Madison to pick through, and when they're done, the rest go to the next survivor who happens through this research station.
          *goto OfficeMenu
  #Go downstairs.
    You head down the steps, ignoring the dried pools of blood on the ground, though it does flake away upon contact with your shoe. The stench of rot is greater the farther down you descend. Once you reach the landing, you find yourself in a rather large work space, tables and computers in key places of the room. The computers here appear unharmed. 

    You delicately step through the room, broken glass lying all over the floor. The light flickers overhead once more, the darkness a bit more imposing without windows to let in the sunlight. At the back of the room you can make out a panel with circuit breakers, and bearing a 'Warning: Electricity' sign on it.

    In the back of the room you see several glass doors with a faint blue light inside of them. Frost indicates a freezer of some kind. Within the freezer you can make out the stiff bodies of three people. In the corner of the floor by the side of the freezer, a metal porthole suggests a room below.
    
    Reilly shuffles around the room, checking behind computers and inspecting the electronics. Madison walks up to the freezer and stands a few feet away, her mouth open and eyes wide as she stares at the three frozen bodies.
    *set count 0
    *label DownstairsMenu
    *set count +1
    *if (count = 2) and not(arc_power_restored)
      *set tag_arc_power_restored "Powered"
      *set arc_power_restored true

      At that moment, the lights flicker on full power, and black spots momentarily dance in front of your eyes.  Between blinks, you see Madison smiling back at the circuit breaker, and says, "I guess I should've warned you all."
      
      "Nice job," Reilly says.
              
      "I think I had to cut power to other buildings," Madison says with a shrug. "I'm only worried about us seeing in here. If there are other survivors running around in this facility, they can do so in the dark."
      
      *gosub ComputersBoot
      *if upstairs_door
      
        Madison rushes to the door and tries the knob. "Darn it, it still locked. I thought maybe it needed power to open." She holds her hands together and scratches her left palm furiously until she pulls away in pain.
      *goto DownstairsChoice
    *elseif count = 3
    
      *if hearing_impaired
        As you walk around the room, you notice Madison rubbing her ears. When she looks back at you, she tilts her head to the side. "You hear something, or am I just going crazy?"
      *if not(hearing_impaired)
        You hear a slight hissing sound in the room, but it's so low you wonder if you're just imagining it.
      
        "Do you hear a noise in here?" you ask.
        
      Reilly nods and stops his search. "Kinda sounds like a snake."
      *if not(hearing_impaired)
        
        "I hear it too," Madison says, her face showing concern.
    
      Reilly coughs and clears his throat. He takes a bottle of water out of his backpack, drinks a large sip, swirls it around his mouth, and spits it into a trashcan.
      
      "I have a bad taste in my mouth, too," you say. As you swallow you notice a metallic taste in your mouth.
      *if science >= 45
        Between the hissing and now the metallic taste. It can only mean one thing—nitrous oxide. Laughing gas.
        
      "I don't like this," Madison says, pacing the floor. "We should get out of here."
      *if upstairs_door
        She runs to the locked door and tries the knob with no success. She balls her hands into fists and beats the surface. With one last kick, she turns and walks away.
      *goto DownstairsChoice
    *elseif count = 4
      *set timecount +25
      
      As you move around the room, you notice a sudden relaxed feeling. The corners of your vision turn hazy, and you feel woozy—a drunk feeling. You glance over at Madison who yawns and sits on the floor. From behind, you hear the rattle of metal and turn to see Reilly fall off a chair. He catches himself before he hits the floor, but he stays down.
      
      You stumble forward and brace your hands against the wall, using it to lower yourself to the floor. Sleep is coming, and there's no way to fight it. You open your mouth to speak but lack the energy to say a word. Moments pass as you think of some way to stay awake. Reilly and Madison both lie on the floor, and you hear the sounds of heavy breathing from both of them.
      
      With your back pressed against the wall, you try once more to stand, though you're not even sure where to go once you succeed. Making it halfway, you slip and tumble back down to the cold tile.
      
      @{(wil >= 65) Just as you feel ready to fall sleep, the door to the room opens. You force your eyes open halfway. The last thing you see is a figure in a hazmat suit stepping inside.|As your eyes close, the last thing you see is the door opening into the room.}
      *goto RedChamber
    *else
      *goto DownstairsChoice
    
    *label DownstairsChoice
    
    Next, you…
    *choice
      *if not(arc_power_restored)
        *selectable_if (electronics >= 60) #Restore power to the room. (Requires Electronics 60+)
          *set tag_arc_power_restored "Powered"
          *set arc_power_restored true
          You walk over to the panel with a warning sign next to it and pop it open. Behind it you see an imposing board full of switches and wires. Some are labeled, such as Greenhouse P or Freezer, while others are blank.
            
          Normally circuit breakers are grouped together by room or area, so the switches for the freezer must be near the ones controlling the lights in the downstairs rooms. Though these switches appeared to be turned off, numerous other groups of switches are in the on position. Though you don't know if there's enough power for all rooms in this station, your only concern is power in the rooms where your companions are scavenging. You cut power in other parts of the research facility.
          
          You glance around and flick some of the switches by the freezer switch, and you see the overhead lights brighten considerably. 

          "Nice job," Reilly says.

          You shrug. "All I had to do was cut power for the other buildings."
          
          *gosub ComputersBoot
          *goto DownstairsMenu
      #Examine the bodies in the freezer.
        You approach the back freezer and lay a hand on it. You immediately pull away, the cold almost overwhelming. The interaction leaves the slight imprint of your appendage, and you notice a small plaque labeled 'Morphological Variations of Homo Mortus'.
        *if not(arc_power_restored)
        
          Though the power is off, something must be keeping the freezer cold. Maybe a backup generator?

        Two infected hang from hooks in the middle of the freezer. At first you wonder what makes these two special, and then you realize a few differences stand out between these and the other infected you've seen. Both infected on the left appear to have bony, sharp spurs erupting from the elbows and knees. Both are also a much darker yellow color, almost bronze, and their teeth are so long they are needle-like.
        
        "These look like super zombies," Madison says, standing just behind you. "It's like somebody shot them full of steroids." She chuckles a bit at her own joke.
        
        The third body appears to be an uninfected human.
        *if search >= 55
          You lean in closer for a better look and spot green freckles around a small puncture wound on the upper left arm. The teeth are slightly turned but still normal and the centers of the fingernails on the left hand are risen to a point.
          
          You point this all out to Madison.
          
          "I was just about to say something about those crazy fingernails. He obviously needs to go to a good salon." Madison holds out her own hands and looks at her nails. "Actually, I need a good manicure and pedicure."
        *if search < 55
          As you start to turn away, Madison stop you.
          
          "Wait. Do you see those little green freckles? There on the upper left arm." She points at the third frozen body.
          
          "I guess so. I see a few dots."
          
          She leans in closer to the glass. "Right in the middle of the cluster, there is a tiny red dot of raised skin. Hmm…I wonder if someone punctured that guy's skin. Oh my gosh, maybe they injected him with the virus, and he didn't change yet."
          
          @{(morality >= 50) "I hope no one would do that. Who would be terrible enough to make a human guinea pig?"|"So someone was experimenting on this guy?"}
          
          Madison shrugs and a moment later she shivers. "The thought of someone injecting that poor man with the virus makes my skin crawl. And really, I know I am not the most empathetic person, but that's just horrible."
        *goto DownstairsMenu
      #Examine the tables.
        One table has two computers on them, but these appear to be unharmed.
        *if not(arc_power_restored)
          Both PCs are off, and you doubt that will run if you turn them on. With the fluctuating power, they wouldn't remain on for long. 

        Two tables have animals splayed out and dissected. One appears to be a coyote, while the other is a cougar. Their skin is folded backwards and held down with metal prongs, and their organs have been removed, though you see no evidence of them around. No blood exists in the cadavers, and the flesh and underlying muscle and tissue are a deep red. No signs of decay are evident, indicating they have been embalmed. For some strange reason, their canines seem to be especially elongated. 

        The last table has an infected, also splayed and dissected. You glance at the separated head and notice a clean, round hole through its head. The wound is so clean and so perfect, it must have been made by a machine.
        
        Nothing else remarkable stands out about the corpses.
        *if research_virus
          *set embalmed_zombie true
          You are unsure if the zombie's tissue can be useful for your research, but you take a specimen for examination later.
        *goto DownstairsMenu
      #Investigate the porthole.
        You step over to the porthole, a metal circle that looks like a hubcap with the wheel on top of it. You turn the wheel and find it moves rather easily. You spin it clockwise, around and around for what seems an eternity. Realizing there must be some other kind of mechanism to open the porthole, you give up turning the wheel and step back
        
        "It doesn't open?" Madison asks, looking it over.
        
        "The wheel just spins but nothing happens."
        
        Reilly chuckles. "If it's like a bank vault, you need to unlock it before turning the wheel. The wheel is just like a doorknob."
        
        Madison shakes her head. "Go figure. The one time he's valuable relates to bank robbery."
        
        You'll need to find the key to opening the lock before accessing the porthole.
        *goto DownstairsMenu
      *selectable_if (arc_power_restored) #Use the computers. (${tag_arc_power_restored})
        *goto ARCPwerRestored
      #Go back upstairs.
        *set upstairs_door true
        As you walk over to the door, Reilly reaches it before you. He turns the lock, but it barely moves. He grabs it with both hands, and all it does is rattle. Moving his body in closer, he strains to twist the knob but nothing happens.
        
        "Damn it. Are we really locked in here? Am I an idiot and don't know how the open the door all of a sudden?" Reilly says.
        
        When he backs away, you try the door and find it's locked.
        
        Madison moves over to join you two. "So we're trapped?" Her voice shakes, and she runs her hands through her hair.
        
        @{(ideal >= 50) "We're going to be okay. There has to be another way out out of here or a way to unlock the door."|"We need to get out of here. No one is coming to save us, and were not going to last forever in here."}
        
        Reilly leans against the wall right by the door. "Let's not lose our heads. We'll figure this out. I'm not going to die of starvation in some stupid research center."
        *goto DownstairsMenu
        
*label ComputersBoot
With the power restored, there is the whir of fans and slight beeps as both computers power up. Knowing it will take a few minutes before you can do anything with the computers, you glance once more at the tables, and the light doesn't make the gruesome sight any better. 

Reilly shakes his head. "Damn government spooks. What good did any of this do?"

Before you can answer, the two computers give a final beep, and you see they are ready for use. 
*return

*label ARCPwerRestored
The first computer appears to have files on animal/zombie research, while the second one is password protected.
*label ARCPoweredHub
*choice
  #Look at the animal/infected research computer.
    You find several unprotected files, all documenting research into animals and substances which bore some resemblance to the zombie virus. 
    *label ARCCompMenu
    *choice
      #Entry on 'zombie ants'.
        The so-called zombie ant bears some interesting similarities to infected humans, but these are superficial at best. The cause in ants is fungal in origin; once an ant comes into contact with the spores, fungal cells will spread throughout the body, and releasing chemicals which hijack the ant's nervous system and brain, making it rather docile until death. Perhaps we could find a chemical means which would make a human infected just as tame and controllable.
        *goto ARCCompMenu
      #Entry on 'zombie alligators'.
        While not mammalian, it would be prudent to look into what is dubbed 'zombie alligators'. The origins of this isn't viral, but rather chemical. It was discovered that the alligators inhabited a lake which caught the run-off of pesticides, killing off most fish but one. With only one food source, the alligators consumed this fish but with one problem: the fish contained a chemical which inhibited the absorption of thiamine. The lack of thiamine led to degeneration of the brain as well as auto-immune disorders. Though the origins of the virus in humans is unknown, did it arise from pollution?
        *goto ARCCompMenu
      #Combat drugs.
        Numerous incidents going back several years were intended to create the 'perfect soldier'. Unfortunately, these end results were suboptimal at best. True, some people were discovered to have increased tolerance to pain, but the side-effects outweighed this one advantage. Organ failure, hallucinations, paranoia, and numerous other conditions could result, ultimately showing little need for future study.
        *goto ARCCompMenu
      #Shut down the computer.
        *goto ARCPoweredHub
  #Look at the password protected computer.
    You look at the screen, and there is a title at the top which reads 'Project Revenant' while at the bottom a cursor awaits the entry of a password.
    *choice
      *selectable_if (electronics >= 60) #Hack the system.
        As you try to override the system, the screen goes dark, and the machine powers down. When you try to reboot it, however, the computer stays off, keeping its secrets to itself.
        *goto PasswordPCMenu
      #Input password.
        There is a brief pause, and for a moment you think the computer got stuck, and then it goes on to the next screen. There are some files simply labeled 'Entry' followed by a number, and it appears some numbers are missing.
        
        *if search_shooters_nest
          You enter the password you saw in the shooter's nest in Greenhouse Pinky—20Mb13. The computer screen changes to a list of options.
          *label PasswordPCMenu
          *choice
            #Entry 1.
              The CDC is throwing as many resources as they can at containing this virus, but I'm afraid it is a losing battle. Quarantining doesn't work, especially if someone already was infected. At first, they may experience flu-like symptoms, but these will grow worse as time goes by…and when the virus takes total control, it has many potential vectors left open.
              *goto PasswordPCMenu
            #Entry 2.
              The outbreak is happening much faster than anticipated. Our superiors have notified us that we need to be ready to leave at a moment's notice. Though nothing is officially being said, some of the more senior researchers were taken aside, and haven't reported back.
              *goto PasswordPCMenu
            #Entry 7.
              This might be idle speculation, but for some reason the way the infected tear into their victims brings to mind the cattle mutilations of the 1960's. Was the virus engineered by the military, and somehow got loose? Further probing was met with a 'Don't waste your time on conspiracy theories.'
              *goto PasswordPCMenu
            #Entry 10.
              I think I've reached a breakthrough. Nowhere near a cure, but a possible way to slow down the rate of infection. 

              The rest of the entry is blank, and there are no further entries after this.
              *goto PasswordPCMenu
            #Shut down the computer.
              *goto ARCPoweredHub
        *else
          You try various passwords but after three failed attempts, the computer locks you out.
          *goto ARCPoweredHub
  *if survnet_mission
    *selectable_if ((arc_power_restored) and (survnet_servers > 0)) #Set up a SurvNet server. (Requires power and a SurvNet server.
      You look around for a place to set up the SurvNet Server. Power won't be a problem, but you don't want to let it just be out in the open where any passing zombie might stumble over it. You settle on a small niche you see near the circuit board, and place it in there. After a few couple seconds, it connects with an outside signal.  You could try to contact Deter, Julianne, or leave.
      *label ARCSurvNetMenu
      *choice
        #Contact Deter.
          You click the icon for DeterChat, and after what seems to take forever, it opens. "Hey," Deter says, "Thanks for putting up another server. There are so few of us left, I thought even you were gone."

          "I'm tougher than I look," you reply honestly, "so how are things in your neck of the woods?"

          "Not good," Deter admits, "We're still on the move, but safe locations are becoming harder to find. Some survivors are banding together, but now they're fighting each other. I can't stay on long, but is there something you need?"
          *set count 0
          *label DeterHub
          *set count +1
          *if count = 3
            
            "Listen, I still have a few things to do. Thanks again for all your help," Deter says and closes the chat window.
            *goto ARCSurvNetMenu
          *choice
            #Warn him about the Silverthorne Militia.
              "Speaking of groups to avoid, try and avoid one that calls itself the Silverthorne Militia," you say.

              "Alright, but why?" he asks.

              "Simple. They wanted to take some members of our group, probably to ensure 'good behavior'. They threatened us, and they've already killed other survivors," you answer.

              Deter grimaces. "Modern day marauders, then."
              *goto DeterHub
            #Forward the information from the research station.
              You send the information you've compiled, and Deter's eyes widen in surprise as he peruses it. "Just where are you?" he asks, as if suddenly noticing you are in a building of some kind.

              "At a research facility that the CDC was also conducting secrete experiments on," you say, "And before you ask, they weren't taken out by infected."

              "Hmm," he says noncommittally, "Alright, I will be careful with this information."

              *goto DeterHub
            #Tell him about the two zombie samples you found.
              "Listen," you say, "It looks like the CDC discovered two, I don't know what you would call them, but two different types of infected, definitely different from what we've seen."

              "Speciation," Deter mutters. "What changes did they see?"

              "One of them appears to be really tough to hurt, extra thick bones. There is a skull here where it was shot numerous times, but only one bullet got through. The other had long protrusions from the knees and elbows," you reply.

              "In other words, don't get close," Deter surmises.
              *goto DeterHub
            #"That's all for now."
              "Nice chatting with you. Good luck," Deter says and breaks the connection.
              *goto ARCSurvNetMenu
        #Contact Julianne.
          When you click open the window to talk to Julianne, she is lounging back on a recliner, eyes closed in a somewhat meditative stance. 

          "Everything alright?" you ask. 

          Her eyes open, and she smiles. "I've been better. With all the running, well, Deter tried to convince me that it was time to quit smoking." She pulls out a cigarette, lights it up, and sighs. "Let's just say that it isn't working." Then she squints. "Are you in some kind of slaughterhouse?"

          "Close. The basement of an agricultural research center. One where the CDC was running experiments."

          "The CDC? Then they were behind this…"

          "They were aware of it, but there is no evidence they created it," you say. "Not that I'm saying they couldn't have. But if they did, it isn't here."

          "Oh," Julianne says. "The information will come to light, I swear it."
          *set count 0
          *label JulianneHub
          *set count +1
          *if count = 3
            
            Suddenly, you can hear gunshots in the distance, and Julianne says "I have to go. Be safe," and the screen goes dark once more.
            *goto ARCSurvNetMenu
          *choice
            #"I agree—you should curb your smoking."
              "I agree with Deter," you say. "You really should cut back on smoking. If nothing else, it would help you outrun the zombies."

              Julianne shakes her head, "If they got that close, they would be biting my bony ass anyways."
              *goto JulianneHub
            *if like_females
              #Flirt with Julianne.
                *set julianne_like 1
                "Uh," you hesitantly say. "I know this probably sounds stupid…and I hope this isn't weird…but I've been thinking a lot about you lately."

                "Oh?" Julianne says, leaning forward.
                *if julianne_faction >= 50
                  "Funny, I've been thinking the same thing."

                  "Good. If it isn't obvious, but I really like you, and…"

                  "Shh," Juliana whispers. "I get it." She presses two fingers against her lips, kisses them, and then places their tips on the screen. You return the gesture for a few more minutes of silence.
                *if julianne_faction < 50
                
                  "If it isn't obvious, but I really like you, and…"
                  
                  "Sorry but the world is ending. Let's keep this platonic."
                *goto JulianneHub
            #Ask where she is.
              "Do you know where you are?" you ask. "Maybe we can meet, and…"

              "Sorry," Julianne says quietly, "I honestly don't know. We've been running so often, and with GPS down, I couldn't tell you where we are."
              *goto JulianneHub
            #"I have to go."
              Julianne says, "Me too. Be safe," and the screen goes dark once more.
              *goto ARCSurvNetMenu
        #Leave the SurvNet server.
          You leave the server running so you can add to the SurvNet network.
          *goto ARCPoweredHub
  #Leave the computer desk.
    You step away from the computer desk.
    *goto DownstairsMenu
    
*label RedChamber
*page_break
*set timecount +100
*set captured_arc true
Your eyelids flutter, and you wake up to flashing red lights, like those on top of a police car. You yawn and stretch. Once the lights fade and your vision clears, you see a gray ceiling over you. Sitting up, you hear the squeak of a metal cot and stiff mattress. The room has sparse furniture: a small desk on the left-hand wall, a series of shelves on the wall at the head of the bed, and a wooden chest at the foot of the bed. A small alcove contains a toilet, a floating sink, and a narrow, standing shower. There are two wooden doors, and a vent hangs high on the wall between them.

You hold a fuzziness in your head, but you feel fine otherwise. Whatever gas was being pumped into the room has left no side effects. You stare up at the vent which reminds you of the same one in the room were you last saw your companions.

Standing, you spot a small speaker and round camera lens high in the corner of the room.

"Hello. I'd say good morning, because you just woke up, but it's not morning."

The voice comes from the speaker, and the camera turns to point at you. The tone suggests a male voice, but the pitch sounds higher and could be female.

"Welcome to the red chamber. I'll explain that later. Don't worry, you are completely safe. For now you're locked in here, but we can see about letting you out real soon. Before we go on, let me just introduce myself. My name is Murphy, which is kind of an odd name, but my parents named me after my uncle who I sadly never met. My mother always used to say, 'boy, you look just like your Uncle Murphy, but not when he's drunk.' I didn't understand the joke until I was older and saw pictures of him sober and inebriated. Thank God I didn't look like drunk Uncle Murphy."

As he laughs over the intercom,
*if short_fuse
  You feel your temperature rise and heart race. This guy is holding you prisoner and acting all casual like nothing's wrong?
  *if wil >= 65
    
    If you let your temper take over, you may say the wrong thing, which could be very bad for you. For now you keep your emotions in check.
    
  Before he starts talking again,
you say…
*choice
  *selectable_if (not(short_fuse) or (wil >= 65)) #"Nice to meet you, Murphy. My name is ${firstname}." He seems like a nice guy, and I don't know for sure he's the one responsible for meeting in this room.
    *set morality %+15
    *set truth %+15
    *set ideal %+15
    *goto PersuadeMurphy
  *selectable_if (not(short_fuse) or (wil >= 65)) #"Pleasure to meet you. My name is ${firstname}." I'll get on his good side and convince him to help let me go.
    *set truth %-15
    *label PersuadeMurphy
    "It's really nice to meet, he says. "I thought you might be mad at me like those other two who were with you. Reilly has a real foul mouth, and Madison can be quite bossy and whiny. Their anger is premature. I know how this looks but I'm not really keeping you here as my prisoners."
    
    "My friends are tired and hungry. That means they're both irritable. It's like you said earlier, you're doing this to help us keep us safe. I appreciate it, and when my friends calm down, they will too."
    *if m_persuasion >= 45
      *set murphy_faction %+(round(empathy/6))
      
      "That's great. I really just want to be friends with you all. I know my actions may be questionable but as the old saying goes, the ends justify the means."
      *goto MetMurphy
    *else
      *set murphy_faction %-(round(20-(empathy/6)))
      Your voice wavers at the end.
      
      "It sounds like you're feeding me a bunch of lines I want to hear. Look, I know how this looks. Some guy you've never met knocks you out, and you wake up in a strange room. I know I have to gain your trust, but I will."
      *goto MetMurphy
  #"I don't know what this is all about, but you need to let me out right now."
    *set impulse %+15
    *set truth %+15
    Murphy sighs over the intercom. "That's not possible just yet. I want to let you out, but I know I don't have your trust."
    
    *if m_leadership >= 45
      *set murphy_faction %+(round(empathy/6))
      "Trust is earned. The first step is to give something and to accept something in return. If you let me out of here, I'll come meet you and hear you out. That's my promise. Actions speak louder than any words. So go ahead and open the door and tell me where you are, so we can meet."
      
      "I…I…I want to. I want to show you I'm a good guy and I have your best interests at heart. I'll let you out soon, but I just have a few things to do first."
      *goto MetMurphy
    *else
      *set murphy_faction %-(round(20-(empathy/6)))
      "You don't have my trust because you locked me in a room and separated before my companions. I don't know what kind of game you're playing, but it ends now. Let me out of here right now, or…or…" You stumble over your words, flustered by the situation.
      
      "You're in no position to boss me around," Murphy says, his voice raised and intense. "Everyone is always bossing me around. Well not anymore. They're all gone, and you know who's left? Me. They're all gone and I'm…" His voice cuts out.
      *goto MetMurphy
  #"Where are my two companions?"
    *set impulse %-15
    A long stretch of silence follows your question.
    
    "They are here and they are safe. You don't have to worry about them."
    
    "I'm  @{(ideal >= 50) worried about them but know they are two capable people. I would just like to know where they are and when I'll have a chance to see them.|very worried about them. We are all dealing with an outbreak, the infected, starvation, bandits, and the town of other problems. How am I not supposed to be worried about them?"}
    
    "Pretty soon, you'll be able to see them," he says.
    *goto MetMurphy
  #"Listen to me carefully. Let me out now, and I'll go on my way. If you keep me here, I will get out, I will find you, and I will kill you."
    *set morality %-15
    *if m_intimidation >= 45
      *set murphy_faction %+(round(empathy/6))
      Murphy takes a quick breath. "Wow, I don't know what to say to that. You gave me goose flesh. You don't need to kill me. I swear I'll let you out of here soon. Please be patient, which I know is a lot to ask."
      *goto MetMurphy
    *else
      *set murphy_faction %-(round(20-(empathy/6)))
      Murphy breathes hard into the microphone. "I've been bullied in my life and endured a variety of threats. I don't want to start off our relationship with intimidation. Really I just want to be friends."
      *goto MetMurphy
    
*label MetMurphy

You hear a clang of metal through the loudspeaker, and sound cuts off. A moment later, a high pitched siren sounds, forcing you to cover your ears with your hands. It doesn't last long, and when it ends, the intercom crackles.

"Sorry about that. Something showed up on one of my monitors that I need to check out," Murphy says. "I'll be back in five, and we can get to know each other a little more."

*set count 0
*label ChamberHub
*set count +1

*if broke_camera and not(murphy_fixed_camera)
  *goto MurphyFixesCamera
*elseif (delusions and not(delusion_chamber)) and (count >= 3)
  *set delusion_chamber true
  *set fatigue %+(round((100-sta)/5))
  A voice comes from behind you—the left side wall of the room.
  
  "${firstname}, are you in there?" It's Ray's voice.
  
  You move closer to the wall, crouch, and speak in a whisper. "I'm here. How the hell did you get here?"
  
  "I followed you, Reilly, and Madison right after you left. I can't believe we're all trapped in here."
  
  "I can't believe it either. Have you tried to escape? Any idea how to get out of here?"
  
  @{(morality >= 50) "Are you stupid? Sorry, you don't have to answer that. I know you're stupid, otherwise you'd use your head and realize I'm talking to you. If I tried to escape or knew how to get out of here, I wouldn't be talking to you right now.|I've been trying to escape ever since I got here. I just want to get us all out of here.} But I did figure out one thing. Under the bed is a small area where the floor meets the wall that looks weak. I've been digging at it, and I'm making some progress. If I can get it worn down, I can break through the wall and get out of the room."
  
  "Okay, I'll go look and see if there's a weak area in my room. I'll talk to you later."
  
  You slide along the floor and under the bed, facing the back wall. Sure enough, some of the grout between the tiles appears old and worn.
  *if spare_tools
    You take out the tools you found and use two screwdrivers
  *if not(spare_tools)
    *set p_health %-(round((100-sta)/5))
    Without any tools, you have to rely on your hands and fingers
  to dig through the wall. You dig and dig, clearing away the dust and debris as it falls. Black and white particles flake off, and even when chunks of the wall drop off, you see no light behind it—only more wall. Your hands ache from the constant motion, and your @{spare_tools fingers spasm from gripping the tools for so long|fingertips leave blood on the wall.} You don't know what Ray was talking about. Maybe in ${ray_his} room, there's a weak wall. This one is solid.
  
  You abandon this approach for escape and climb out from under the bed.
  *goto ChamberChoices
*elseif (ptsd and not(ptsd_chamber)) and (count >= 3)
  *set ptsd_chamber true
  *set timecount +25
  The lights in the room flicker, and a loud rattling echoes through the room. You spin in a circle and search for the source of the noise, sensing something is often in the room. The rattling intensifies for a few moments and then reaches a peak level, like you're next to the sound of automatic gunfire. It shakes the walls, and the lights shut off, leaving a constant buzz.
  
  Your heart pounds, and your breathing turns rapid. The air in the room turns thick, and your skin grows hot, so hot it's bathed in sweat almost instantly. Something tells you to run, but you're locked inside of this room—a room that's rattling and shaking.
  
  *if wil >= 65
    You want to get away from the sound, thinking it indicates a danger far worse than the noise. But it's just noise and flashing lights. What you're feeling is nothing more than fear, and the only danger revealed is the danger of your own body shutting down.
    
    You sit on the floor in the middle of the room with your back pressed against the foot of the bed. You tuck your knees up to your chest, wrap your arms around your shins, and rest your chin on your knees. What is really going on? What could be causing this sound? A generator? Of course the flickering lights indicate a power outage, which caused the generator to kick in. Nothing here can cause you harm. The room won't be exploding, and the building isn't falling down.

    The clamorous noise continues with long and steady strumming of gears and machine parts. You block out the sound, slow your breathing, and clear your mind. Your body relaxes, and your heart rate returns to a normal pace. You wipe your arms of sweat and find yourself chuckling at your loss of composure and fear over the scary noises of the simple generator.
  *if wil < 65
    *set stress %+(round((100-wil)/5))
    The room spins, and the noises turn to one throbbing echo in your ears. Dizzy, you drop to your knees on the floor by the end of the bed. Your chest tightens. Your vision goes narrow. You fall to your side, knees tucked to your chest, and you roll on the floor holding the back of your neck with your forearms pressed your ears to block out the sounds.
    
    An image forms in your mind—the battle of the hill. Gunshots firing from all around you. The infected coming at you swarm after swarm, their hands reaching for your throat. Their moans filled your ears. There was no escape. Everywhere you turned was death and blood and the smell of gunsmoke. You hear the cries of your companions, and you find yourself shouting until you pass out.
    
    Your eyes blink you awake, and you're lying where you fell to the floor in a puddle of your own sweat. The noise in the room has stopped, and the overhead lights shine with their normal intensity.
    
    You sit up and take a few minutes to regain your composure. There are things to do. You're no closer to escaping this room, and you still have work to do.
    
    Next, you…
  *goto ChamberChoices
*elseif hacked_speakers and not(listened_to_murphy)
  *set listened_to_murphy true
  *set timecount +25
  
  You hear a crackling over the loudspeakers, but this time it's different. Sounds flow through it much louder, and you hear ambient sounds in the background. At first it's just whistling and then a percolating like someone is brewing coffee. Then you hear Murphy's voice coming in like you were standing in his room.
  
  "Okay now, where was I? Right, coffee. I have such a headache. Just need some caffeine. Maybe I'll have a grilled cheese for lunch. Oh wait, maybe leftover beef stew. I'm not really in the mood for beef though."
  
  You move over to the speakers and listen as more sounds come through: lights footsteps on tile, the hum of a refrigerator, clicking of switches.
  
  "That Reilly is a tough one. I'm not so sure if he's ever going to be a friend. I really hate to cut him loose. Same with the girl, though I'm guessing she's more afraid than she's letting on. I don't know where I'm going to get a chocolate cake, but if that's what she wants, I'll figure it out. I saw cake batter in the pantry, but I'm no baker. I'm sure I can find a video or walk-through. YouTube is down, but I've got Wikipedia downloaded."
  
  More sounds come through, like sliding doors and the clatter of silverware.
  
  "I'm not making any progress with Laurel. She eats a lot so I'll probably have to cut her. I don't know about ${firstname}. We haven't talked enough. Maybe ${he} will be my friend. God knows I'm getting tired of talking to myself, but that's the only thing keeping me calm right now."
  
  A buzzer sounds, and Murphy says, "Damn, that was ten minutes already? I should've timed out that experiment better."
  
  You hear a sliding door open, then footsteps, and then the door slides shut.
  
  Murphy is gone from the room, and so you…
  *goto ChamberChoices
*elseif count = 2

  Next, you…
  *goto ChamberChoices
*elseif count = 5

  *goto MurphyReturnTalk
*elseif count >= 6
  *set murphy_alive false
  *set reilly_killed_murphy 1
  
  A loud banging comes from the hallway, and you hear the sound of heavy footsteps. You rush to the door just as it slides open, and you spot Reilly and Madison on the other side.
  *if (main_ro = "Madison") or (second_ro = "Madison")
    
    Madison rushes into your arms, hugs you close, and kisses you hard. You melt in her embrace, but your survival instincts kick in, and you pull away.
    
  *if (main_ro = "Reilly") or (second_ro = "Reilly")
  
    Reilly rushes inside and places a hand on your shoulder. "Are you okay? Are you hurt?"
    
    "I'm fine." You give him a quick kiss.
  "What about Murphy? We should get out of here."
  
  Reilly scoffs and scratches his nose with the barrel of his revolver. "Nah, that asshole is out of the picture."
  
  Madison lights up with a mischievous smile. "You're not going to believe this, but Reilly tricked him and escaped."
  
  "The oldest trick in the book—I just played sick and got him in my cell, I mean chamber. One shot to the chin knocked him out." Reilly speaks as if he's telling you about a boring day of work, not about an escape in the fistfight.
  
  "So you left him unconscious?" you ask.
  
  "Nope, I wasn't about to let him wake up and hit us with sleeping gas or some other bullshit. I killed him."
  
  A woman stands in view of the entryway. She's tall and full figured and has a dark brown complexion. She has straight hair to her shoulders and offers a warm smile. "Hi, I'm Laurel.
  *if talked_laurel
    I think we spoke through the wall."
    
    "Hey Laurel. Yep, it's me, ${firstname}."
    
    She puts her fist out for a bump. "I feel like were already friends. It was so good talking to you."
    
    You bump her fist. "It definitely helped pass in time."
  *if not(talked_laurel)
    I was in the chamber on your right." She puts her fist out for a bump.
    
    You bump her fist. "So you're another captive of Murphy?"
  
  Madison backs into the hallway and looks to her left. "It's great to have introductions and all, but we should go. We don't know if there are others here."
  
  Reilly follows her out. "${firstname}, follow me. I know where all your stuff is, and you're going to want to see the control room we found. Come on."
  *page_break
  *goto ARCControlRoom
*else

  Next you…
  *goto ChamberChoices

*label ChamberChoices
*choice
  #Call out for Reilly and Madison.
    *set person_on_right true
    Taking a deep breath and yell at the top of your lungs. @{(madison_faction >= reilly_faction) "Madison! Reilly!"|"Reilly! Madison!"}
    
    Calling out over and over, you hear nothing in return but your voice bouncing off the walls. You spend a solid minute repeating their names. When you start to give up hope, you hear a loud bang against the wall on the right. You rush up to it and press your ear to the cold surface. You call out again, and this time here a long scraping sound like metal on stone. It must be one of your companions, or maybe it's another survivor who was taken captive?
    *goto ChamberHub
  *if person_on_right
    #Communicate with the person in the room on the right.
      *set talked_laurel true
      *set timecount +25
      You move to the wall where you heard the scraping before and pound your hand on the flat surface to get the attention of whoever's on the other side. After a few minutes, you hear a knocking coming through. It moves along the wall diagonally until it grows too low to hear. You follow the direction of the knocks, but they are lost behind a cabinet sitting low on the floor. You pop open the two doors and find it empty. More taps come from behind it. Moving the cabinet aside, you see a small vent the size of a deck of cards laid side-by-side.
      
      A whisper comes through the vent. You get down on your hands and knees and move in as close as possible.
      *if hearing_impaired
        Even with your hearing aids, you can't pick up enough of the sound to hear the person on the other side.
        
        "I'm sorry," you say. "I can't hear you. Talk louder."
        
        Someone shouts through the vent, but you still can't decipher the words. The volume is much louder but it all sounds garbled to you. Trying for a few more minutes, all you can offer is a one-sided conversation."
        
        "My name is ${firstname}. I've been taken prisoner by a man inside here. I need your help to get me out of here."
        
        Since you can't hear the other person, that's the best you can do for now.
        *label LeaveSmallVent
        
        You stand and return the cabinet in front of the vent to avoid any suspicion should Murphy spy inside your room again.
        *goto ChamberHub
      *else
        *set chat_count 0
        
        "Hey, is someone there? Please help me. Some weird guy has taken me prisoner."
        
        You don't recognize the voice, but it's high and almost squeaky.
        *choice
          #"My name is ${firstname}. I've been taken prisoner too."
            *set truth %+15
            *set ideal %+15
            *set told_laurel_name true
            "You too? Well damn," the voice says. "My name is Laurel. I can't believe this. I've been stuck in here for hours."
            *goto TalkToLaurel
          #I find out more about them before I reveal any information about myself.
            *set impulse %-15
            "I'm here. Who are you? What's your name? How did you get here?"
            
            "Okay, like, you're throwing a lot of questions," the voice says. "My name is Laurel. I was getting chased by the infected and ran into this research station. I met this guy named Murphy who told me I'd be safe here and then locked me up in this room."
            *goto TalkToLaurel
          #I say nothing and let the other person talk for a while. I don't know if I can trust them.
            *set ideal %-15
            "Hello? Hellllllloooooooooo? I know someone's there. I hear you breathing. My hearing is on point," the voice says.
            
            You listen for a few more minutes and still remain quiet.
            
            "Fine, if you're not going to talk, then I will. My name is Laurel, and I'm trapped here. I'm a good person and smart and funny and right now, bored as hell. If you just talk to me, maybe we can keep each other company."
            *choice
              #I'll talk to her. She sounds like a good person, and we may be able to help each other.
                *set morality %+15
                *set ideal %+15
                "Hello. My name is ${firstname}."
                
                "Well, hey. Alright, nice to meet ya. I'm so glad to have someone to talk to."
                *goto TalkToLaurel
              #I'll talk to her. I'll try to get whatever information I can out of her to gain my freedom.
                *set truth %-15
                "I'm here. I've been taken prisoner too."
                
                "Well, hey. You can talk! It sucks you're in there, but I'm not gonna lie, I'm glad to have someone to talk to."
                *goto TalkToLaurel
              #I'm not talking to her. I don't trust her and can get myself out of here.
                *set ideal %-15
                You don't know this person and don't automatically trust everyone you come across. For all you know, she could be working with Murphy to get information about you.
                *goto LeaveSmallVent
  #Examine the vent between the two doors.
    *set examined_vent true
    The vent lies in the wall eight to ten feet high and looks similar to the room with the freezers where you lost consciousness. You pull over a chair from the desk and stand on it to gain a better view.
    
    Since the chair has wheels on the bottom, you step onto the middle of it and feel the chair roll in all directions with the slightest bit of pressure or movement.
    *if m_athletics >= 60
      With agility and grace you bring up both feet and balance in the center without much strain or difficulty.
    *if (m_athletics < 60) and (m_athletics >= 45)
      *set fatigue %+(round((100-sta)/5))
      You hop onto the center of the chair and wobble from side to side, almost falling into you brace yourself against the wall with both hands. It takes great strength to hold yourself in position, and you squeeze your legs and stomach to stay upright.
    *if m_athletics < 45
      *set fatigue %+(round((110-sta)/5))
      *set p_health %-(round((100-sta)/5))
      You step up with once foot and dangle the other to keep your balance. The chair shifts beneath your weight, and you tumble off, landing on your hands and knees. You groan in pain and sit on the floor until the throbbing stops. You wait for a few moments and try again. Though you're able to find your balance this time, the strain on your legs and back deplete your energy, forcing you to jump off. There's no way you can stand on the chair to get a better view of the vent.
    *if m_athletics >= 45
    
      Now that you have a closer view, you can see that the vent is made of metal with a thin grate behind it. Dust and dirt cover this side, and intricate spiderwebs filled with balls of trapped insects lie between the vent and the grate. A light flow of air comes into the room. At first you pull away, sparked by a memory of the room from before, but you don't smell the same metallic odor.
      
      Just as you are ready to step down, you notice one of the screws holding the bottom corner is missing. The other corners screw is held in loosely. With enough pressure or a tool you may be able to pry it open.
    *goto ChamberHub
  #Inspect the camera and intercom.
    *set inspected_camera true
    *set timecount +25
    With the camera and the speaker so high in the room, you need some way to reach for a proper inspection. You slide the only chair in the room into the corner and stand on the seat which puts you a foot below the camera. The chair has wheels on it, which makes it difficult to hold your balance.
    *if examined_vent
      At least the camera is not as high as the vent above the door.
    You manage to find your balance and keep from falling while you inspect the two devices.
    
    The camera looks like a typical eye-in-the-sky with a rounded screen that sees the entire room. However as you look further, you see a small camera lens sitting inside the cover. Currently, it is aimed at the bed where you sat while talking to Murphy.
    *if search >= 55
      Though it is very hard to see, beneath the camera is a shining red light. It must turn green when it's recording.
      
    The speaker is a toaster-sized, two-way device, so Murphy can hear inside the room, and you can hear his voice. It may be possible to reverse the speaker's wiring to eavesdrop on his room. 
    *goto ChamberHub
  *if inspected_camera
    *if spare_tools and (tried_to_destroy_camera and not(broke_camera))
      #Use the tools you found to destroy the camera and speaker.
        Now that you've found tools, you bring the chair back under the camera and speaker and stand high in the corner of the room. You balance on the seat
        *goto UseToolsCamera
    #Break the camera and speaker.
      *set tried_to_destroy_camera true
      You're not giving Murphy the opportunity to spy on you. Standing on the chair, you reach up and move your hands around the cover to find hand holds. The smooth surface wraps around the entire camera with no breaks or seals. The speaker is no better. It's cemented to the wall with nowhere to grab.
      
      *if spare_tools
        You remember finding the tools hidden in the closet
        *label UseToolsCamera
        *set broke_camera true
        and take out a Spackle knife. You use the thin edge to cut into the plastic cover and pry it off. Once you have the cover off, you slice into the wires with the Spackle knife, shredding all of them and destroying the camera. You repeat this on the speaker and destroy it as well.
        *goto ChamberHub
      *else
        Without a way to tear down either device, you step off the chair, pick it up, and swing it at the camera. One of the legs strikes the cover and bounces off. The chair leg looks bent from the impact, though it still usable. If you continue to use it to hammer the camera, you'll likely break it.
        
        *if (m_athletics >= 60) or (crafting >= 60)
          *set broke_camera true
          *set fatigue %+(round((100-sta)/5))
          You put the chair back down under the camera speaker and stand on the seat. Stepping up, you @{(m_athletics >= crafting) push in on the cover with all of your might. Your arms strain and you grunt and groan as you apply as much pressure as your hands allow. Your legs shake as they balance on the chair and you feel sweat drip down your back. Finally, you feel crackling beneath your fingers. With a few hard shoves, the cover pops and splits in two. You pull your hands away to a avoid being cut and let the pieces of the cover drop to the floor. With the cover broken,|feel around the outside of the cover until you find two areas of minor depressions in the surface. Placing your thumbs in the small grooves you apply a bit of pressure and twist. It takes a bit of shaking back and forth, but the cover turns a few degrees. Readjusting your hands for leverage, you apply more pressure and now the cover turns a quarter of the way. Now that the cover is loosened, you keep turning it until it comes off.} you grab the camera and twist it until the metal breaks, wires snap, and the lens fractures.
          
          Holding onto one of the long shards of metal from the broken camera, you use it @{(m_athletics >= crafting) to tear into the speaker until the whole device is ripped apart.|like a screwdriver and dismantle the speaker.}
          *goto ChamberHub
        *else
          You stare at the camera and speaker, frustrated. There's nothing else in the room that you can use to break down the spying devices so you abandon this whole idea.
          *goto ChamberHub
    *selectable_if (not(broke_camera)) #Wire the speaker so I can hear inside Murphy's room. (Requires a working speaker)
      *set timecount +25
      If you can hear inside Murphy's room, you may be able to find out some useful information about and use it to escape this room.
      
      You prop the chair in the corner of the room and balance yourself on the seat. The speakers cover it is difficult to pry off but you find seam close to where it meets the wall. After a few minutes of running your hand along the seam, you find a small indentation—a weak point. Once you figure out a good angle, you apply pressure and pop open the case.
      
      Inside is an assortment of tangled wires that look like black spaghetti noodles all mixed up in a bowl.
      *if (electronics >= 50) or ((electronics >= 40) and spare_tools)
        *set hacked_speakers true
        You've seen speakers and intercom systems before today, but this is a very old system. You're not even sure why there are so many wires, though you theorize that parts of the speaker have been replaced and hacked and jury-rigged many times by incompetent workers who failed to remove nonworking parts.
        
        You identify the main bundle of working wires connected to the active circuit board. Stripping the insulation off the bundle, you find the wires dedicated for receiving sounds.
        *if spare_tools
          Having a grounded pair of pliers helps immensely.
        You repurpose underused wires and connect them to the circuit board. A few sparks flip out
        *if spare_tools
          but they hit the pliers and not your hands.
        *if not(spare_tools)
          *set p_health %-(round((100-sta)/5))
          and burn your fingertips.
        You hear a buzz coming from the other end of the system. You're fairly confident you can now hear through the speaker.
      *if electronics < 50
        You have no idea what you're looking at or where to get started. Without any knowledge of electrical systems, you have no business trying to redirect the sound. After a few more minutes of studying the speaker, you give up and place the cover back over it.
      *goto ChamberHub
  *if false_area
    #Climb through the false area in the back of the closet.
      You return to the closet and crawl on the floor close to the weak board in the back. You rap your knuckles around the area to determine what's solid and what's hollow. Once you're sure of the weakest part, you turn your body around, press your feet on the wood, and push in. The wood bends and breaks in the middle, and you keep forcing your feet through to clear the way.
      
      When your legs have gone through, you spin your body back around so your head faces the hole you've just created. It's dark inside, and with the light shining in from the chamber, you can only see a few feet into the space. You only have a foot of space on each side of you, but you will fit. Of course, you have no idea where this area leads.
      
      You climb inside of the hole. Warm, musty air greets you, and a stronger odor of rotten wood pervades. Crawling no more than five feet, your hands push through a spider's web, and though you can't see anything, you feel a bundled insect squished beneath your palm. You run your hand along the wood to clean it off, and then you continue through the hole.
      
      *if claustrophobic
        When it starts to narrow, you stop and take a few deep breaths. "I'm okay. I'm okay," you repeat over and over. Though you're not moving, you swear the walls are closing in. You can't catch your breath, and a pounding starts in your chest. You're going to blackout and be stuck inside this coffin-like space. Will anyone ever find you? Will you die here? Will the insects eat your corpse?
        
        *if wil >= 65
          Though you want to crawl out and end this torture, you must continue. Your companions are counting on you, and escape is the way to your survival. You shake your head and squeeze your eyes shut for a few moments to clear away the thoughts freezing you in place. When you open your eyes, you're ready again, and all of the doubts and worries are pushed away like the cobwebs in your path.
          
          *goto ChamberPassage
        *else
          *set stress %+(round((100-wil)/5))
          You can't do it. You don't want to pass out in the tomb. You crawl out backwards, heart racing out of control. Across the short distance, you wiggle your body until your feet pop back into the closet. Your torso soon follows, and you collapse to the floor.
          
          You don't know how long you're lying there. When your body relaxes and your heart rate returns to something close to normal, you leave the closet and sit on the bed for a few minutes while the room stops spinning.
          *goto ChamberHub
      *else
        *label ChamberPassage
        *set timecount +25
        The path remains straight for at least twenty feet, and then takes a sharp right for a short distance and ends at a wooden wall. The space widens, and as you feel your hands along the surface, you follow it higher. Strands of light weave in from broken portions and provide illumination. 
        *if night_blindness
          *set p_health %-(round((100-sta)/5))
          Though some light leaks into the room from beyond the wall, your poor vision in the darkness has you nearly blind. When you try to stand, you bang your head on the corner of the short wall of concrete. You grit your teeth and pain and stumble against the plywood.
        *if not(night_blindness)
          There's enough room to stand, and when you do, you can see you are in a small alcove.
          
        You listen at the wall and hear nothing from the other side. @{(impulse >= 50) Though you're not the most patient person, you wait long enough to be certain the area beyond the wall is clear.|Being a patient person, you wait until you're confident there's no one on the other side of the wall.}
        
        You prepared to bash through the wall as quietly as possible not to alert anyone else in the research facility, assuming you are even in the research facility. For all you know, Murphy could've brought you somewhere else. When you feel the wall and touch along the seams of the slab of plywood, it lifts straight back with only a minor amount of force.
        
        Entering the room, you flip a wall switch and light the area. Large drums and canisters of chemicals stand around the small supply room. You read the labels: Perchloric acid, Acetic anhydride, Ethyl acetate, and maybe a dozen more.
        *if science >= 60
          Many are toxic or even flammable.
        For now you leave them all behind and exit the room.
        *goto ChamberHallway
  #Open the door on the left.
    *set searched_closet true
    You turn the doorknob on the door on the left and find a closet with numerous shelves and drawers. You take your time to go through all of the contents. There are blankets and washcloths, medical scrubs and clean underwear, toothpaste and toiletries. Everything looks new.
    *if search >= 70
      *set false_area true
      
      Still searching, you find a small section of weak wood in the back of the closet on the bottom. Pushing it in various places, you see a small false area covered over. Running your hand inside, you can tell it's deep and extends much farther than you can see. You imagine this room used to be much larger but was sectioned off, and this hole in the wall is a remnant of the construction that had been overlooked. It may even be large enough for you to climb into the space.
    *if scavenging >= 45
      *set spare_tools true
      
      Just before you finish searching, your knuckles brush on the underside of a drawer and feel something different about the surface of the wood.
    *if (search < 70) and (scavenging < 45)
    
      Spending quite a while searching every nook and cranny of the closet, you find nothing else of note.
    *goto ChamberHub
  #Open the door on the right.
    You move to the door, try the knob, but it doesn't twist. This must be the main door that's locked from the other side. You study it for several minutes and can see no way to pry it open. Kicking or pushing it does nothing. It's a solid door that's not opening from the side.
    *if spare_tools
      
      You take out needle-nose pliers from the tools that you found and try to pick the lock. Even pliers won't open the lock. The tumblers must be tied to something magnetic or electric and impervious to being picked.
    *goto ChamberHub
  *if examined_vent
    #Pry open the vent.
      If you can open the vent, you may have a chance to climb through it and escape the room.
      
      You balance on the chair and 
      *if spare_tools
        *label PryWithTools
        use the tools to unscrew the bottom screws from the grate over the ventilation shaft. It's been closed for so long the grate is rusted shut, so you wedge in a Spackle knife and screwdriver to pry it open. It takes considerable effort, but after a few seconds of solid pressure, the grate pops open.
        *goto CrawlThroughVent
      *elseif str >= 60
        dig your fingers through the grate barring your access to the vent. With a deep breath, you pull with all of your might. Your fingers strain and stretch under the pressure. The metal digs into your hands, and you grunt in pain while struggling to yank the grate free. It's been closed for so long it's rusted shut, but after a few long, arduous moments, the bottom screws pop and the grate opens.
        *goto CrawlThroughVent
      *else
        *set tried_vent true
        grab the grate, dating your fingers through the little holes. As you apply pressure, you cry out in pain as the metal cuts your skin. You try to position your body in multiple ways for the best leverage, but nothing works. The grate is too rusted to pull it off.
        *goto ChamberHub
    *if tried_vent and spare_tools
      #Pry open the vent with the tools you found.
        Now that you found tools, you feel more confident in being able to access the vent.
        
        You balance on the chair and
        *goto PryWithTools
    *if count > 2
      #Rest until Murphy returns.
        *set fatigue %-(round(sta/5))
        You're not sure what else to do, and you've been struggling for days without much food and rest, at least not what you're normally used to before the days of the outbreak. Instead of trying to figure a way out of here, you rest on the bed and conserve your energy.
        
        You don't know when you fell asleep, but your eyes close and pop open again when you hear the crackle of the speaker go on.
        *goto MurphyReturnTalk
    
*label TalkToLaurel

You hear movement on the other side of the vent. Moments pass, and Laurel speaks again. "Sorry, I was just trying to get comfortable. I don't know how long we have until Murphy comes back. I've been here for six hours or so. He'll leave me alone for an hour or so but always comes back."
*label LaurelChat
*set chat_count +1

*if chat_count = 1
  Starting the conversation with Laurel, you ask…
  *goto LaurelQuestions
*elseif (chat_count = 2) and (empathy >= 55)
  As Laurel answers your questions, you can tell by her demeanor, the tone of her voice, and some quality deep inside of the language she uses that everything about her is authentic and genuine. In fact, you sense no deception in any part of what she's telling, like she does not have the capacity to lie.
  *goto LaurelQuestions
*elseif chat_count = 5
  Footsteps move past your door, and you hear the distinct sound of whistling though it fades quickly.
  
  "You hear that? I think Murphy's coming back. Hurry up, hide the vent. I'll talk to you later. Be safe, my friend," Laurel says.
  *goto LeaveSmallVent
*else
  Next you ask…
  *goto LaurelQuestions
  
*label LaurelQuestions
*choice
  #"What does Murphy want with us?"
    Laurel laughs before answering. "I wish I knew. He says he just wants to be friends. He keeps telling me how lonely he gets and now that the world is coming to an end he's afraid to be left all alone. I don't mind talking to the guy but damn, how you gonna lock me up and then tell me you want to be friends? I know a lot of people that got locked up, and I'll tell you right now it wasn't their friends who arrested them."
    
    "He told me the same thing—that he wants to be friends and that he's doing this just to keep me safe."
    
    "If he really wants to be friends, he has a funny way of showing it. He's the kind of friend who asks to borrow your car and then totals it on the way to the casino, then goes to the casino and loses all the money they borrowed from you. That's why I don't talk to Cassandra anymore."

    "Wait, who's Cassandra?"

    "Just this nasty ass girl who lived in my neighborhood. Sorry, I took another path in the conversation."
    *goto LaurelChat
  #"Do you know if Murphy has any other prisoners here?"
    "I know there's a young girl in the room on the right," Laurel says. "She does not want to talk to me. She seems very privileged, like I'm supposed to get her out. Girl, I'm tryin' to get myself out first. This world does not revolve around you."
    
    "Did the girl tell you her name?"
    
    "No. She wouldn't tell me anything. Honestly, we only talked for maybe two minutes before Murphy came back. I had to hide the vent and run over to the bed like I was sleeping."
    *goto LaurelChat
  #"Have you tried to escape?"
    *set laurel_escape true
    Laurel lets out a big laugh. "Hell yeah, I tried to escape. I tried to climb up to the vent above the door, but my big booty won't fit through, and that small chair with the wheels was like trying to ice skate. Do you know any black hockey players or figure skaters? No. You know why? 'Cause we have the sense not to go on ice. And I have the sense not to climb this big body on a chair with tiny ass wheels."
    
    "Besides the vent, have you tried anything else?"
    
    Laurel clicks her teeth. "I tried to pick the lock on the door, tried to ram the door, kick the door, and yank the door knob off. None of that worked. I tried to overflow the toilet just to get Murphy to come in the room. He pumped a bunch of that silly gas into the room. So that didn't work. I've been trying to be really nice to him, and hopefully he lets his guard down. If I can get him in the room, I know I can kick his ass. Shoot, he will be crying for his mama. Locking me up…" Her voice fades, and she babbles a few things under her breath.
    *goto LaurelChat
  #"Where are you from?"
    Laurel takes a deep breath and lets it out slowly. "I grew up in Atlantic City close to the boardwalk. It wasn't the greatest place to be. Everyone thinks with all the casinos that it must be a rich place. Wrong. Sure, the casinos have money, but outside of that, there are a lot of poor people living there."
    
    She pauses for a moment, and you can tell that she hasn't talked about this in a long time. "When I was eight years old, we moved out here to Colorado to live with my uncle on his farm. For the longest time he raised crops like wheat and barley and sorghum. I didn't like it at first. I was a city girl and didn't know nothing about grains and tending crops. The ocean was thousands of miles away in every direction. Eventually I grew to love it, except for killing animals. I never got used to that.
    
    "I was fortunate to live with a mother who taught me the value of education, and my aunt always pushed me to do better for myself even when I wanted to hang out and party and smoke weed like the rest of my friends. I still got down like that from time to time but not as much as I wanted to." She breaks out into laughter but eventually calms down. "I went to nursing school and got my degree. Eventually, I went back and got my Masters degree and even became a nurse anesthetist. Shocked the hell out of all my family. So how about you? Where you from?"
    
    You tell her…
    *choice
      #Where I lived. I trust her.
        *set ideal %+15
        *set truth %+15
        *label LaurelLive
        *set laurel_faction %+(round(empathy/6))
        "I lived in
        *if v_loc = "city"
          Nightfall.
        *if v_loc = "suburbs"
          Chipper Ridge.
        *if v_loc = "country"
          Stodgy Farms.
        It's not too far from here."
        
        "That's what's up," she says. "I've never been there myself. There's a lot of places I never visited. I hope I still get the chance."
        *goto LaurelChat
      #Where I lived, because it doesn't matter now. I'm never going back there.
        *set ideal %-15
        *goto LaurelLive
      #Colorado and keep it vague.
        *set honor %-15
        *set laurel_faction %-(round(20-(empathy/6)))
        "I've lived in Colorado most of my life," you say.
        
        "Where in Colorado?" she asks.
        
        "Here and there."
        
        Laurel clicks her teeth. "Damn, you're not going to tell me where you lived? You think I'm gonna break in your house? That's okay—be shady. You're only hurting my feelings a little bit."
        *goto LaurelChat
      #Somewhere on the East Coast, so she believes we have a connection.
        *set truth %-15
        *set laurel_faction %+(round(empathy/6))
        "I grew up in New Jersey too," you say.
        
        "Oh damn, where at?" she asks, her voice raised in excitement.
        
        You think fast, knowing she moved from Atlantic City at a young age. You remember hearing about a town in northern New Jersey and think it may throw her off. "Edison, New Jersey. It's up near New York.
        
        "Well damn, we're practically cousins," she says.
        *goto LaurelChat
  #"What did you do before the outbreak?"
    "I was a nurse anesthetist, which basically means I took care of people during operations. The anesthesiologists don't do as much as you think. We're the ones keeping people alive in there. At the time of the actual outbreak, I was in surgery with two different patients on the tables. They started an evacuation procedure, but I stayed with my patients. They were not going to die on my watch. I wheeled them into a back room where they keep surgical supplies and locked us in there."
    
    "So did they survive?"
    
    Laurel scoffs. "Hell yeah they survived. I know what I'm doing. They were both having fairly minor procedures but were pretty weak after that. We shared the little bit of food that was in the storage room, and when we left, the one ditched me. He ran right out of the hospital and left me behind. The other patient, Mr. Cooper, was a little old man from Colorado Springs. A few of his family came to get him, but as they were all leaving, we got overrun by a pack of zombies. I couldn't believe it. I kept him alive and fed him and got him to his family, and he didn't survive for more than fifteen minutes after they showed up." Laurel takes a deep breath and sighs. "So what did you do before the outbreak?"
    *fake_choice
      *if bank_robber
        #"Robbed banks."
          "Oh, for real? Well damn. I got a straight up criminal next to me. If you're so good about breaking in the vaults, get us out of here."
          
          @{(ideal >= 50) "I will do my best."|"Robbing banks is easier than breaking out of places like this."}
      *if college_student
        #"I'm in college."
          "Oh for real?" Laurel says. "What's your major?"
          
          "$!{college_degree}."
          
          *if college_degree = "biomedical sciences"
            *set laurel_faction %+(round(empathy/6))
            "Well damn. Good to know someone with experience dealing with viruses. Got any ideas about how to stop this Zeta from destroying the planet?"
            
            @{(ideal >= 50) "I'm going to do my best. If I can find any scientists who I can work with, I'll try my hardest to help them."|"It won't destroy the planet—it will just destroy us. All of civilization."}
            
            @{(ideal >= 50) "That's what's up. I'm a nurse and not used to working in a lab, but I'll help too."|"Real talk. I always hated driving in traffic and used to joke how I wish we could get rid of half the people on the road, but I never thought it would come true."}
          *if college_degree = "business"
            "No offense but that's probably not gonna help us much now. Maybe if we all survive past this outbreak, I'll hit you up for some help starting a new business, because there will be lots of opportunity in the new world."
          *if college_degree = "communications"
            "Now I can see why you're such a good talker."
          *if college_degree = "computer science"
            *set laurel_faction %+(round(empathy/6))
            "Can't you rig something to get us out of here?"
            
            "I haven't tried yet but that's a good idea."
            
            "I've got lots of good ideas but haven't been able to get any of them to work just yet."
          *if college_degree = "psychology"
            "Well I'm going to need a lot of therapy once we get out of here. And probably more if we stay in here. I just need therapy."
          *if college_degree = "education"
            "So you are studying to be a teacher? I respect that. That probably doesn't help as much right now, but I respect it."
          *if college_degree = "history"
            "They say history is the best teacher, so maybe you can think of something from the past that can help us to get out of here."
          *if college_degree = "graphic arts"
            "That sounds cool, but it doesn't really help as much now."
          *if college_degree = "engineering"
            "Well maybe you can engineer our way out of here."
          *if college_degree = "undecided"
            "Undecided? Well I'm undecided forever if I don't get out of here."
      *if commander
        #"I'm a captain in the Army."
          "That's what's up, a real commander leading troops. You got a battalion waiting outside you can call to help us out of here?"
          
          "No, we have to rely on ourselves at the moment."
      *if con_artist
        #"Believe it or not, I'm a professional con artist."
          *set laurel_faction %+(round(empathy/6))
          "Well damn, can't you con your way out of here and take me with you?"
          
          "That idea has definitely crossed my mind."
      *if cop
        #"I'm a police officer."
          "Lucky for you I'm one of the few black folks who get along with the police. I don't know how that can help us get out of here, but it's a nice thought."
      *if (doctor or nurse) or social_worker
        #"I'm a ${profession} at St. Matthias."
          *set laurel_faction %+(round(empathy/6))
          "Oh for real? I did a rotation at St. Matthias maybe five years ago. That place is way more about politics and serving egos than taking care of patients. No offense—I'm sure that's not you."
      *if engineer
        #"I'm a civil engineer."
          "Well maybe you can engineer our way out of here."
            
          "I haven't tried yet but that's a good idea."
      *if hacker
        #"I'm a hacker."
          *set laurel_faction %+(round(empathy/6))
          "Can't you rig something to get us out of here?" Laurel asks.
            
          "I haven't tried yet but that's a good idea."
          
          "I've got lots of good ideas but haven't been able to get any of them to work just yet."
      *if homemaker
        #"I'm a homemaker."
          "Oh. I respect that. Doesn't really help us get out here, but I respect that."
      *if infantry
        #"I'm an infantry soldier."
          "Oh for real? Do you have a group of special forces specialist ninja warriors coming to rescue us?"
          
          "Unfortunately we are on our own."
          
          "I thought you'd say that, but a girl can dream."
      *if laborer
        #"I'm a general laborer."
          Well maybe you can figure a way to break out of here."
            
          "I haven't tried yet but that's a good idea."
      *if medic
        #"I'm an Army medic."
          *set laurel_faction %+(round(empathy/6))
          "I dated an Army medic when I first started nursing school. He got me interested in medicine. He was dumber than a box of rocks, so I figured if he could do it, I could do it. I just hope you have some of your army buddies, to break us out."
          
          "Unfortunately we are on our own."
          
          "I thought you'd say that."
      *if mma
        #"I'm an MMA fighter."
          "Oh for real? I really don't like fighting. I've seen too many people get hurt, especially getting in the head until they got a concussion. Too violent for me. But I bet you're a bad ass. If you can get face-to-face with Murphy, kick his ass for me."
      *if movie_star
        #"I work in films and TV."
          "Oh for real? Like acting?
          *if told_laurel_name
            Hold up, I know your name. Oh damn, I didn't know…You are in that movie I saw a month ago. Damn, Cassandra ain't never going to believe this. If we get out of your can have your autograph?"
            
            "Sure, as soon as we're free."
          *if not(told_laurel_name)
            I never heard of you. Were you in anything I've ever heard of?"
            
            Since you gave Laurel a fake name, you don't want to blow your cover. "Probably not. I did a lot of local theater."
            
            "That sounds cool. I tried out for Grease in high school but our racist drama teacher wouldn't cast me, 'cause he said Rydell High had no black kids."
      *if scientist
        #"I'm a research scientist."
          *set laurel_faction %+(round(empathy/6))
          "Well damn. Good to know someone with experience dealing with viruses. Got any ideas about how to stop this Zeta from destroying the planet?"
          
          "My plan is to work on it @{(ideal >= 50) when we|if we ever} get out of here."
          
          "Oh we will. Now we have even more reason to get out of here."
      *if teenager
        #"I'm a student at Chipper Ridge High School."
          "Oh for real? You sounded young but I wasn't trying to come off like an old lady. I'm only thirty-two but that's like double your age. Damn, now I feel like an old lady."
      *if wrestler
        #"I'm a professional wrestler."
          *set laurel_faction %+(round(empathy/6))
          "Oh for real? I used to watch wrestling with my uncle, but he called it rasslin', 'cause he's from the country. I'm not even into violence like that but I enjoyed watching it. They always had good storylines like on soap operas."
          
          "There is a lot of that in wrestling."
          
          "Keeps people coming back every week. My uncle loved it and he didn't like many things."
      *if custom_prof
        #"I'm a ${profession}."
          "Oh for real? Well I'm sure you got the skills to survive this outbreak to the end or wherever it goes from here."
      #"I did odd jobs."
        "Oh for real? Well I'm sure you got the skills to survive this outbreak to the end or wherever it goes from here."
      #"What does it matter now?"
        "I guess you're right. I'm so used to asking people what they do for a living, but now I guess the real question is—what can you do to survive this outbreak?"
        
    "It's really great to meet you, Laurel."
    *goto LaurelChat
  #"What do you know about Murphy?"
    *set laurel_murphy true
    Laurel grumbles and it turns into a sigh. "He's a weird dude. Most of the time he just wants to know if I need anything, well, besides getting out of here. He asks if I like the food he brings and other things to make me comfortable. He asks about my life and what I hope happens with the outbreak. He never really asks about anybody I've been surviving with and never tries to find out if I have supplies stored somewhere outside of here. I've known a lot of people in the world, and I've known a lot of liars. He's not a liar. Or he's the Meryl Streep of survivors, because he can act. I don't think he's acting though. I think he's a lonely man who's afraid of surviving the outbreak all by himself. Part of me actually feels sorry for him. Part of me wants to kick his ass. Actually most of me wants to kick his ass. You don't put people through this kind of imprisonment and try to make friends out of them."
    
    "Has he told you anything about his past? Anything that I can use when I talk to him?"
    
    "He's afraid. He tells me he's always been afraid. He goes to a psychiatrist and takes medicine for anxiety. He mumbled something about it once. At one point when we were talking, he started getting all nervous. Come to think of it, that might be when you showed up on his monitors. It was like he was having a panic attack. If I didn't want to bust out of here and lock him up, I would try to help him. He needs to feel safe, and that feeling is in short supply anymore."
    *goto LaurelChat
  #"If I get out of here, I'm going to free you."
    *set laurel_faction %+(round(empathy/6))
    "Thank you for saying that." She clears her throat and lets out an exaggerated moan. "I don't know why I'm crying. It's just good to hear someone I just met cares. I haven't had much luck finding nice people during this outbreak. It's been so stressful. Besides that, I barely ate or slept in three days before I got here. Being trapped in this room is the first real break I've had. It's really screwed up. I get why Murphy is so afraid to be alone. He just went about it the wrong way. It's nice to know you got my back, and trust me I got yours."
    *goto LaurelChat
  #"We should stop talking now in case Murphy comes back."
    "You're right. He will be back soon," Laurel says. "I'll talk to you later, my friend. Be safe."
    *goto LeaveSmallVent
    
*label MurphyFixesCamera
*set murphy_fixed_camera true
*set murphy_faction %-(round(20-(empathy/6)))

As you take a moment to rest on the bed, you hear clicking noises coming through the main door into the room. A bullhorn crackles, and use a voice.

"${firstname}, it's me, Murphy. Why did you break the camera? I'm trying to be your friend, and you're destroying property. I need to come in. Please stay on your bed while I work. You'll be fine there."

As Murphy opens the door to come inside your room, you…
*choice
  #Stand right by the door and prepare to fight.
    *set impulse %+15
    You move to the right side of the door and prepare to attack Murphy as soon as it opens. He may have a weapon or may be a formidable fighter, but this is your best shot of escape and possibly the only chance you'll get.
    *goto KnockoutGas
  #Sit in the corner near the broken camera and pretend to be crying.
    *set truth %-15
    You rush to the corner of the room far from the door, sit in the fetal position, and fake crying. If you can make him believe you're injured or distraught, you may convince him to let you go.
    *goto KnockoutGas
  #Fake an injury to lure him close to me, so I can catch him off guard.
    *set truth %-15
    You lie on the floor near the bed and clutch your stomach to fake an injury. If you can draw him close and hit him with a surprise attack, you may have a shot at overwhelming him.
    *goto KnockoutGas
  *if laurel_escape
    #Remembering Laurel's escape attempt, I wrap wet cloth around my face to protect myself from the knockout gas.
      *set protected_from_gas true
      You @{searched_closet rush to the supply closet for a small towel|strip off a pillowcase from a pillow on the bed} and run it under the faucet to wet the cloth. When you're satisfied that it's completely soaked, you wrap it firmly around your mouth and nose like a mask. Hopefully this is enough to protect you from the gas.
      
      A hissing sound comes from the top of the room followed by the side walls. You wait to feel for any of the effects of the knockout gas: the dizziness, disorientation, the metallic taste. While you feel a little of all of it, you're wide awake. Your heart is pumping fast, and you can almost feel the rush of adrenaline. This may be your only shot at escape and you need to make it count.
      
      As the door opens, you…
      *choice
        #Knock him unconscious, so I can then escape.
          *gosub JumpMurphy
          *goto RipOffHood
        #Restrain him so I can question him.
          *set impulse %-15
          *set murphy_restrained_bed true
          *gosub JumpMurphy
          *goto RipOffHood
        #Kill him.
          *gosub JumpMurphy
          swing him around. He slams head-first into the opposite wall. The crown of his head smashes into the concrete and he falls to the floor, motionless.
          *goto KillMurphy
          
*label JumpMurphy
You stand to the side of the doorway and prepare for the fight of your life. The door slides sideways into the wall, and in walks a figure in a hazmat suit. You hear a muffled whistling from under the hood, and the figure holds a device that resembles a TV remote control.

You wait for him to pass, And he doesn't notice you standing behind him. You grab him from behind by the collar of the suit and
*return

*label DescMurphy
He's a chubby man with a noticeably round face, clean-shaved with thick eyebrows that add to the whole crazy scientist façade.
*return

*label RipOffHood
yank off the hood.
          
"What? No!" he shouts. Even with those few words, you recognize Murphy's voice.

You hold him from behind and swing him around into the middle of the room, tossing him hard to the floor. He lands with a grunt and slides. As he tries to push off the ground, you plant a foot between his shoulder blades to hold him in place.

"Please, no," he shouts, his voice slower and drawn. He squirms and struggles to stand, but you hold him while the knockout gas does the rest. It doesn't take long, and though you feel woozy and fatigued, Murphy goes unconscious.
*page_break
*if murphy_restrained_bed
  Murphy lies on the bed in the red chamber, bound by cords you found in a supply closet nearby. You waited for the knockout gas to dissipate before waking him up. He looks so comfortable on the bed, his dark brown hair all tasseled and his cheeks puffed out as he snores.
  *gosub DescMurphy
  *label WakeMurphy
  
  You walk over to the sink and fill the cup with water. Moving back to the bed, you decide it's time to wake Murphy up and get some answers.
  
  *if morality >= 65
    "Murphy, wake up," you say.
  *if (morality < 65) and (morality > 35)
    You grab his shoulder and shake it violently. "Hey, wake up."
  *if morality > 35
  
    He grunts and shakes his head, eyes fluttering. "What? Where am I?"
  *if morality >= 65
  
    "Would you like a sip of water?" you ask, offering him the cup.
    
    "N—no." He shakes his head and struggles against the cords that bind him.
  *if (morality < 65) and (morality > 35)
    
    You drink the water from the cup, crush it, and toss the trash onto the floor.
  *if morality <= 35
    You stand over him and pour the cup of water onto his face. He sputters and coughs, twisting his head from side to side to avoid the stream. His eyes pop open, and his face turns dark red.
    
    "What? Please don't hurt me."
    
    "Shut up, moron." You drink the rest of the contents of the cup, crush it, and toss the ball into his face. It bounces off his cheek and lands on the floor.
    
    "Where am I?"
    
  "You're in the red chamber where you had me locked up."
  
  He looks around the room, and his eyes widen and a sense of realization crosses his expression.
  *if search >= 55
    His body shakes, especially his hands which show uncontrollable tremors.
  *if empathy >= 55
    He displays fear in all definitions of the word.
  "You messed up everything. I only wanted to be your friend."
  
  With Murphy restrained to the bed, you begin to question him…
  *set chat_count 0
  *goto QuestionMurphy
*else
  *set murphy_unconscoius true
  With Murphy out of the way, you rush into the hallway. Once outside of the room, you rip the wet cloth off your face. With the first breath of fresh air, you begin a coughing fit which has you doubled over for a few moments. You don't have time for this—others can be in this facility ready to hunt you down.
  *goto ChamberHallway

*label QuestionMurphy
*set chat_count +1
*choice
  #"Why did you really capture us?"
    Murphy sighs. "I watched all of you from the moment you came into the ARC. You have to believe me—all I ever wanted was to help you three. After watching you, I knew you wouldn't just accept my help or be my friend or stay with me here."
    
    "So you captured us?"
    
    "I just figured that if I kept you safe and fed you and showed you what a good person I am, you would grow to like me over time."
    *fake_choice
      #"If you would have introduced yourself and offered to help us, we could've worked together. You didn't have to take us prisoner."
        *set ideal %+15
        "I couldn't take that chance," he says, shaking his head. "So many people in my life have disappointed me. When I saw you three come into the ARC, I had something I could give you all and show you how valuable I can be. I was afraid if you met me, you would be like all the others. You may be friendly but you would leave me here, all alone."
      #"You didn't treat us like people, you treated us like pets."
        *set murphy_faction %-(round(20-(empathy/6)))
        "I can't control how you see it, but you're wrong. I treated you all with decency and respect."
        
        "By taking away our freedom?"
        
        "By giving you a safe place to live with all of your needs met," he says, raising his voice. "You may not believe me now, but I know what I was trying to do."
      #"What you did was wrong. You have to realize that."
        Murphy shakes his head. "It wasn't wrong. I have been trying to help you all, but you just won't let me. All three of you are either yelling at me or threatened me or trying to figure out ways to break out. You just wouldn't what me show you how I can take care of you all."
      #"You're not a good person. You are sick and disturbed."
        *set ideal %-15
        *set murphy_faction %-(round(25-(empathy/6)))
        Murphy shakes his head. "You can make fun of me all you want, but I know I was just trying to help you all. You wouldn't let me, and now you've ruined everything."
      *if murphy_restrained_bed or murphy_restrained_floor
        #"That's the stupidest thing I ever heard, and trust me, you're going to pay for your actions."
          *set murphy_faction %-(round(20-(empathy/6)))
          Murphy whimpers and closes his eyes. When he opens them again, he says, "Please don't hurt me. I just wanted to help you."
    *goto QuestionMurphy
  #"Why did you keep us in separate rooms?"
    Murphy licks his lips before speaking. "After looking at you guys for quite a while, I realized it would take different strategies to get you to see how good of a person I am. Reilly is a very aggressive, maybe psychotic man who doesn't use reasoning in any decision-making. He may even try to kill me the moment he sees me. Madison is a spoiled rich girl who mostly whines to get her way.
    *if morality >= 75
      You're the only good one of the bunch. I knew if I could get your friendship first, you could convince the others.
    *if (morality < 75) and (morality >= 50)
      You are mostly a good person. You would be the easiest one to talk to and show just what a good friend I can be.
    *if (morality < 50) and (morality >= 25)
      You are not as bad as the others. Of the three of you, I thought maybe I could start a friendship with you first.
    *if morality <= 25
      You are equally not as nice as they are, and I worried about reaching out to any of you and starting a friendship.
    So when I had my chance, I decided to put the three of you to sleep, separate you in different rooms, and figure out the best way to show you the person I am."
    *goto QuestionMurphy
  #"Where in the research facility are we right now?"
    Murphy takes a deep breath and holds it in for a moment before blowing out. "When you came into the facility, you are on the A level, which we call the Admin Level. The next level down is the Science Level. One level below that is the Research Experiments Level, or as we call it, Level X. It's super secure and safe and only accessible by senior researchers.
    *goto QuestionMurphy
  #"Where are Madison and Reilly?"
    Murphy's eyes shift to the right. "They are in rooms farther down the hall. It's you, Laurel, Madison, and then Reilly."
    
    "What's with calling it the red chamber?"
    
    "Each room was originally created as a dorm room for researchers and senior lab techs to stay overnight or on weekends. If you're doing an experiment that requires frequent check ins, you can't afford to go home and come back, or you risk coming late to a step. The red chambers were for long-term occupancy, while yellow was short-term, and green was just overnight."
    *goto QuestionMurphy
  *if talked_laurel
    #"When did you capture Laurel?"
      "She came in yesterday," Murphy says. "She's actually very smart. At first, I thought she was kind of stupid because of all the noise she made, but she figured out how to maneuver around the facility without killing a single infected. It was quite fun to watch, and I actually started rooting for her. When she got down to the Science Level, I realized she may be worth keeping around."
      
      "What do you mean, keeping around? Have you made decisions about others that you didn't keep around?"
      
      Murphy puffs out his round cheeks and blows out a sigh. "I guess I let the cat out of the bag. Some people came in to the ARC who I determined would never be friendly. I couldn't let them rob my place of work, and I couldn't risk them getting to me. So I had to handle them in the most humane way."
      
      "So you killed them?"
      
      Murphy's stares at you with great intensity, his lips pressed together, and his chin jutting out. "You can judge me if you want, but just think about any antisocial behavior you've committed over these past few days. I don't believe in God, I don't believe we sin, and there is nothing real except for survival of the fittest. In this case, I have the advantage of survival over many others, because I have the resources so few others have."
      
      *if ruthless >= 65
        *set murphy_faction %-(round(25-(empathy/6)))
        "Not anymore," you say.
        
        "What?"
        
        "You're not in control of this facility anymore."
        
        Murphy looks away from you and remains silent.
      *if (ruthless < 65) and (ruthless > 35)
        *if murphy_restrained_bed or murphy_restrained_floor
          *set murphy_faction %-(round(20-(empathy/6)))
          "You don't really have the advantage anymore."
          
          "What?"
          
          "To be fair, you're not in control anymore. And I'm not sure where to go from here with you."
          
          Murphy starts to say something but looks away and remains silent.
        *if not(murphy_restrained_bed) and not(murphy_restrained_floor)
          "We both have the advantage now. If were trying to build a friendship here, shouldn't we be making these decisions together?
          
          Murphy bites the side of his lip and looks hesitant to speak. "I guess so."
      *if ruthless <= 35
        "I guess that's where you and I differ. Just because we're in a survival situation doesn't mean we have to be ruthless and accord resources for ourselves. We should be willing to help others and try to build a community again."
        
        "We'll agree to disagree then. I've seen how the outbreak has brought the worst out of people, and I'm not about to reward them for their antisocial behavior."
      *goto QuestionMurphy
  #"What do you know about those gray-skinned zombies?"
    "You're calling them zombies?" he says with a chuckle. "I know the media has termed them zombies, but I don't like the popularization of that word."
    
    "What do you call them?"
    
    "We called them vectors. They carry the virus, so that's what they are—vectors. Now, the gray ones are curious. Vectors need food just like any organism. In our research we found that feeding from other organisms prevents the effects of death. In zombies, as you call them, the virus animates the body enough to stimulate life and prevent the body's natural breakdown after death. When a vector hasn't eaten, those defenses against bacteria weaken."
    *goto QuestionMurphy
  #"Are there other people in this research facility?"
    "Only you, your companions, and Laurel," Murphy says, scrunching his nose. "I have a bad itch on my nose."
    *if not(talked_laurel)
    
      "Who's Laurel?"
      
      He blows air from his mouth towards his nose. "She's in the room directly to the right of yours."
      
      "So she's one of your prisoners," you say.
      
      "I want to keep her safe just like the rest of you."
      
    "There are five people in this whole facility. It seems like a lot of resources going to waste."
    
    Murphy shrugs. "If it were up to me, I'd have dozens of people here. Day zero of the outbreak, everyone either fled, died, or became infected. The few of us that stuck around had a hard time after that. As soon as those raiders showed up, I put the ARC on lockdown. Anyone who wasn't inside had to fend for themselves."
    
    *if honor >= 65
      *if talked_to_shooter
        "Like Alan David? You know he was beat up by the raiders? Doesn't sound like you're trying to be his friend."
      *if not(talked_to_shooter)
        "That sounds harsh. Wouldn't you try to help as many people as possible?"
    *if (honor < 65) and (honor > 35)
      *if talked_to_shooter
        "Like Alan David. I met him out in the greenhouse. He had a tough time with those raiders."
      *if not(talked_to_shooter)
        "That sounds harsh. Wouldn't you try to help as many people as possible?"
    *if honor <= 35
      "I can't I say blame you. I would've probably done the same thing."
      
    "I couldn't help other people if I'm dead."
    *goto QuestionMurphy
  #"What is the purpose of this research facility?"
    Murphy scrunches his forehead in a look of deep thought. "Originally, it was a facility to help develop new food sources. This planet is grossly overpopulated by humans. We live in a bubble in America in which water and food is so plentiful while millions if not billions in other parts of the world are malnourished. We throw half eaten bags of fast food out of car windows on our way to work, while children in Africa and India are walking a mile in the morning to drink out of communal water sources filled with bacteria and viruses."
    
    "So you were making alternative foods and drinkable water?" you ask.
    
    Murphy nods. "For quite a few years. We had been interested in genetically modified organisms but the bad press about it destroyed any chances of us continuing that research.  I'm sure you would not be surprised that we turned to plant-based food options. That all changed when the military came in. The amount of money that they threw at this place was obscene. It seemed like overnight we were building infrastructure and hiring workers. We were also working around-the-clock. At that point we were researching viruses and the way they can be transmitted through saliva. Few of us knew specifics. Those who knew the name of the virus we were actually studying are all dead now. I was one of the last to be brought into a meeting to be told about the Zeta virus. That was the day before day zero. If I had known sooner, maybe I could've helped."
    *goto QuestionMurphy
  #"Do I need a passcode or keycard to access different areas of this research facility?"
    "Not on this level," Murphy says. "If you are on this level, it means you are already cleared. But just so you know, I have this level set as a one-way door. Once you go out, you can't get back in without an optic scan and a fingerprint scan. So if you leave, you're not getting back in."
    
    *if morality >= 65
      "Thanks, I'll make sure to remember that."
      
      Murphy scoffs. "You better. Because I wouldn't let you back in. Too risky."
    *if (morality < 65) and (morality > 35)
      "You're really worried about security, huh?"
      
      A creepy smile stretches across Murphy's face. "I'm safe in here, and I'm only giving that safety to those people who deserve it."
    *if morality <= 35
      "That's true, unless I rip out your eye and cut off a finger."
      
      Murphy swallows hard. "You don't have to do that. I'll figure out a way to get you back in here."
    *goto QuestionMurphy
  #"Where is the control room—the place where you've been spying on me?"
    Murphy nods his head to the right. "Just down the hall past the fourth door and make a right. You really would have to be an idiot to miss it. The place screams 'control room.'"
    
    "Do I need a keycard or password to access the room or any of the computers or controls?"
    
    He shakes his head. "Two years ago, yes to all of that. But the researchers got tired of being logged out of their computers every fifteen minutes or being forced to carry around security fobs. All of us felt they were just nuisances. We had stringent security measures to access this floor, so why did we need equally stringent security measures while already on the floor? So we did away with all of them. The military certainly did not like that. They told us to add all of those measures back in, but we couldn't slow down the research, so we never got around to it."
    *goto QuestionMurphy
  *if count > 1
    *if not(murphy_restrained_bed) and not(murphy_restrained_floor)
      #"Will you help me free my companions now?"
        *set with_murphy true
        *set murphy_faction %+(round(empathy/6))
        Murphy nods. "Absolutely. We can go right now. Just vouch for me."
        
        "The first thing we need to do is get my friends out of those rooms. Then we need our stuff back."
        
        "No problem," Murphy says, moving to the door. "I'll lead you right to my control room. What a relief to have a friend in the Apocalypse."
        *goto ChamberHallway
      #"Murphy, I'm going to free my friends now. You have to leave the ARC and never come back here."
        *set murphy_told_to_leave true
        Murphy looks at you with surprise. "Leave? Why?"
        
        "For what you did to us. You had no right to imprison us. Besides, I am certain Reilly will want to kill you the first chance he gets."
        
        Tears form in Murphy's eyes. "I won't survive out there."
        *fake_choice
          #"Then you better grab whatever gear you need to survive before you go."
            *set morality %+15
          #"Hurry up and get out of here. I can't guarantee my friends will be as kind to you as I am."
            *set ideal %-15
            *set honor %+15
          #"Get out of here. Leave the entire facility. I don't even want to see you in the greenhouse when I leave here. Go before I change my mind about this."
            *set truth %+15
            *set honor %-15
            Murphy takes a few steps forward, his whole body shaking. "You'll never see me again."
          #"You have five seconds to get out of my sight. 1…2…"
            *set morality %-15
        He looks puzzled. He hesitates, starts to speak to you, hesitates again, and rushes off down the hall.
        
        You take your own path through the hallway to free your companions, find your gear, and uncover any secrets this place holds.
        *goto ChamberHallway
      #I kill Murphy. He has no right to live.
        *label NoToolsKill
        You
        *if mma_style <= 2
          @{(mma_style <= 1) lash out at Murphy with a fist to the|turn and throw a sidekick into Murphy's} chest. His shoulders roll forward, and his hands cover his sternum as he groans in pain. You lunge forward and slam your forearm into his chin. His head slams against the concrete wall and his eyes roll back. He drops to his knees and falls to the floor, smashing his face.
        *if mma_style = 3
          grab Murphy by the shirt swing him around and throw him head-first into the opposite wall. The crown of his head smashes into the concrete and he falls to the floor, motionless.
        *if mma_style = 4
          grip Murphy's shirt, spin, and flip him over your hip. His body moves in an awkward somersault, and he lands on his head on the concrete floor. When you release him, his body lies motionless.
        *label KillMurphy
        *set honor %-15
        *set humanity %-15
        *set murphy_alive false
        *set survivor_kills +1
        
        With Murphy lying unconscious on the ground, he puts up no resistance as you wrap your arm around his throat and squeeze the life out of him. His body twitches, neck bulging, eyes wide and red. He only makes a slight gagging sound, until his face turns blue then purple. You tighten your arm into his windpipe, straining your muscles until his body relaxes into the sleep of death.
        *goto ChamberHallway
    *if murphy_restrained_bed or murphy_restrained_floor
      #"I'm going to let you go Murphy, but you have to promise to help me."
        *set with_murphy true
        *set murphy_faction %+(round(empathy/6))
        Murphy nods his head so vigorously he looks like a bobble head doll. "Absolutely. All I want to do is help you."
        
        You untie him and bring him to his feet. "The first thing we need to do is get my friends out of those rooms. Then we need our stuff back."
        
        "No problem," Murphy says, rubbing his arms where you had tied him. "I'll lead you right to my control room. What a relief to have a friend in the Apocalypse."
        *goto ChamberHallway
      #"I'm going to let you go, Murphy, but you have to leave and never come back here."
        *set murphy_told_to_leave false
        Murphy nods his head so vigorously he looks like a bobble head doll. "I promise I will. Cross my heart and…I promise."
        
        You untie him, help him up, and say…
        *choice
          #"Grab whatever gear you need to survive out there before you go."
            *set morality %+15
            Murphy claps his hands together like he's praying and bows to you. "Thank you, ${firstname}. Thank you so much."
            *label MurphyLeaves
            
            He @{murphy_restrained_bed leaves the room, and you follow into the hallway to find your companions, your gear, and|stands and rushes ahead of you down the hall, and you follow close behind to free your companions, find your gear, and uncover} any secrets this place holds.
            *goto ChamberHallway
          #"Hurry up and get out of here. I can't guarantee my friends will be as kind to you as I am."
            *set ideal %-15
            *set honor %+15
            Murphy rises, his whole body shaking. "Thank you. I'm so out of here."
            *goto MurphyLeaves
          #"Okay, get out of here. Leave the entire facility. I don't even want to see you in the greenhouse when I leave here. Go before I change my mind about this."
            *set truth %+15
            *set honor %-15
            Murphy rises, his whole body shaking. "Yes, thank you. You'll never see me again."
            *goto MurphyLeaves
          #"You have five seconds to get out of my sight. 1…2…"
            *set morality %-15
            Murphy rises, his whole body shaking. "I'm going. I'm going."
            *goto MurphyLeaves
      *if murphy_restrained_bed
        #I leave the room with Murphy still tied up. I don't care if he lives or dies.
          *label LeaveMurphyTied
          *set murphy_alive false
          *set survivor_kills +1
          You start away from Murphy, and he struggles on the @{murphy_restrained_bed bed.|floor.}
          
          "Where are you going?" he asks in a shaky voice. When you don't reply, his voice grows louder and frantic. "Wait! Untie me. Don't leave me here. Come back!"
          
          You ignore his pleas and go on a search for your companions, your gear, and whatever secrets this place holds.
          *goto ChamberHallway
      *if not(murphy_restrained_bed)
        #I leave Murphy still tied up and go find my companions. I don't care if he lives or dies.
          *goto LeaveMurphyTied
      #I kill Murphy. He has no right to live.
        *set murphy_alive false
        *set honor %-15
        *set humanity %-15
        *set survivor_kills +1
        With Murphy restrained, there's nothing he can do to stop you as you wrap an extra cord around his throat and strangle the life from him. He struggles against his ties, neck bulging, eyes wide and red. He only makes a slight gagging sound, until his face turns blue then purple. You tighten the cord, straining your arm muscles until his body relaxes into the sleep of death.
        
        When you're finished, you continue down the hallway to find your friends and a way out of this nightmare.
        *goto ChamberHallway
      
*label KnockoutGas

A hissing sound comes from the top of the room followed by the side walls. A metallic taste fills your mouth—the knockout gas. Murphy must be filling the room with gas before he enters. You think fast to come up with another strategy, but already your body weakens. Your limbs feel rubbery and your eyelids droop. You slap your face and will yourself to stay awake. Your vision blurs, and everything gets foggy.

The door opens, and in walks a figure in a hazmat suit. It's the last thing you see before everything goes white.
*page_break
You awaken on the bed in the red chamber with a pressure headache and a dry mouth.
*if broke_camera
  A new camera and speakers hang on the wall.
You drop your feet to the floor and set up, woozy but otherwise fine. Murphy is gone, and you have no idea what time it is, where your friends are, or how to escape.
*goto ChamberChoices

*label MurphyReturnTalk

"Hello there, friend. I'm back for a while. How are you doing in there?"
*choice
  #"I am really hungry. Is there any chance you can get me some food?" I might as well get something to build up my strength.
    *set murphy_faction %+(round(empathy/6))
    "Sure thing," he says, his voice more upbeat than expected. "Since you are awake, please go into the shower and close the door. Once you're inside, I can bring in some food for you. @{(murphy_faction >= 50) I know it sounds paranoid, but we're only becoming friends now. It will take a bit longer before we can really trust each other. If you ask me I think we are on the right road."|Since we've had some bumps along our path of friendship, I need to take precautions until I know I can trust you. I have hope we will build it soon."}
    
    You step into the shower area and close the door, leaving it partially open. Should you see an opportunity to pop it open and run out to attack or confront him, you may have to take that chance.
    
    "Sorry, but you'll have to close it all the way," Murphy says over the loudspeaker. "Sometimes the latch sticks. I was really hoping to fix that before you got here, but boy oh boy do I have a lot on my to do list."
    
    You close the sliding door of the shower into you hear a click. A metal latch flips over the latch. You're locked in. He actually locked you in the shower.
    
    The chamber door slides open with the scraping of metal on metal, and footsteps tap the tile floor. You try the door again, but it's locked. Even if you could pry it open, Murphy would have time to run out of the room, and there's no telling what he'll do to you.
    
    The smoky glass walls of the shower obscure your view of the chamber, but you see the outline of the shape walk to your bed, place something down, and leave the room. A minute passes, and the door to the shower unlocks. Stepping outside, you see a plate of food on the bed.
    
    The overhead speaker crackles. "I gave you a healthy portion of beef stew, a piece of sourdough bread, and a cup of coffee. Bon appétit."
    
    *if vege
      *set fatigue %-(round(sta/7.5))
      "I'm actually a vegetarian. I don't eat beef."
      
      "Oh really? I'm so sorry. That is a fact I did not know about you. I don't have a lot of time to make you something else, so for now you can eat the bread and drink the coffee. Now that I know you don't eat meat, I will make sure you only get fruits and vegetables and grains. If you want to make any food requests, please let me know. The pantry is well-stocked but only for now. Who knows how long this outbreak will last."
      
      You eat the sourdough bread and drink the cup of coffee, and though you've satisfied your cravings for food, you wish you had more.
    *if not(vege)
      *set fatigue %-(round(sta/5))
      *set stress %-(round(wil/5))
      @{(morality >= 50) "Thank you for the food," you say and|You} sit on the edge of the bed. You place the tray on your lap and begin eating. It tastes better then you've ever had before. The meat is thick and tender, and the stock has a subtle peppery taste. Packets of real butter sit under the sourdough bun, and you smear an entire packet all over the bread and dip it into the stew.
      
      It doesn't take long to eat it. When you're finished, you enjoy the cup of coffee and set the tray on the floor by the main door.
    *goto NextMurphy
  #I find out if Murphy has any mental issues. Maybe he's off his meds?
    You
    *if truth >= 50
      *set murphy_faction %-(round(20-(empathy/6)))
      don't want to waste any time, see you come right out with it. "So Murphy, are you taking medication?"
      
      "Well that's a bit insensitive.
    *if truth < 50
      can't exactly come out and ask him if he has mental problems, so you try to work it into the conversation. "You know what I hate about this outbreak the most? I can't find my medication. What about you?"
      
      @{(m_persuasion >= 60) "You're preaching to the choir. I ran out two days ago.|"Nice try. If you're going to ask me a question, just ask. No need to manipulate me.}
    I can already feel the facts, and let me tell you, a few more days like this, and I'm going to be completely out of my mind."
    
    @{(truth >= 50) "If you lose your mind, then I'm screwed. There's no way I'm getting out of here. You're condemning me to death."|"That sounds terrible. What happens if you lose your mind? And I going to be trapped in here forever?"}
    
    "Trust me, if I don't find a way to get more medicine in a few days, you're going to be happy you're in a cell," Murphy says.
    
    *if short_fuse
      *if wil >= 65
        Your rage fires up, but you know you can't let it out. He's in control, and if you let your emotions take over, you'll never get out of here.
        *goto ImpulseMurphy
      *if wil < 65
        *set murphy_faction %-(round(25-(empathy/6)))
        Hearing this, your rage takes over. Murphy has imprisoned you, and when his mind breaks down, you'll be trapped in here into you starve to death or he pumps this room full of poisonous gas. "Let me out of here, you psycho!"
        
        "Calm down. It's not like I want antipsychotics or something. It's just a bit of flatulence. I have
    *if impulse < 50
      "Why is that? Are they antipsychotics? Or do they treat depression or something?"
      
      "Oh gosh no. To be honest, I have
    *if impulse >= 50
      *label ImpulseMurphy
      "Murphy, you gotta let me out of here. If you have a mental breakdown, you won't be able to get me food or keep me alive. You're basically condemning me to death."
      
      "Mental breakdown? No, I just have
    really bad gastric reflux, and I get a bit of the winds. Last time I ran out of medicine, my roommate in grad school left the apartment because of the odor. I was so embarrassed."
    
    You shake your head. "So you're worried about farting? That's it?"
    
    You hear Murphy scoff through the speaker. "You've never smelled what I'm dishing out, my friend."
    *goto NextMurphy
  #I befriend him. If he truly wants companionship, I could always use another friend.
    *set truth %+15
    *set murphy_faction %+(round(empathy/6))
    *label BefriendMurphy
    "I'm feeling fine, I guess," you say. "I'm nervous and wish I could see my companions or at least know that they are okay."
    
    "I can understand your worry, but you and your friends are all fine. I can keep you safe. It's funny—in a few weeks from now, we'll all be laughing together about how we met. You know, when we're all friends. For now, I know you have to trust me, but it's only a matter of time. I have your best interest in mind."
    
    "I'm glad to hear that. I can use more friends during this outbreak. I've met my share of people looking to rob me or hurt me in some way. I'd rather make allies and enemies." You turn and smile into the camera. "So when do you think I can get out of here? If you want me to be your friend, it's hard to do so when I'm locked up."
    
    There's a long pause on the other side of the loudspeaker. You hear no sound coming through, so Murphy must've shut off the receiver. After a full minute, you hear the crackle of the speaker again.
    *if (murphy_faction >= 60) and (persuasion >= 45)
      "I see your point. It's always been hard for me to make friends. Even Alan David isn't my friend and we've worked together. Maybe the first step in making friends, real friends, is to take a chance on someone. I'm going to take a chance on you. I think you're a good person, and together, we can convince your friends that all of us can help one another."
      *goto MurphyOpensDoor
    *else
      "I really want to show you that I want to be your friend, but I can't take the risk now to let you free. Let's just take our time and build trust."
      *goto NextMurphy
  #I befriend him but only to gain his trust to exploit later.
    *set truth %-15
    *goto BefriendMurphy
  *if laurel_murphy
    #Since Laurel told me of Murphy's anxiety, I play on his fears to get him to trust me.
      *set truth %-15
      "I'm doing okay. Well, that's not entirely true. I'll be honest—I'm worried, not about being here. This place seems very safe, but when I was on the road earlier, I saw a group with weapons and armored vehicles not far from this facility. Do you think they are coming back here to break in and loot?"
      
      Even though Murphy is on the other end of the speaker, you can tell by his shaky voice that panic is setting in. "They had vehicles? They were coming here?"
      
      "I can only assume they were coming this way. They looks like a dangerous bunch. If they are in fact headed this way, I am genuinely afraid for my life, the lives of my companions, and even you. We don't have the kind of firepower, and even though this place has security systems and metal doors, how long will they stand up?"
      
      "I—I definitely see your point." In the background Murphy makes a sound somewhere between a hiccup and a moan. "Maybe they will just take what's left of the supplies in the greenhouses. Why would they even know about the lower levels of the ARC?"
      
      *if (persuasion >= 65) or (intimidation >= 55)
        *set scared_murphy true
        You press further to ramp up his fears. "You're probably right. They can't possibly know about this level. @{talked_to_shooter Well, unless Alan told them about it. They beat him up pretty badly and interrogated him. You don't think he told them,|But it's strange. They were looking at blueprints when we saw them. You don't think they have blueprints of this place,} do you?"
        
        "Oh God, oh God," he says, his voice murmuring over and over. "What do I do?"
        
        "If they are coming to attack, and it only makes sense that they are, then you need to fight them off."
        
        For the first time since you've met him, Murphy yells into the loudspeaker. "How the hell am I supposed to do that? I am one person who has never fired a gun. Hell, I've never been in a fist fight. I get nosebleeds when I take an elevator too high. I need to take a Valium before going to the dentist for a cleaning for God's sake."
        
        You toss out the bait for him to bite. "Is there anyone else here who can help you?"
        
        "Only you and your companions and Laurel," he says.
        
        "I can't help you. How can I help you?"
        
        Murphy scoffs through the loudspeaker. "You must know how to fight. And I know Reilly knows how to fire a gun—he's threatened to shoot me on more than one occasion."
        
        "It's hard to fight locked inside a room. Trust me, I'm happy where I'm at. After those raiders break in here, maybe I can convince them not to kill me by explaining I was taken prisoner."
        
        "No, no, no. You have to help. Please. Oh my God, I'm not feeling so good."
        
        Now's your chance. "Murphy, and get me out of here. I'll help you."
        *goto MurphyOpensDoor
      *else
        You need to get him even more panicked, so you push as hard as you can. "Murphy, you have got to let me out right now. The only way to keep us alive is to join together and fight the raiders. Come on, hurry up."
        
        Murphy takes a deep breath and lets it come out as a long sigh. "I don't know. I really doubt they can break in. You don't have to worry. In fact I'm going to go check on our security right now."
        *goto NextMurphy
  #I tell him I'm not feeling well to lure him into my room.
    *set lured_murphy true
    *set truth %-15
    "I'll be honest, I'm not feeling so well," you say. You run to the bathroom and make a wrenching sound as loudly as you can.
    
    *if persuasion >= 45
      "Okay, okay. I'll be right there. I can help you," Murphy shouts through the loudspeaker.
      *goto MurphyOpensDoor
    *else
      "Sorry to hear that. We can talk later when you're feeling better," Murphy says.
      *goto NextMurphy
    
*label NextMurphy
*set timecount +25

You hear the speaker scramble and click off. Murphy is gone for now, but you don't know for how long.
*page_break
*goto ChamberHub
  
*label MurphyOpensDoor

The speaker cuts out. For a few minutes you're not sure what's happening. Is he coming to get you? Is he going to set you free? The man seems unhinged and anything can be happening.

You hear movement from the main door into the room and the beeping of the keypad. Assuming it's Murphy, you…
*choice
  #Stand right by the door and prepare to fight.
    *set impulse %+15
    You move to the right side of the door and prepare to attack  as soon as it opens. Whoever comes inside may have a weapon or may be a formidable fighter, but this is your best shot of escape and possibly the only chance you'll get.
    
    You @{spare_tools take out a screwdriver from the spare tools you found.|stand by the wall and raise your hands.} The door slides into the wall, and a man steps in.
    *goto FightMurphy
  #Wait to talk to him. I trust that he truly wanted to be friends.
    *set truth %+15
    *set chat_count 0
    You sit on the bed and wait for Murphy. When you hear the door to the chamber opening, you @{(ideal >= 50) know this is the best option to escape. If you can convince Murphy you're a friend, he will let you go or at least you may gain the opportunity to fight or flee.|reconsider the decision. Is gaining his trust the best way to escape? Can you truly be friends with this man?}
    
    The door slides into the wall, and the man himself steps inside—hair dark brown and tousled, face round and puffy, and his lips constantly moving like he's talking to himself.
    
    *if scared_murphy
      "Are you going to help me?" he says and glances around the room nervously. "We have to figure out a way to stop the raiders."
      
      @{(truth >= 50) "I'll be honest with you, Murphy, I may have embellished the threat just a little bit. I want to be friends, so please let's talk and|"The raiders are coming, but we have time to get to know one another. We need to} figure out a way to work together."
      
      Murphy's shoulders relax, and he breathes out a sigh of relief. "Okay, if we're not in immediate danger, we can have a chat."
    *if not(scared_murphy)
      "Hi there," he says and gives you a wave like a shy child may. "I'm sure you have a lot of questions for me and maybe then we can be friends like I had always hoped."
    *goto QuestionMurphy
  #Fake an injury to lure him close to me, so I can catch him off guard.
    *set truth %-15
    You lie on the floor near the bed and clutch your stomach to fake an injury. If you can draw him close and hit him with a surprise attack, you may have a shot at overwhelming him.
    *goto FightMurphy
    
*label KnockMurphyOut
You creep up behind him and
*if spare_tools
  slam the handle of the screwdriver into the back of his neck.
*if not(spare_tools)
  *if mma_style < 3
    drive a punch into the back of his neck.
  *if mma_style = 3
    Grip him around the waist. You lift him off the ground, and he shrieks and wiggles in your arms until you suplex him on the ground. His head hits the floor, and his body goes stiff. Crouching over him, you hear the soft sounds of his unconscious breathing. At least you didn't kill him.
  *if mma_style = 4
    Wrap your arms around his throat. It's a simple chokehold that cuts off the carotid artery. He's out even faster than past training partners, and you rest his limp body on the floor.
*if spare_tools or (mma_style < 3)
  He drops to the floor face-first, forcing you to catch him so he doesn't bash his head.
*return

*label FightMurphy
*gosub DescMurphy

He steps past you and glances around the room, unaware of your location directly behind him. "${firstname}, where are you? Where did you go?"

You…
*choice
  #Knock him unconscious, so I can then escape.
    *set honor %-15
    *gosub KnockMurphyOut
      
    With Murphy sleeping at the foot of the bed, you leave the red chamber and close the door behind you.
    *goto ChamberHallway
  #Restrain him so I can question him.
    *set impulse %-15
    *set murphy_restrained_bed true
    *gosub KnockMurphyOut
    
    With the door to the chamber still open, you walk outside and find a supply closet directly next to the room. Inside of it you find long spools of electrical cords. You take a bundle, head back into the room, drag Murphy onto the bed, and bind him to it. He looks so comfortable on the bed, his dark brown hair all tasseled and his cheeks puffed out as he snores.
    *goto WakeMurphy
  #Kill him.
    *set honor %-15
    *set humanity %-15
    *set murphy_alive false
    *set survivor_kills +1
    *if spare_tools
      *goto ChamberHallway
    *else
      *goto NoToolsKill

*label CrawlThroughVent

Knowing this may be the only means of escape, you boost yourself into the vent.
*if fear_heights
  *set stress %+(round((100-wil)/5))
  When you climb up, you glance down at the floor seven to eight feet below. You feel dizzy from the height and lose your balance.
  *if wil >= 65
    One of your hands shoots out and catches the side of the vent, steadying you in place. You can't fall. You can't give into your fears. You have to push on. Swallowing hard, you throw yourself headfirst into the vent and forget about the height.
    *if claustrophobic
      *goto ClaustroCheck
    *else
      Once inside, your body relaxes, and you start your track through the ventilation system.
      
      *goto VentTrek
  *else
    *set p_health %-(round((100-sta)/5))
    *goto ChamberHub
*elseif claustrophobic
  *label ClaustroCheck
  *set stress %+(round((100-wil)/5))
  Once your body is inside, you feel the walls creep in from all sides. It's no bigger than a coffin and feels like one too.
  
  *if wil >= 65
    You want to give up and lower yourself back to the ground where the room is wide open and the air is fresh. You just can't do it. This may be your only means of escape, and dying from claustrophobia is no way to go out in the zombie apocalypse. You laugh to yourself and hear it echo off the metal walls. Pushing all of your fear aside, you move on.
    *if night_blindness
      *goto CheckNB
    *else
    
      *goto VentTrek
  *else
    You can't do it. This may be the only way to escape, but if you have a heart attack or stop breathing, you'll die anyway. As your heart races and breathing becomes tight and shallow, you back out of the vent and lower yourself to the ground. Dropping to the floor, you suck in long gulps of air until your heart rate slows and your breathing returns to normal
    *goto ChamberHub
*elseif night_blindness
  *label CheckNB
  
  As you move through the first part of the shaft, darkness envelops you. The closest source of light comes from the red chamber and every few feet you crawl, it grows darker. With your poor night vision, you can barely see. You move ahead in a straight line but as the shaft tightens, you bang your head and grind your elbow into the wall. You won't be able to navigate without seeing where you're going, so you're forced to back out and abandon this means of escape.
  *goto ChamberHub
*else
  *label VentTrek
  *set climbed_vent true
  You move through the shaft guided by the light from the red chamber. As you move farther, darkness creeps in, but there's enough ambient light to see. You crawl on hands and knees, keeping your head low. After fifteen feet or so, the walls tighten and force you to draw your arms and legs together in a more awkward crawl.
  
  At a fork, you choose a right side tunnel and continue on. The path widens, and you listen for any sounds that might guide your way. A general hum pervades the ventilation system but it grows quieter from a side shaft ahead. Taking the turn, you crawl for another ten feet and the path ends at a vent below you. The screws are old and rusty and come out easily with a simple push on the grate. It falls with a rattle into a closet. You descend from the shaft and peek out the door. The hallway waits before you, and you see no one ahead.  
  *goto ChamberHallway

*label ChamberHallway
*page_break
You stand in a wide hallway with white walls, white floors, and a white ceiling. A row of doors, spaced twenty feet apart, take up the right side, and past them the hallway turns.
*if murphy_alive and (not(with_murphy) and (not(murphy_restrained_bed) and not(murphy_unconscoius)))
  Before you make it around the corner, you hear a cheerful whistling drawing closer. Peeking past the wall, you see someone coming towards you.
  *gosub DescMurphy
  
  Looking around, you spot a computer printer the size of a small refrigerator, and you duck behind it. Several spools of cables lie behind it as does a heavy flashlight.
  
  "Do you know the way to San Jose," the man sings off key as he passes you by.
  
  You hoist the flashlight overhead and with a shout, you rise and bring it down on the back of his head. He drops to his knees and grunts in pain. "Stop, it's me. It's Murphy."
  
  You…
  *choice
    #Knock him unconscious, so I can then escape.
      *set impulse %+15
      You raise the flashlight again and smash him across the back of the neck. He falls flat on his face, and only by the rise and fall of his back do you know that he's still alive.
      
      With the Murphy unconscious, you move on down the hallway.
      *label MurphyKnit
      You make it only a few feet before coming to a door. It's outlined in red, and you realize this is where you've been trapped. Standing on the other side, you pause in a moment of reflection. Not too long ago this door separated you and your freedom. Now it's just a door. You move on.
      *goto ContHallway
    #Restrain him so I can question him.
      *set impulse %-15
      *set murphy_restrained_floor true
      Murphy lifts his hands to his head and rubs the area you struggle with the flashlight. Remembering the bundles of printer cables, you reach behind the printer and grab them, and then loop them around his body.
      
      "What… What are you doing?" he asks, his voice slurred.
      
      You loop each of his wrists with the cables and sends them down behind his back. He doesn't resist and before long he's prone on the floor, tied with the white cables. With Murphy restrained, you begin to question him…
      *set chat_count 0
      *goto QuestionMurphy
    #Kill him.
      *set honor %-15
      *set humanity %-15
      *set murphy_alive false
      *set survivor_kills +1
      You raise the flashlight again and smash him across the back of the neck. He falls flat on his face, and only by the rise and fall of his back do you know that he's still alive. You wind back your arm and slammed the flashlight onto the back of his head, and you hit him again and again, as images of your imprisonment float through your mind. You picture Madison and Reilly locked away, and you imagine all of your companions back at the Junkyard. You blink hard and when you look back at Murphy, his skull is a grotesque portrait of bloody bone and brain matter. Your clothes are painted in red and more blood has sprayed across the floor and nearby wall.
      
      Releasing the flashlight, it rattles to the ground and you flick your hand to get off some of the blood. You reach down and wipe yourself clean with the edge of his pant leg. When you're finished, you continue down the hallway to find your friends and a way out of this nightmare.
      *page_break
      *goto MurphyKnit
*else
  *goto ContHallway

*label ContHallway
*if with_murphy

  "I guess we should get your friends out first?" Murphy asks.

At the first door directly on the other side of the red chamber, you stop at a sensor and casually wave your hand over it. To your surprise, the door slides open. A woman stands by the door. She's tall and full figured and has a dark brown complexion. She has straight hair to her shoulders and stands to the side with her fists up ready to fight.

*if talked_laurel
  "Laurel, it's me, ${firstname}."
  
  She lowers her hands and breathes a sigh of relief. "Oh damn, you got out. And you got me out. Thank you so much."
*if not(talked_laurel)
  "Who the hell are you?" she yells, waving her fists. "I'm not going down without a fight."
  
  "I'm here to get you out," you say and back away from the door. "I'm ${firstname}."
  
*if with_murphy
  "Hi Laurel," Murphy says in his sheepish voice.
  
  Laurel rushes out of the room and winds her arm back like she's going to hit him. "I know your voice, Murphy. I should beat your ass for what you did to me—locking me up like that."
  
  He moves behind you for protection, but you step farther down the hall. "We don't really have time for this now. I'm going to get my friends out of here and then we're all leaving
*if not(with_murphy)
  She steps closer to the doorway and looks out hesitantly, arms lowering. "Where's that Murphy dude?"
  
  *if murphy_alive
    *if murphy_restrained_bed
      "I have him tied up in my chamber. He's not going anywhere."
    *if murphy_restrained_floor
      "He's tied up father down the hallway."
      
      She looks out of the room and to the left. Her face lights up with a smile and she lets out a low, devilish laugh.
      
      "Laurel! Please untie me," Murphy shouts.
      
      "Sorry I'm all tied up trying to get out of here," Laurel says with a clap of her hands.
    *if murphy_told_to_leave
      "He's around here somewhere. I told him to leave. I don't think we have to worry about him anymore."
  *if not(murphy_alive)
    "He's dead."
    
    She nods and looks around the hallway. "Good. What now?"
    
  "I need to let my friends out and then were getting our stuff that Murphy stole in getting the hell out of
this damn research station."
*page_break
Freeing Reilly and Madison turned out to be an easy task as a simple wave over the sensors outside their chambers opened the doors. Both were surprised to see you and after the excited reunion, you introduced them both to Laurel and filled them in on the last half hour of your life.
*if with_murphy
  It took you, Madison, and Laurel to stop Reilly from beating Murphy who shrank in the corner and covered up. While @{(honor >= 50) you're just as angry at Murphy, you explained that hurting him serves no purpose.|While you don't blame Reilly for his reaction, you convince him to leave Murphy alone for now in case he's needed.}
  
  "Where did you put our gear, rat?" Madison says, her face red with anger. "Your new name is rat, because, well…because you're nothing but a rat." She so upset, she can barely get the words out.
  
  "The control center is just down the hall." Murphy points to the next hallway and sure enough room sits at the edge labeled Control Central. "Look, I know what I did seems wrong, but it's just I needed to make some friends. You all have companions, and I have no one. I kept you all safe and didn't want to hurt any of you. I just wanted friends."
  
  Reilly steps up to him and holds a fist under the man's chin. "One more word. One."
  
  Murphy lets out a whimper and shirks away.
*if not(with_murphy)
  After the introductions you're all quick to decide to search the rest of the floor for a way out. Fortunately, it's a short hunt as a room labeled Control Central sits at the end of the nearest hallway past the four chambers.
  
*label ARCControlRoom
*set visited_arc_control_center true
The @{with_murphy Five|four} of you enter the room. It's shaped like a square of metal and has electronics and rolling leather chairs like the inside of an air traffic control station. Rows of monitors hang from the ceiling above long desks. A storage room is clearly labeled on the northwest corner and on the western side is an elevator. A table stretches along the northern wall with trays of food and bottles of water and juice like Murphy was setting up a buffet line.

"I really need to use the bathroom," Madison says, dancing in place and squeezing her legs together.

@{(impulse >= 50) "Didn't you just going hour ago?"|"You went not long ago. Are you okay?"} you ask.

"Yes, but when I got in the room, I got nervous and drank a whole bottle of water. Rat man could have been watching so I wouldn't go to the bathroom." Her cheeks turn a rosy pink.

Reilly nods as he sits in a chair next to the buffet. "Performance anxiety. First night I was in the joint, I couldn't poop or pee with all those convicts watching."

"This is a little different," Madison says.

@{with_murphy "There are no cameras in the bathrooms in the chambers," Murphy says. "The staff washroom is out the door and just down the hall."|"I thought I saw a bathroom just outside and down the hall," you say.}

Madison hurries out of the room, while Laurel and Reilly grab food from the table, and you…
*set count 0
*label CCHub
*set count +1
*if count = 3

  Madison returns to the room and seems in better spirits as she smiling and skipping through the room. She heads over to a pile of manuals on a table and looks through them.
  *goto CCChoice
*elseif count = 4

  Madison, Laurel, and Reilly pack up the food in plastic containers. It's more food than you could've expected and will go a long way to feed everyone at the junkyard.
  *goto CCChoice
*else
  
  Next you…
  *goto CCChoice

*label CCChoice
*choice
  #Eat and drink with Laurel and Reilly.
    *set fatigue %-(round(sta/5))
    *set stress %-(round(wil/5))
    You walk over to the long buffet table and stare at the assortment of food. Small sterno heaters sit under hot plates of fried chicken, cooked ham, and pork ribs in barbecue sauce. Fluffy biscuits sit in a large bowl separating the rest of the table which holds a variety of cold salads and dishes of sautéed vegetables. Laurel and Reilly pack heaping plates and eat greedily.
    *if count = 3
      Madison takes a modest plate of food and sits in one of the leather chairs.
    
    @{vege The one side of the table is packed with meat dishes. You're able to fill your plate with fruits and vegetables and nuts and tofu.|You fill your plate from the smörgåsbord, eating as you continue piling more on.}
    
    "If y'all are heading back to y'alls camp after this, we should pack up some food for you to take." Laurel reaches under the table and pulls out plastic containers. "I can help you pack."
    
    "Snds gdt me," Reilly says with his mouth full. He swallows and clears his throat. "Sounds good to me. Thank you, Laurel."
    *if with_murphy
      
      "There are more containers and storage," Murphy says, walking over to the table. As he reaches for a biscuit, Reilly slams a fork into the table right before the scientist's hand. Murphy yanks his hand away just in time and scurries to the side wall.
      
    As you sit and eat and drink, you feel your stress and fatigue slip away.
    *goto CCHub
  #Examine the elevator.
    *set examined_elevator true
    You step over to the elevator and press the button on the outside. A chime sounds as the doors slide open to a sizable elevator. Stepping on, you place your foot in front of the bumper to keep the door from closing. Only one button shows on the elevator panel—ground floor. This is a one-way elevator to get out of the facility. There is no returning to the control room unless you make your way back through the entire research center.
    
    Now that you're sure of a way out, you step off the elevator and let the doors close.
    *goto CCHub
  #Search the storage room.
    *set searched_storage true
    *set timecount +25
    You step into the storage room and see large bins marked with each of your names. As soon as you step inside, you're joined by Laurel and Reilly, and the three of you take all of your gear and backpacks and duffel bags of inventory items.
    
    "This has got to be the weirdest thing I've ever seen in my life, and I've seen some weird shit," Reilly says. "He steals all of our stuff just to store here in these little cubbyholes like we're kids at preschool."
    *if with_murphy
    
      "I wasn't trying to rob you, just keep your stuff safe until we were friends," Murphy says, peeking in through the door.
      
      "Well that was a terrible plan. I thought scientists were smart. To lock us away in cells and expect us to all forget about it later and be your friend? Do you really think that is a smart plan?" Reilly asks.
      
      Murphy shrugs. "I thought it was. Now that you mention it though…" The sentence drips off.
      
    Laurel puts on a gold necklace with her name on it and a Christian cross dangling from the middle.
    *if with_murphy
      "Murphy, please stop saying you were trying to be our friend. You never asked us or tried to help us before you locked this up. So just give it all a rest."
    *if not(with_murphy)
      "He said he was trying to be our friends and keeping our gear until he built trust in us."
      
      Reilly gives her a side eye.
      
      She shrugs. "I'm not defending the little rat. I'm just saying what he told me."
    
    In one section of the room, you find an assortment of other items that may come in handy to your group. You decide to leave everything for now and come back to select gear before you return home.
    
    The three of you finish collecting leave the supply room.
    *goto CCHub
  *if survnet_mission
    #Set up a SurvNet server.
      *set arc_cc_survnet_server true
      *set timecount +25
      Between the type of technology available in the ARC and the security of the facility, this would be a perfect place to set up a SurvNet server. You don't even need to go into your own equipment. You repurpose one of the computer towers and make sure it's on the network. Once it boots, you see that is online and ready to receive and send messages through SurvNet.
      *goto CCHub
  #Use the computer terminals and monitors.
    You turn on a panel of monitors and one of the systems. All of them boot up in a matter of seconds with clear pictures of various parts of the research center. On the outside you see the two greenhouses quiet and calm, @{murphy_told_to_leave though along road leading out of the facility, a man is running away. You figure out a way to zoom in and see its Murphy carrying an oversized backpack as he stumbles along ready to fall over in any moment. You watch him for a while until he goes out of view of the camera.|and the road is calm leading away from the research facility.}
    
    You look through the cameras and take a visual tour around the rest of the facility but noticed no other living soul anywhere to be found. An entire facility left abandoned or taken over by the infected. If there was only a way to gain re-entrance, this would be a place for your group to live and endure the rest of the outbreak in relative security.
    *if with_murphy
    
      "Hey Murphy, is there any way to get back inside this facility after we leave?" you ask.
      
      He shakes his head and stares at the table of food guarded by Reilly. "Not even for me. The security system is protecting the ARC and not letting anyone else in. Once you leave, you have no way to reenter."
      
      "That's dumb," Laurel says.
      
    With no other use for the monitors and computer system, you shut it all down.
    *goto CCHub
  *if examined_elevator
    #Leave the Control Center and return home.
      *set group_food +400
      "Let's get ready to head home," you say to everyone.
      
      @{(count = 4) You gather the plastic containers filled with food and each of you take as much as you can carry.|Before you leave, you instruct everyone to pack any remaining food in plastic containers you find under the table. With all of the food you store, you'll be able to feed everyone at the Junkyard a normal meal for at least a few days.}
      
      *if searched_storage
        Now that you're ready to leave, you return to the supply room to look through the other items you may want to take back home.
      *if not(searched_storage)
        "We should grab our gear first," Madison says as she opens the storage room.
        
        You all join her in the room where you each have a large bin labeled with your names. All of your gear is set inside of your bin, and you spend a few moments gathering everything and putting it on. You also look through the other supplies to decide on items to take back with you to the Junkyard.
        
      *set inv_count 0
      *gosub_scene Part1Events CalcSlots
      *label CCStorage
      *if (inv_count >= (max_count+10))
        *goto FinalLaurel
      *else
        *gosub_scene CarryList
        *set item_count ((max_count+10) - inv_count)
        You have the following items: ${inventory}
              
        You can take ${item_count} more items.
        *set inv_count +1
        *choice
          *if scavenging >= 45
            #Antibiotics.
              *set antibiotics +1
              You add the antibiotics to your inventory.
              *goto CCStorage
          #Batteries (1 pack).
            *set batteries +1
            You add the batteries to your inventory.
            *goto CCStorage
          #Cookware.
            *set cookware +1
            You gather the pots and pans and add them to your inventory.
            *goto CCStorage
          *allow_reuse #Duct tape (1 roll).
            *set duct_tape +1
            You add the duct tape to your inventory.
            *goto CCStorage
          *allow_reuse #Food (3).
            *set group_food +3
            You add the food to your inventory.
            *goto CCStorage
          *allow_reuse #Electrical parts (2).
            *set electric_parts +2
            You add the electrical parts to your inventory.
            *goto CCStorage
          *allow_reuse #Flare.
            *set flares +1
            You add the flare to your personal inventory.
            *goto CCStorage
          #Flashlight.
            *set w_flashlight +1
            You add the flashlight to your inventory.
            *goto CCStorage
          *allow_reuse #Gunpowder (1 tin).
            *set gunpowder +1
            You add the gunpowder to your inventory.
            *goto CCStorage
          #Heavy battery.
            *set heavy_battery +1
            You add the heavy battery to your inventory.
            *goto CCStorage
          #Liquid cleaner.
            *set liquid_cleaners +1
            Tucked into a cabinet is bottle of liquid cleaner, which you add to your inventory.
            *goto CCStorage
          *allow_reuse #Mechanical parts (2).
            *set mech_parts +2
            You add the mechanical parts to your inventory.
            *goto CCStorage
          *allow_reuse #Metal parts (2).
            *set metal_parts +2
            You add the metal parts to your inventory.
            *goto CCStorage
          *selectable_if (item_count > 2) #Microscope (1). (3 slots).
            *set microscope +1
            You add the microscope to your inventory.
            *goto CCStorage
          *if scavenging >= 45
            #Night vision goggles.
              *set w_nvg +1
              You add the night vision goggles to your inventory.
              *goto CCStorage
          *if scavenging >= 45
            #Respirator.
              *set respirator +1
              You add the respirator to your inventory.
              *goto CCStorage
          *allow_reuse #Solar panel.
            *set solar_panels +1
            You add the solar panel to your inventory.
            *goto CCStorage
          *allow_reuse #Wood parts (2). 
            *set wood_parts +2
            You add the wood parts to your inventory.
            *goto CCStorage
          #That's all I take.
            *goto FinalLaurel
            
*label FinalLaurel
*set timecount +25
You finish taking your items and handing some over for Madison and Reilly to carry back. Just as you're ready to leave, you notice Laurel packing a separate bag.

"Hey, any interest in coming back with us?" Reilly asks. "We got a fairly nice spot that's secure tucked away in the woods."
*if empathy >= 55
  
  You can tell by his body language and the way he's staring at her that Reilly may have a crush on Laurel.
  
Laurel smiles and waves her hand. "Oh thank you but I need to go handle some things on my own. If you don't mind telling me where it is, maybe I can swing by if I'm in the area."

Madison nudges you and whispers in your ear, "What the hell is Reilly doing? We can't tell her where the Junkyard is."
*choice
  #I intervene so Reilly doesn't give away our location.
    *set madison_faction %+(round(empathy/6))
    *set reilly_faction %-(round(20-(empathy/6)))
    You move in close to Reilly. Before he talks, you place your hand on his shoulder. "Hey can I talk to over here for second."
    
    Laurel laughs and shakes her head. "Don't worry. You don't have to tell me. It ain't all that deep. The world is a funny place and I'm sure if were going to meet up again it's meant to be."
    *goto LastLaurel
  #"She seems like a good person. It's fine if she knows the location of the Junkyard," I say to Madison.
    *set reilly_faction %+(round(empathy/6))
    *set madison_faction %-(round(20-(empathy/6)))
    Reilly goes on to give her the location of the Junkyard,
    *label ReillyTells
    *set laurel_knows_loc_junkyard true
    and she writes it down with a marker on her arm.

    "That's not too far from here. I'll look you up when I can," she says.
    *goto LastLaurel
  #It's Reilly's decision, but I give him a signal that I don't agree with telling Laurel.
    *set madison_faction %-(round(20-(empathy/6)))
    You wave your hands behind Laurel's back to let Reilly know you disagree with him giving away the location of the Junkyard. He tells her anyway,
    *goto ReillyTells

*label LastLaurel
*if with_murphy

  "What about me?" Murphy asks with a hopeful stare at you and your companions.
  
  Reilly glares back at him, and Madison scoffs and shakes her head.
   
  "I actually forgot that I have a few things I have to take care of," Murphy says. "I'll look you guys up…" His voice trails off, and he looks away.
  *goto CallElevator
*else
  *goto CallElevator

*label CallElevator
You call the elevator and step inside.
*if with_murphy
  Laurel and Madison join you side-by-side. Since the elevator is only made for a few people, you're forced to the back behind the ladies. That's when you notice Reilly call Murphy outside with him. For scientist hesitates, and Reilly wraps his arms around the man's shoulders and glances back at you with a sinister smile. As the doors slide close, you…
  *choice
    #Rush out of the elevator and stop Reilly.
      *set morality %+15
      *set humanity %+15
      Though you far back in the elevator, you are able to reach out and stick your hands between the doors before they close. You shove past Madison on your way out, and she bumps into you on your way past giving you the impression that she's trying to block your way. Squeezing past you exit into the control room. Reilly drops his arm from Murphy and shoves his revolver into the man's ribs.
      
      "I'm sorry, but I just can't let him live," he says, staring at you.
      
      Murphy's eyes swell with tears in his bottom lip quivers. You've heard the term "blubbering" before but never had a picture to it until now. "I don't want to die. I never meant to hurt you. I just wanted friends."
      *choice
        #"Reilly, you and I are friends, and as friends, I am asking you not to kill him. He doesn't deserve to die."
          *set truth %+15
          *set ideal %+15
          *if m_persuasion >= (120 - reilly_faction)
            *set prevented_reilly_kill_murphy 1
            *label ReillyAngryOverMurphy
            Reilly tilts his head to the side and scoffs. He squeezes his lips shut and his eyes follow like he's forcing away a giant scream or some explosion of emotion.  It comes out anyway with an earsplitting shout, and he turns and shoots at the buffet table, exploding a bowl of salad.
            *label SaveMurphy
            
            "Murphy, you have three seconds to get out of my sight, because I have five more bullets loaded in this gun," Reilly says.
            
            Murphy's blubbering stops cold, and he quick walks out of the room, looking over his shoulder every few steps but keeping his pace until he is out of your sight.
            *label ReillyElevator
            *set murphy_faction %+(round(empathy/6))
            
            Reilly steps to the edge of the elevator where Laurel and Madison hold the doors. He shakes his head at you, steps on, and taps his head against the metal wall. You follow him inside, and Madison hits the down arrow on the elevators panel.
            
            The elevator takes you on a short ride down to a ground-floor
            *goto ExitStation
          *else
            *label ReillyShootsMurphy
            *set murphy_alive false
            *set reilly_killed_murphy 2
            Reilly stares at you for a long moment, his expression blank and emotionless. You spot his hand twitch, and you hear muffled gunshots which quickly ripple through the control room in a blast of sound. Murphy's body jerks, and he takes two gasps of air before dropping to the ground. His head lolls sideways, and he tries to speak but only short wheezes of air escape his mouth.
            *label TryHelpMurphy
            *choice
              *if prof_health
                #I rush to help Murphy. It's my duty to try to save all life.
                  *set honor %+15
                  *label RushHelpMurphy
                  You drop by Murphy's side and cradle his head. He coughs, and blood pours out of the sides of his mouth. You lift his shirt, and see to ragged bullet holes in his ribs. Blood pulses out in waves. Even if you somehow could stop the blood flow, without immediate surgery, you doubt you can keep him alive. His glassy eyes stare at you, pleading. He mouths some words, but his voice is too weak.
                  
                  "We should go now," Madison says in a near quiet voice.
                  
                  Murphy's eyes fix on the ceiling, and his body goes still. His chest and stomach stop moving. You reach up and close his eyes, feeling no breath hit your hand, and you lay his head on the cold floor.
                  
                  The elevator door buzzes, and the down arrow blinks. You rise and walk to the back of the elevator, and Reilly steps on. The
                  *label TakeElevator
                  elevator starts with the jolt and takes you on a short ride down to a ground-floor
                  *goto ExitStation
              *if not(prof_health)
                #I rush to help Murphy. Maybe I can help him.
                  *set morality %+15
                  *goto RushHelpMurphy
              #I go back on the elevator. What's done is done.
                *set honor %-15
                You look down at the dying man and shake your head. You see no reason to watch him die on that floor, and so you walk back in the elevator and take your spot in the back behind the two women. Reilly steps on, and the
                *goto TakeElevator
              #"You had no right to do that, Reilly," I shout.
                *set impulse %+15
                "I had every right to do that. He deserved to die. I swore I'd never go back to prison, and this asshole put me there, " Reilly says, yelling back.
                
                You look down at the dying man and shake your head. He coughs, and blood pours out of the sides of his mouth. "We just can't kill everybody. Everything in this world is falling apart, and we can't fall apart too."
                
                Reilly shrugs. "I don't know what you want me to do. I wasn't going to let him live. You can hate me for it all you want, and you can kick me out of the group. I got my justice, and if I have to I'll live with whatever happens next."
                
                You stare back down at Murphy. His eyes are fixed on the ceiling, and his body is still. His chest and stomach aren't moving.
                
                The elevator door buzzes, and the down arrow blinks. You walk to the back of the elevator, and Reilly steps on. The
                *goto TakeElevator
        #"Don't kill him. Let him stay here alone while he starves to death. Killing him now would end his suffering." I just say this to convince Reilly not to kill him.
          *set truth %-15
          *set ideal %-15
          *if (m_persuasion >= (120 - reilly_faction)) or (m_intimidation >= (120 - reilly_faction))
            *set prevented_reilly_kill_murphy 2
            Reilly takes a step back and a slow realization comes over his face. "I kind of like the sound of that. You're going to die alone—you hear that? Everything you've done has been for nothing, and now you're going to spend your last days here with no one to help you and no one to talk to."
            
            Murphy tries to speak, but his words don't come out. He's shaking so much, his legs look wobbly.
            *goto SaveMurphy
          *else
            *goto ReillyShootsMurphy
        *if leader
          #"As leader of our group, I am ordering you not to kill him."
            *set honor %+15
            *if m_leadership >= 55
              *set prevented_reilly_kill_murphy 3
              *set reilly_faction %-(round(20-(m_leadership/6)))
              *goto SaveMurphy
            *else
              *goto ReillyShootsMurphy
        #I dive for Reilly's gun and knock it away before he shoots Murphy.
          *set impulse %+15
          Reilly holds his gun against the man's rib cage, providing little room for you to reach in and pull it away before he fires. You need to buy yourself some time and get Reilly to relax before you can disarm him.
          
          "Look Reilly, let's talk about this for another minute. No one's going anywhere and no one's coming to save him. We can talk, and you don't need to shoot him right the second." You creep forward every few words and close the distance between you and that gun.
          
          Reilly hangs his head and then looks up at you. "We can talk all you want after I kill him. Face it, it's got to happen. I'm not leaving here until he's dead."
          *if m_athletics >= 55
            *set prevented_reilly_kill_murphy 4
            *set reilly_faction %-(round(20-(empathy/6)))
            
            "That's fine, but we can still talk for a few more minutes. He hasn't eaten or drank anything, and it seems wrong to deny a dying man a last drink or bite to eat."
            
            Reilly turns to you, moving the gun a good foot away from Murphy's rib cage. "Seriously? This piece of shit doesn't deserve anything let alone a cold one and some nachos. What's this delay tactic your hitting me with? Are you trying to—"
            
            You dive for the gun. Both your hands cup his forearm and push it away. The gun fires, exploding a salad bowl across the room on the buffet table. Reilly shoves you back, and Murphy talks and runs out of the control room, tiny whimpers leaving a trail behind him.
            
            "Get out of the way," Reilly yells at you and turns the revolver's at the running man. 
            
            "It's over," you shout and hold your hands up. "It's over. Just let him go."
            *goto ReillyElevator
          *else
            He shifts his body closer to Murphy, and in that moment your gut tells you he's going to fire.
            
            You leap at him, extending your hands to his forearm. The pistol fires with a loud pop. You cry out in pain as the blast explodes in your eardrums. Murphy's body jerks, and he takes two gasps of air before dropping to the ground. You land next to him, and Reilly backs away, speaking to you with garbled words like he's underwater. A buzzing sound fills your ears, and you can't help but cover them with your hands until the noise stops. When they do you stare down at Murphy who writhes on the floor and gasps for breath.
            
            You…
            *goto TryHelpMurphy
        #"Reilly, if you kill him, I want @{with_nora you and Nora|you} out of the Junkyard. You won't be welcome with the group anymore."
          *set honor %-15
          *if ({social_skill} >= (120 - reilly_faction)) or (nora_join and ({social_skill} >= (105 - reilly_faction)))
            *set prevented_reilly_kill_murphy 5
            *goto SaveMurphy
          *else
            *goto ReillyShootsMurphy
    #Stay inside the elevator. I don't want to stop Reilly from what he feels he has to do.
      *set honor %-15
      *goto StayInElevator
    #Stay inside the elevator. I hope Reilly kills Murphy for what he's done to us.
      *set morality %-15
      *set humanity %-15
      *label StayInElevator
      *set murphy_alive false
      *set reilly_killed_murphy 2
      The elevator goes down, and you hear a muffled gunshot from above. You glance at Madison who has a look of satisfaction on her face. Reilly must've told her his plans, but for some reason neither decided to tell you.
  
      Before you can address this with Madison, the doors slide open to a short
      *goto ExitStation
*else
  Your companions join you on a short ride down to a ground-floor
  *goto ExitStation
  
*label ExitStation
hallway with thick glass doors leading to the outside of the research center.

You step off the elevator, and Laurel
*if laurel_faction >= 60
  pounces on you with a hug.
  
  "I'm going to miss you so much," she says. "Thank you for everything. It's not goodbye—it's so long for now."
*if laurel_faction < 60
  turns to you with a smile.
  
  "I'm outta here," she says. "Peace out, people. Stay safe. Remember to love one another."
  
She takes a pair of wired headphones out of her backpack, puts them on, and shakes her head to blaring music as she walks away from
*if reilly_killed_murphy = 2
  you and Madison.
  
  A few moments pass, and Reilly gets off the elevator. He stops, eyes you, and rubs his chin. "It had to be done, and there's nothing to discuss. Let's head back to the Junkyard." He walks ahead of you along the path, and Madison shrugs and follows.
  *goto LeaveRM
*else
  your group. She skips along the narrow paved path, stopping every once in a moment for a quick shake of her hips or kick of her legs.
  
  "That girl's got style," Madison says.
  
  @{((main_ro = "Reilly") or (second_ro = "Reilly")) "It|"Hell yeah she does. She's got all that and more. Besides, it} would be good to have a nurse in our group." Reilly says.
  *if nurse
    "No offense, ${firstname}."
  *goto LeaveRM
    
*label LeaveRM

Before you leave, you notice the elevator has no button on the outside to call it back down. It's a one-way elevator, and you don't know of another way in to the Control Center. Maybe you'll never need to come back here or maybe it's a problem for another day.
*label MissionEnd
*page_break
*set timecount +50
The return trip proves to be much quieter, almost eerily so as Madison and Reilly don't take the time to snap at each other. Then again, you feel weary and assume the two of them feel the same way.

Turning onto the road leading to the Junkyard, you pick up car tracks in the dirt. Since others in your group are taking out vehicles for scavenging trips, you think nothing of it until the bodies of zombies lie scattered outside the main gates. Since they're wide open, you drive through and see everyone in the middle of the yard. Pulling to a stop, you head over to find out what's drawing the crowd.

*if main_ro != ""
  *if (main_ro != "Madison") and (main_ro != "Reilly")
    As you reach the back of the circle, ${main_ro} rushes over to meet you.
  *if main_ro = "Bailey"
    She leans against you and gives you a quick kiss on the lips. "We have new people."
  *if main_ro = "Brody"
    He @{brody_rival bumps you with his shoulder, and you give him a playful push back.|He slides next to you, puts his arm on your shoulder, and kisses the side of your neck.} "You're not going to believe this, but we have new people here. I think they're staying."
  *if main_ro = "Gina"
    She moves in close until you can smell a mix of her perspiration and a soft sent of flowers. "While you were away, these people showed up, and it looks like they're staying."
  *if main_ro = "Jaime"
    He leans over and hugs you. "We have a lot to talk about. Some people showed up. I'll introduce you."
  *if main_ro = "Jillian"
    She takes your hands, leans in, and presses her lips hard into yours. Moments passed as you forget your standing in the middle of the Junkyard. Finally she pulls away. "Looks like we have a few more mouths to feed. People showed up, and it looks like they've got a spot at the table."
  *if main_ro = "Kelly"
    She wraps her arms around you and plants and kiss on your mouth. "So glad to see you're back. Every time you leave I miss you more and more. But look, we have guests, well…I guess they're more than guests."
  *if main_ro = lopez
    He slinks his arms around your waist and greet you with a kiss. "You might want to see this. Eli's inviting more people to live here."
  *if main_ro = "Madison"
    "What the heck is going on over here?" Madison asks and walks with you.
  *if main_ro = "Rachel"
    She grabs your hand, gives you a quick kiss on the mouth, and pulls you through the crowd. "Wait until you see this. We have to get Eli under control."
  *if main_ro = "Reilly"
    "What the hell are all these people doing? The gates wide open, and they're having a party?" Reilly asks and walks with you.
  *if main_ro = "Rosie"
    She jumps into your arms, almost knocking you over. She kisses your cheek, your neck, and your forehead. "We've got new people. They're kind of cool but also really super annoying."
  *if main_ro = "Tommy"
    He moves his body in close to yours and gives you a kiss. His scent fills your nose, and you feel dizzy for a moment. "We've got company. I don't know what's going on, but it sounds like they're staying," he says to you.
  *if main_ro = "Woody"
    He leans in close to you, looks around to make sure no one's watching, and gives you a kiss. In the next moment his expression changes to annoyance. "In a few short hours, we started inviting people in like it's the gosh darn Hilton. You better check it out."
  *goto BFSCheck
*elseif (main_ro = "") and dependent
  As you reach the back of the circle, ${dep_name} rushes over to meet you. "${name_call}, Guess what? You're never going to guess who's here, not in a million years. Come on. I'll show you."
  *goto BFSCheck
*else
  As you reach the back of the circle, Kevin walks up to you. "I just want to say this wasn't my idea. I told them they can't stay, but you know my dad. Just don't blame me is all I ask."
  *goto BFSCheck
  
*label EliFred
Eli puts his hands on his hips and turns to you. "I'll tell you, this guy was one of the best mechanics I've ever employed. He could take a broken down engine and make it purr like a tiger. Maybe I'll hire him again if he is not to much of a big shot city mechanic."
*return

*label BFSCheck
*set billie_junkyard true
*set fred_junkyard true
*set sean_junkyard true

The group lets you through to an SUV near the start of the garage. Three people stand by the front bumper. One of them, a dark skinned heavyset man with a short salt-and-pepper beard chats with Eli. A pale skinned man smokes a cigarette with his bony arms folded over his chest. He has thick messy hair and a sharp nose with eyes looking everywhere. Finally there is an olive skinned young woman who's rambling on, though no one seems to be listening. That's when you do a double take and realize it's
*if fred_introduced
  *set target 2
  Fred, your former neighbor in Nightfall.
  
  "Oh, hi ${firstname}. It's me, Fred. I hope you liked that chili I left you."
  
  "I can't believe you're here. @{went_to_freds That was nice of you to leave chili for me.|I never got the chance to go to your house.} Wait, what are you doing here?"
  
  "I've been friends with Eli for years, ever since I worked at this junkyard, maybe fifteen years ago. Things have changed, that's for sure. It's really good to see you. I was worried about you."
  
  *gosub EliFred
*if sean_introduced
  *set target 3
  Sean, your former neighbor in Chipper Ridge.
  
  "Well damn, who let this ${guy} in. Get over here and shake my hand," he says to you with a huge smile. Before you can resist, he grabs her hand and shakes it like a politician in front of a reporter.
  
  "What are you doing here?" you ask.
  
  "Fred over there, the one who looks like a younger James Earl Jones, well he used to work as a mechanic for Eli. Fred put together my first motorcycle and fixed it every time I crashed it. Needless to say I got to know him very well. Sheila was a helluva bike. Anyway, he suggested we come here, because it's off the beaten track. Damn, you're a sight for sore eyes."
*if billie_introduced
  Billie, your former neighbor in Stodgy Farms.
  
  "Oh my God, oh my God, oh my God, is that you, ${firstname}? I just drank some really cloudy water, so please tell me you're not a hallucination."
  
  "It's really me, Billie. What are you doing here?"
  
  She steps away from the SUV and hops next to you. "I was walking down the highway and came across Butch and Sundance over there," she says, motioning to the two men. "Their real names are Fred and Sean. If it wasn't for me, they'd be toast. Bitten by infected toast. They didn't even see a zombie walking up to them while they were parked by an overheated car. And then these two guys came out of nowhere in this SUV and try to rob us. But I save the day again, and then Sean stole the SUV, and here we are. Fred used to work for Eli as a mechanic, and oh my God I'm so glad to see you."
*if not(billie_introduced)
  
  The woman makes her way over to you and waves even though you're two feet from her. "I'm Billie. It's good to finally meet you although I haven't really heard a lot about you. Fred just said you were his neighbor. He doesn't talk a lot. Oh and this is my dog Mishy. Come here, girl." A small, tan dog pops her head up in the back of this SUV and rushes out of the open back door. She trots over to you.
*if not(fred_introduced)

  The dark skinned man waves to you and steps over with the hesitation to his walk. "Hi, I'm Fred."
  
  "I'm ${firstname}," you say.
  
  He offers his hand for you to shake but retracts it and then extended again. Before you have a chance to shake, he pulls his hand back again. "It's good to meet you." He walks back over to stand near the car.
  
  *gosub EliFred
  
@{sean_introduced The pale skinned guy smoking the cigarette blows smoke out of his mouth and walks up to you. "How's it going—I'm Sean. We were just talking|Sean runs his hand through his hair a few times. "Now that we've gotten all the introductions set aside, we should talk} about where we're all staying." He dies out his cigarette on his shoe and flicks it into a pile of trash. "They told me Eli runs this place, but @{leader you're|${group_leader}'s} the leader of the group. So how does that work? Because Eli said we're welcome to stay, so I'm not sure why I got to run it by anyone else."

Kevin walks over to his father and pats him on the shoulder. "Hey dad, can you help me in the garage for a minute? I forget how to get the gas cap off that old Chevy in there."

Eli shakes his head. "I've told you this a million times—it's backwards. You just have to twist it the reverse way. Come on, I'll show you."

As they walk away, Kevin looks back and nods to your group.

*if leader
  Addressing the situation, you say…
  *choice
    #"Of course you all can stay. We're happy to have you here with us."
      *set morality %+15
      *set billie_faction %+(round(empathy/6))
      *set fred_faction %+(round(empathy/6))
      *set sean_faction %+(round(empathy/6))
      *if sop = 1
        *goto NonDemocratic
      *elseif sop = 5
        *goto RaidGroup
      *else
        "Thanks, ${firstname}. We're damn lucky to find this place and some good people running it. There's a lot of douche bags out there already," Sean says.
        *goto InviteBFS
    #"Eli is confused about the outbreak, so we're staying here and have taken over the Junkyard. You can stay if you follow our rules."
      *set honor %+15
      *set fred_faction %+(round(empathy/6))
      *set sean_faction %+(round(empathy/6))
      *if sop = 1
        *goto NonDemocratic
      *elseif sop = 5
        *goto RaidGroup
      *else
        "You don't have to worry about us. We'll follow the rules," Sean says.
        *goto InviteBFS
    #"Eli is not in charge here. I am. You can stay, as long as you prove your value to the group."
      *set honor %-15
      *set fred_faction %+(round(empathy/6))
      *set sean_faction %+(round(empathy/6))
      *if sop = 1
        *goto NonDemocratic
      *elseif sop = 5
        *goto RaidGroup
      *else
        "You don't have to worry about us. We'll sing for our supper," Sean says.
        
        "Like karaoke?" Billie says, perking up.
        
        "He doesn't literally mean singing, he means working hard. Geez, even I know that," Brody says.
        
        Billie sticks her tongue out at him.
        *goto InviteBFS
    #"I'm the leader, but we decide things as a group."
      *set diplomacy %+15
      *set billie_faction %+(round(empathy/6))
      *set fred_faction %+(round(empathy/6))
      *set sean_faction %+(round(empathy/6))
      Sean shakes his head. "Fine, have your little powwow."
      *if woody_join
      
        Woody raises his hand, extending one finger. "A powwow is a celebratory or ceremonial event among certain indigenous peoples and using it outside of that diminishes its importance among those people."
        
        Sean blinks a few times. "Who the hell are you? You're not even Indian."
        
        "Who the hell are you?" Woody shouts.
        
        "This is my cousin. Maybe you shouldn't offend him when he's going to be voting in a few minutes," Jaime says.
      
      You step back and raise your hands, waving everyone towards the opposite side of the yard. "Can everyone follow me over here for a moment?"
      *goto GroupDiscussesBFS
    *if billie_introduced
      #"Billie can stay, but you two have to go," you say, pointing to Fred and Sean.
        *set morality %-15
        *goto KickoutBFS
    *if fred_introduced
      #"Fred can stay, but you two have to go," you say, pointing to Billie and Sean.
        *set morality %-15
        *goto KickoutBFS
    *if sean_introduced
      #"You can stay, but you two have to go," you say, pointing to Billie and Fred.
        *set morality %-15
        *goto KickoutBFS
*else
  *if group_leader = "Rachel"
    Rachel steps up to address the newcomers. "We came here as guests and quickly realized Eli does not have the capacity to run this junkyard and maintain safety. We talked it over with him and Kevin, and we are working together to improve our chances of surviving this outbreak. As for you staying, it's possible, but will need to discuss it with our group."
  *if group_leader = "Jaime"
    Jaime steps up to address the newcomers. "Eli brought us here, but we realized he had some confusion about this outbreak. He doesn't even think there is an outbreak. So we decided to stay here and run the place, since it is safer than anywhere else we have come across. We're not trying to kick anybody out or taking advantage of his kindness, but we just can't be taking everybody without our group agreeing to it, and I mean everybody."
    
  Sean scoffs and waves his hand in the direction of the group. "So my fate is in the hands of a bunch of strangers? You think this is how it goes down? Is that supposed to be fair?"
  
  Billie's face turns red, and she starts whimpering. "You have no idea how long we've been on the road: the horrible things we've seen, the places we had to sleep, the food we've had to scrape together. If you kick us out of here, I don't know how much longer I can go on." She buries her head in Fred's chest.
  
  *if group_leader = "Rachel"
    "Our intention is not to upset any of you, but to make decisions that work best for everyone. Our group will have a little chat, and we will tell you our decision," Rachel says.
  *if group_leader = "Jaime"
    Jaime raises his hands like he's on a highway trying to stop a speeding truck. "Look, I'm sorry. I'm not trying to upset you. I just don't want to make a decision without checking with my friends here. Just give us a few minutes."
  *goto GroupDiscussesBFS
  
*label NonDemocratic
*set church_approve true
*set dante_approve true
*set jaime_approve true
*set nora_approve true
*set reilly_approve true
*set tommy_approve true

"Wait, don't we get to take a vote or something?" Brody asks.
*if gina_join

  "I would like a vote," Gina says.
*if kelly_join

  "I thought this group was a democracy, not a dictatorship," Kelly says.
*if parker_join

  Parker throws his hands up in anger. "Now we're going to just make decisions without asking anyone's opinion?"
  
Reilly steps in front of the crowd. "We elected a leader, so let that person lead. I don't want to stop and take a vote every five minutes. Just let ${firstname} make the decisions and stop bitching about it."

"@{target Billie|Fred|Sean} is my friend, and I am not going to abandon her and her friends. I realize were not voting on this, but you just have to trust me on this one."

@{parker_join "It's not that we don't want them here, it's that we aren't even given a vote. We are supposed to make decisions together, and everyone gets a voice," Parker says. "It's okay. We'll get over it, and your friends are welcome. But let's vote next time."|"I think people are more upset about the lack of a vote than they are about people joining us," Jaime says. "Your friends are welcome here though. We'll make room for them."}
*goto InviteBFS

*label GroupDiscussesBFS
*set bailey_approve true
*set brody_approve true
*set church_approve true
*set dante_approve true
*set driver_approve true
*set gina_approve true
*set jaime_approve true
*set jillian_approve true
*set kelly_approve true
*set kevin_approve true
*set lopez_approve true
*set parker_approve true
*set reilly_approve true
*set rosie_approve true
*set tommy_approve true
*set woody_approve true
The entire occupants of the Junkyard glide fifteen feet south of the SUV and the newcomers and Eli who remains with them.
*if leader
  You stand before them all to address them.
  
  "Everyone, listen up.
  *if sop = 1
    We're running this group as a democracy, so we're going to take a vote on these three who want to stay at the Junkyard. Anyone who wants to share their opinion on why they vote one way or another, please feel free to do so now."
  *if sop = 2
    We are trying to build a community of like-minded survivors, and we have three new potential members who would like to join us. Before we vote I'd like to open up the floor for anyone who would like to share an opinion on letting them join or not."
  *if sop = 3
    Normally I wouldn't bother you with decisions about how this group runs, but I want to give everyone a vote on whether we should accept these new members are not. Before that I'd like to hear from any of you who want to state an opinion."
  *if sop = 4
    We've been working hard at building up this Junkyard so we can survive this outbreak and beyond. We have a few people who want to join us, and I'm going to allow a vote on whether we should let them in or not. Anyone want to voice any concerns or give an opinion before we vote?"
  *if sop = 5
    Normally I'm not interested in inviting people to join us. This world has become too dangerous to accept outsiders, but I have history with one of these people. If were going to survive we need numbers, but we need the right people. So were going to vote on taking them in or kicking them out. Anyone have any opinions on those three before we make a decision on their fate?"
*if group_leader = "Rachel"
  Rachel stands at the front and addresses the group.
  
  "This will only take a moment, and everyone can then return to their duties. We have three new people, outsiders, who would like to live among us and contribute to our group. One of them has a history with Eli and with ${firstname}. Besides that, we know very little about them all. Before we take a vote, I'd like to open this up to a discussion. Do you think they should join, or should we turn them away?"
*if group_leader = "Jaime"
  Jaime stands at the front addresses the group.
  
  "Hey everyone. This will only take a minute. We haven't had any new members want to join this group in a few days, but now we have three people who want to live here in the Junkyard and maybe even help us out. Maybe they have as much right to be here as we do, but for now things affect us a lot more than just Eli, so we have to decide. Do we let them stay or ask them to move on its? We should vote, but before we do, I like to hear from anyone who wants to talk. Do you have any concerns or feel like we should let them in?"

"I'll go first and get this over with," Madison says. "I vote not to let them in and Brody will vote to let them in, so we cancel each other out. Next."
*if church_join

  "I don't see how we can turn these people away, and we can definitely use them," Church says.
*if dante_join
  
  Dante slides up to the front of the crowd. "You know I'm going to say they should join us, so that's my vote."
*if driver_join

  ${driver} raises his hand until @{leader you call|${group_leader} calls} on him. "This outbreak has turned the world into a desolate and unfriendly place. We should share what we have with these three, or else we condemn them to death. And what do we have to share but something we have just claimed ourselves. It isn't even ours to offer, and yet we vote on the inclusion of three souls in the Apocalypse."
*if rosie_join

  @{driver_join "Yeah, what he said." Rosie puts a strand of hair in her mouth, spits it out, and looks at ${driver}. "Wait, what?"|"I say let them in. There is a lot to do around here. If they don't work out, give 'em the boot. But we can try them first." Rosie puts a strand of hair in her mouth, spits it out, and coughs.}
  
Reilly shrugs and holds his arms up. "I like that Sean guy even though he's got a big mouth and he's kind of pushy. Fred is a mechanic, so we can use him. I don't know what to say about the other one, but she doesn't look like she'd caused much trouble."
*if nora_join

  Nora holds her hand to her heart and fakes chest pains. "My son has a heart. I can't believe it."
  
  *if leader
    "So how do you vote, Nora?" you ask.
  *if group_leader = "Rachel"
    "Do you agree with your sons vote?" Rachel asks.
  *if group_leader = "Jaime"
    "So you agree with him, Ms. Nora?" Jaime asks.
    
  Nora points a thumb to her chest. "Who me? I don't care one way or another as long as they don't touch my bed and stay out of my way."
  *if ray_join
  
    Ray steps up next to you and holds his fist out like an Emperor in front of a gladiator. $!{he} @{nb turn|turns} ${his} fist and @{nb point|points} it to the @{(morality >= 50) ground. "Kick them out."|sky. "Invite them in."}
*if (main_ro = "Bailey") or (second_ro = "Bailey")

  *if leader
    You look across the crowd to find Bailey standing behind Brody and Madison like she's trying to hide.
    
    "Bailey, what do you think?" you ask.
    
    When you call on her, she
  *if group_leader = "Rachel"
    Rachel searches the crowd and points near the twins. "Bailey, I'd like to hear from you."
    
    Bailey
  *if group_leader = "Jaime"
    Jaime searches the crowd and points near the twins. "Bailey, would you like to say anything?"
    
    Bailey
  smiles and lowers her hoodie. The twins step apart, so everyone can see her. "Billie seems nice, and it would be great to have someone else my age around here. I'm okay with Fred and Sean if everyone else is."
*if (main_ro = "Gina") or (second_ro = "Gina")
  
  "I was invited to this group most recently. It would be pretty stupid of me to deny someone else an invitation to this group when I was in their shoes only a few days ago," Gina says.
*if (main_ro = "Jillian") or (second_ro = "Jillian")

  Somehow members of the crowd all look at once to Jillian. When she sees the stares, she raises her hands defensively. "Why is everyone looking at me? It's not like I have any big say in the matter. Sure, let them in. Let everyone in."
*if (main_ro = "Kelly") or (second_ro = "Kelly")

  @{leader You find Kelly in the crowd and not to her.|"What about you, Kelly?" ${group_leader} asks.}
  
  She runs a hand through her hair and holds it out of her face, revealing a look of hesitation. "I don't want to say they can't join us, but I'm starting to get worried about how were going to feed everyone. I know we'll make it happen, but I'm worried. But I vote yes."
*if (main_ro = lopez) or (second_ro = lopez)

  ${lopez} coughs and gains everyone's attention. "If they have been able to survive since the beginning of the outbreak, then they must know what they're doing. I vote to let them stay here and be a part of us."
*if (main_ro = "Tommy") or (second_ro = "Tommy")

  "Everyone needs help sometimes, and right now we are able to help them by giving them a place to stay. So my vote is yes," Tommy says, looking over at the three newcomers as he speaks.
*if (main_ro = "Woody") or (second_ro = "Woody")
  
  Woody walks out in front of the crowd and paces in front of them. "Not sure why we are debatin'. We've not been the kind to turn people away. If Eli says we're supposed to invite 'em in, who're we to defy the man with his name on the deed? Besides, they can help out around here, and we're going to need the extra hands."
  
Kevin steps up in front of everyone, hands in his pockets and staring at the ground as he speaks. "Since this is my father's Junkyard, I should get a vote at least. Fred's a good dude. He stops by every Thanksgiving with a turkey for my father, and for every year he worked here he made us Thanksgiving dinner. That's just the type of guy is. I don't know those other two, but if they're friends of Fred's, they're okay in my book." He walks back into the crowd.

*if leader
  "Well then, it's settled. No need to vote. I'll tell them the good news," you say.
*if group_leader = "Rachel"
  "I doubt a vote is needed. It looks fairly unanimous, so I will let our three friends know they can join us," Rachel says.
*if group_leader = "Jaime"
  "Doesn't look like there's any need to vote with some many people in agreement. I'll call them over to let them know they can join us," Jaime says.
*goto InviteBFS

*label RaidGroup
*set bailey_approve true
*set brody_approve true
*set church_approve true
*set dante_approve true
*set driver_approve true
*set gina_approve true
*set jillian_approve true
*set lopez_approve true
*set madison_approve true
*set reilly_approve true
*set rosie_approve true
*set tommy_approve true

"I don't have a problem with your friends joining, ${firstname}, but they'd better be ready to get their hands dirty," Reilly says.

"I got no problem working hard," Fred says.

Sean smirks. He puts a cigarette in his mouth and pats his pockets with frustration. "We've gotten our hands pretty dirty. We haven't had a day off since the start of this crap.Just a few minutes before we got here, we got ambushed by a whole swarm of infected and almost had a car coming over."

@{lopez_join ${lopez} snickers. "He doesn't mean working hard. We don't just scavenge abandoned houses. Sometimes we have to take supplies from other people. You gotta be cool with that."|Madison scoffs. "He's not talking about work. He's talking about going out with us and scavenging and taking supplies from other groups if we have to."}

Billie gasps. "You mean robbing other people?"

"We do what we gotta do," Reilly says. He tosses a lighter to Sean.

Sean catches it, likes the end of his cigarette, and tosses it back to Reilly. "We'll do our part no matter what."
*goto InviteBFS

*label NoTrouble
"I'm glad you didn't have any trouble out there," Rachel says.

Jaime nods in agreement. "It's always a worry whenever you head out that you may not make it back."
*return

*label KickoutBFS
*set jillian_approve true
*set lopez_approve true
*set madison_approve true
*set nora_approve true
*set reilly_approve true
*set rosie_approve true
*set billie_faction %-(round(20-(m_leadership/6)))
*set fred_faction %-(round(20-(m_leadership/6)))
*set sean_faction %-(round(20-(m_leadership/6)))

"Wait, hold on. We all came here together, and we're all staying," Sean says, his voice raised.

"Watch your tone, brother," Reilly says.

"I'm not your brother." Sean backs away to the hood of the SUV and lowers his voice.
*if church_join

  "I know we don't have a lot of room around here, and supplies are limited, but I don't feel right turning any of them away," Church says.
*if dante_join

  "We'll make room for them. Turning people away at this point is just a death sentence," Dante says.

"You can't ask two of them to leave, when they all came together. We can figure this out. We can fix up some areas or make room in the car lot, but I think they should all stay," Jaime says.

Rachel leans in close to you. "Usually I would not be in favor of this, but we may need the extra hands around here, especially considering the Silverthornes and now a new group across the lake."

You shake your head and sigh. "Fine, you can all stay, but you better prove your value around here. Consider this a probationary period which lasts for long as I say it does."
*label InviteBFS
*gosub_scene Part3Events ChangeGroupStat "allegiance"
*gosub_scene Part3Events ChangeGroupStat "morale"
*gosub_scene Part3Events ClearApprovals
*set billie_join true
*set fred_join true
*set sean_join true
*set billie_junkyard true
*set fred_junkyard true
*set sean_junkyard true

The group circles the three newcomers, every member introducing themselves. Hands are shook and backs are patted. Eli invites everyone to dinner—a barbecue in the middle of the yard. Everyone seems content and even a bit more hopeful with these three newcomers joining the group. While you move to the back of the crowd to give others room to meet Billie, Fred, and Sean, you feel a tap on the shoulder and turn to see Rachel and Jaime.

"Why don't we talk about your trip to the research station," Jaime says and waves you towards the house. Agreeing, you walk with them into the main office. Eli spends little time here nowadays, and it has become a central hub for Junkyard command. Hunting posters and the [i]Hot Ladies of Towing[/i] calendar are gone, replaced by maps of the area and a blueprint of the Junkyard.

"I tried to chat to Reilly and Madison, but both told me to speak to you," Rachel says, sitting on the corner of the desk.

"Were there any problems there?" Jaime asks.
*choice
  *if not(captured_arc) and visited_greenhouse_pinky
    #"We had some trouble. We were attacked by a scientist in a greenhouse."
      *set truth %+15
      Jaime's face takes on a grim expression. "Attacked? You and Madison and Reilly all look fine, so I'm guessing everything turned out okay. What happened?"
      
      "We went into this greenhouse where they were growing different strains of plants and someone started shooting at us.
      *if not(shooter_alive)
        We had to kill him.
      *elseif shooter_surrendered
        We forced him to surrender to us.
      *else
        We had to subdue him.
      After that we were able to search the greenhouse."
      
      "I'm just glad you all made it out safely," Rachel says.
      *if reilly_poison_gas
        
        "The shooter put out some kind of poison trap, and Reilly got hit with it. I didn't see any effects from it, but we should keep an eye on him for a while," you say.
        
        Jaime shakes his head. "It really sucks that we have to send people out into dangerous situations just to find the food and supplies we need."
      *if talked_to_shooter
      
        "We were able to talk to the shooter. He was not mentally stable but he did answer a few questions for us, mostly about what to expect inside the research center.
        *if shooter_alan
          His name was Alan David and he had worked there before the outbreak.
        *if paynes_research_mission
          He was attacked by a group of bandits who came to the research center to scavenge. They beat him up pretty badly.
        *if warned_about_arc_by_alan
          He told us the place was put on lockdown but there's lots of equipment and gear inside.
        @{visited_arc We went in and searched through the upper levels but didn't want to go any farther. The place already had lots of zombies, and we didn't want to risk it any further.|After talking to him unchecking the outside, we all decided not to go in the research center. It sounded like a deathtrap.}
      *goto NextDebrief
  *if captured_arc
    #"We had some trouble. @{visited_greenhouse_pinky We were attacked by a scientist in a greenhouse and another|A} scientist imprisoned us for several hours, but we were able to escape."
      *set truth %+15
      Jaime's face takes on a grim expression. "Imprisoned? How the hell did that happen? Are you okay?"
      
      "I'm @{(ideal >= 50) fine. He didn't hurt us but just kept us apart in separate rooms until we finally broke out.|good considering he knocked us out with some kind of gas and locked us in separate rooms with no way to communicate to each other. I thought he was going to kill us.} It turned out that he wanted to keep us there until we became his friend. I know it sounds strange but it was like he wanted pets for the apocalypse."
      
      "Where is this scientist now?" Rachel asks.
      
      *if murphy_alive
        "As we were leaving the facility, Reilly was going to kill him, but I convinced him not to. We left the scientist, whose name is Murphy, behind in the facility. I believe he left right after we did, because there was nothing left for him there."
      *if not(murphy_alive)
        *if reilly_killed_murphy = 0
          "I killed him. @{(honor >= 50) I saw no other way to escape than to eliminate him. Leaving him alive presented too many risks."|He had to die for imprisoning us."}
        *if reilly_killed_murphy > 0
          "He's gone, killed by Reilly.
          *if reilly_killed_murphy = 1
            During his escape, Reilly killed the scientist, whose name was Murphy."
          *if reilly_killed_murphy = 2
            Right as we were leaving the facility, Reilly stayed back with the scientist, whose name was Murphy. I heard gunshots, and Reilly came down later."
          
          "I can't say I blame him," Rachel says.
          
          Jaime shakes his head. "I guess. Considering Reilly spent time locked up, he wasn't going to let that Murphy guy live after taking away his freedom again.
        But he was a scientist and maybe we could have used him."
        
        "For what? How can you trust someone who imprisoned you?" Rachel asks.
        
        "I don't know. @{(reilly_killed_murphy > 0) I'll tell you what I do know—Reilly has a mean streak. Even if it was justified, his answer to everything seems to be violence which could be a problem in this group."|At some point we have to start taking a chance on people. What he did was wrong but maybe we could have given him a group and got him right again. It's tough, but if we don't start giving second chances, there will be no one left."} Jaime steps back, hands on his hips, and brings out a deep sigh.
      *goto NextDebrief
  #"We killed a few zombies but nothing out of the ordinary during this outbreak." I don't want them to know what we encountered.
    *set truth %-15
    *if m_persuasion >= 65
      *gosub NoTrouble
    *if m_persuasion < 65
      *set rachel_faction %-(round(20-(empathy/6)))
      *set lied_to_rachel +1
      "I'm glad to hear it," Jaime says.
      
      Rachel furrows her brow. "Are you sure? Just a few zombies and nothing more?"
      
      You shake your head. "Like I said, a few infected."
      *goto NextDebrief
  #"Nothing we couldn't handle." No need to worry them over something that's not relevant to our ongoing survival.
    *set impulse %-15
    *if m_persuasion >= 65
      *gosub NoTrouble
    *if m_persuasion < 65
      *set lied_to_rachel +1
      *set rachel_faction %-(round(20-(empathy/6)))
      "I'm glad to hear it," Jaime says.
      
      Rachel furrows her brow. "Are you sure? Nothing happened out of the ordinary?"
      
      You shake your head. "Nothing to worry about."
      *goto NextDebrief
      
*label NextDebrief
      
"Do you think it would be worth it for us to relocate to the research facility?" Rachel asks.
*fake_choice
  #"No, the research facility is far less accommodating than the Junkyard."
    *set truth %+15
    "That type of facility with two greenhouses sounds perfect for us.?" Jaime asks.
    
    You shake your head. "No, between all the zombies and the facility being locked down, it would be too risky and take too much effort to make it worthwhile."
    
    Rachel rubs her chin. "That's disappointing."
  *if warned_about_arc_by_alan
    #"Possibly, but it would take a lot of work. The main building has been locked down, and the other areas are just greenhouses."
      *set ideal %-15
      "Locked down?" Jaime asks.
      
      "The main research facility, called the ark, has a system that has been activated which electronically locks all doors in the event of a catastrophe. One of the scientists activated the lock, and we could find no way to deactivate it. The other buildings are just greenhouses which have been looted or infested with zombies. I don't think that compound would be any better for us than staying here. In fact the Junkyard is much more secure at the moment."
      
      Rachel rubs her chin. "That's disappointing. It sounds like that facility has amazing security features, but if we can't gain control of them, it's rather pointless. Oh well, we will go with plan A and remain here."
  #"It may be worth it for some of us to take over the facility, while some of us stay here." This is my chance to get rid of some of our members.
    *set truth %-15
    *set lied_facility_move true
    "So it would be worth it to send a small group over there?" Jaime asks.
    
    "It would be worth it. Sure, there is some work to be done. It's a research facility, so it's not going to be comfortable for everyone. Then again, the Junkyard is no five-star hotel. With a bit of work, we can make the research facility a comfortable and secure place to live for a number of our group while others live here."
    
    *if m_persuasion >= 65
      "Well done for scouting out this place and finding it for us. This is really great news," Rachel says.
    *if m_persuasion < 65
      *set lied_to_rachel +1
      *set rachel_faction %-(round(20-(empathy/6)))
      Rachel folds her arms over her chest and leans forward. "So you believe this facility has more to offer than the Junkyard?"
      
      "It offers us an alternative. Even now we have three new people moving in, so we have to figure out where were going to put everyone. The research facility has room, but we need to fix the place up and make it a bit more secure."
      
"Moving on, can we go back to gather more supplies?" Rachel ask.
*fake_choice
  #"No, there are little supplies left. The main building has been locked down, and the other areas have been looted."
    *set truth %+15
    Jaime grumbles. "Damn it. I was hoping there would be a huge stockpile in there. A research facility should be well-stocked."
    
    "Believe me, we looked. We took supplies from a few offices and from a storage area, but getting back to them would put us at risk. There are a number of infected in the main area, and a lot of people know about that research facility. It's a target for scavenging from anyone."
  #"It would take a lot of work, but if we brought a large team, we can strip all the valuable gear and resources of the place."
    *set ideal %+15
    Jaime strokes his chin. "I'm not sure that's worth it unless you think some of those resources are worth the effort and the risk. I'm not sure what we could even do with high end scientific equipment. @{(science >= 50) That's more your area of expertise.|It's not like any of us can use it.}"
    
    "I don't think it's worth it. We have many other areas to explore which may offer opportunities for food and resources," Rachel says.
  #"No, we took everything we could find. There's nothing left, and the place is overrun by zombies by now." I lie to her just in case I ever want to go back to gather supplies for myself.
    *set truth %-15
    "We scavenged as much as we could find. There may be a little left to take, but I'm not sure it's worth the risk of encountering the raider group."
    
    "That research center isn't too far away, so I wonder if we have to worry about that raider group anyway," Jaime says, stroking his chin.
    
    Rachel nods. "As time goes on we will have to deal with a lot more aggressive groups. As resources dwindle in an area, competition pushes everyone to more violent and antisocial behavior. It's inevitable, so we will have to prepare for it."

Shouts and gunfire call from outside, and you hear crying screams as someone runs into the garage. Billie slams against the glass partition, her hands covered in blood which she smears along the window.

"Oh my God, oh my God…they got in. The infected got in!" she shouts, crying and shaking the window. Her dog, Mishy, runs inside and lies down on the garage floor, her eyes wide and round. Her soft whimpers echo.

You, Rachel, and Jaime burst from the office and into the yard, into chaos. Shouting, screams, blood, crossfire, howls of the infected. You look around and scan the inside of the Junkyard, taking in as much as you can in a moment.

*if church_join or (gina_join or driver_join)
  Zombies writhe on the ground in a pack, their hands digging and pulling up blood. At the bottom of the pack, a pair of legs poke out, twitching.
Brody @{bailey_join and Bailey stand|stands} towards the front of the yard and attack zombies as Fred and Kevin work on closing the main gate.
*if tommy_join
  Tommy stands at the other gate and pushes it into the zombie stragglers trying to make their way in.
Madison @{dante_join and Dante have|has} climbed to the top of a storage container and @{dante_join fire|fires} down on the infected.
*if rosie_join
  Rosie @{driver_join uses her submachine gun like a baseball bat and swings wildly at the pack towards the front of the Junkyard.|stands by the camper van and fires wildly with her submachine gun.}
*if jillian_join
  Jillian @{nora_join and Nora shoot pistols|shoots a pistol}
*if nora_join and not(jillian_join)
  Nora shoots a pistol
*if jillian_join or nora_join
  through an open window from inside the RV.
*if kelly_join
  Kelly
*if parker_join
  @{kelly_join and Parker|Parker}
*if kelly_join or parker_join
  @{(kelly_join and parker_join) use two-by-fours|uses a two-by-four} to push zombies away as they attack.
*if lopez_join
  In the center of the yard, ${lopez} takes careful shots with his carbine, dropping infected after infected.
With a quick count, you guess over two dozen zombies have entered the Junkyard.
*if ptsd
  *set p_health %-(round((100-sta)/5))
  *set stress %+(round((100-wil)/5))
  
  The sounds of gunfire, the screams, and the house of the infected all washed together in a union of discord. It all warbles together like you're underwater, and everything moves around you in slow motion. Your vision blurs like you're looking through a fishbowl at the world. You take a few steps and trip over your own feet. Tumbling, you hit the ground hard and feel dampness on your right arm. You're in a state of confusion and each second has the world spinning faster and faster.
  
  Something lifts you in the air, and your vision clears enough to see Jaime holding you up.
  
  "Are you okay? Can you stand on your own?" he asks.
  
  "I…I'm fine," you say.
  
"We need to get those gates closed," Sean yells and swings a clawed hammer into the head of an infected. When it drops, the zombie reaches up to grip Sean who stomps its head with his foot.

Eli runs in a short line through the middle of the yard, turns, and cuts back towards the main house, his face full of fear, his movement erratic, frantic.
*if pet_owner

  ${pet_name}
  *if small_pet
    lies beneath the RV, his tiny body shaking and eyes darting left to right.
  *if not(small_pet)
    @{husky howls|barks} At one of the infected, who chases him in a circle around an oil drum. The dog keeps just out of the zombie's reach, leaping away when it gets too close.

Reilly hobbles towards you holding his @{woody_join head, his other arm wrapped around Woody's shoulders who half carries him into the garage. The two collapse|head. He stumbles into the garage and collapses} to the floor as you run past.

"The old man let them in," Reilly says. His hand presses on a gash across his forehead with blood coming between his fingers.
*if woody_join

  Woody takes his rifle off his shoulder and runs with you.
*if dependent
  
  As soon as you reach the middle of the yard, you look around for your nephew but see him nowhere. You shout, "Does anyone know where ${dep_name} is?"
  
  @{nora_join "My ma took him in the RV with her.|"He ran into the RV.} He's safe," Reilly shouts.
  
Mishy runs to Reilly and lies next to him. He drapes his arm across the dog and rubs her head.
  
Rachel draws a pistol and fires clean shots into the heads of advancing infected, while Jaime sprints forward and shoulder blocks a zombie into another. As you join the battle, you decide to…
*if dependent
  *set dep_weapon ".38 Special"
  *set dep_mod 5
  *set dep_class "pistol"
  *set dep_weaponmode "a shot"
  *set dep_type "ranged"
  *set dep_arrow "shot"
*set main_target ""
*choice
  #Attack zombies in the middle of the Junkyard.
    *set leader_role %+10
    *label AttackJY
    *set using_primary false
    *gosub_scene CheckWeapons
    *set ranged_matters false
    *set target_difficulty 100
    Observing the mayhem, you decide your best effort would be spent fighting off the infected, and you draw your…
    *fake_choice
      #$!{p_weapon}.
        *gosub_scene FightCode UsePrimary
        *set using_primary true
      #$!{s_weapon}.
        *gosub_scene FightCode UseSecondary
    *gosub_scene FightCode AttackResult
    With all of the movement in the Junkyard, the survivors fighting off the infected and the infected striving to bite the closest living being, you struggle for a moment in deciding where to join the fight.
    *gosub BattleVignette
    *goto JunkyardBattleKnit
  *if leader
    #Climb to the top of the RV and call down orders to coordinate our efforts.
      *set leader_role %+15
      With the mayhem in the Junkyard, you set your mind on creating order and directing your group mates into a more coordinated attack and defense. Needing a high point from which to shout, you climb up the RV, first onto the steps, then onto a sunken windowsill, and finally atop the roof.
      *if m_athletics >= 50
        You easily scramble up the side and get your bearings before
      *if m_athletics < 50
        *set fatigue %+(round((100-sta)/5))
        At the end of your trip up the side, you find yourself gasping and scrambling to swing your body onto the flat surface. You take a a few deep breaths and rest for a moment before standing and
      walking to the front of the RV.
      
      "Everyone, listen up! We need to focus and work together."
      
      *if m_leadership >= 60
        You spot a unified pause for a split second among the survivors, and many look in your direction, ready to respond to your orders.
      *if (m_leadership < 60) and (m_leadership >= 45)
        Several of the survivors react to your voice, though some continue acting on their own.
      *if m_leadership < 45
        All of the survivors continue acting on their own—none of them react to the sound of your voice.
      Assessing the situation, you work out a plan in your head and call out to specific members of your group to carry out your strategy.
      
      *if m_leadership >= 60
        "We need to clear out the main gates. Madison and Dante, focus your fire on the zombies coming in now. Give them time to get those gates closed.
        *if lopez_join
          ${lopez},
        *if not(lopez_join)
          Everyone,
        kill any attacking
        *if bailey_join and tommy_join
          Brody, Bailey, and Tommy.
        *if (bailey_join = false) and tommy_join
          Brody and Tommy.
        *if bailey_join and (tommy_join = false)
          Brody and Bailey.
        *if (bailey_join = false) and (tommy_join = false)
          Brody.
        Keep those infected off our people.
        *if nora_join and jillian_join
          Nora and Jillian,
        *if nora_join and (jillian_join = false)
          Nora,
        *if (nora_join = false) and jillian_join
          Jillian,
        *if nora_join or jillian_join
          kill the infected in the middle of the yard.
        Everyone else, run into the parking lot. Close those gates. Pin the zombies inside the yard."
        
        Every name you call snaps to attention and follows your order, like you've trained these people for years. The zombies inside the yard dwindle in numbers, and the main gates sit halfway closed.
      *if (m_leadership < 60) and (m_leadership >= 45)
        "Get those main gates closed. Focus your fire on the zombies running in. You guys up front, get those gates shut.
        *if kelly_join
          Kelly,
        *if parker_join
          Parker,
        *if kelly_join or parker_join
          get to safety.
        Everyone else, watch your crossfire. Bring down the zombies inside. Head shots kill but leg shots bring them down."
        
        Many of the survivors listen to your orders, though the noise in the Junkyard competes with your voice. The main gates move closer to the center, and the many of the zombies inside the yard have fallen to the defenders.
      *if m_leadership < 45
        "The main gates are closing. We need more people closing the gates.
        *if lopez_join
          Lopez, shoot that one over there!
        Jaime, run over and get those two.
        *if kelly_join
          Kelly,
        *if parker_join
          Parker,
        *if kelly_join or parker_join
          stop what you're doing.
        Rachel, what are you doing? Madison, kill that one. Wait, everyone listen! Stop running everywhere."
        
        None of the names you call respond to your orders, though the noise in the Junkyard drowns out your voice. The main gates remain in the same position as more zombies shamble into the yard.
      
      Sean climbs onto the top of the camper van and cups his hands around his mouth. He shouts, "We need more people killing that pile at the front. You two over there, fire at that group now!"
      
      Hearing his words, you shout, "Sean,
      *if m_leadership >= 60
        stand down. I'm in control here. Everyone, keep with the plan. Main gates need to close."
        
        Sean waves to you and climbs off the camper van. Once his feet hit the ground, he joins Rachel and Jaime to defend the middle of the yard.
      *if (m_leadership < 60) and (m_leadership >= 45)
        get off that van. Everyone, listen to me, not to Sean. I'm the leader. We need to get those gates closed."
        
        Sean hesitates and shrugs that you, but climbs off of the camper van. He sticks to the sidelines and attacks a zombie running past him.
      *if m_leadership < 45
        Shut up! Everyone needs to listen to me. Come on, listen up. We need to work together!"
        
        Sean cups his mouth with his hands again and shouts across the yard. "We need to get those gates closed. Come on, do it."
      
      *if sop <= 2
        *set group_bonus +(m_leadership/14)
      *if sop = 3
        *set group_bonus +(m_leadership/8)
      *if sop >= 4
        *set group_bonus +(m_leadership/10)
      *set allegiance %+(round(m_leadership/6))
      *goto JunkyardBattleKnit
  #Head into the RV. My safety is my primary concern.
    *set leader_role %-15
    You have no plans on dying here today. It makes no sense to you to put yourself in danger. 
    *label HeadInRV
    With a clear path to the RV, you cross the yard and pull open the door.
    *if nora_join and jillian_join
      Nora and Jillian glance over their shoulders at you and then turn their
    *if nora_join and (jillian_join = false)
      Nora glances over her shoulder at you and then turns her
    *if (nora_join = false) and jillian_join
      Jillian glances over her shoulder at you and @{((main_ro = "Jillian") or (second_ro = "Jillian")) smiles. "Hey sugar, come to check on me?" She turns her|then turns her}
    *if nora_join or jillian_join
      focus back to firing at the infected in the yard.
    *if ((nora_join = false) and (jillian_join = false)) and not(dependent)
      No one's inside, and you turn and locked the door to keep it that way. Once that's done you rush over to the side window and push aside the curtain. The complete mayhem in the yard continues as zombies run everywhere, and the survivors work to defend the place you're trying to make your safe haven.
    *if dependent
      
      "${name_call}! Did you see what happened?" your nephew shouts as you step to the center of the RV. He holds a revolver in his hand. "Mr. Eli didn't know what he was doing. He went over, and he opened the gate. I know he didn't mean to do it."
      
      "We'll worry about that later. I'm glad you came in here.
      *if discussed_nephews_revolver
        Are you staying out of the way?"
        
        He shakes his head. "I'm
      *if not(discussed_nephews_revolver)
        Where did you get that gun?"
        
        *gosub_scene Part3Events NephewRevolver
        
        "I never @{(honor >= 50) thought I'd see the day when you hold the gun in your hand."|even thought to give you a gun."}
        
        "I know what I'm doing with it, and I'm
      trying to help. I shot one in the head. It was getting close to the RV and I shot it."
      
    Something hits the side of the RV and shakes it. You rush to a side window and look out. A tall zombie slams his body against the side of the RV, shaking it. He hammers it like an angry gorilla and claws at it like his sharpened fingers can break through the aluminum. A good chunk of skull is missing, exposing flattened, dark brown brain with a putrid slime covering. One of his lips hangs off below his chin like a piece of gum is stuck there and his teeth gnash and click as he pounds the vehicle.
    
    A revolver fires from inside the cabin.
    *if dependent
      ${dep_name} stands on a milk crate at another window and holds up his handgun. The gun pops again, and the body of the infected jerks from the impact. A hole on the cuff of his shoulder opens and bleeds. He moves towards the sounds of the gunfire, his nails screeching along the outside wall and his head tilted back as he cries out. Howls whistle through the missing part of his teeth and mouth.
      *if nora_join
      
        "Get it, boy," Nora says, cheering him on. She wears a proud smile and presses her face against another window.
      *if jillian_join
        
        Jillian moves behind him and looks over his head.
        
      Your nephew tightens his jaw and tilts his head forward, pure focus on his face. He adjusts his grip and points the barrel outside the window. Two more shots fire in rapid succession. The tall infected man staggers as the bullets hit, one cracking his jawbone and the other puncturing his ear. He collapses to the dirt. Your nephew stares open mouth at the dead zombie.
      *if nora_join
      
        Nora pats his back which shakes his entire body. "Good job. You're already a better shot than me. Bring on those f…fumbling idiots."
      *if jillian_join
      
         "That was amazing." Jillian bends and kisses his cheek.
         
      @{(dep_treat >= 50) "Awesome! You did a great job, and I'm really proud of you,"|"You did what you had to do. Now stay alert for any others. There times to celebrate when the fight is over,"} you say.
      
      ${dep_name} nods, holds out the pistol, and aims it around the yard like he's searching and waiting for any new threats.
      *goto RVKnit
    *elseif jillian_join
      Jillian holds out her revolver with both hands, her whole body moving with each squeeze of the trigger like she's throwing a fishing line. Her bullets miss every time.
      
      *if ranged >= 45
        @{((main_ro = "Jillian") or (second_ro = "Jillian")) You walk behind her, wrap your arms around her, and steady her hands. "Relax, baby. Extend your arms, aim, and squeeze the trigger. You're safe in here, so think of this is practice."|"Jillian, stop swinging your arms around. Extend your arms, take a deep breath, and let it out as you squeeze the trigger. Aim along the barrel and relax."}
        
        "Okay, okay," she says.
      *if ranged < 45
        "You can do this, Jillie," she says to herself. She extends her arms, takes a deep breath, and squints one eye.
      *gosub RVShot
      
      Jillian holds her hands up in the air and dances in place. "I did it, I did it."
      *if (main_ro = "Jillian") or (second_ro = "Jillian")
        Still in your arms, she spends and kisses your lips.
      
        "Nice work. That was excellent," you say.
        
        "Thanks. You can reward me later."
      *if (main_ro != "Jillian") and (second_ro != "Jillian")
        @{(morality >= 50) "Good job. That was really impressive,"|"You did it. I didn't think it was going to go down,"} you say.
        
        Jillian backs away from the window and presses her body against the wall of the RV. "I'm trying. I still can't believe this is all happening. Even when we are safe, we're never safe."
      *goto RVKnit
    *elseif nora_join
      Nora holds out her revolver with one hand and braces herself with the other on an overhead cabinet. The tall infected man staggers from a bullet hole through his jaw, and he slides along the RV, scraping his nails on the below surface.
      
      "I got this," Nora says and steadies her arm holding the pistol.
      
      *gosub RVShot
      
      *if morality >= 50
        "My shot, Nora," you say.
        
        "Thanks.
      *if morality < 50
        "Oh wow, you killed it," you say.
        
        "Of course I did.
      I just pictured he was my first husband. Never had a chance."
      *goto RVKnit
    *elseif ray_join
      Ray stands by inside window, pointing ${ray_his} finger out at the infected man. "Pew pew." Ray doesn't hold a weapon, but somehow you hear gunshots. When you look back at the tall zombie outside, he stumbles and drops to the floor with a hole in the back of his head. Turning back to Ray, he blows on the end of ${ray_his} finger and stuffs ${ray_his} hand into ${ray_his} pants pocket.
      *goto RVKnit
    *else
      Or at least you thought it did. When you look around, you assure yourself no one else is inside the vehicle. You hear gunfire again and realize the sound is bleeding through the walls of the RV. The tall zombie drops to the ground with a bullet in his head, and you stare across the yard at Reilly who aims his large revolver in the infected man's direction.
      *goto RVKnit
    
    *label RVKnit
    
    You wait out the rest of the battle inside, watching the numbers of infected slowly dwindle and the main gates closing. When the last zombie falls to a bullet, you open the door of the RV and step outside.
    *goto JunkyardBattleKnit
  *if main_ro != ""
    #Help ${main_ro}. I'm worried about ${main_ro_him}.
      *set leader_role %-10
      *set helping_ro true
      *set main_target main_ro
      *if main_ro = "Bailey"
        *set main_target_he "she"
        *set main_target_him "her"
        *set main_target_his "her"
        *goto CloseGates
      *elseif main_ro = "Brody"
        *goto CloseGates
      *elseif main_ro = "Jaime"
        *goto JaimeBattle
      *elseif main_ro = "Gina"
        *goto GinaBattle
      *elseif main_ro = "Jillian"
        *set main_target_he "she"
        *set main_target_him "her"
        *set main_target_his "her"
        *goto JillianBattle
      *elseif main_ro = "Kelly"
        *set main_target_he "she"
        *set main_target_him "her"
        *set main_target_his "her"
        *goto KellyBattle
      *elseif main_ro = lopez
        *goto LopezBattle
      *elseif main_ro = "Madison"
        *set main_target_he "she"
        *set main_target_him "her"
        *set main_target_his "her"
        *goto MadisonBattle
      *elseif main_ro = "Rachel"
        *set main_target_he "she"
        *set main_target_him "her"
        *set main_target_his "her"
        *goto RachelBattle
      *elseif main_ro = "Reilly"
        *goto ReillyBattle
      *elseif main_ro = "Rosie"
        *set main_target_he "she"
        *set main_target_him "her"
        *set main_target_his "her"
        *goto RosieBattle
      *elseif main_ro = "Tommy"
        *goto CloseGates
      *elseif main_ro = "Woody"
        *goto WoodyBattle
      *else
        *goto AttackJY
  *if second_ro != ""
    #Help ${second_ro}. I'm worried about ${second_ro_him}.
      *set leader_role %-10
      *set helping_ro true
      *set main_target second_ro
      *if second_ro = "Bailey"
        *goto CloseGates
      *elseif second_ro = "Brody"
        *goto CloseGates
      *elseif second_ro = "Gina"
        *label GinaBattle
        *set gina_faction %+(round(empathy/6))
        You find Gina near the front of the yard using her shotgun as a club against the skull of the zombie. When she sees you coming, she gives you a nod and swings wide at another infected pushing through the gate.
        
        You stick close to her to fight off the swarm. You're a bit distracted from combat since you're more worried about her, but you draw your…
        *gosub BattleTarget
        
        *gosub BattleVignette
        @{(attack_result >= 3) The two of you stand side-by-side picking off the infected in the middle of the yard. You move like dancers moving around one another, no one getting in the line of fire or arc of a swing.|As the fight rages on, you find yourself overwhelmed by the chaos, and Gina fights by your side, keeping the infected from attacking you.}
        *goto JunkyardBattleKnit
      *elseif second_ro = "Jaime"
        *label JaimeBattle
        *set jaime_faction %+(round(empathy/6))
        You stay with Jaime and move with him to fight off a small pack of zombies in the middle of the yard. When he sees you by his side, he gives you a nod just before grabbing a two-by-four of wood and smashing it into the skull of the first infected.
        
        You stick close to him to fight off the swarm. You're a bit distracted from combat since you're more worried about him, but you draw your…
        *gosub BattleTarget
        
        *gosub BattleVignette
        @{(attack_result >= 3) The two of you stand side-by-side picking off the infected in the middle of the yard. Jaime's large body blocks away more than once, and half of the fight involves you maneuvering around him.|As the fight rages on, you find yourself overwhelmed by the chaos, and Jaime fights by your side, keeping the infected from attacking you.}
        *goto JunkyardBattleKnit
      *elseif second_ro = "Jillian"
        *label JillianBattle
        *set jillian_faction %+(round(empathy/6))
        You cut toward the RV and dodge around a pair of infected scrambling toward the parking lot. A fog of gun smoke hangs in the center of the yard, and you wave your arms through it.
        *goto HeadInRV
      *elseif second_ro = "Kelly"
        *label KellyBattle
        *set kelly_faction %+(round(empathy/6))
        You rush across the middle of the yard, dodging infected and maneuvering around your fellow teammates. Kelly @{parker_join and Parker hold|holds} a swarm of zombies away with planks of wood as @{parker_join they back|she backs} into the parking lot. You have no choice but to draw a weapon.
        *gosub BattleTarget
        
        *gosub BattleVignette
        
        You @{(attack_result >= 3) rush over to Kelly and dispatch another of the infected attacking her. "Get into the parking lot and close the gates!"|You run to meet Kelly as she closes the gate to the parking lot. You slip past her and hear the clang of metal on metal.}
        *if parker_join
        
          Parker tosses aside his plank of wood now covered in dark brown blood. "This can't be happening."
        
        Kelly falls into you and wipes her eyes with the back of her hands. She trembles against you, and you feel her breathing hard in your arms.
        *goto JunkyardBattleKnit
      *elseif second_ro = lopez
        *label LopezBattle
        *set lopez_faction %+(round(empathy/6))
        You rush over to ${lopez} who holds up his carbine, popping shots, turning, and firing some more. It's a dance of death, and you spot a mix of excitement and worry on his face. Blood speckles his pants and shirt, and he stands in a puddle of dark fluid. As you reach his side, his hand flies out to grip your shoulder. When he recognizes you, he lets you go and backs away as more infected swarm the middle of the yard.
        
        "Good to see you. Now help me kill these bastards."
        *gosub BattleTarget
        
        *gosub BattleVignette
        You back into someone in turn to spot ${lopez}. @{(attack_result >= 3) "Nice work. We've almost killed them all. Just a few more to go.|"Stay behind me. I'll keep you safe.} I can't believe this happened."
        *goto JunkyardBattleKnit
      *elseif second_ro = "Madison"
        *label MadisonBattle
        *set madison_faction %+(round(empathy/6))
        You rush along the RV, keeping your head low, and to you reach the storage container. Madison stands atop of it, running along its length and firing down with her rifle. She's breathing fast—too fast—and she's licking her lips over and over again, nervousness showing on her face. A few of her shots go wide while others find their mark, though it takes a few bullets to bring them down with head shots.
        
        You yell up to her. "Maddie, @{(ideal >= 50) just relax. You got this. You're our best shot. This is just target practice out on your grandfather's range. I'm with you now. Everything's fine."|calm down. You shouldn't be missing. Our group needs you, so if you don't relax, people will die. None of them can reach you, so take your time and aim for the head."}
        
        She pauses and looks over at you. She swallows hard, puffs out a hard breath, and nods to you. Pivoting her body towards the swarm below, she fires once. You track her shot across the yard where it blows out the skull of the zombie.
        *if dante_join
        
          "Glad you are here, ${firstname}," Dante says and rolls his eyes in Madison's direction.
          
        As more come in the main gate, you reach for a weapon.
        *gosub BattleTarget
        
        *gosub BattleVignette
        You stick to the outside of the storage container, @{(attack_result >= 3) killing off any that try to climb to attack Madison. When she spots you below her, she flashes a weak smile and refocuses on her work killing zombies.|Trying your best to keep zombies off the surface. At one point, Madison looks over the side and flashes a weak smile. She then disappears, and you hear the sound of her rifle firing again.}
        *goto JunkyardBattleKnit
      *elseif second_ro = "Rachel"
        *label RachelBattle
        *set rachel_faction %+(round(empathy/6))
        You run beside Rachel as she advances to the center of the yard, the pistol in her hand flashing with precise movements and popping off rounds in quick succession. Her eyes lock on each target, and before its body drops, she's lining up the next shot.
        
        A new wave of zombies come into the main gates and fill the middle of the Junkyard. You draw weapon…
        *gosub BattleTarget
        
        *gosub BattleVignette
        
        Rachel flashes you a smile as the two of you come together again in the middle of the yard. @{(attack_result >= 3) "Nice work. I don't know where all of these came from, but the tide has turned in our favor. A few more to go."|"Stay close to me. It looks like they've gotten the gates closed, so we just need to kill the ones in the yard."}
        *goto JunkyardBattleKnit
      *elseif second_ro = "Reilly"
        *label ReillyBattle
        *set reilly_faction %+(round(empathy/6))
        You run back to the garage where Reilly sits on the floor with his back to the bumper of Eli's car. He glances up at you with a smile. When he pulls his hand away from his head, a new stream of blood runs down his face. You rush to a tool chest on the other side of the car and yank open drawers until you find a clean cloth which you place against the wound on his face.
        
        @{(medicine >= 45) "You're going to need stitches to close that up. Let me get some supplies,"|"Your head is bleeding too much. I need to find somebody to help you. Maybe you need stitches,"} you say.
        
        Reilly reaches out and grips the back of your neck. "No, you need to get out there and help them defend this place. I'll get stitched up later. Okay?"
        
        You nod, and he pulls you into a kiss. His lips taste salty, and you see dried tears down his cheeks. Pulling away, you run your thumb through the line of tears. "I'll be back soon." You turn and walk sideways into the yard, drawing your…
        *gosub BattleTarget
        
        *gosub BattleVignette
        
        Stepping to the edge of the garage, you see the full view of the Junkyard.
        *goto JunkyardBattleKnit
      *elseif second_ro = "Rosie"
        *label RosieBattle
        *set rosie_faction %+(round(empathy/6))
        You crouch and run along the side of the Junkyard, keeping low until you reach @{driver_join Rosie. She stands over a pack of infected in a pile towards the front of the yard. They dig and claw at something in the middle of the circle, each of them struggling to push closer to the source. Blood splattered everywhere. The smell of rotting flesh rises. Somewhere beneath the twisted bodies of the undead, a pair of legs with leather boots stick out, twitching. You recognize the boots—they're ${Driver}'s.|the camper van. Rosie fires round after round, burst after burst, painting the zombies with bullets and streaking the floor of the Junkyard with their blood. Her hair is pulled back, and her eyes are squinted and focused. She's murmuring to herself, and only when her submachine gun runs dry does she take a break from killing.}
        
        More of the infected shamble through the main gates, which are now half closed. A few cut towards the camper van in a swarm, and you have no choice but to fight. You draw your…
        *gosub BattleTarget
        
        *gosub BattleVignette
        
        You fight on and stand near Rosie to protect her from any zombies in her blind spots. With her weapon out of ammo, she clubs any infected close to her with her teeth gritted and ponytail spinning like a propeller behind her. She attacks with raw energy, uncaring of her own safety. She sees death and brings death.
        *goto JunkyardBattleKnit
      *elseif second_ro = "Tommy"
        *goto CloseGates
      *elseif second_ro = "Woody"
        *label WoodyBattle
        *set woody_faction %+(round(empathy/6))
        You catch up to Woody who has rushed into the center of the yard and stands close to the camper van with his rifle raised. He hesitates, fires off a shot, and blows out the knee of one of the infected near to the main gate. As you run up by his side, he gives you a nod and points at pile of zombies at the far end of the yard.
        
        "Bastards got one of us. I don't know which one, but one o' our group lies underneath that pile, dead to rites, God help 'em."
        
        You blink hard and squint to focus your eyes on the writhing pack of undead. One of your group is dead. How could this have happened? How did those gates get open?
        
        As more of the infected rush through the main gates, you join the fight and reach for your…
        *gosub BattleTarget
        
        *gosub BattleVignette
        
        You stick by Woody's side and fight against the remaining infected until the main gates of the Junkyard have been closed.
        *goto JunkyardBattleKnit
      *else
        *goto CloseGates
  #Run along the side of the Junkyard to help close the main gates.
    *set leader_role %+10
    *goto CloseGates
    
*label CloseGates
*if main_target = ""
  *set main_target "Brody"
You crouch and run along the side of the Junkyard, keeping low until you reach the front gate. Fred and Kevin stand on ladders positioned against the top of the fence, so they can fire down with rifles at the infected still rushing across the main road. ${main_target} has ${main_target_his} fingers laced through the chain-link and leans into it with ${main_target_his} legs extended outward and feet pushing into the dirt. Several zombies on the other side fight against ${main_target_him} in a reverse tug-of-war. As you make your approach, you gain speed and ram your shoulder into the gate on ${main_target}'s side. The two infected bounce back a yard allowing ${main_target} to swing the gate a few feet shut. A few more zombies rush against the outside of the same gate, and they snarl and snap their teeth.

*if main_target = "Bailey"
  *set bailey_faction %+(round(empathy/6))
  "Oh thank God you're here. If you can help me push this or even take care of some of these zombies, me and Brody can get the gate shut," she says through grunts as she shows that the gate.
*if main_target = "Brody"
  *set brody_faction %+(round(empathy/6))
  "Thanks for the hand. Just keep them off me, and I'll have this gate closed in no time," he says through one long groan.
*if main_target = "Tommy" 
  *set tommy_faction %+(round(empathy/6))
  "Glad to see you, ${firstname}. Watch my back, and I'll get this closed. I swear I will," Tommy says.

$!{main_target_his} words turn true in that moment as a few of the swarm come around the gate.

You raise a weapon to fight…
*gosub BattleTarget

*gosub BattleVignette

Moving back to ${main_target}, you see ${main_target_he} has
*if main_target = "Brody"
  the two gates touching in the middle, and he slips a chain around the lock to hold it shut.
*if main_target != "Brody"
  ${main_target_his} gate touching the opposite one, and Brody slips a chain around it to lock it shut.
Only a few other infected remain in the yard, and Rachel, Jaime, and the others work to finish them. Madison @{dante_join and Dante climb the ladders|climbs a ladder} at the edge of the fence to shoot over it as a few stray infected still coming along the main road. Fred sits on the ground with his hand on his chest and takes in deep, wheezing breath. Kevin strides past you, looking left and right, a look of fear and confusion on his face

"Where's my father? Has anyone seen my father?"

Once the gate is locked, ${main_target} collapses against it. $!{main_target_he} flashes a smile which quickly fades as ${main_target_he} looks past you at the corpses all around.
*if helping_ro
  You step over to ${main_target_him} and rub @{(main_target = "Bailey") her shoulder|his chest}.

  "Good job getting that closed."

  *if main_target = "Bailey"
    She shakes her head and wraps her arms around your neck. When you hold her close, you feel her body shaking and listen to her soft sobs.
  *if main_target = "Brody"
    "I was too slow. I just couldn't get the gate closed fast enough. I just couldn't…" He says as his words trail off, and he falls into your arms.
  *if main_target = "Tommy"
    "It should've never happened. I can't believe this." He lifts his palms to his eyes and rubs them dry.
    
*label JunkyardBattleKnit
Only a few remaining infected shamble in the middle of the yard, and Rachel, Jaime, and the others bring them down.
*page_break
With the Junkyard closed off, you stare at the carnage in the middle of the yard. A few dozen bodies of the infected lie scattered about, some still twitching or squirming as the virus won't let them rest in peace. A bitter silence hangs across the living. This is not like the battle on the hill—the hill was not your home.
*if ideal >= 65
  In the short time here, you felt secure and felt the potential to make this more than just a place you happened to find on the road to salvation. Will you ever feel safe again? It's something you'll have to strive for and a neverending goal to reach. As you look across the faces of the survivors, you know it's not a time to talk about the future. Now is only time to mourn.
*if (ideal < 65) and (ideal > 35)
  The Junkyard is not your home yet, but it's on its way. Or at least it was. Maybe if you can increase defenses and work harder, it can be made into a true safe haven. To say this battle is a setback is an understatement. You've taken things too lightly and let your guard down for a moment. When you came inside, the gates were open. Why were they open?
*if ideal <= 35
  Ever since you made it into the Junkyard, you wanted to believe this place was safe. You knew it wasn't. Nowhere is safe in this world. The dead now claim it as their own, and there is no escape. Even if you struggle to fix a chain-link fence and order a few people on watch duty, when will it be enough? It wasn't enough now.
*if church_join or driver_join
  *set scripted_death true
*if church_join
  *set church_join false
  *set church_alive false
  *set church_killed 9
  *set church_killed_by 3
  *set church_saw_kill 1
  *set junkyard_battle_killed +1
  *if second_in_command = "Church"
    *set second_in_command ""
*if driver_join
  *set driver_join false
  *set driver_alive false
  *set driver_killed 9
  *set driver_killed_by 3
  *set driver_saw_kill 1
  *set junkyard_battle_killed +1
*if gina_join and (junkyard_defense < 6)
  *set gina_join false
  *set gina_alive false
  *set gina_killed 9
  *set gina_killed_by 3
  *set gina_saw_kill 1
  *set junkyard_battle_killed +1
  *if second_in_command = "Gina"
    *set second_in_command ""
*set reilly_hurt true
*gosub_scene Part3Events CheckAvailable
*gosub_scene Part3Events GroupOD
*set group_offense +group_bonus
*set group_defense +group_bonus
*if (group_offense + junkyard_defense) < 60
  *if main_target = "Bailey"
    *set kelly_join false
    *set kelly_alive false
    *set kelly_killed 9
    *set kelly_killed_by 3
    *set kelly_saw_kill 1
    *set junkyard_battle_killed +1
    *if second_in_command = "Kelly"
      *set second_in_command ""
  *if main_target != "Bailey"
    *set bailey_join false
    *set bailey_alive false
    *set bailey_killed 9
    *set bailey_killed_by 3
    *set bailey_saw_kill 1
    *set junkyard_battle_killed +1
*if (group_defense + junkyard_defense) < 45
  *if main_target = "Tommy"
    *set woody_join false
    *set woody_alive false
    *set woody_killed 9
    *set woody_killed_by 3
    *set woody_saw_kill 1
    *set junkyard_battle_killed +1
  *if main_target != "Tommy"
    *set tommy_join false
    *set tommy_alive false
    *set tommy_killed 9
    *set tommy_killed_by 3
    *set tommy_saw_kill 1
    *set junkyard_battle_killed +1
    
Near the main house, Kevin kneels on the ground over the body of a fallen man. As you walk closer, you see the young man holding up Eli's head and cradling him in his arms. Tears fall and he rocks back and forth with his father held close to his chest. Bite marks cover the old man's body with one large gash low on his throat.

Rachel and Jaime step beside you as you walk in closer. Kevin looks up at you, his face streaked with tears, sobbing and almost unintelligible.

"It wasn't his fault. He didn't know, didn't understand. He thought they were just people, people who needed a place to stay, just like you…just like you."
*if junkyard_battle_killed > 0

  Brody calls from the front gate. You, Jaime, and Rachel rush forwards, stepping over bodies.
  *if bailey_killed = 9
    
    On the left side of the main gate, Bailey's body sits against the fence. Her face above her eyes has been torn off, leaving exposed skull which has been gouged and broken. Her hands are bloodied and bruised and around her lie the bodies of two dead infected.
    
    *if main_target = "Bailey"
      You drop beside her and move forward on hands and knees until you're close to her body. Her mouth hangs open, and a fly crawls out of it. You wave your hand to chase the insect away. "Can someone grab a blanket or a towel or something to cover her. She shouldn't be seen like this."
      
      Rachel motions to someone in the distance, though you can't see who it is.
      
      You reach for her hand but slide up to her forearm instead. Her hands are all black and blue, and you're almost afraid to touch them, though you know she cannot feel pain anymore. A moment passes, and Rachel hands you a long blanket and helps you cover Bailey. Blood seeps into the cloth from underneath it.
    *if main_target != "Bailey"
      You push aside the infected bodies and stand over the body of the young woman. Rachel walks up by your side and stares down at her, her head hung and eyes teary. @{(rachel_faction >= 50) You feel her take your hand, and she's shaking.|She places her hands on top of her head, lacing her fingers together.} "I save her once but couldn't see her again."
  *if gina_killed = 9
  
    *gosub ZombiePile
    
    Gina.
    
    Her body turns and a river of blood pours out of her parted lips. You @{((gina_faction >= 50) and (humanity >= 50)) take two steps forward and drop to your knees. You drag your hands through the dirt and reach out to touch her.|look away for a moment and then back at her. Crouching beside her, you reach out.} Her skin's cold and it's bathed in sweat. Her open eyes stare to the sky. Flecks of green swirl in the white irises. You run your hand over her eyelids and close them for the last time.
  *if church_killed = 9
  
      *if zombie_pile
        "Oh my gosh, it's the reverend," Billie shouts.
      *if not(zombie_pile)
        *gosub ZombiePile
        
        Church.
      
      You walk over to Church's body. His stomach lies half open exposing all the way down to his spinal column. One of his arms has been stripped to the bone and one leg is twisted and hanging from his hip.
  *if driver_killed = 9
  
      *if zombie_pile
        You hear crying from the side of the yard. Even from a distance, you can make out the body of ${driver} dead along the side fence.
      *if not(zombie_pile)
        *gosub ZombiePile
        
        ${driver}.
        
      As you step closer, you see
      *if rosie_join
        Rosie crying over his body. When she notices you, she puts on a smile. "He's going to be okay. He's just kidding around. No one knows his sense of humor like I do. Come on, Edgar. Wake up."
      *if not(rosie_join)
        Billie crying by his body. "I barely knew him, but he was so nice to me."
        *if bailey_join
        
          Bailey walks over, crouches by her side, and touches her shoulder. Billie gives her a hug, and Bailey comforts her. She looks over at you with a pout, her eyes red and swollen.
        
        ${driver} lies on his side with large gouges of flash missing from his stomach and legs. One arm is badly broken, and he still holds a bloodied buck knife in the other hand. A pile of viscera sits in front of his corpse.
        
        @{(driver_faction >= 60) You step over and crouch by his side. Somehow his face appears unmarred by the zombies, and you brush his hair with your fingers one last time.|Jaime steps over and crouches by his side. He puts a hand near ${driver}'s body but leaves it hovering like he's too afraid to touch it. "Rest in peace, brother. I'm so glad I met you in my journey."}
  *if kelly_killed = 9
    
    *if junkyard_battle_killed = 0
      Brody nods his head towards the parking lot
    *if junkyard_battle_killed > 0
      Someone calls @{leader your name|${group_leader}} from the parking lot,
    and you rush to the gate separating the two yards. @{parker_join Parker sits on the ground next to Kelly's body.|Sean stands over another body, this one Kelly's.} Claw marks cover her, and her face has a bluish tinge like she was smothered before she died.
    
    @{parker_join "There were too many of them. They were trying to get into the parking lot. She shoved me in and closed the gate. They rushed on top of her, and I watched her screaming until they pushed so hard she couldn't breathe." He breaks down and lowers his head to cry.|"I was fighting and trying to get to her. Zombies had her pinned against the gate. She was screaming for help and then her screams got muffled. I think they smothered…" He pauses and looks away. "I tried to get to her."}
    
    You
    *if main_target = "Kelly"
      sit next to Kelly and pull in close to her body, taking her hand in yours. It's bloodied with dirt caked beneath the fingernails. Her face shows a mix of fear and sadness, and death locks the expression forever. You lean over and kiss her forehead. Her skin's cold, and you leave your lips against her for a moment to feel it come alive with your warmth for at least a little while.
    *if main_target != "Kelly"
      *if kelly_faction >= 50
        crouch and touch her arm, feeling her cold skin. She looks oddly peaceful in this moment, though you cannot imagine what she felt in those last moments.
      *if kelly_faction < 50
        stare down at her face which looks oddly peaceful. "She should have never died like this—no one should. @{parker_join "Sorry for your loss, Parker. I'm sorry for all of us. She was everyone's friend, but I know how much she meant to you."|"I'm sure you did your best, Sean. This place was overwhelmed. We all did our best."}
  *if woody_killed = 9
    @{(junkyard_battle_killed = 0) |} He nods his head back towards the RV. Jaime catches sight of something in that direction, and his skin turns pale.|Jaime paces in front of you, but then he stops and looks towards the RV.} He breaks into a trot, calling out, "Woody! Woody!"
    
    You follow after him. A pile of bodies lie against the side of the RV, and among them you spot a familiar face, Woody. Jaime's body slams into the side of the vehicle, which shakes beneath the force, and he grabs corpses and tosses them out like bags of sand. Rushing in, you help him drag away the last bodies and then slide Woody out.
    
    "Be careful with him," Jaime says and cradles his cousin's head in one hand while scooping his back with the other hand.
    
    You take Woody's legs, and the two of you carry him out to a clear strip of the yard. His throat has been ripped open and stomach and back have huge bite marks with most of the skin mangled. One hand is missing four fingers, the ends serrated where they were chewed off.
    
    *if main_target = "Woody"
      You slide up besides Jaime and kiss Woody's mouth. His lips hold a bitter coldness, and you caress his face and hold him close to you. "He's so cold. He shouldn't be this cold."
    *if main_target != "Woody"
      Jaime sits on the floor, lowers Woody's body over his own legs, and cradles his head in his arms. "He's so cold. Can someone get a blanket? Maybe we just need to get him warm again."
      
      *if jaime_faction >= 50
        You kneel beside Jaime and put your arm around him. "I'm so sorry, Jaime. We can get him a blanket."
        
        Seeing Sean nearby, you rise and walk over to him. "Hey, can you go into the main house and grab a blanket."
        
        He nods and runs off. You return to Jaime and sit with him as he walks back and forth with Woody in his arms.
        *if tommy_killed != 9
          You stay with him for a little while. Sean brings over a blanket, and Jaime unfolds it over Woody's body. You take the end and drape it over his head, and Jaime breaks down in deep sobs.
      *if jaime_faction < 50
        You shake your head and walk away, letting your friend grieve for his cousin.
  *if tommy_killed = 9
    
    @{(junkyard_battle_killed = 0) He nods towards the right side gate, where you see Tommy lying on the ground.|A voice calls out for help, and you run towards the sound. Brody and Madison stand before a body, and as you move closer you recognize Tommy lying on the ground against the far corner of the main gate.} His eyes are closed and he looks asleep with no visible marks to the front of his body. His body slides against the chain-link fence, and as gravity turns him over, you see a body torn apart and ravaged with violence. Large chunks of flesh have been torn out, and the back of his skull has long puncture wounds like something dug at the base of his brain. Blood covers his hands, which you failed to see since both were tucked under his legs. Bruises cover his knuckles and several fingers are broken at angles.
    *if main_target = "Tommy"
    
      You step over to Tommy and feel weak in your knees. Reaching out to the gate, you steady yourself and keep your balance as you lower yourself to the ground.
      
    "He was a fighter. He forced that gate closed even when they were clawing at his back. He never stopped, not until he…" Brody breaks down and buries his face in Madison's hair as she clings to his body.
    
    @{(humanity >= 50) |}
  *if main_target != ""
    *set stress %+(round((120-wil)/5))
    *set m_health %-(round((110-sta)/5))
    
"How did this happen?" Rachel asks, her voice stern and powerful.

Sean steps next to her and blows out a long sigh before he talks. "Right after you and ${firstname} stepped into the office, we were all still standing around getting to know one another, and I looked over and saw Eli at the main gate. He was waving his arms, and I don't know…it was like he was inviting them in. He pushed the gates wide, and next thing I know, a few dozen infected were coming at us."

Still kneeling, Kevin leans back from his father's body. Dark blood covers his shirt. "He didn't understand. He didn't know the difference between somebody who's infected and someone who's alive. It wasn't his fault."

Sean hold his hands up defensively. "No, I don't mean it was his fault. I'm just saying what happened. I know he wasn't all there."

Billie slams her hand on the hood of the SUV. "It was our fault: you, Fred, and me. We passed that horde on the road and thought we outran them. But we didn't outrun them. We led them right here. It's our fault."

Reilly walks out of the garage, holding a bloodied rag to his head. "It's everyone's fault. Every single one of us. None of us closed those gates. No one kept them closed. We all fell down on the job, and @{(junkyard_battle_killed = 0) Eli|people} died. We're not safe, and we better start acting like we give a shit about our safety, or we're all going to wind up dead."
*if m_health < 50
  *set ptsd true
*page_break Next Chapter
*goto_scene Part3Tasks

*label DeadEnd
*page_break
*goto_scene ending

*label ZombiePile
*set zombie_pile true
Near the front of the main gate, @{lopez_join ${lopez}|Fred} pulls corpses off the pile. A dozen or so infected fought for a piece of warm flesh, dragging one of your own to the ground. Some of the zombies hold half eaten pieces of human meat in their mouths. When he pulls the last body off the pile, you recognize the face of the survivor, though it's covered in blood.
*return

*label RVShot
The gun lets off three more pops, and the zombie's body jerks from the impact. Three bullet holes break out on his face, and he tumbles backwards to the dirt.
*return

*label RachelKillsZ
When it lifts its hands to attack, its head jerks to the side. The infected falls to the ground at the edge of the yard, dark blood spurting from a bullet hole in its left temple. You look around and spot Rachel aiming a pistol in the dead zombie's direction.

You raise your ${curr_weapon} and try to contribute to the fight, but you just can't seem to get the timing right.
*return

*label MeleeZombie
Swinging early, you miss by a few inches, and your momentum exposes your left side. The zombie lumbers forward and swipes at your shoulder, cutting through your skin. Running a wide circle around it,
*return

*label BattleTarget
*set using_primary false
*gosub_scene CheckWeapons
*set ranged_matters false
*set target_difficulty 115
*fake_choice
  #$!{p_weapon}.
    *gosub_scene FightCode UsePrimary
    *set using_primary true
  #$!{s_weapon}.
    *gosub_scene FightCode UseSecondary
*gosub_scene FightCode AttackResult
*return

*label BattleVignette
As a solitary zombie breaks from the swarm, you raise your ${curr_weapon} and
*if curr_type = "ranged"
  *set fatigue %+(round((100-sta)/5))
  take aim.
  *if attack_result >= 3
    *if curr_class = "shotgun"
      A quick blast from your shotgun blows a hole into the side of its head, and it flops to the ground,
    *if (curr_weapon = "compound bow") or (curr_weapon = "recurve bow")
      Your first arrow flies out and impales its forehead. The zombie flops backwards
    *if ((curr_weapon != "compound bow") and (curr_weapon != "recurve bow")) and (curr_class != "shotgun")
      Your shot breaks through the outer edge of his eyesockets, twisting his head. He flops to the ground,
    *set group_offense +((ranged + curr_mod)/10)
    *if ((ranged + curr_mod)/15) >= curr_ammo_num
      *set zombie_kills +curr_ammo_num
    *if ((ranged + curr_mod)/15) < curr_ammo_num
      *set zombie_kills +round((ranged + curr_mod)/15)
    spewing dark blood into the dirt floor of the yard.
     
    *if helping_ro
      *return
    *else
      You keep your ${curr_weapon} raised and take precise shots, avoiding your own teammates while downing any infected that crosses your line of sight. It doesn't take long for you to run out of ammunition, forcing you to reload.
      *return
  *if attack_result < 3
    Your shot goes wide, and the zombie changes course to come at you. With so much going on around you and the discordant sounds blocking your focus, you fire again and miss your target. As it closes in, you back away to the edge of the garage.
    *gosub RachelKillsZ
    
    Only hitting a few infected with body shots, you waste your ammo.
  *gosub_scene FightCode CheckAmmo
  
  *if helping_ro
    *return
  *else
    Luckily the rest of the group kills the remaining zombies.
    *return
*elseif (curr_class = "spray") or (curr_class = "taser")
  *set fatigue %+(round((100-sta)/5))
  rush forward to attack. You @{(curr_class = "spray") spray its face, but it has no effect, the zombie runs straight at you. You spray it|fire at it, shooting out barbs which attach to its chin. Sending a charge of electricity, you see no effect on your target, who continues to run straight at you. You press the Taser} again and run backwards to the edge of the garage. As it closes in, you hear the pop of gunfire and its head jerks to the side.
  
  @{((main_ro = "Rachel") or (second_ro = "Rachel")) "What are you doing? That won't work on a zombie. If you need a lethal weapon, you need to ask,"|"Are you mad? You know that won't work on a zombie. Get your head out of your arse and use a lethal weapon,"} Rachel shouts at you.
  *set rachel_faction %-(round(20-(empathy/6)))
  
  *if helping_ro
    *return
  *else
    Running it back into the middle of the yard, you reach for your backup weapon, but the fight is already over.
    *return
*elseif curr_type = "melee"
  *set fatigue %+(round((120-sta)/5))
  charge at it.
  *if attack_result >= 3
    *set group_offense +((ccw + curr_mod)/10)
    *set zombie_kills +round((ccw + curr_mod)/15)
    Timing your swing, you stop a few feet ahead of your target and bring the weapon in a wide arc.
    *if curr_class = "hack"
      The blade sinks into its forehead, splitting the two sides with the spray of dark fluid. It drops to its knees, and you plant your foot on its chest and yank your weapon out of his head.
    *if curr_class = "club"
      The hard edge strikes its temple, twisting its head sideways. As it staggers and growls, you swing back the other way, connecting on the other side of the head and sending the zombie toppling over to the ground.
    *if curr_class = "sword"
      The blade slices through its forehead, lopping off a chunk of scalp. It drops to its knees, and you thrust again and pierce through its open mouth and out the back of it skull. You kick its chest and yank your blade out of its head.
    *if curr_class = "knife"
      The blade sticks into its temple with a sickening thud. It drops to its knees, and you plant your foot on its chest to yank your blade out of its head.
    The dirt floor of the yard consumes the blood of your victim.
    
    *if helping_ro
      *return
    *else
      You keep your ${curr_weapon} raised and take precise swings, weaving in and out of battle to take down any infected that crosses the middle of the yard.
      *return
  *else
    *gosub MeleeZombie
    you poke the zombie with your weapon but only manage to strike its chest and knock it backwards.
    *gosub RachelKillsZ
    
    *if helping_ro
      *return
    *else
      Luckily the rest of the group kills the remaining zombies.
      *return
*else
  *set fatigue %+(round((120-sta)/5))
  charge at it.
  *if attack_result >= 3
    *set group_offense +((hth + curr_mod)/10)
    *set zombie_kills +round((hth + curr_mod)/15)
    You time your 
    *if mma_style <= 2
      approach, leap in the air, and throw a @{(mma_style = 1) forearm at the top of|side kick at} the infected's head. He wobbles from the blow, but growls and swings his arms to grip you. With him still off balance, you twist your hips and throw an elbow to the side of his head, staggering him and sending him to the ground. You @{(mma_style = 1) drop your knee onto his chest to pin him down and then hammer the top of his skull with forearms|lift your leg high in the air and crash it on his head} over and over until it cracks open. When you @{(mma_style = 1) stand,|stop,} panting from the exertion, you look down at the zombie's dark blood seeping across the dirt floor of the yard.
    *if mma_style = 3
      approach, shoot on his legs, lift him in the air, and slam him shoulder first into the ground. Before he can focus his eyes and teeth on you, you spin him on his chest, grab him by his tattered shirt, raise up his head, and bash it against the dirt floor. Over and over you lift and bash, lift and bash, until his limp body stops resisting, and his dark blood seeps from his broken skull.
    *if mma_style = 4
      approach and anticipate his attack. As his hands shoot out to grip you, you grab one of his wrists, twist your body, and flip him over your shoulder. He tumbles feet over head and slams hard on the dirt floor. Once he lands, you spin him on his chest, kneel on the base of his skull, and twist his neck with all of your might. After a few seconds of exertion, you hear crackling in his skull and then it pops, spewing dark fluid across his back and onto the ground. His body goes limp, and you back away, panting.
    
    *if helping_ro
      *return
    *else
      You weave in and out of battle to take down any infected that crosses the middle of the yard.
      *return
  *else
    *gosub MeleeZombie
    you jab the zombie and open a small wound on its forehead.
    
    *gosub RachelKillsZ
    
    *if helping_ro
      *return
    *else
      Luckily the rest of the group kills the remaining zombies.
      *return